+ "Acquire MUTEX for the dynamic scope of BODY.
+
+If WAIT-P is true (the default), and the MUTEX is not immediately available or
+held by the current thread, sleep until it is available.
+
+If TIMEOUT is given, it specifies a relative timeout, in seconds, on how long
+the system should try to acquire the lock in the contested case.
+
+If the mutex isn't acquired succesfully due to either WAIT-P or TIMEOUT, the
+body is not executed, and WITH-RECURSIVE-LOCK returns NIL.
+
+Otherwise body is executed with the mutex held by current thread, and
+WITH-RECURSIVE-LOCK returns the values of BODY.
+
+Unlike WITH-MUTEX, which signals an error on attempt to re-acquire an already
+held mutex, WITH-RECURSIVE-LOCK allows recursive lock attempts to succeed."
+ `(dx-flet ((with-recursive-lock-thunk () ,@body))
+ (call-with-recursive-lock
+ #'with-recursive-lock-thunk
+ ,mutex
+ ,wait-p
+ ,timeout)))
+
+(sb!xc:defmacro with-recursive-system-lock ((lock
+ &key without-gcing)
+ &body body)
+ `(dx-flet ((with-recursive-system-lock-thunk () ,@body))
+ (,(cond (without-gcing
+ 'call-with-recursive-system-lock/without-gcing)
+ (t
+ 'call-with-recursive-system-lock))
+ #'with-recursive-system-lock-thunk
+ ,lock)))
+
+(macrolet ((def (name &optional variant)
+ `(defun ,(if variant (symbolicate name "/" variant) name)
+ (function mutex)
+ (declare (function function))
+ (flet ((%call-with-system-mutex ()
+ (dx-let (got-it)
+ (unwind-protect
+ (when (setf got-it (grab-mutex mutex))
+ (funcall function))
+ (when got-it
+ (release-mutex mutex))))))
+ (declare (inline %call-with-system-mutex))
+ ,(ecase variant
+ (:without-gcing
+ `(without-gcing (%call-with-system-mutex)))
+ (:allow-with-interrupts
+ `(without-interrupts
+ (allow-with-interrupts (%call-with-system-mutex))))
+ ((nil)
+ `(without-interrupts (%call-with-system-mutex))))))))
+ (def call-with-system-mutex)
+ (def call-with-system-mutex :without-gcing)
+ (def call-with-system-mutex :allow-with-interrupts))
+
+#!-sb-thread
+(progn
+ (defun call-with-mutex (function mutex value waitp timeout)
+ (declare (ignore mutex waitp timeout)
+ (function function))
+ (unless (or (null value) (eq *current-thread* value))
+ (error "~S called with non-nil :VALUE that isn't the current thread."
+ 'with-mutex))
+ (funcall function))
+
+ (defun call-with-recursive-lock (function mutex waitp timeout)
+ (declare (ignore mutex waitp timeout)
+ (function function))
+ (funcall function))
+
+ (defun call-with-recursive-system-lock (function lock)
+ (declare (function function) (ignore lock))
+ (without-interrupts
+ (funcall function)))
+
+ (defun call-with-recursive-system-lock/without-gcing (function mutex)
+ (declare (function function) (ignore mutex))
+ (without-gcing
+ (funcall function))))
+
+#!+sb-thread
+;;; KLUDGE: These need to use DX-LET, because the cleanup form that
+;;; closes over GOT-IT causes a value-cell to be allocated for it --
+;;; and we prefer that to go on the stack since it can.
+(progn
+ (defun call-with-mutex (function mutex value waitp timeout)
+ (declare (function function))
+ (unless (or (null value) (eq *current-thread* value))
+ (error "~S called with non-nil :VALUE that isn't the current thread."
+ 'with-mutex))
+ (dx-let ((got-it nil))
+ (without-interrupts
+ (unwind-protect
+ (when (setq got-it (allow-with-interrupts
+ (grab-mutex mutex :waitp waitp
+ :timeout timeout)))
+ (with-local-interrupts (funcall function)))
+ (when got-it
+ (release-mutex mutex))))))
+
+ (defun call-with-recursive-lock (function mutex waitp timeout)
+ (declare (function function))
+ (dx-let ((inner-lock-p (eq (mutex-%owner mutex) *current-thread*))
+ (got-it nil))
+ (without-interrupts
+ (unwind-protect
+ (when (or inner-lock-p (setf got-it (allow-with-interrupts
+ (grab-mutex mutex :waitp waitp
+ :timeout timeout))))
+ (with-local-interrupts (funcall function)))
+ (when got-it
+ (release-mutex mutex))))))
+
+ (macrolet ((def (name &optional variant)
+ `(defun ,(if variant (symbolicate name "/" variant) name)
+ (function lock)
+ (declare (function function))
+ (flet ((%call-with-recursive-system-lock ()
+ (dx-let ((inner-lock-p
+ (eq *current-thread* (mutex-owner lock)))
+ (got-it nil))
+ (unwind-protect
+ (when (or inner-lock-p
+ (setf got-it (grab-mutex lock)))
+ (funcall function))
+ (when got-it
+ (release-mutex lock))))))
+ (declare (inline %call-with-recursive-system-lock))
+ ,(ecase variant
+ (:without-gcing
+ `(without-gcing (%call-with-recursive-system-lock)))
+ ((nil)
+ `(without-interrupts (%call-with-recursive-system-lock))))))))
+ (def call-with-recursive-system-lock)
+ (def call-with-recursive-system-lock :without-gcing)))