src/code/fd-stream.lisp

   1 ;;;; streams for UNIX file descriptors
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13
  14 ;;;; BUFFER
  15 ;;;;
  16 ;;;; Streams hold BUFFER objects, which contain a SAP, size of the
  17 ;;;; memory area the SAP stands for (LENGTH bytes), and HEAD and TAIL
  18 ;;;; indexes which delimit the "valid", or "active" area of the
  19 ;;;; memory. HEAD is inclusive, TAIL is exclusive.
  20 ;;;;
  21 ;;;; Buffers get allocated lazily, and are recycled by returning them
  22 ;;;; to the *AVAILABLE-BUFFERS* list. Every buffer has it's own
  23 ;;;; finalizer, to take care of releasing the SAP memory when a stream
  24 ;;;; is not properly closed.
  25 ;;;;
  26 ;;;; The code aims to provide a limited form of thread and interrupt
  27 ;;;; safety: parallel writes and reads may lose output or input, cause
  28 ;;;; interleaved IO, etc -- but they should not corrupt memory. The
  29 ;;;; key to doing this is to read buffer state once, and update the
  30 ;;;; state based on the read state:
  31 ;;;;
  32 ;;;; (let ((tail (buffer-tail buffer)))
  33 ;;;;   ...
  34 ;;;;   (setf (buffer-tail buffer) (+ tail n)))
  35 ;;;;
  36 ;;;; NOT
  37 ;;;;
  38 ;;;; (let ((tail (buffer-tail buffer)))
  39 ;;;;   ...
  40 ;;;;  (incf (buffer-tail buffer) n))
  41 ;;;;
  42
  43 (declaim (inline buffer-sap buffer-length buffer-head buffer-tail
  44                  (setf buffer-head) (setf buffer-tail)))
  45 (defstruct (buffer (:constructor %make-buffer (sap length)))
  46   (sap (missing-arg) :type system-area-pointer :read-only t)
  47   (length (missing-arg) :type index :read-only t)
  48   (head 0 :type index)
  49   (tail 0 :type index))
  50
  51 (defvar *available-buffers* ()
  52   #!+sb-doc
  53   "List of available buffers.")
  54
  55 (defvar *available-buffers-spinlock* (sb!thread::make-spinlock
  56                                       :name "lock for *AVAILABLE-BUFFERS*")
  57   #!+sb-doc
  58   "Mutex for access to *AVAILABLE-BUFFERS*.")
  59
  60 (defmacro with-available-buffers-lock ((&optional) &body body)
  61   ;; CALL-WITH-SYSTEM-SPINLOCK because
  62   ;;
  63   ;; 1. streams are low-level enough to be async signal safe, and in
  64   ;;    particular a C-c that brings up the debugger while holding the
  65   ;;    mutex would lose badly
  66   ;;
  67   ;; 2. this can potentially be a fairly busy (but also probably
  68   ;;    uncontended) lock, so we don't want to pay the syscall per
  69   ;;    release -- hence a spinlock.
  70   ;;
  71   ;; ...again, once we have smarted locks the spinlock here can become
  72   ;; a mutex.
  73   `(sb!thread::with-system-spinlock (*available-buffers-spinlock*)
  74      ,@body))
  75
  76 (defconstant +bytes-per-buffer+ (* 4 1024)
  77   #!+sb-doc
  78   "Default number of bytes per buffer.")
  79
  80 (defun alloc-buffer (&optional (size +bytes-per-buffer+))
  81   ;; Don't want to allocate & unwind before the finalizer is in place.
  82   (without-interrupts
  83     (let* ((sap (allocate-system-memory size))
  84            (buffer (%make-buffer sap size)))
  85       (when (zerop (sap-int sap))
  86         (error "Could not allocate ~D bytes for buffer." size))
  87       (finalize buffer (lambda ()
  88                          (deallocate-system-memory sap size))
  89                 :dont-save t)
  90       buffer)))
  91
  92 (defun get-buffer ()
  93   ;; Don't go for the lock if there is nothing to be had -- sure,
  94   ;; another thread might just release one before we get it, but that
  95   ;; is not worth the cost of locking. Also release the lock before
  96   ;; allocation, since it's going to take a while.
  97   (if *available-buffers*
  98       (or (with-available-buffers-lock ()
  99             (pop *available-buffers*))
 100           (alloc-buffer))
 101       (alloc-buffer)))
 102
 103 (declaim (inline reset-buffer))
 104 (defun reset-buffer (buffer)
 105   (setf (buffer-head buffer) 0
 106         (buffer-tail buffer) 0)
 107   buffer)
 108
 109 (defun release-buffer (buffer)
 110   (reset-buffer buffer)
 111   (with-available-buffers-lock ()
 112     (push buffer *available-buffers*)))
 113
 114 ;;; This is a separate buffer management function, as it wants to be
 115 ;;; clever about locking -- grabbing the lock just once.
 116 (defun release-fd-stream-buffers (fd-stream)
 117   (let ((ibuf (fd-stream-ibuf fd-stream))
 118         (obuf (fd-stream-obuf fd-stream))
 119         (queue (loop for item in (fd-stream-output-queue fd-stream)
 120                        when (buffer-p item)
 121                        collect (reset-buffer item))))
 122     (when ibuf
 123       (push (reset-buffer ibuf) queue))
 124     (when obuf
 125       (push (reset-buffer obuf) queue))
 126     ;; ...so, anything found?
 127     (when queue
 128       ;; detach from stream
 129       (setf (fd-stream-ibuf fd-stream) nil
 130             (fd-stream-obuf fd-stream) nil
 131             (fd-stream-output-queue fd-stream) nil)
 132       ;; splice to *available-buffers*
 133       (with-available-buffers-lock ()
 134         (setf *available-buffers* (nconc queue *available-buffers*))))))
 135 \f
 136 ;;;; the FD-STREAM structure
 137
 138 (defstruct (fd-stream
 139             (:constructor %make-fd-stream)
 140             (:conc-name fd-stream-)
 141             (:predicate fd-stream-p)
 142             (:include ansi-stream
 143                       (misc #'fd-stream-misc-routine))
 144             (:copier nil))
 145
 146   ;; the name of this stream
 147   (name nil)
 148   ;; the file this stream is for
 149   (file nil)
 150   ;; the backup file namestring for the old file, for :IF-EXISTS
 151   ;; :RENAME or :RENAME-AND-DELETE.
 152   (original nil :type (or simple-string null))
 153   (delete-original nil)       ; for :if-exists :rename-and-delete
 154   ;;; the number of bytes per element
 155   (element-size 1 :type index)
 156   ;; the type of element being transfered
 157   (element-type 'base-char)
 158   ;; the Unix file descriptor
 159   (fd -1 :type fixnum)
 160   ;; controls when the output buffer is flushed
 161   (buffering :full :type (member :full :line :none))
 162   ;; controls whether the input buffer must be cleared before output
 163   ;; (must be done for files, not for sockets, pipes and other data
 164   ;; sources where input and output aren't related).  non-NIL means
 165   ;; don't clear input buffer.
 166   (dual-channel-p nil)
 167   ;; character position if known -- this may run into bignums, but
 168   ;; we probably should flip it into null then for efficiency's sake...
 169   (char-pos nil :type (or unsigned-byte null))
 170   ;; T if input is waiting on FD. :EOF if we hit EOF.
 171   (listen nil :type (member nil t :eof))
 172
 173   ;; the input buffer
 174   (unread nil)
 175   (ibuf nil :type (or buffer null))
 176
 177   ;; the output buffer
 178   (obuf nil :type (or buffer null))
 179
 180   ;; output flushed, but not written due to non-blocking io?
 181   (output-queue nil)
 182   (handler nil)
 183   ;; timeout specified for this stream as seconds or NIL if none
 184   (timeout nil :type (or single-float null))
 185   ;; pathname of the file this stream is opened to (returned by PATHNAME)
 186   (pathname nil :type (or pathname null))
 187   (external-format :default)
 188   ;; fixed width, or function to call with a character
 189   (char-size 1 :type (or fixnum function))
 190   (output-bytes #'ill-out :type function))
 191 (def!method print-object ((fd-stream fd-stream) stream)
 192   (declare (type stream stream))
 193   (print-unreadable-object (fd-stream stream :type t :identity t)
 194     (format stream "for ~S" (fd-stream-name fd-stream))))
 195 \f
 196 ;;;; CORE OUTPUT FUNCTIONS
 197
 198 ;;; Buffer the section of THING delimited by START and END by copying
 199 ;;; to output buffer(s) of stream.
 200 (defun buffer-output (stream thing start end)
 201   (declare (index start end))
 202   (when (< end start)
 203     (error ":END before :START!"))
 204   (when (> end start)
 205     ;; Copy bytes from THING to buffers.
 206     (flet ((copy-to-buffer (buffer tail count)
 207              (declare (buffer buffer) (index tail count))
 208              (aver (plusp count))
 209              (let ((sap (buffer-sap buffer)))
 210                (etypecase thing
 211                  (system-area-pointer
 212                   (system-area-ub8-copy thing start sap tail count))
 213                  ((simple-unboxed-array (*))
 214                   (copy-ub8-to-system-area thing start sap tail count))))
 215              ;; Not INCF! If another thread has moved tail from under
 216              ;; us, we don't want to accidentally increment tail
 217              ;; beyond buffer-length.
 218              (setf (buffer-tail buffer) (+ count tail))
 219              (incf start count)))
 220       (tagbody
 221          ;; First copy is special: the buffer may already contain
 222          ;; something, or be even full.
 223          (let* ((obuf (fd-stream-obuf stream))
 224                 (tail (buffer-tail obuf))
 225                 (space (- (buffer-length obuf) tail)))
 226            (when (plusp space)
 227              (copy-to-buffer obuf tail (min space (- end start)))
 228              (go :more-output-p)))
 229        :flush-and-fill
 230          ;; Later copies should always have an empty buffer, since
 231          ;; they are freshly flushed, but if another thread is
 232          ;; stomping on the same buffer that might not be the case.
 233          (let* ((obuf (flush-output-buffer stream))
 234                 (tail (buffer-tail obuf))
 235                 (space (- (buffer-length obuf) tail)))
 236            (copy-to-buffer obuf tail (min space (- end start))))
 237        :more-output-p
 238          (when (> end start)
 239            (go :flush-and-fill))))))
 240
 241 ;;; Flush the current output buffer of the stream, ensuring that the
 242 ;;; new buffer is empty. Returns (for convenience) the new output
 243 ;;; buffer -- which may or may not be EQ to the old one. If the is no
 244 ;;; queued output we try to write the buffer immediately -- otherwise
 245 ;;; we queue it for later.
 246 (defun flush-output-buffer (stream)
 247   (let ((obuf (fd-stream-obuf stream)))
 248     (when obuf
 249       (let ((head (buffer-head obuf))
 250             (tail (buffer-tail obuf)))
 251         (cond ((eql head tail)
 252                ;; Buffer is already empty -- just ensure that is is
 253                ;; set to zero as well.
 254                (reset-buffer obuf))
 255               ((fd-stream-output-queue stream)
 256                ;; There is already stuff on the queue -- go directly
 257                ;; there.
 258                (aver (< head tail))
 259                (%queue-and-replace-output-buffer stream))
 260               (t
 261                ;; Try a non-blocking write, queue whatever is left over.
 262                (aver (< head tail))
 263                (synchronize-stream-output stream)
 264                (let ((length (- tail head)))
 265                  (multiple-value-bind (count errno)
 266                      (sb!unix:unix-write (fd-stream-fd stream) (buffer-sap obuf)
 267                                          head length)
 268                    (cond ((eql count length)
 269                           ;; Complete write -- we can use the same buffer.
 270                           (reset-buffer obuf))
 271                          (count
 272                           ;; Partial write -- update buffer status and queue.
 273                           ;; Do not use INCF! Another thread might have moved
 274                           ;; head...
 275                           (setf (buffer-head obuf) (+ count head))
 276                           (%queue-and-replace-output-buffer stream))
 277                          #!-win32
 278                          ((eql errno sb!unix:ewouldblock)
 279                           ;; Blocking, queue.
 280                           (%queue-and-replace-output-buffer stream))
 281                          (t
 282                           (simple-stream-perror "Couldn't write to ~s"
 283                                                 stream errno)))))))))))
 284
 285 ;;; Helper for FLUSH-OUTPUT-BUFFER -- returns the new buffer.
 286 (defun %queue-and-replace-output-buffer (stream)
 287   (let ((queue (fd-stream-output-queue stream))
 288         (later (list (or (fd-stream-obuf stream) (bug "Missing obuf."))))
 289         (new (get-buffer)))
 290     ;; Important: before putting the buffer on queue, give the stream
 291     ;; a new one. If we get an interrupt and unwind losing the buffer
 292     ;; is relatively OK, but having the same buffer in two places
 293     ;; would be bad.
 294     (setf (fd-stream-obuf stream) new)
 295     (cond (queue
 296            (nconc queue later))
 297           (t
 298            (setf (fd-stream-output-queue stream) later)))
 299     (unless (fd-stream-handler stream)
 300       (setf (fd-stream-handler stream)
 301             (add-fd-handler (fd-stream-fd stream)
 302                             :output
 303                             (lambda (fd)
 304                               (declare (ignore fd))
 305                               (write-output-from-queue stream)))))
 306     new))
 307
 308 ;;; This is called by the FD-HANDLER for the stream when output is
 309 ;;; possible.
 310 (defun write-output-from-queue (stream)
 311   (synchronize-stream-output stream)
 312   (let (not-first-p)
 313     (tagbody
 314      :pop-buffer
 315        (let* ((buffer (pop (fd-stream-output-queue stream)))
 316               (head (buffer-head buffer))
 317               (length (- (buffer-tail buffer) head)))
 318          (declare (index head length))
 319          (aver (>= length 0))
 320          (multiple-value-bind (count errno)
 321              (sb!unix:unix-write (fd-stream-fd stream) (buffer-sap buffer)
 322                                  head length)
 323            (cond ((eql count length)
 324                   ;; Complete write, see if we can do another right
 325                   ;; away, or remove the handler if we're done.
 326                   (release-buffer buffer)
 327                   (cond ((fd-stream-output-queue stream)
 328                          (setf not-first-p t)
 329                          (go :pop-buffer))
 330                         (t
 331                          (let ((handler (fd-stream-handler stream)))
 332                            (aver handler)
 333                            (setf (fd-stream-handler stream) nil)
 334                            (remove-fd-handler handler)))))
 335                  (count
 336                   ;; Partial write. Update buffer status and requeue.
 337                   (aver (< count length))
 338                   ;; Do not use INCF! Another thread might have moved head.
 339                   (setf (buffer-head buffer) (+ head count))
 340                   (push buffer (fd-stream-output-queue stream)))
 341                  (not-first-p
 342                   ;; We tried to do multiple writes, and finally our
 343                   ;; luck ran out. Requeue.
 344                   (push buffer (fd-stream-output-queue stream)))
 345                  (t
 346                   ;; Could not write on the first try at all!
 347                   #!+win32
 348                   (simple-stream-perror "Couldn't write to ~S." stream errno)
 349                   #!-win32
 350                   (if (= errno sb!unix:ewouldblock)
 351                       (bug "Unexpected blocking in WRITE-OUTPUT-FROM-QUEUE.")
 352                       (simple-stream-perror "Couldn't write to ~S"
 353                                             stream errno))))))))
 354   nil)
 355
 356 ;;; Try to write THING directly to STREAM without buffering, if
 357 ;;; possible. If direct write doesn't happen, buffer.
 358 (defun write-or-buffer-output (stream thing start end)
 359   (declare (index start end))
 360   (cond ((fd-stream-output-queue stream)
 361          (buffer-output stream thing start end))
 362         ((< end start)
 363          (error ":END before :START!"))
 364         ((> end start)
 365          (let ((length (- end start)))
 366            (synchronize-stream-output stream)
 367            (multiple-value-bind (count errno)
 368                (sb!unix:unix-write (fd-stream-fd stream) thing start length)
 369              (cond ((eql count length)
 370                     ;; Complete write -- done!
 371                     )
 372                    (count
 373                     (aver (< count length))
 374                     ;; Partial write -- buffer the rest.
 375                     (buffer-output stream thing (+ start count) end))
 376                    (t
 377                     ;; Could not write -- buffer or error.
 378                     #!+win32
 379                     (simple-stream-perror "couldn't write to ~s" stream errno)
 380                     #!-win32
 381                     (if (= errno sb!unix:ewouldblock)
 382                         (buffer-output stream thing start end)
 383                         (simple-stream-perror "couldn't write to ~s" stream errno)))))))))
 384
 385 ;;; Deprecated -- can go away after 1.1 or so. Deprecated because
 386 ;;; this is not something we want to export. Nikodemus thinks the
 387 ;;; right thing is to support a low-level non-stream like IO layer,
 388 ;;; akin to java.nio.
 389 (defun output-raw-bytes (stream thing &optional start end)
 390   (write-or-buffer-output stream thing (or start 0) (or end (length thing))))
 391
 392 (define-compiler-macro output-raw-bytes (stream thing &optional start end)
 393   (deprecation-warning 'output-raw-bytes)
 394   (let ((x (gensym "THING")))
 395     `(let ((,x ,thing))
 396        (write-or-buffer-output ,stream ,x (or ,start 0) (or ,end (length ,x))))))
 397 \f
 398 ;;;; output routines and related noise
 399
 400 (defvar *output-routines* ()
 401   #!+sb-doc
 402   "List of all available output routines. Each element is a list of the
 403   element-type output, the kind of buffering, the function name, and the number
 404   of bytes per element.")
 405
 406 ;;; common idioms for reporting low-level stream and file problems
 407 (defun simple-stream-perror (note-format stream errno)
 408   (error 'simple-stream-error
 409          :stream stream
 410          :format-control "~@<~?: ~2I~_~A~:>"
 411          :format-arguments (list note-format (list stream) (strerror errno))))
 412 (defun simple-file-perror (note-format pathname errno)
 413   (error 'simple-file-error
 414          :pathname pathname
 415          :format-control "~@<~?: ~2I~_~A~:>"
 416          :format-arguments
 417          (list note-format (list pathname) (strerror errno))))
 418
 419 (defun stream-decoding-error (stream octets)
 420   (error 'stream-decoding-error
 421          :stream stream
 422          ;; FIXME: dunno how to get at OCTETS currently, or even if
 423          ;; that's the right thing to report.
 424          :octets octets))
 425 (defun stream-encoding-error (stream code)
 426   (error 'stream-encoding-error
 427          :stream stream
 428          :code code))
 429
 430 (defun c-string-encoding-error (external-format code)
 431   (error 'c-string-encoding-error
 432          :external-format external-format
 433          :code code))
 434
 435 (defun c-string-decoding-error (external-format octets)
 436   (error 'c-string-decoding-error
 437          :external-format external-format
 438          :octets octets))
 439
 440 ;;; Returning true goes into end of file handling, false will enter another
 441 ;;; round of input buffer filling followed by re-entering character decode.
 442 (defun stream-decoding-error-and-handle (stream octet-count)
 443   (restart-case
 444       (stream-decoding-error stream
 445                              (let* ((buffer (fd-stream-ibuf stream))
 446                                     (sap (buffer-sap buffer))
 447                                     (head (buffer-head buffer)))
 448                                (loop for i from 0 below octet-count
 449                                      collect (sap-ref-8 sap (+ head i)))))
 450     (attempt-resync ()
 451       :report (lambda (stream)
 452                 (format stream
 453                         "~@<Attempt to resync the stream at a character ~
 454                         character boundary and continue.~@:>"))
 455       (fd-stream-resync stream)
 456       nil)
 457     (force-end-of-file ()
 458       :report (lambda (stream)
 459                 (format stream "~@<Force an end of file.~@:>"))
 460       t)))
 461
 462 (defun stream-encoding-error-and-handle (stream code)
 463   (restart-case
 464       (stream-encoding-error stream code)
 465     (output-nothing ()
 466       :report (lambda (stream)
 467                 (format stream "~@<Skip output of this character.~@:>"))
 468       (throw 'output-nothing nil))))
 469
 470 (defun external-format-encoding-error (stream code)
 471   (if (streamp stream)
 472       (stream-encoding-error-and-handle stream code)
 473       (c-string-encoding-error stream code)))
 474
 475 (defun external-format-decoding-error (stream octet-count)
 476   (if (streamp stream)
 477       (stream-decoding-error stream octet-count)
 478       (c-string-decoding-error stream octet-count)))
 479
 480 (defun synchronize-stream-output (stream)
 481   ;; If we're reading and writing on the same file, flush buffered
 482   ;; input and rewind file position accordingly.
 483   (unless (fd-stream-dual-channel-p stream)
 484     (let ((adjust (nth-value 1 (flush-input-buffer stream))))
 485       (unless (eql 0 adjust)
 486         (sb!unix:unix-lseek (fd-stream-fd stream) (- adjust) sb!unix:l_incr)))))
 487
 488 (defun fd-stream-output-finished-p (stream)
 489   (let ((obuf (fd-stream-obuf stream)))
 490     (or (not obuf)
 491         (and (zerop (buffer-tail obuf))
 492              (not (fd-stream-output-queue stream))))))
 493
 494 (defmacro output-wrapper/variable-width ((stream size buffering restart)
 495                                          &body body)
 496   (let ((stream-var (gensym "STREAM")))
 497     `(let* ((,stream-var ,stream)
 498             (obuf (fd-stream-obuf ,stream-var))
 499             (tail (buffer-tail obuf))
 500             (size ,size))
 501       ,(unless (eq (car buffering) :none)
 502          `(when (<= (buffer-length obuf) (+ tail size))
 503             (setf obuf (flush-output-buffer ,stream-var)
 504                   tail (buffer-tail obuf))))
 505       ,(unless (eq (car buffering) :none)
 506          ;; FIXME: Why this here? Doesn't seem necessary.
 507          `(synchronize-stream-output ,stream-var))
 508       ,(if restart
 509            `(catch 'output-nothing
 510               ,@body
 511               (setf (buffer-tail obuf) (+ tail size)))
 512            `(progn
 513              ,@body
 514              (setf (buffer-tail obuf) (+ tail size))))
 515       ,(ecase (car buffering)
 516          (:none
 517           `(flush-output-buffer ,stream-var))
 518          (:line
 519           `(when (eql byte #\Newline)
 520              (flush-output-buffer ,stream-var)))
 521          (:full))
 522     (values))))
 523
 524 (defmacro output-wrapper ((stream size buffering restart) &body body)
 525   (let ((stream-var (gensym "STREAM")))
 526     `(let* ((,stream-var ,stream)
 527             (obuf (fd-stream-obuf ,stream-var))
 528             (tail (buffer-tail obuf)))
 529       ,(unless (eq (car buffering) :none)
 530          `(when (<= (buffer-length obuf) (+ tail ,size))
 531             (setf obuf (flush-output-buffer ,stream-var)
 532                   tail (buffer-tail obuf))))
 533       ;; FIXME: Why this here? Doesn't seem necessary.
 534       ,(unless (eq (car buffering) :none)
 535          `(synchronize-stream-output ,stream-var))
 536       ,(if restart
 537            `(catch 'output-nothing
 538               ,@body
 539               (setf (buffer-tail obuf) (+ tail ,size)))
 540            `(progn
 541              ,@body
 542              (setf (buffer-tail obuf) (+ tail ,size))))
 543       ,(ecase (car buffering)
 544          (:none
 545           `(flush-output-buffer ,stream-var))
 546          (:line
 547           `(when (eql byte #\Newline)
 548              (flush-output-buffer ,stream-var)))
 549          (:full))
 550     (values))))
 551
 552 (defmacro def-output-routines/variable-width
 553     ((name-fmt size restart external-format &rest bufferings)
 554      &body body)
 555   (declare (optimize (speed 1)))
 556   (cons 'progn
 557         (mapcar
 558             (lambda (buffering)
 559               (let ((function
 560                      (intern (format nil name-fmt (string (car buffering))))))
 561                 `(progn
 562                    (defun ,function (stream byte)
 563                      (declare (ignorable byte))
 564                      (output-wrapper/variable-width (stream ,size ,buffering ,restart)
 565                        ,@body))
 566                    (setf *output-routines*
 567                          (nconc *output-routines*
 568                                 ',(mapcar
 569                                    (lambda (type)
 570                                      (list type
 571                                            (car buffering)
 572                                            function
 573                                            1
 574                                            external-format))
 575                                    (cdr buffering)))))))
 576             bufferings)))
 577
 578 ;;; Define output routines that output numbers SIZE bytes long for the
 579 ;;; given bufferings. Use BODY to do the actual output.
 580 (defmacro def-output-routines ((name-fmt size restart &rest bufferings)
 581                                &body body)
 582   (declare (optimize (speed 1)))
 583   (cons 'progn
 584         (mapcar
 585             (lambda (buffering)
 586               (let ((function
 587                      (intern (format nil name-fmt (string (car buffering))))))
 588                 `(progn
 589                    (defun ,function (stream byte)
 590                      (output-wrapper (stream ,size ,buffering ,restart)
 591                        ,@body))
 592                    (setf *output-routines*
 593                          (nconc *output-routines*
 594                                 ',(mapcar
 595                                    (lambda (type)
 596                                      (list type
 597                                            (car buffering)
 598                                            function
 599                                            size
 600                                            nil))
 601                                    (cdr buffering)))))))
 602             bufferings)))
 603
 604 ;;; FIXME: is this used anywhere any more?
 605 (def-output-routines ("OUTPUT-CHAR-~A-BUFFERED"
 606                       1
 607                       t
 608                       (:none character)
 609                       (:line character)
 610                       (:full character))
 611   (if (eql byte #\Newline)
 612       (setf (fd-stream-char-pos stream) 0)
 613       (incf (fd-stream-char-pos stream)))
 614   (setf (sap-ref-8 (buffer-sap obuf) tail)
 615         (char-code byte)))
 616
 617 (def-output-routines ("OUTPUT-UNSIGNED-BYTE-~A-BUFFERED"
 618                       1
 619                       nil
 620                       (:none (unsigned-byte 8))
 621                       (:full (unsigned-byte 8)))
 622   (setf (sap-ref-8 (buffer-sap obuf) tail)
 623         byte))
 624
 625 (def-output-routines ("OUTPUT-SIGNED-BYTE-~A-BUFFERED"
 626                       1
 627                       nil
 628                       (:none (signed-byte 8))
 629                       (:full (signed-byte 8)))
 630   (setf (signed-sap-ref-8 (buffer-sap obuf) tail)
 631         byte))
 632
 633 (def-output-routines ("OUTPUT-UNSIGNED-SHORT-~A-BUFFERED"
 634                       2
 635                       nil
 636                       (:none (unsigned-byte 16))
 637                       (:full (unsigned-byte 16)))
 638   (setf (sap-ref-16 (buffer-sap obuf) tail)
 639         byte))
 640
 641 (def-output-routines ("OUTPUT-SIGNED-SHORT-~A-BUFFERED"
 642                       2
 643                       nil
 644                       (:none (signed-byte 16))
 645                       (:full (signed-byte 16)))
 646   (setf (signed-sap-ref-16 (buffer-sap obuf) tail)
 647         byte))
 648
 649 (def-output-routines ("OUTPUT-UNSIGNED-LONG-~A-BUFFERED"
 650                       4
 651                       nil
 652                       (:none (unsigned-byte 32))
 653                       (:full (unsigned-byte 32)))
 654   (setf (sap-ref-32 (buffer-sap obuf) tail)
 655         byte))
 656
 657 (def-output-routines ("OUTPUT-SIGNED-LONG-~A-BUFFERED"
 658                       4
 659                       nil
 660                       (:none (signed-byte 32))
 661                       (:full (signed-byte 32)))
 662   (setf (signed-sap-ref-32 (buffer-sap obuf) tail)
 663         byte))
 664
 665 #+#.(cl:if (cl:= sb!vm:n-word-bits 64) '(and) '(or))
 666 (progn
 667   (def-output-routines ("OUTPUT-UNSIGNED-LONG-LONG-~A-BUFFERED"
 668                         8
 669                         nil
 670                         (:none (unsigned-byte 64))
 671                         (:full (unsigned-byte 64)))
 672     (setf (sap-ref-64 (buffer-sap obuf) tail)
 673           byte))
 674   (def-output-routines ("OUTPUT-SIGNED-LONG-LONG-~A-BUFFERED"
 675                         8
 676                         nil
 677                         (:none (signed-byte 64))
 678                         (:full (signed-byte 64)))
 679     (setf (signed-sap-ref-64 (buffer-sap obuf) tail)
 680           byte)))
 681
 682 ;;; the routine to use to output a string. If the stream is
 683 ;;; unbuffered, slam the string down the file descriptor, otherwise
 684 ;;; use OUTPUT-RAW-BYTES to buffer the string. Update charpos by
 685 ;;; checking to see where the last newline was.
 686 (defun fd-sout (stream thing start end)
 687   (declare (type fd-stream stream) (type string thing))
 688   (let ((start (or start 0))
 689         (end (or end (length (the vector thing)))))
 690     (declare (fixnum start end))
 691     (let ((last-newline
 692            (string-dispatch (simple-base-string
 693                              #!+sb-unicode
 694                              (simple-array character (*))
 695                              string)
 696                thing
 697              (position #\newline thing :from-end t
 698                        :start start :end end))))
 699       (if (and (typep thing 'base-string)
 700                (eq (fd-stream-external-format stream) :latin-1))
 701           (ecase (fd-stream-buffering stream)
 702             (:full
 703              (buffer-output stream thing start end))
 704             (:line
 705              (buffer-output stream thing start end)
 706              (when last-newline
 707                (flush-output-buffer stream)))
 708             (:none
 709              (write-or-buffer-output stream thing start end)))
 710           (ecase (fd-stream-buffering stream)
 711             (:full (funcall (fd-stream-output-bytes stream)
 712                             stream thing nil start end))
 713             (:line (funcall (fd-stream-output-bytes stream)
 714                             stream thing last-newline start end))
 715             (:none (funcall (fd-stream-output-bytes stream)
 716                             stream thing t start end))))
 717       (if last-newline
 718           (setf (fd-stream-char-pos stream) (- end last-newline 1))
 719           (incf (fd-stream-char-pos stream) (- end start))))))
 720
 721 (defvar *external-formats* ()
 722   #!+sb-doc
 723   "List of all available external formats. Each element is a list of the
 724   element-type, string input function name, character input function name,
 725   and string output function name.")
 726
 727 (defun get-external-format (external-format)
 728   (dolist (entry *external-formats*)
 729     (when (member external-format (first entry))
 730       (return entry))))
 731
 732 (defun get-external-format-function (external-format index)
 733   (let ((entry (get-external-format external-format)))
 734     (when entry (nth index entry))))
 735
 736 ;;; Find an output routine to use given the type and buffering. Return
 737 ;;; as multiple values the routine, the real type transfered, and the
 738 ;;; number of bytes per element.
 739 (defun pick-output-routine (type buffering &optional external-format)
 740   (when (subtypep type 'character)
 741     (let ((entry (get-external-format external-format)))
 742       (when entry
 743         (return-from pick-output-routine
 744           (values (symbol-function (nth (ecase buffering
 745                                           (:none 4)
 746                                           (:line 5)
 747                                           (:full 6))
 748                                         entry))
 749                   'character
 750                   1
 751                   (symbol-function (fourth entry))
 752                   (first (first entry)))))))
 753   (dolist (entry *output-routines*)
 754     (when (and (subtypep type (first entry))
 755                (eq buffering (second entry))
 756                (or (not (fifth entry))
 757                    (eq external-format (fifth entry))))
 758       (return-from pick-output-routine
 759         (values (symbol-function (third entry))
 760                 (first entry)
 761                 (fourth entry)))))
 762   ;; KLUDGE: dealing with the buffering here leads to excessive code
 763   ;; explosion.
 764   ;;
 765   ;; KLUDGE: also see comments in PICK-INPUT-ROUTINE
 766   (loop for i from 40 by 8 to 1024 ; ARB (KLUDGE)
 767         if (subtypep type `(unsigned-byte ,i))
 768         do (return-from pick-output-routine
 769              (values
 770               (ecase buffering
 771                 (:none
 772                  (lambda (stream byte)
 773                    (output-wrapper (stream (/ i 8) (:none) nil)
 774                      (loop for j from 0 below (/ i 8)
 775                            do (setf (sap-ref-8 (buffer-sap obuf)
 776                                                (+ j tail))
 777                                     (ldb (byte 8 (- i 8 (* j 8))) byte))))))
 778                 (:full
 779                  (lambda (stream byte)
 780                    (output-wrapper (stream (/ i 8) (:full) nil)
 781                      (loop for j from 0 below (/ i 8)
 782                            do (setf (sap-ref-8 (buffer-sap obuf)
 783                                                (+ j tail))
 784                                     (ldb (byte 8 (- i 8 (* j 8))) byte)))))))
 785               `(unsigned-byte ,i)
 786               (/ i 8))))
 787   (loop for i from 40 by 8 to 1024 ; ARB (KLUDGE)
 788         if (subtypep type `(signed-byte ,i))
 789         do (return-from pick-output-routine
 790              (values
 791               (ecase buffering
 792                 (:none
 793                  (lambda (stream byte)
 794                    (output-wrapper (stream (/ i 8) (:none) nil)
 795                      (loop for j from 0 below (/ i 8)
 796                            do (setf (sap-ref-8 (buffer-sap obuf)
 797                                                (+ j tail))
 798                                     (ldb (byte 8 (- i 8 (* j 8))) byte))))))
 799                 (:full
 800                  (lambda (stream byte)
 801                    (output-wrapper (stream (/ i 8) (:full) nil)
 802                      (loop for j from 0 below (/ i 8)
 803                            do (setf (sap-ref-8 (buffer-sap obuf)
 804                                                (+ j tail))
 805                                     (ldb (byte 8 (- i 8 (* j 8))) byte)))))))
 806               `(signed-byte ,i)
 807               (/ i 8)))))
 808 \f
 809 ;;;; input routines and related noise
 810
 811 ;;; a list of all available input routines. Each element is a list of
 812 ;;; the element-type input, the function name, and the number of bytes
 813 ;;; per element.
 814 (defvar *input-routines* ())
 815
 816 ;;; Return whether a primitive partial read operation on STREAM's FD
 817 ;;; would (probably) block.  Signal a `simple-stream-error' if the
 818 ;;; system call implementing this operation fails.
 819 ;;;
 820 ;;; It is "may" instead of "would" because "would" is not quite
 821 ;;; correct on win32.  However, none of the places that use it require
 822 ;;; further assurance than "may" versus "will definitely not".
 823 (defun sysread-may-block-p (stream)
 824   #+win32
 825   ;; This answers T at EOF on win32, I think.
 826   (not (sb!win32:fd-listen (fd-stream-fd stream)))
 827   #-win32
 828   (sb!unix:with-restarted-syscall (count errno)
 829     (sb!alien:with-alien ((read-fds (sb!alien:struct sb!unix:fd-set)))
 830       (sb!unix:fd-zero read-fds)
 831       (sb!unix:fd-set (fd-stream-fd stream) read-fds)
 832       (sb!unix:unix-fast-select (1+ (fd-stream-fd stream))
 833                                 (sb!alien:addr read-fds)
 834                                 nil nil 0 0))
 835     (case count
 836       ((1) nil)
 837       ((0) t)
 838       (otherwise
 839        (simple-stream-perror "couldn't check whether ~S is readable"
 840                              stream
 841                              errno)))))
 842
 843 ;;; If the read would block wait (using SERVE-EVENT) till input is available,
 844 ;;; then fill the input buffer, and return the number of bytes read. Throws
 845 ;;; to EOF-INPUT-CATCHER if the eof was reached.
 846 (defun refill-input-buffer (stream)
 847   (let ((fd (fd-stream-fd stream))
 848         (errno 0)
 849         (count 0))
 850     (declare (optimize sb!c::stack-allocate-value-cells)
 851              (dynamic-extent fd errno count))
 852     (tagbody
 853        ;; Check for blocking input before touching the stream, as if
 854        ;; we happen to wait we are liable to be interrupted, and the
 855        ;; interrupt handler may use the same stream.
 856        (if (sysread-may-block-p stream)
 857            (go :wait-for-input)
 858            (go :main))
 859        ;; These (:CLOSED-FLAME and :READ-ERROR) tags are here so what
 860        ;; we can signal errors outside the WITHOUT-INTERRUPTS.
 861      :closed-flame
 862        (closed-flame stream)
 863      :read-error
 864        (simple-stream-perror "couldn't read from ~S" stream errno)
 865      :wait-for-input
 866        ;; This tag is here so we can unwind outside the WITHOUT-INTERRUPTS
 867        ;; to wait for input if read tells us EWOULDBLOCK.
 868        (unless (wait-until-fd-usable fd :input (fd-stream-timeout stream))
 869          (signal-timeout 'io-timeout :stream stream :direction :read
 870                          :seconds (fd-stream-timeout stream)))
 871      :main
 872        ;; Since the read should not block, we'll disable the
 873        ;; interrupts here, so that we don't accidentally unwind and
 874        ;; leave the stream in an inconsistent state.
 875
 876        ;; Execute the nlx outside without-interrupts to ensure the
 877        ;; resulting thunk is stack-allocatable.
 878        ((lambda (return-reason)
 879           (ecase return-reason
 880             ((nil))             ; fast path normal cases
 881             ((:wait-for-input) (go :wait-for-input))
 882             ((:closed-flame)   (go :closed-flame))
 883             ((:read-error)     (go :read-error))))
 884         (without-interrupts
 885           ;; Check the buffer: if it is null, then someone has closed
 886           ;; the stream from underneath us. This is not ment to fix
 887           ;; multithreaded races, but to deal with interrupt handlers
 888           ;; closing the stream.
 889           (block nil
 890             (prog1 nil
 891               (let* ((ibuf (or (fd-stream-ibuf stream) (return :closed-flame)))
 892                      (sap (buffer-sap ibuf))
 893                      (length (buffer-length ibuf))
 894                      (head (buffer-head ibuf))
 895                      (tail (buffer-tail ibuf)))
 896                 (declare (index length head tail)
 897                          (inline sb!unix:unix-read))
 898                 (unless (zerop head)
 899                   (cond ((eql head tail)
 900                          ;; Buffer is empty, but not at yet reset -- make it so.
 901                          (setf head 0
 902                                tail 0)
 903                          (reset-buffer ibuf))
 904                         (t
 905                          ;; Buffer has things in it, but they are not at the
 906                          ;; head -- move them there.
 907                          (let ((n (- tail head)))
 908                            (system-area-ub8-copy sap head sap 0 n)
 909                            (setf head 0
 910                                  (buffer-head ibuf) head
 911                                  tail n
 912                                  (buffer-tail ibuf) tail)))))
 913                 (setf (fd-stream-listen stream) nil)
 914                 (setf (values count errno)
 915                       (sb!unix:unix-read fd (sap+ sap tail) (- length tail)))
 916                 (cond ((null count)
 917                        #!+win32
 918                        (return :read-error)
 919                        #!-win32
 920                        (if (eql errno sb!unix:ewouldblock)
 921                            (return :wait-for-input)
 922                            (return :read-error)))
 923                       ((zerop count)
 924                        (setf (fd-stream-listen stream) :eof)
 925                        (/show0 "THROWing EOF-INPUT-CATCHER")
 926                        (throw 'eof-input-catcher nil))
 927                       (t
 928                        ;; Success! (Do not use INCF, for sake of other threads.)
 929                        (setf (buffer-tail ibuf) (+ count tail))))))))))
 930     count))
 931
 932 ;;; Make sure there are at least BYTES number of bytes in the input
 933 ;;; buffer. Keep calling REFILL-INPUT-BUFFER until that condition is met.
 934 (defmacro input-at-least (stream bytes)
 935   (let ((stream-var (gensym "STREAM"))
 936         (bytes-var (gensym "BYTES"))
 937         (buffer-var (gensym "IBUF")))
 938     `(let* ((,stream-var ,stream)
 939             (,bytes-var ,bytes)
 940             (,buffer-var (fd-stream-ibuf ,stream-var)))
 941        (loop
 942          (when (>= (- (buffer-tail ,buffer-var)
 943                       (buffer-head ,buffer-var))
 944                    ,bytes-var)
 945            (return))
 946          (refill-input-buffer ,stream-var)))))
 947
 948 (defmacro input-wrapper/variable-width ((stream bytes eof-error eof-value)
 949                                         &body read-forms)
 950   (let ((stream-var (gensym "STREAM"))
 951         (retry-var (gensym "RETRY"))
 952         (element-var (gensym "ELT")))
 953     `(let* ((,stream-var ,stream)
 954             (ibuf (fd-stream-ibuf ,stream-var))
 955             (size nil))
 956        (if (fd-stream-unread ,stream-var)
 957            (prog1
 958                (fd-stream-unread ,stream-var)
 959              (setf (fd-stream-unread ,stream-var) nil)
 960              (setf (fd-stream-listen ,stream-var) nil))
 961            (let ((,element-var nil)
 962                  (decode-break-reason nil))
 963              (do ((,retry-var t))
 964                  ((not ,retry-var))
 965                (unless
 966                    (catch 'eof-input-catcher
 967                      (setf decode-break-reason
 968                            (block decode-break-reason
 969                              (input-at-least ,stream-var 1)
 970                              (let* ((byte (sap-ref-8 (buffer-sap ibuf)
 971                                                      (buffer-head ibuf))))
 972                                (declare (ignorable byte))
 973                                (setq size ,bytes)
 974                                (input-at-least ,stream-var size)
 975                                (setq ,element-var (locally ,@read-forms))
 976                                (setq ,retry-var nil))
 977                              nil))
 978                      (when decode-break-reason
 979                        (stream-decoding-error-and-handle stream
 980                                                          decode-break-reason))
 981                      t)
 982                  (let ((octet-count (- (buffer-tail ibuf)
 983                                        (buffer-head ibuf))))
 984                    (when (or (zerop octet-count)
 985                              (and (not ,element-var)
 986                                   (not decode-break-reason)
 987                                   (stream-decoding-error-and-handle
 988                                    stream octet-count)))
 989                      (setq ,retry-var nil)))))
 990              (cond (,element-var
 991                     (incf (buffer-head ibuf) size)
 992                     ,element-var)
 993                    (t
 994                     (eof-or-lose ,stream-var ,eof-error ,eof-value))))))))
 995
 996 ;;; a macro to wrap around all input routines to handle EOF-ERROR noise
 997 (defmacro input-wrapper ((stream bytes eof-error eof-value) &body read-forms)
 998   (let ((stream-var (gensym "STREAM"))
 999         (element-var (gensym "ELT")))
1000     `(let* ((,stream-var ,stream)
1001             (ibuf (fd-stream-ibuf ,stream-var)))
1002        (if (fd-stream-unread ,stream-var)
1003            (prog1
1004                (fd-stream-unread ,stream-var)
1005              (setf (fd-stream-unread ,stream-var) nil)
1006              (setf (fd-stream-listen ,stream-var) nil))
1007            (let ((,element-var
1008                   (catch 'eof-input-catcher
1009                     (input-at-least ,stream-var ,bytes)
1010                     (locally ,@read-forms))))
1011              (cond (,element-var
1012                     (incf (buffer-head (fd-stream-ibuf ,stream-var)) ,bytes)
1013                     ,element-var)
1014                    (t
1015                     (eof-or-lose ,stream-var ,eof-error ,eof-value))))))))
1016
1017 (defmacro def-input-routine/variable-width (name
1018                                             (type external-format size sap head)
1019                                             &rest body)
1020   `(progn
1021      (defun ,name (stream eof-error eof-value)
1022        (input-wrapper/variable-width (stream ,size eof-error eof-value)
1023          (let ((,sap (buffer-sap ibuf))
1024                (,head (buffer-head ibuf)))
1025            ,@body)))
1026      (setf *input-routines*
1027            (nconc *input-routines*
1028                   (list (list ',type ',name 1 ',external-format))))))
1029
1030 (defmacro def-input-routine (name
1031                              (type size sap head)
1032                              &rest body)
1033   `(progn
1034      (defun ,name (stream eof-error eof-value)
1035        (input-wrapper (stream ,size eof-error eof-value)
1036          (let ((,sap (buffer-sap ibuf))
1037                (,head (buffer-head ibuf)))
1038            ,@body)))
1039      (setf *input-routines*
1040            (nconc *input-routines*
1041                   (list (list ',type ',name ',size nil))))))
1042
1043 ;;; STREAM-IN routine for reading a string char
1044 (def-input-routine input-character
1045                    (character 1 sap head)
1046   (code-char (sap-ref-8 sap head)))
1047
1048 ;;; STREAM-IN routine for reading an unsigned 8 bit number
1049 (def-input-routine input-unsigned-8bit-byte
1050                    ((unsigned-byte 8) 1 sap head)
1051   (sap-ref-8 sap head))
1052
1053 ;;; STREAM-IN routine for reading a signed 8 bit number
1054 (def-input-routine input-signed-8bit-number
1055                    ((signed-byte 8) 1 sap head)
1056   (signed-sap-ref-8 sap head))
1057
1058 ;;; STREAM-IN routine for reading an unsigned 16 bit number
1059 (def-input-routine input-unsigned-16bit-byte
1060                    ((unsigned-byte 16) 2 sap head)
1061   (sap-ref-16 sap head))
1062
1063 ;;; STREAM-IN routine for reading a signed 16 bit number
1064 (def-input-routine input-signed-16bit-byte
1065                    ((signed-byte 16) 2 sap head)
1066   (signed-sap-ref-16 sap head))
1067
1068 ;;; STREAM-IN routine for reading a unsigned 32 bit number
1069 (def-input-routine input-unsigned-32bit-byte
1070                    ((unsigned-byte 32) 4 sap head)
1071   (sap-ref-32 sap head))
1072
1073 ;;; STREAM-IN routine for reading a signed 32 bit number
1074 (def-input-routine input-signed-32bit-byte
1075                    ((signed-byte 32) 4 sap head)
1076   (signed-sap-ref-32 sap head))
1077
1078 #+#.(cl:if (cl:= sb!vm:n-word-bits 64) '(and) '(or))
1079 (progn
1080   (def-input-routine input-unsigned-64bit-byte
1081       ((unsigned-byte 64) 8 sap head)
1082     (sap-ref-64 sap head))
1083   (def-input-routine input-signed-64bit-byte
1084       ((signed-byte 64) 8 sap head)
1085     (signed-sap-ref-64 sap head)))
1086
1087 ;;; Find an input routine to use given the type. Return as multiple
1088 ;;; values the routine, the real type transfered, and the number of
1089 ;;; bytes per element (and for character types string input routine).
1090 (defun pick-input-routine (type &optional external-format)
1091   (when (subtypep type 'character)
1092     (dolist (entry *external-formats*)
1093       (when (member external-format (first entry))
1094         (return-from pick-input-routine
1095           (values (symbol-function (third entry))
1096                   'character
1097                   1
1098                   (symbol-function (second entry))
1099                   (first (first entry)))))))
1100   (dolist (entry *input-routines*)
1101     (when (and (subtypep type (first entry))
1102                (or (not (fourth entry))
1103                    (eq external-format (fourth entry))))
1104       (return-from pick-input-routine
1105         (values (symbol-function (second entry))
1106                 (first entry)
1107                 (third entry)))))
1108   ;; FIXME: let's do it the hard way, then (but ignore things like
1109   ;; endianness, efficiency, and the necessary coupling between these
1110   ;; and the output routines).  -- CSR, 2004-02-09
1111   (loop for i from 40 by 8 to 1024 ; ARB (well, KLUDGE really)
1112         if (subtypep type `(unsigned-byte ,i))
1113         do (return-from pick-input-routine
1114              (values
1115               (lambda (stream eof-error eof-value)
1116                 (input-wrapper (stream (/ i 8) eof-error eof-value)
1117                   (let ((sap (buffer-sap ibuf))
1118                         (head (buffer-head ibuf)))
1119                     (loop for j from 0 below (/ i 8)
1120                           with result = 0
1121                           do (setf result
1122                                    (+ (* 256 result)
1123                                       (sap-ref-8 sap (+ head j))))
1124                           finally (return result)))))
1125               `(unsigned-byte ,i)
1126               (/ i 8))))
1127   (loop for i from 40 by 8 to 1024 ; ARB (well, KLUDGE really)
1128         if (subtypep type `(signed-byte ,i))
1129         do (return-from pick-input-routine
1130              (values
1131               (lambda (stream eof-error eof-value)
1132                 (input-wrapper (stream (/ i 8) eof-error eof-value)
1133                   (let ((sap (buffer-sap ibuf))
1134                         (head (buffer-head ibuf)))
1135                     (loop for j from 0 below (/ i 8)
1136                           with result = 0
1137                           do (setf result
1138                                    (+ (* 256 result)
1139                                       (sap-ref-8 sap (+ head j))))
1140                           finally (return (if (logbitp (1- i) result)
1141                                               (dpb result (byte i 0) -1)
1142                                               result))))))
1143               `(signed-byte ,i)
1144               (/ i 8)))))
1145
1146 ;;; the N-BIN method for FD-STREAMs
1147 ;;;
1148 ;;; Note that this blocks in UNIX-READ. It is generally used where
1149 ;;; there is a definite amount of reading to be done, so blocking
1150 ;;; isn't too problematical.
1151 (defun fd-stream-read-n-bytes (stream buffer start requested eof-error-p
1152                                &aux (total-copied 0))
1153   (declare (type fd-stream stream))
1154   (declare (type index start requested total-copied))
1155   (let ((unread (fd-stream-unread stream)))
1156     (when unread
1157       ;; AVERs designed to fail when we have more complicated
1158       ;; character representations.
1159       (aver (typep unread 'base-char))
1160       (aver (= (fd-stream-element-size stream) 1))
1161       ;; KLUDGE: this is a slightly-unrolled-and-inlined version of
1162       ;; %BYTE-BLT
1163       (etypecase buffer
1164         (system-area-pointer
1165          (setf (sap-ref-8 buffer start) (char-code unread)))
1166         ((simple-unboxed-array (*))
1167          (setf (aref buffer start) unread)))
1168       (setf (fd-stream-unread stream) nil)
1169       (setf (fd-stream-listen stream) nil)
1170       (incf total-copied)))
1171   (do ()
1172       (nil)
1173     (let* ((remaining-request (- requested total-copied))
1174            (ibuf (fd-stream-ibuf stream))
1175            (head (buffer-head ibuf))
1176            (tail (buffer-tail ibuf))
1177            (available (- tail head))
1178            (n-this-copy (min remaining-request available))
1179            (this-start (+ start total-copied))
1180            (this-end (+ this-start n-this-copy))
1181            (sap (buffer-sap ibuf)))
1182       (declare (type index remaining-request head tail available))
1183       (declare (type index n-this-copy))
1184       ;; Copy data from stream buffer into user's buffer.
1185       (%byte-blt sap head buffer this-start this-end)
1186       (incf (buffer-head ibuf) n-this-copy)
1187       (incf total-copied n-this-copy)
1188       ;; Maybe we need to refill the stream buffer.
1189       (cond (;; If there were enough data in the stream buffer, we're done.
1190              (eql total-copied requested)
1191              (return total-copied))
1192             (;; If EOF, we're done in another way.
1193              (null (catch 'eof-input-catcher (refill-input-buffer stream)))
1194              (if eof-error-p
1195                  (error 'end-of-file :stream stream)
1196                  (return total-copied)))
1197             ;; Otherwise we refilled the stream buffer, so fall
1198             ;; through into another pass of the loop.
1199             ))))
1200
1201 (defun fd-stream-resync (stream)
1202   (dolist (entry *external-formats*)
1203     (when (member (fd-stream-external-format stream) (first entry))
1204       (return-from fd-stream-resync
1205         (funcall (symbol-function (eighth entry)) stream)))))
1206
1207 (defun get-fd-stream-character-sizer (stream)
1208   (dolist (entry *external-formats*)
1209     (when (member (fd-stream-external-format stream) (first entry))
1210       (return-from get-fd-stream-character-sizer (ninth entry)))))
1211
1212 (defun fd-stream-character-size (stream char)
1213   (let ((sizer (get-fd-stream-character-sizer stream)))
1214     (when sizer (funcall sizer char))))
1215
1216 (defun fd-stream-string-size (stream string)
1217   (let ((sizer (get-fd-stream-character-sizer stream)))
1218     (when sizer
1219       (loop for char across string summing (funcall sizer char)))))
1220
1221 (defun find-external-format (external-format)
1222   (when external-format
1223     (find external-format *external-formats* :test #'member :key #'car)))
1224
1225 (defun variable-width-external-format-p (ef-entry)
1226   (when (eighth ef-entry) t))
1227
1228 (defun bytes-for-char-fun (ef-entry)
1229   (if ef-entry (symbol-function (ninth ef-entry)) (constantly 1)))
1230
1231 ;;; FIXME: OAOOM here vrt. *EXTERNAL-FORMAT-FUNCTIONS* in fd-stream.lisp
1232 (defmacro define-external-format (external-format size output-restart
1233                                   out-expr in-expr)
1234   (let* ((name (first external-format))
1235          (out-function (symbolicate "OUTPUT-BYTES/" name))
1236          (format (format nil "OUTPUT-CHAR-~A-~~A-BUFFERED" (string name)))
1237          (in-function (symbolicate "FD-STREAM-READ-N-CHARACTERS/" name))
1238          (in-char-function (symbolicate "INPUT-CHAR/" name))
1239          (size-function (symbolicate "BYTES-FOR-CHAR/" name))
1240          (read-c-string-function (symbolicate "READ-FROM-C-STRING/" name))
1241          (output-c-string-function (symbolicate "OUTPUT-TO-C-STRING/" name))
1242          (n-buffer (gensym "BUFFER")))
1243     `(progn
1244       (defun ,size-function (byte)
1245         (declare (ignore byte))
1246         ,size)
1247       (defun ,out-function (stream string flush-p start end)
1248         (let ((start (or start 0))
1249               (end (or end (length string))))
1250           (declare (type index start end))
1251           (synchronize-stream-output stream)
1252           (unless (<= 0 start end (length string))
1253             (sequence-bounding-indices-bad-error string start end))
1254           (do ()
1255               ((= end start))
1256             (let ((obuf (fd-stream-obuf stream)))
1257               (setf (buffer-tail obuf)
1258                     (string-dispatch (simple-base-string
1259                                       #!+sb-unicode
1260                                       (simple-array character (*))
1261                                       string)
1262                         string
1263                       (let ((sap (buffer-sap obuf))
1264                             (len (buffer-length obuf))
1265                             ;; FIXME: rename
1266                             (tail (buffer-tail obuf)))
1267                        (declare (type index tail)
1268                                 ;; STRING bounds have already been checked.
1269                                 (optimize (safety 0)))
1270                        (loop
1271                          (,@(if output-restart
1272                                 `(catch 'output-nothing)
1273                                 `(progn))
1274                             (do* ()
1275                                  ((or (= start end) (< (- len tail) 4)))
1276                               (let* ((byte (aref string start))
1277                                      (bits (char-code byte)))
1278                                 ,out-expr
1279                                 (incf tail ,size)
1280                                 (incf start)))
1281                             ;; Exited from the loop normally
1282                             (return tail))
1283                          ;; Exited via CATCH. Skip the current character
1284                          ;; and try the inner loop again.
1285                          (incf start))))))
1286             (when (< start end)
1287               (flush-output-buffer stream)))
1288           (when flush-p
1289             (flush-output-buffer stream))))
1290       (def-output-routines (,format
1291                             ,size
1292                             ,output-restart
1293                             (:none character)
1294                             (:line character)
1295                             (:full character))
1296           (if (eql byte #\Newline)
1297               (setf (fd-stream-char-pos stream) 0)
1298               (incf (fd-stream-char-pos stream)))
1299           (let* ((obuf (fd-stream-obuf stream))
1300                  (bits (char-code byte))
1301                  (sap (buffer-sap obuf))
1302                  (tail (buffer-tail obuf)))
1303             ,out-expr))
1304       (defun ,in-function (stream buffer start requested eof-error-p
1305                            &aux (index start) (end (+ start requested)))
1306         (declare (type fd-stream stream)
1307                  (type index start requested index end)
1308                  (type
1309                   (simple-array character (#.+ansi-stream-in-buffer-length+))
1310                   buffer))
1311         (let ((unread (fd-stream-unread stream)))
1312           (when unread
1313             (setf (aref buffer index) unread)
1314             (setf (fd-stream-unread stream) nil)
1315             (setf (fd-stream-listen stream) nil)
1316             (incf index)))
1317         (do ()
1318             (nil)
1319           (let* ((ibuf (fd-stream-ibuf stream))
1320                  (head (buffer-head ibuf))
1321                  (tail (buffer-tail ibuf))
1322                  (sap (buffer-sap ibuf)))
1323             (declare (type index head tail)
1324                      (type system-area-pointer sap))
1325             ;; Copy data from stream buffer into user's buffer.
1326             (dotimes (i (min (truncate (- tail head) ,size)
1327                              (- end index)))
1328               (declare (optimize speed))
1329               (let* ((byte (sap-ref-8 sap head)))
1330                 (setf (aref buffer index) ,in-expr)
1331                 (incf index)
1332                 (incf head ,size)))
1333             (setf (buffer-head ibuf) head)
1334             ;; Maybe we need to refill the stream buffer.
1335             (cond ( ;; If there was enough data in the stream buffer, we're done.
1336                    (= index end)
1337                    (return (- index start)))
1338                   ( ;; If EOF, we're done in another way.
1339                    (null (catch 'eof-input-catcher (refill-input-buffer stream)))
1340                    (if eof-error-p
1341                        (error 'end-of-file :stream stream)
1342                        (return (- index start))))
1343                   ;; Otherwise we refilled the stream buffer, so fall
1344                   ;; through into another pass of the loop.
1345                   ))))
1346       (def-input-routine ,in-char-function (character ,size sap head)
1347         (let ((byte (sap-ref-8 sap head)))
1348           ,in-expr))
1349       (defun ,read-c-string-function (sap element-type)
1350         (declare (type system-area-pointer sap)
1351                  (type (member character base-char) element-type))
1352         (locally
1353             (declare (optimize (speed 3) (safety 0)))
1354           (let* ((stream ,name)
1355                  (length
1356                   (loop for head of-type index upfrom 0 by ,size
1357                         for count of-type index upto (1- array-dimension-limit)
1358                         for byte = (sap-ref-8 sap head)
1359                         for char of-type character = ,in-expr
1360                         until (zerop (char-code char))
1361                         finally (return count)))
1362                  ;; Inline the common cases
1363                  (string (make-string length :element-type element-type)))
1364             (declare (ignorable stream)
1365                      (type index length)
1366                      (type simple-string string))
1367             (/show0 before-copy-loop)
1368             (loop for head of-type index upfrom 0 by ,size
1369                for index of-type index below length
1370                for byte = (sap-ref-8 sap head)
1371                for char of-type character = ,in-expr
1372                do (setf (aref string index) char))
1373             string))) ;; last loop rewrite to dotimes?
1374         (defun ,output-c-string-function (string)
1375           (declare (type simple-string string))
1376           (locally
1377               (declare (optimize (speed 3) (safety 0)))
1378             (let* ((length (length string))
1379                    (,n-buffer (make-array (* (1+ length) ,size)
1380                                           :element-type '(unsigned-byte 8)))
1381                    (tail 0)
1382                    (stream ,name))
1383               (declare (type index length tail))
1384               (with-pinned-objects (,n-buffer)
1385                 (let ((sap (vector-sap ,n-buffer)))
1386                   (declare (system-area-pointer sap))
1387                   (dotimes (i length)
1388                     (let* ((byte (aref string i))
1389                            (bits (char-code byte)))
1390                       (declare (ignorable byte bits))
1391                       ,out-expr)
1392                     (incf tail ,size))
1393                   (let* ((bits 0)
1394                          (byte (code-char bits)))
1395                     (declare (ignorable bits byte))
1396                     ,out-expr)))
1397               ,n-buffer)))
1398       (setf *external-formats*
1399        (cons '(,external-format ,in-function ,in-char-function ,out-function
1400                ,@(mapcar #'(lambda (buffering)
1401                              (intern (format nil format (string buffering))))
1402                          '(:none :line :full))
1403                nil ; no resync-function
1404                ,size-function ,read-c-string-function ,output-c-string-function)
1405         *external-formats*)))))
1406
1407 (defmacro define-external-format/variable-width
1408     (external-format output-restart out-size-expr
1409      out-expr in-size-expr in-expr)
1410   (let* ((name (first external-format))
1411          (out-function (symbolicate "OUTPUT-BYTES/" name))
1412          (format (format nil "OUTPUT-CHAR-~A-~~A-BUFFERED" (string name)))
1413          (in-function (symbolicate "FD-STREAM-READ-N-CHARACTERS/" name))
1414          (in-char-function (symbolicate "INPUT-CHAR/" name))
1415          (resync-function (symbolicate "RESYNC/" name))
1416          (size-function (symbolicate "BYTES-FOR-CHAR/" name))
1417          (read-c-string-function (symbolicate "READ-FROM-C-STRING/" name))
1418          (output-c-string-function (symbolicate "OUTPUT-TO-C-STRING/" name))
1419          (n-buffer (gensym "BUFFER")))
1420     `(progn
1421       (defun ,size-function (byte)
1422         (declare (ignorable byte))
1423         ,out-size-expr)
1424       (defun ,out-function (stream string flush-p start end)
1425         (let ((start (or start 0))
1426               (end (or end (length string))))
1427           (declare (type index start end))
1428           (synchronize-stream-output stream)
1429           (unless (<= 0 start end (length string))
1430             (sequence-bounding-indices-bad string start end))
1431           (do ()
1432               ((= end start))
1433             (let ((obuf (fd-stream-obuf stream)))
1434               (setf (buffer-tail obuf)
1435                     (string-dispatch (simple-base-string
1436                                       #!+sb-unicode
1437                                       (simple-array character (*))
1438                                       string)
1439                         string
1440                       (let ((len (buffer-length obuf))
1441                             (sap (buffer-sap obuf))
1442                             ;; FIXME: Rename
1443                             (tail (buffer-tail obuf)))
1444                         (declare (type index tail)
1445                                  ;; STRING bounds have already been checked.
1446                                  (optimize (safety 0)))
1447                         (loop
1448                           (,@(if output-restart
1449                                  `(catch 'output-nothing)
1450                                  `(progn))
1451                              (do* ()
1452                                   ((or (= start end) (< (- len tail) 4)))
1453                                (let* ((byte (aref string start))
1454                                       (bits (char-code byte))
1455                                       (size ,out-size-expr))
1456                                  ,out-expr
1457                                  (incf tail size)
1458                                  (incf start)))
1459                              ;; Exited from the loop normally
1460                              (return tail))
1461                           ;; Exited via CATCH. Skip the current character
1462                           ;; and try the inner loop again.
1463                           (incf start))))))
1464             (when (< start end)
1465               (flush-output-buffer stream)))
1466           (when flush-p
1467             (flush-output-buffer stream))))
1468       (def-output-routines/variable-width (,format
1469                                            ,out-size-expr
1470                                            ,output-restart
1471                                            ,external-format
1472                                            (:none character)
1473                                            (:line character)
1474                                            (:full character))
1475           (if (eql byte #\Newline)
1476               (setf (fd-stream-char-pos stream) 0)
1477               (incf (fd-stream-char-pos stream)))
1478         (let ((bits (char-code byte))
1479               (sap (buffer-sap obuf))
1480               (tail (buffer-tail obuf)))
1481           ,out-expr))
1482       (defun ,in-function (stream buffer start requested eof-error-p
1483                            &aux (total-copied 0))
1484         (declare (type fd-stream stream)
1485                  (type index start requested total-copied)
1486                  (type
1487                   (simple-array character (#.+ansi-stream-in-buffer-length+))
1488                   buffer))
1489         (let ((unread (fd-stream-unread stream)))
1490           (when unread
1491             (setf (aref buffer start) unread)
1492             (setf (fd-stream-unread stream) nil)
1493             (setf (fd-stream-listen stream) nil)
1494             (incf total-copied)))
1495         (do ()
1496             (nil)
1497           (let* ((ibuf (fd-stream-ibuf stream))
1498                  (head (buffer-head ibuf))
1499                  (tail (buffer-tail ibuf))
1500                  (sap (buffer-sap ibuf))
1501                  (decode-break-reason nil))
1502             (declare (type index head tail))
1503             ;; Copy data from stream buffer into user's buffer.
1504             (do ((size nil nil))
1505                 ((or (= tail head) (= requested total-copied)))
1506               (setf decode-break-reason
1507                     (block decode-break-reason
1508                       (let ((byte (sap-ref-8 sap head)))
1509                         (declare (ignorable byte))
1510                         (setq size ,in-size-expr)
1511                         (when (> size (- tail head))
1512                           (return))
1513                         (setf (aref buffer (+ start total-copied)) ,in-expr)
1514                         (incf total-copied)
1515                         (incf head size))
1516                       nil))
1517               (setf (buffer-head ibuf) head)
1518               (when decode-break-reason
1519                 ;; If we've already read some characters on when the invalid
1520                 ;; code sequence is detected, we return immediately. The
1521                 ;; handling of the error is deferred until the next call
1522                 ;; (where this check will be false). This allows establishing
1523                 ;; high-level handlers for decode errors (for example
1524                 ;; automatically resyncing in Lisp comments).
1525                 (when (plusp total-copied)
1526                   (return-from ,in-function total-copied))
1527                 (when (stream-decoding-error-and-handle
1528                        stream decode-break-reason)
1529                   (if eof-error-p
1530                       (error 'end-of-file :stream stream)
1531                       (return-from ,in-function total-copied)))
1532                 (setf head (buffer-head ibuf))
1533                 (setf tail (buffer-tail ibuf))))
1534             (setf (buffer-head ibuf) head)
1535             ;; Maybe we need to refill the stream buffer.
1536             (cond ( ;; If there were enough data in the stream buffer, we're done.
1537                    (= total-copied requested)
1538                    (return total-copied))
1539                   ( ;; If EOF, we're done in another way.
1540                    (or (eq decode-break-reason 'eof)
1541                        (null (catch 'eof-input-catcher
1542                                (refill-input-buffer stream))))
1543                    (if eof-error-p
1544                        (error 'end-of-file :stream stream)
1545                        (return total-copied)))
1546                   ;; Otherwise we refilled the stream buffer, so fall
1547                   ;; through into another pass of the loop.
1548                   ))))
1549       (def-input-routine/variable-width ,in-char-function (character
1550                                                            ,external-format
1551                                                            ,in-size-expr
1552                                                            sap head)
1553         (let ((byte (sap-ref-8 sap head)))
1554           (declare (ignorable byte))
1555           ,in-expr))
1556       (defun ,resync-function (stream)
1557         (let ((ibuf (fd-stream-ibuf stream)))
1558           (loop
1559             (input-at-least stream 2)
1560             (incf (buffer-head ibuf))
1561             (unless (block decode-break-reason
1562                       (let* ((sap (buffer-sap ibuf))
1563                              (head (buffer-head ibuf))
1564                              (byte (sap-ref-8 sap head))
1565                              (size ,in-size-expr))
1566                         (declare (ignorable byte))
1567                         (input-at-least stream size)
1568                         (setf head (buffer-head ibuf))
1569                         ,in-expr)
1570                      nil)
1571              (return)))))
1572       (defun ,read-c-string-function (sap element-type)
1573         (declare (type system-area-pointer sap))
1574         (locally
1575             (declare (optimize (speed 3) (safety 0)))
1576           (let* ((stream ,name)
1577                  (size 0) (head 0) (byte 0) (char nil)
1578                  (decode-break-reason nil)
1579                  (length (dotimes (count (1- ARRAY-DIMENSION-LIMIT) count)
1580                            (setf decode-break-reason
1581                                  (block decode-break-reason
1582                                    (setf byte (sap-ref-8 sap head)
1583                                          size ,in-size-expr
1584                                          char ,in-expr)
1585                                    (incf head size)
1586                                    nil))
1587                            (when decode-break-reason
1588                              (c-string-decoding-error ,name decode-break-reason))
1589                            (when (zerop (char-code char))
1590                              (return count))))
1591                  (string (make-string length :element-type element-type)))
1592             (declare (ignorable stream)
1593                      (type index head length) ;; size
1594                      (type (unsigned-byte 8) byte)
1595                      (type (or null character) char)
1596                      (type string string))
1597             (setf head 0)
1598             (dotimes (index length string)
1599               (setf decode-break-reason
1600                     (block decode-break-reason
1601                       (setf byte (sap-ref-8 sap head)
1602                             size ,in-size-expr
1603                             char ,in-expr)
1604                       (incf head size)
1605                       nil))
1606               (when decode-break-reason
1607                 (c-string-decoding-error ,name decode-break-reason))
1608               (setf (aref string index) char)))))
1609
1610       (defun ,output-c-string-function (string)
1611         (declare (type simple-string string))
1612         (locally
1613             (declare (optimize (speed 3) (safety 0)))
1614           (let* ((length (length string))
1615                  (char-length (make-array (1+ length) :element-type 'index))
1616                  (buffer-length
1617                   (+ (loop for i of-type index below length
1618                         for byte of-type character = (aref string i)
1619                         for bits = (char-code byte)
1620                         sum (setf (aref char-length i)
1621                                   (the index ,out-size-expr)))
1622                      (let* ((byte (code-char 0))
1623                             (bits (char-code byte)))
1624                        (declare (ignorable byte bits))
1625                        (setf (aref char-length length)
1626                              (the index ,out-size-expr)))))
1627                  (tail 0)
1628                  (,n-buffer (make-array buffer-length
1629                                         :element-type '(unsigned-byte 8)))
1630                  stream)
1631             (declare (type index length buffer-length tail)
1632                      (type null stream)
1633                      (ignorable stream))
1634             (with-pinned-objects (,n-buffer)
1635               (let ((sap (vector-sap ,n-buffer)))
1636                 (declare (system-area-pointer sap))
1637                 (loop for i of-type index below length
1638                       for byte of-type character = (aref string i)
1639                       for bits = (char-code byte)
1640                       for size of-type index = (aref char-length i)
1641                       do (prog1
1642                              ,out-expr
1643                            (incf tail size)))
1644                 (let* ((bits 0)
1645                        (byte (code-char bits))
1646                        (size (aref char-length length)))
1647                   (declare (ignorable bits byte size))
1648                   ,out-expr)))
1649             ,n-buffer)))
1650
1651       (setf *external-formats*
1652        (cons '(,external-format ,in-function ,in-char-function ,out-function
1653                ,@(mapcar #'(lambda (buffering)
1654                              (intern (format nil format (string buffering))))
1655                          '(:none :line :full))
1656                ,resync-function
1657                ,size-function ,read-c-string-function ,output-c-string-function)
1658         *external-formats*)))))
1659
1660 ;;; Multiple names for the :ISO{,-}8859-* families are needed because on
1661 ;;; FreeBSD (and maybe other BSD systems), nl_langinfo("LATIN-1") will
1662 ;;; return "ISO8859-1" instead of "ISO-8859-1".
1663 (define-external-format (:latin-1 :latin1 :iso-8859-1 :iso8859-1)
1664     1 t
1665   (if (>= bits 256)
1666       (external-format-encoding-error stream bits)
1667       (setf (sap-ref-8 sap tail) bits))
1668   (code-char byte))
1669
1670 (define-external-format (:ascii :us-ascii :ansi_x3.4-1968
1671                          :iso-646 :iso-646-us :|646|)
1672     1 t
1673   (if (>= bits 128)
1674       (external-format-encoding-error stream bits)
1675       (setf (sap-ref-8 sap tail) bits))
1676   (code-char byte))
1677
1678 (let* ((table (let ((s (make-string 256)))
1679                 (map-into s #'code-char
1680                           '(#x00 #x01 #x02 #x03 #x9c #x09 #x86 #x7f #x97 #x8d #x8e #x0b #x0c #x0d #x0e #x0f
1681                             #x10 #x11 #x12 #x13 #x9d #x85 #x08 #x87 #x18 #x19 #x92 #x8f #x1c #x1d #x1e #x1f
1682                             #x80 #x81 #x82 #x83 #x84 #x0a #x17 #x1b #x88 #x89 #x8a #x8b #x8c #x05 #x06 #x07
1683                             #x90 #x91 #x16 #x93 #x94 #x95 #x96 #x04 #x98 #x99 #x9a #x9b #x14 #x15 #x9e #x1a
1684                             #x20 #xa0 #xe2 #xe4 #xe0 #xe1 #xe3 #xe5 #xe7 #xf1 #xa2 #x2e #x3c #x28 #x2b #x7c
1685                             #x26 #xe9 #xea #xeb #xe8 #xed #xee #xef #xec #xdf #x21 #x24 #x2a #x29 #x3b #xac
1686                             #x2d #x2f #xc2 #xc4 #xc0 #xc1 #xc3 #xc5 #xc7 #xd1 #xa6 #x2c #x25 #x5f #x3e #x3f
1687                             #xf8 #xc9 #xca #xcb #xc8 #xcd #xce #xcf #xcc #x60 #x3a #x23 #x40 #x27 #x3d #x22
1688                             #xd8 #x61 #x62 #x63 #x64 #x65 #x66 #x67 #x68 #x69 #xab #xbb #xf0 #xfd #xfe #xb1
1689                             #xb0 #x6a #x6b #x6c #x6d #x6e #x6f #x70 #x71 #x72 #xaa #xba #xe6 #xb8 #xc6 #xa4
1690                             #xb5 #x7e #x73 #x74 #x75 #x76 #x77 #x78 #x79 #x7a #xa1 #xbf #xd0 #xdd #xde #xae
1691                             #x5e #xa3 #xa5 #xb7 #xa9 #xa7 #xb6 #xbc #xbd #xbe #x5b #x5d #xaf #xa8 #xb4 #xd7
1692                             #x7b #x41 #x42 #x43 #x44 #x45 #x46 #x47 #x48 #x49 #xad #xf4 #xf6 #xf2 #xf3 #xf5
1693                             #x7d #x4a #x4b #x4c #x4d #x4e #x4f #x50 #x51 #x52 #xb9 #xfb #xfc #xf9 #xfa #xff
1694                             #x5c #xf7 #x53 #x54 #x55 #x56 #x57 #x58 #x59 #x5a #xb2 #xd4 #xd6 #xd2 #xd3 #xd5
1695                             #x30 #x31 #x32 #x33 #x34 #x35 #x36 #x37 #x38 #x39 #xb3 #xdb #xdc #xd9 #xda #x9f))
1696                 s))
1697        (reverse-table (let ((rt (make-array 256 :element-type '(unsigned-byte 8) :initial-element 0)))
1698                           (loop for char across table for i from 0
1699                                do (aver (= 0 (aref rt (char-code char))))
1700                                do (setf (aref rt (char-code char)) i))
1701                           rt)))
1702   (define-external-format (:ebcdic-us :ibm-037 :ibm037)
1703       1 t
1704     (if (>= bits 256)
1705         (external-format-encoding-error stream bits)
1706         (setf (sap-ref-8 sap tail) (aref reverse-table bits)))
1707     (aref table byte)))
1708
1709
1710 #!+sb-unicode
1711 (let ((latin-9-table (let ((table (make-string 256)))
1712                        (do ((i 0 (1+ i)))
1713                            ((= i 256))
1714                          (setf (aref table i) (code-char i)))
1715                        (setf (aref table #xa4) (code-char #x20ac))
1716                        (setf (aref table #xa6) (code-char #x0160))
1717                        (setf (aref table #xa8) (code-char #x0161))
1718                        (setf (aref table #xb4) (code-char #x017d))
1719                        (setf (aref table #xb8) (code-char #x017e))
1720                        (setf (aref table #xbc) (code-char #x0152))
1721                        (setf (aref table #xbd) (code-char #x0153))
1722                        (setf (aref table #xbe) (code-char #x0178))
1723                        table))
1724       (latin-9-reverse-1 (make-array 16
1725                                      :element-type '(unsigned-byte 21)
1726                                      :initial-contents '(#x0160 #x0161 #x0152 #x0153 0 0 0 0 #x0178 0 0 0 #x20ac #x017d #x017e 0)))
1727       (latin-9-reverse-2 (make-array 16
1728                                      :element-type '(unsigned-byte 8)
1729                                      :initial-contents '(#xa6 #xa8 #xbc #xbd 0 0 0 0 #xbe 0 0 0 #xa4 #xb4 #xb8 0))))
1730   (define-external-format (:latin-9 :latin9 :iso-8859-15 :iso8859-15)
1731       1 t
1732     (setf (sap-ref-8 sap tail)
1733           (if (< bits 256)
1734               (if (= bits (char-code (aref latin-9-table bits)))
1735                   bits
1736                   (external-format-encoding-error stream byte))
1737               (if (= (aref latin-9-reverse-1 (logand bits 15)) bits)
1738                   (aref latin-9-reverse-2 (logand bits 15))
1739                   (external-format-encoding-error stream byte))))
1740     (aref latin-9-table byte)))
1741
1742 (define-external-format/variable-width (:utf-8 :utf8) nil
1743   (let ((bits (char-code byte)))
1744     (cond ((< bits #x80) 1)
1745           ((< bits #x800) 2)
1746           ((< bits #x10000) 3)
1747           (t 4)))
1748   (ecase size
1749     (1 (setf (sap-ref-8 sap tail) bits))
1750     (2 (setf (sap-ref-8 sap tail)       (logior #xc0 (ldb (byte 5 6) bits))
1751              (sap-ref-8 sap (+ 1 tail)) (logior #x80 (ldb (byte 6 0) bits))))
1752     (3 (setf (sap-ref-8 sap tail)       (logior #xe0 (ldb (byte 4 12) bits))
1753              (sap-ref-8 sap (+ 1 tail)) (logior #x80 (ldb (byte 6 6) bits))
1754              (sap-ref-8 sap (+ 2 tail)) (logior #x80 (ldb (byte 6 0) bits))))
1755     (4 (setf (sap-ref-8 sap tail)       (logior #xf0 (ldb (byte 3 18) bits))
1756              (sap-ref-8 sap (+ 1 tail)) (logior #x80 (ldb (byte 6 12) bits))
1757              (sap-ref-8 sap (+ 2 tail)) (logior #x80 (ldb (byte 6 6) bits))
1758              (sap-ref-8 sap (+ 3 tail)) (logior #x80 (ldb (byte 6 0) bits)))))
1759   (cond ((< byte #x80) 1)
1760         ((< byte #xc2) (return-from decode-break-reason 1))
1761         ((< byte #xe0) 2)
1762         ((< byte #xf0) 3)
1763         (t 4))
1764   (code-char (ecase size
1765                (1 byte)
1766                (2 (let ((byte2 (sap-ref-8 sap (1+ head))))
1767                     (unless (<= #x80 byte2 #xbf)
1768                       (return-from decode-break-reason 2))
1769                     (dpb byte (byte 5 6) byte2)))
1770                (3 (let ((byte2 (sap-ref-8 sap (1+ head)))
1771                         (byte3 (sap-ref-8 sap (+ 2 head))))
1772                     (unless (and (<= #x80 byte2 #xbf)
1773                                  (<= #x80 byte3 #xbf))
1774                       (return-from decode-break-reason 3))
1775                     (dpb byte (byte 4 12) (dpb byte2 (byte 6 6) byte3))))
1776                (4 (let ((byte2 (sap-ref-8 sap (1+ head)))
1777                         (byte3 (sap-ref-8 sap (+ 2 head)))
1778                         (byte4 (sap-ref-8 sap (+ 3 head))))
1779                     (unless (and (<= #x80 byte2 #xbf)
1780                                  (<= #x80 byte3 #xbf)
1781                                  (<= #x80 byte4 #xbf))
1782                       (return-from decode-break-reason 4))
1783                     (dpb byte (byte 3 18)
1784                          (dpb byte2 (byte 6 12)
1785                               (dpb byte3 (byte 6 6) byte4))))))))
1786 \f
1787 ;;;; utility functions (misc routines, etc)
1788
1789 ;;; Fill in the various routine slots for the given type. INPUT-P and
1790 ;;; OUTPUT-P indicate what slots to fill. The buffering slot must be
1791 ;;; set prior to calling this routine.
1792 (defun set-fd-stream-routines (fd-stream element-type external-format
1793                                input-p output-p buffer-p)
1794   (let* ((target-type (case element-type
1795                         (unsigned-byte '(unsigned-byte 8))
1796                         (signed-byte '(signed-byte 8))
1797                         (:default 'character)
1798                         (t element-type)))
1799          (character-stream-p (subtypep target-type 'character))
1800          (bivalent-stream-p (eq element-type :default))
1801          normalized-external-format
1802          (bin-routine #'ill-bin)
1803          (bin-type nil)
1804          (bin-size nil)
1805          (cin-routine #'ill-in)
1806          (cin-type nil)
1807          (cin-size nil)
1808          (input-type nil)           ;calculated from bin-type/cin-type
1809          (input-size nil)           ;calculated from bin-size/cin-size
1810          (read-n-characters #'ill-in)
1811          (bout-routine #'ill-bout)
1812          (bout-type nil)
1813          (bout-size nil)
1814          (cout-routine #'ill-out)
1815          (cout-type nil)
1816          (cout-size nil)
1817          (output-type nil)
1818          (output-size nil)
1819          (output-bytes #'ill-bout))
1820
1821     ;; Ensure that we have buffers in the desired direction(s) only,
1822     ;; getting new ones and dropping/resetting old ones as necessary.
1823     (let ((obuf (fd-stream-obuf fd-stream)))
1824       (if output-p
1825           (if obuf
1826               (reset-buffer obuf)
1827               (setf (fd-stream-obuf fd-stream) (get-buffer)))
1828           (when obuf
1829             (setf (fd-stream-obuf fd-stream) nil)
1830             (release-buffer obuf))))
1831
1832     (let ((ibuf (fd-stream-ibuf fd-stream)))
1833       (if input-p
1834           (if ibuf
1835               (reset-buffer ibuf)
1836               (setf (fd-stream-ibuf fd-stream) (get-buffer)))
1837           (when ibuf
1838             (setf (fd-stream-ibuf fd-stream) nil)
1839             (release-buffer ibuf))))
1840
1841     ;; FIXME: Why only for output? Why unconditionally?
1842     (when output-p
1843       (setf (fd-stream-char-pos fd-stream) 0))
1844
1845     (when (and character-stream-p
1846                (eq external-format :default))
1847       (/show0 "/getting default external format")
1848       (setf external-format (default-external-format)))
1849
1850     (when input-p
1851       (when (or (not character-stream-p) bivalent-stream-p)
1852         (multiple-value-setq (bin-routine bin-type bin-size read-n-characters
1853                                           normalized-external-format)
1854           (pick-input-routine (if bivalent-stream-p '(unsigned-byte 8)
1855                                   target-type)
1856                               external-format))
1857         (unless bin-routine
1858           (error "could not find any input routine for ~S" target-type)))
1859       (when character-stream-p
1860         (multiple-value-setq (cin-routine cin-type cin-size read-n-characters
1861                                           normalized-external-format)
1862           (pick-input-routine target-type external-format))
1863         (unless cin-routine
1864           (error "could not find any input routine for ~S" target-type)))
1865       (setf (fd-stream-in fd-stream) cin-routine
1866             (fd-stream-bin fd-stream) bin-routine)
1867       ;; character type gets preferential treatment
1868       (setf input-size (or cin-size bin-size))
1869       (setf input-type (or cin-type bin-type))
1870       (when normalized-external-format
1871         (setf (fd-stream-external-format fd-stream)
1872               normalized-external-format))
1873       (when (= (or cin-size 1) (or bin-size 1) 1)
1874         (setf (fd-stream-n-bin fd-stream) ;XXX
1875               (if (and character-stream-p (not bivalent-stream-p))
1876                   read-n-characters
1877                   #'fd-stream-read-n-bytes))
1878         ;; Sometimes turn on fast-read-char/fast-read-byte.  Switch on
1879         ;; for character and (unsigned-byte 8) streams.  In these
1880         ;; cases, fast-read-* will read from the
1881         ;; ansi-stream-(c)in-buffer, saving function calls.
1882         ;; Otherwise, the various data-reading functions in the stream
1883         ;; structure will be called.
1884         (when (and buffer-p
1885                    (not bivalent-stream-p)
1886                    ;; temporary disable on :io streams
1887                    (not output-p))
1888           (cond (character-stream-p
1889                  (setf (ansi-stream-cin-buffer fd-stream)
1890                        (make-array +ansi-stream-in-buffer-length+
1891                                    :element-type 'character)))
1892                 ((equal target-type '(unsigned-byte 8))
1893                  (setf (ansi-stream-in-buffer fd-stream)
1894                        (make-array +ansi-stream-in-buffer-length+
1895                                    :element-type '(unsigned-byte 8))))))))
1896
1897     (when output-p
1898       (when (or (not character-stream-p) bivalent-stream-p)
1899         (multiple-value-setq (bout-routine bout-type bout-size output-bytes
1900                                            normalized-external-format)
1901           (pick-output-routine (if bivalent-stream-p
1902                                    '(unsigned-byte 8)
1903                                    target-type)
1904                                (fd-stream-buffering fd-stream)
1905                                external-format))
1906         (unless bout-routine
1907           (error "could not find any output routine for ~S buffered ~S"
1908                  (fd-stream-buffering fd-stream)
1909                  target-type)))
1910       (when character-stream-p
1911         (multiple-value-setq (cout-routine cout-type cout-size output-bytes
1912                                            normalized-external-format)
1913           (pick-output-routine target-type
1914                                (fd-stream-buffering fd-stream)
1915                                external-format))
1916         (unless cout-routine
1917           (error "could not find any output routine for ~S buffered ~S"
1918                  (fd-stream-buffering fd-stream)
1919                  target-type)))
1920       (when normalized-external-format
1921         (setf (fd-stream-external-format fd-stream)
1922               normalized-external-format))
1923       (when character-stream-p
1924         (setf (fd-stream-output-bytes fd-stream) output-bytes))
1925       (setf (fd-stream-out fd-stream) cout-routine
1926             (fd-stream-bout fd-stream) bout-routine
1927             (fd-stream-sout fd-stream) (if (eql cout-size 1)
1928                                            #'fd-sout #'ill-out))
1929       (setf output-size (or cout-size bout-size))
1930       (setf output-type (or cout-type bout-type)))
1931
1932     (when (and input-size output-size
1933                (not (eq input-size output-size)))
1934       (error "Element sizes for input (~S:~S) and output (~S:~S) differ?"
1935              input-type input-size
1936              output-type output-size))
1937     (setf (fd-stream-element-size fd-stream)
1938           (or input-size output-size))
1939
1940     (setf (fd-stream-element-type fd-stream)
1941           (cond ((equal input-type output-type)
1942                  input-type)
1943                 ((null output-type)
1944                  input-type)
1945                 ((null input-type)
1946                  output-type)
1947                 ((subtypep input-type output-type)
1948                  input-type)
1949                 ((subtypep output-type input-type)
1950                  output-type)
1951                 (t
1952                  (error "Input type (~S) and output type (~S) are unrelated?"
1953                         input-type
1954                         output-type))))))
1955
1956 ;;; Handles the resource-release aspects of stream closing, and marks
1957 ;;; it as closed.
1958 (defun release-fd-stream-resources (fd-stream)
1959   (handler-case
1960       (without-interrupts
1961         ;; Drop handlers first.
1962         (when (fd-stream-handler fd-stream)
1963           (remove-fd-handler (fd-stream-handler fd-stream))
1964           (setf (fd-stream-handler fd-stream) nil))
1965         ;; Disable interrupts so that a asynch unwind will not leave
1966         ;; us with a dangling finalizer (that would close the same
1967         ;; --possibly reassigned-- FD again), or a stream with a closed
1968         ;; FD that appears open.
1969         (sb!unix:unix-close (fd-stream-fd fd-stream))
1970         (set-closed-flame fd-stream)
1971         (when (fboundp 'cancel-finalization)
1972           (cancel-finalization fd-stream)))
1973     ;; On error unwind from WITHOUT-INTERRUPTS.
1974     (serious-condition (e)
1975       (error e)))
1976   ;; Release all buffers. If this is undone, or interrupted,
1977   ;; we're still safe: buffers have finalizers of their own.
1978   (release-fd-stream-buffers fd-stream))
1979
1980 ;;; Flushes the current input buffer and unread chatacter, and returns
1981 ;;; the input buffer, and the amount of of flushed input in bytes.
1982 (defun flush-input-buffer (stream)
1983   (let ((unread (if (fd-stream-unread stream)
1984                     1
1985                     0)))
1986     (setf (fd-stream-unread stream) nil)
1987     (let ((ibuf (fd-stream-ibuf stream)))
1988       (if ibuf
1989           (let ((head (buffer-head ibuf))
1990                 (tail (buffer-tail ibuf)))
1991             (values (reset-buffer ibuf) (- (+ unread tail) head)))
1992           (values nil unread)))))
1993
1994 (defun fd-stream-clear-input (stream)
1995   (flush-input-buffer stream)
1996   #!+win32
1997   (progn
1998     (sb!win32:fd-clear-input (fd-stream-fd stream))
1999     (setf (fd-stream-listen stream) nil))
2000   #!-win32
2001   (catch 'eof-input-catcher
2002     (loop until (sysread-may-block-p stream)
2003           do
2004           (refill-input-buffer stream)
2005           (reset-buffer (fd-stream-ibuf stream)))
2006     t))
2007
2008 ;;; Handle miscellaneous operations on FD-STREAM.
2009 (defun fd-stream-misc-routine (fd-stream operation &optional arg1 arg2)
2010   (declare (ignore arg2))
2011   (case operation
2012     (:listen
2013      (labels ((do-listen ()
2014                 (let ((ibuf (fd-stream-ibuf fd-stream)))
2015                   (or (not (eql (buffer-head ibuf) (buffer-tail ibuf)))
2016                       (fd-stream-listen fd-stream)
2017                       #!+win32
2018                       (sb!win32:fd-listen (fd-stream-fd fd-stream))
2019                       #!-win32
2020                       ;; If the read can block, LISTEN will certainly return NIL.
2021                       (if (sysread-may-block-p fd-stream)
2022                           nil
2023                           ;; Otherwise select(2) and CL:LISTEN have slightly
2024                           ;; different semantics.  The former returns that an FD
2025                           ;; is readable when a read operation wouldn't block.
2026                           ;; That includes EOF.  However, LISTEN must return NIL
2027                           ;; at EOF.
2028                           (progn (catch 'eof-input-catcher
2029                                    ;; r-b/f too calls select, but it shouldn't
2030                                    ;; block as long as read can return once w/o
2031                                    ;; blocking
2032                                    (refill-input-buffer fd-stream))
2033                                  ;; At this point either IBUF-HEAD != IBUF-TAIL
2034                                  ;; and FD-STREAM-LISTEN is NIL, in which case
2035                                  ;; we should return T, or IBUF-HEAD ==
2036                                  ;; IBUF-TAIL and FD-STREAM-LISTEN is :EOF, in
2037                                  ;; which case we should return :EOF for this
2038                                  ;; call and all future LISTEN call on this stream.
2039                                  ;; Call ourselves again to determine which case
2040                                  ;; applies.
2041                                  (do-listen)))))))
2042        (do-listen)))
2043     (:unread
2044      (setf (fd-stream-unread fd-stream) arg1)
2045      (setf (fd-stream-listen fd-stream) t))
2046     (:close
2047      (cond (arg1                    ; We got us an abort on our hands.
2048             (let ((outputp (fd-stream-obuf fd-stream))
2049                   (file (fd-stream-file fd-stream))
2050                   (orig (fd-stream-original fd-stream)))
2051               ;; This takes care of the important stuff -- everything
2052               ;; rest is cleaning up the file-system, which we cannot
2053               ;; do on some platforms as long as the file is open.
2054               (release-fd-stream-resources fd-stream)
2055               ;; We can't do anything unless we know what file were
2056               ;; dealing with, and we don't want to do anything
2057               ;; strange unless we were writing to the file.
2058               (when (and outputp file)
2059                 (if orig
2060                     ;; If the original is EQ to file we are appending to
2061                     ;; and can just close the file without renaming.
2062                     (unless (eq orig file)
2063                       ;; We have a handle on the original, just revert.
2064                       (multiple-value-bind (okay err)
2065                           (sb!unix:unix-rename orig file)
2066                         ;; FIXME: Why is this a SIMPLE-STREAM-ERROR, and the
2067                         ;; others are SIMPLE-FILE-ERRORS? Surely they should
2068                         ;; all be the same?
2069                         (unless okay
2070                           (error 'simple-stream-error
2071                                  :format-control
2072                                  "~@<Couldn't restore ~S to its original contents ~
2073                                   from ~S while closing ~S: ~2I~_~A~:>"
2074                                  :format-arguments
2075                                  (list file orig fd-stream (strerror err))
2076                                  :stream fd-stream))))
2077                     ;; We can't restore the original, and aren't
2078                     ;; appending, so nuke that puppy.
2079                     ;;
2080                     ;; FIXME: This is currently the fate of superseded
2081                     ;; files, and according to the CLOSE spec this is
2082                     ;; wrong. However, there seems to be no clean way to
2083                     ;; do that that doesn't involve either copying the
2084                     ;; data (bad if the :abort resulted from a full
2085                     ;; disk), or renaming the old file temporarily
2086                     ;; (probably bad because stream opening becomes more
2087                     ;; racy).
2088                     (multiple-value-bind (okay err)
2089                         (sb!unix:unix-unlink file)
2090                       (unless okay
2091                         (error 'simple-file-error
2092                                :pathname file
2093                                :format-control
2094                                "~@<Couldn't remove ~S while closing ~S: ~2I~_~A~:>"
2095                                :format-arguments
2096                                (list file fd-stream (strerror err)))))))))
2097            (t
2098             (finish-fd-stream-output fd-stream)
2099             (let ((orig (fd-stream-original fd-stream)))
2100               (when (and orig (fd-stream-delete-original fd-stream))
2101                 (multiple-value-bind (okay err) (sb!unix:unix-unlink orig)
2102                   (unless okay
2103                     (error 'simple-file-error
2104                            :pathname orig
2105                            :format-control
2106                            "~@<couldn't delete ~S while closing ~S: ~2I~_~A~:>"
2107                            :format-arguments
2108                            (list orig fd-stream (strerror err)))))))
2109             ;; In case of no-abort close, don't *really* close the
2110             ;; stream until the last moment -- the cleaning up of the
2111             ;; original can be done first.
2112             (release-fd-stream-resources fd-stream))))
2113     (:clear-input
2114      (fd-stream-clear-input fd-stream))
2115     (:force-output
2116      (flush-output-buffer fd-stream))
2117     (:finish-output
2118      (finish-fd-stream-output fd-stream))
2119     (:element-type
2120      (fd-stream-element-type fd-stream))
2121     (:external-format
2122      (fd-stream-external-format fd-stream))
2123     (:interactive-p
2124      (= 1 (the (member 0 1)
2125             (sb!unix:unix-isatty (fd-stream-fd fd-stream)))))
2126     (:line-length
2127      80)
2128     (:charpos
2129      (fd-stream-char-pos fd-stream))
2130     (:file-length
2131      (unless (fd-stream-file fd-stream)
2132        ;; This is a TYPE-ERROR because ANSI's species FILE-LENGTH
2133        ;; "should signal an error of type TYPE-ERROR if stream is not
2134        ;; a stream associated with a file". Too bad there's no very
2135        ;; appropriate value for the EXPECTED-TYPE slot..
2136        (error 'simple-type-error
2137               :datum fd-stream
2138               :expected-type 'fd-stream
2139               :format-control "~S is not a stream associated with a file."
2140               :format-arguments (list fd-stream)))
2141      (multiple-value-bind (okay dev ino mode nlink uid gid rdev size
2142                                 atime mtime ctime blksize blocks)
2143          (sb!unix:unix-fstat (fd-stream-fd fd-stream))
2144        (declare (ignore ino nlink uid gid rdev
2145                         atime mtime ctime blksize blocks))
2146        (unless okay
2147          (simple-stream-perror "failed Unix fstat(2) on ~S" fd-stream dev))
2148        (if (zerop mode)
2149            nil
2150            (truncate size (fd-stream-element-size fd-stream)))))
2151     (:file-string-length
2152      (etypecase arg1
2153        (character (fd-stream-character-size fd-stream arg1))
2154        (string (fd-stream-string-size fd-stream arg1))))
2155     (:file-position
2156      (if arg1
2157          (fd-stream-set-file-position fd-stream arg1)
2158          (fd-stream-get-file-position fd-stream)))))
2159
2160 ;; FIXME: Think about this.
2161 ;;
2162 ;; (defun finish-fd-stream-output (fd-stream)
2163 ;;   (let ((timeout (fd-stream-timeout fd-stream)))
2164 ;;     (loop while (fd-stream-output-queue fd-stream)
2165 ;;        ;; FIXME: SIGINT while waiting for a timeout will
2166 ;;        ;; cause a timeout here.
2167 ;;        do (when (and (not (serve-event timeout)) timeout)
2168 ;;             (signal-timeout 'io-timeout
2169 ;;                             :stream fd-stream
2170 ;;                             :direction :write
2171 ;;                             :seconds timeout)))))
2172
2173 (defun finish-fd-stream-output (stream)
2174   (flush-output-buffer stream)
2175   (do ()
2176       ((null (fd-stream-output-queue stream)))
2177     (serve-all-events)))
2178
2179 (defun fd-stream-get-file-position (stream)
2180   (declare (fd-stream stream))
2181   (without-interrupts
2182     (let ((posn (sb!unix:unix-lseek (fd-stream-fd stream) 0 sb!unix:l_incr)))
2183       (declare (type (or (alien sb!unix:off-t) null) posn))
2184       ;; We used to return NIL for errno==ESPIPE, and signal an error
2185       ;; in other failure cases. However, CLHS says to return NIL if
2186       ;; the position cannot be determined -- so that's what we do.
2187       (when (integerp posn)
2188         ;; Adjust for buffered output: If there is any output
2189         ;; buffered, the *real* file position will be larger
2190         ;; than reported by lseek() because lseek() obviously
2191         ;; cannot take into account output we have not sent
2192         ;; yet.
2193         (dolist (buffer (fd-stream-output-queue stream))
2194           (incf posn (- (buffer-tail buffer) (buffer-head buffer))))
2195         (let ((obuf (fd-stream-obuf stream)))
2196           (when obuf
2197             (incf posn (buffer-tail obuf))))
2198         ;; Adjust for unread input: If there is any input
2199         ;; read from UNIX but not supplied to the user of the
2200         ;; stream, the *real* file position will smaller than
2201         ;; reported, because we want to look like the unread
2202         ;; stuff is still available.
2203         (let ((ibuf (fd-stream-ibuf stream)))
2204           (when ibuf
2205             (decf posn (- (buffer-tail ibuf) (buffer-head ibuf)))))
2206         (when (fd-stream-unread stream)
2207           (decf posn))
2208         ;; Divide bytes by element size.
2209         (truncate posn (fd-stream-element-size stream))))))
2210
2211 (defun fd-stream-set-file-position (stream position-spec)
2212   (declare (fd-stream stream))
2213   (check-type position-spec
2214               (or (alien sb!unix:off-t) (member nil :start :end))
2215               "valid file position designator")
2216   (tagbody
2217    :again
2218      ;; Make sure we don't have any output pending, because if we
2219      ;; move the file pointer before writing this stuff, it will be
2220      ;; written in the wrong location.
2221      (finish-fd-stream-output stream)
2222      ;; Disable interrupts so that interrupt handlers doing output
2223      ;; won't screw us.
2224      (without-interrupts
2225        (unless (fd-stream-output-finished-p stream)
2226          ;; We got interrupted and more output came our way during
2227          ;; the interrupt. Wrapping the FINISH-FD-STREAM-OUTPUT in
2228          ;; WITHOUT-INTERRUPTS gets nasty as it can signal errors,
2229          ;; so we prefer to do things like this...
2230          (go :again))
2231        ;; Clear out any pending input to force the next read to go to
2232        ;; the disk.
2233        (flush-input-buffer stream)
2234        ;; Trash cached value for listen, so that we check next time.
2235        (setf (fd-stream-listen stream) nil)
2236          ;; Now move it.
2237          (multiple-value-bind (offset origin)
2238              (case position-spec
2239                (:start
2240                 (values 0 sb!unix:l_set))
2241                (:end
2242                 (values 0 sb!unix:l_xtnd))
2243                (t
2244                 (values (* position-spec (fd-stream-element-size stream))
2245                         sb!unix:l_set)))
2246            (declare (type (alien sb!unix:off-t) offset))
2247            (let ((posn (sb!unix:unix-lseek (fd-stream-fd stream)
2248                                            offset origin)))
2249              ;; CLHS says to return true if the file-position was set
2250              ;; succesfully, and NIL otherwise. We are to signal an error
2251              ;; only if the given position was out of bounds, and that is
2252              ;; dealt with above. In times past we used to return NIL for
2253              ;; errno==ESPIPE, and signal an error in other cases.
2254              ;;
2255              ;; FIXME: We are still liable to signal an error if flushing
2256              ;; output fails.
2257              (return-from fd-stream-set-file-position
2258                (typep posn '(alien sb!unix:off-t))))))))
2259
2260 \f
2261 ;;;; creation routines (MAKE-FD-STREAM and OPEN)
2262
2263 ;;; Create a stream for the given Unix file descriptor.
2264 ;;;
2265 ;;; If INPUT is non-NIL, allow input operations. If OUTPUT is non-nil,
2266 ;;; allow output operations. If neither INPUT nor OUTPUT is specified,
2267 ;;; default to allowing input.
2268 ;;;
2269 ;;; ELEMENT-TYPE indicates the element type to use (as for OPEN).
2270 ;;;
2271 ;;; BUFFERING indicates the kind of buffering to use.
2272 ;;;
2273 ;;; TIMEOUT (if true) is the number of seconds to wait for input. If
2274 ;;; NIL (the default), then wait forever. When we time out, we signal
2275 ;;; IO-TIMEOUT.
2276 ;;;
2277 ;;; FILE is the name of the file (will be returned by PATHNAME).
2278 ;;;
2279 ;;; NAME is used to identify the stream when printed.
2280 (defun make-fd-stream (fd
2281                        &key
2282                        (input nil input-p)
2283                        (output nil output-p)
2284                        (element-type 'base-char)
2285                        (buffering :full)
2286                        (external-format :default)
2287                        timeout
2288                        file
2289                        original
2290                        delete-original
2291                        pathname
2292                        input-buffer-p
2293                        dual-channel-p
2294                        (name (if file
2295                                  (format nil "file ~A" file)
2296                                  (format nil "descriptor ~W" fd)))
2297                        auto-close)
2298   (declare (type index fd) (type (or real null) timeout)
2299            (type (member :none :line :full) buffering))
2300   (cond ((not (or input-p output-p))
2301          (setf input t))
2302         ((not (or input output))
2303          (error "File descriptor must be opened either for input or output.")))
2304   (let ((stream (%make-fd-stream :fd fd
2305                                  :name name
2306                                  :file file
2307                                  :original original
2308                                  :delete-original delete-original
2309                                  :pathname pathname
2310                                  :buffering buffering
2311                                  :dual-channel-p dual-channel-p
2312                                  :external-format external-format
2313                                  :char-size (external-format-char-size external-format)
2314                                  :timeout
2315                                  (if timeout
2316                                      (coerce timeout 'single-float)
2317                                      nil))))
2318     (set-fd-stream-routines stream element-type external-format
2319                             input output input-buffer-p)
2320     (when (and auto-close (fboundp 'finalize))
2321       (finalize stream
2322                 (lambda ()
2323                   (sb!unix:unix-close fd)
2324                   #!+sb-show
2325                   (format *terminal-io* "** closed file descriptor ~W **~%"
2326                           fd))
2327                 :dont-save t))
2328     stream))
2329
2330 ;;; Pick a name to use for the backup file for the :IF-EXISTS
2331 ;;; :RENAME-AND-DELETE and :RENAME options.
2332 (defun pick-backup-name (name)
2333   (declare (type simple-string name))
2334   (concatenate 'simple-string name ".bak"))
2335
2336 ;;; Ensure that the given arg is one of the given list of valid
2337 ;;; things. Allow the user to fix any problems.
2338 (defun ensure-one-of (item list what)
2339   (unless (member item list)
2340     (error 'simple-type-error
2341            :datum item
2342            :expected-type `(member ,@list)
2343            :format-control "~@<~S is ~_invalid for ~S; ~_need one of~{ ~S~}~:>"
2344            :format-arguments (list item what list))))
2345
2346 ;;; Rename NAMESTRING to ORIGINAL. First, check whether we have write
2347 ;;; access, since we don't want to trash unwritable files even if we
2348 ;;; technically can. We return true if we succeed in renaming.
2349 (defun rename-the-old-one (namestring original)
2350   (unless (sb!unix:unix-access namestring sb!unix:w_ok)
2351     (error "~@<The file ~2I~_~S ~I~_is not writable.~:>" namestring))
2352   (multiple-value-bind (okay err) (sb!unix:unix-rename namestring original)
2353     (if okay
2354         t
2355         (error 'simple-file-error
2356                :pathname namestring
2357                :format-control
2358                "~@<couldn't rename ~2I~_~S ~I~_to ~2I~_~S: ~4I~_~A~:>"
2359                :format-arguments (list namestring original (strerror err))))))
2360
2361 (defun open (filename
2362              &key
2363              (direction :input)
2364              (element-type 'base-char)
2365              (if-exists nil if-exists-given)
2366              (if-does-not-exist nil if-does-not-exist-given)
2367              (external-format :default)
2368              &aux ; Squelch assignment warning.
2369              (direction direction)
2370              (if-does-not-exist if-does-not-exist)
2371              (if-exists if-exists))
2372   #!+sb-doc
2373   "Return a stream which reads from or writes to FILENAME.
2374   Defined keywords:
2375    :DIRECTION - one of :INPUT, :OUTPUT, :IO, or :PROBE
2376    :ELEMENT-TYPE - the type of object to read or write, default BASE-CHAR
2377    :IF-EXISTS - one of :ERROR, :NEW-VERSION, :RENAME, :RENAME-AND-DELETE,
2378                        :OVERWRITE, :APPEND, :SUPERSEDE or NIL
2379    :IF-DOES-NOT-EXIST - one of :ERROR, :CREATE or NIL
2380   See the manual for details."
2381
2382   ;; Calculate useful stuff.
2383   (multiple-value-bind (input output mask)
2384       (ecase direction
2385         (:input  (values   t nil sb!unix:o_rdonly))
2386         (:output (values nil   t sb!unix:o_wronly))
2387         (:io     (values   t   t sb!unix:o_rdwr))
2388         (:probe  (values   t nil sb!unix:o_rdonly)))
2389     (declare (type index mask))
2390     (let* ((pathname (merge-pathnames filename))
2391            (namestring
2392             (cond ((unix-namestring pathname input))
2393                   ((and input (eq if-does-not-exist :create))
2394                    (unix-namestring pathname nil))
2395                   ((and (eq direction :io) (not if-does-not-exist-given))
2396                    (unix-namestring pathname nil)))))
2397       ;; Process if-exists argument if we are doing any output.
2398       (cond (output
2399              (unless if-exists-given
2400                (setf if-exists
2401                      (if (eq (pathname-version pathname) :newest)
2402                          :new-version
2403                          :error)))
2404              (ensure-one-of if-exists
2405                             '(:error :new-version :rename
2406                                      :rename-and-delete :overwrite
2407                                      :append :supersede nil)
2408                             :if-exists)
2409              (case if-exists
2410                ((:new-version :error nil)
2411                 (setf mask (logior mask sb!unix:o_excl)))
2412                ((:rename :rename-and-delete)
2413                 (setf mask (logior mask sb!unix:o_creat)))
2414                ((:supersede)
2415                 (setf mask (logior mask sb!unix:o_trunc)))
2416                (:append
2417                 (setf mask (logior mask sb!unix:o_append)))))
2418             (t
2419              (setf if-exists :ignore-this-arg)))
2420
2421       (unless if-does-not-exist-given
2422         (setf if-does-not-exist
2423               (cond ((eq direction :input) :error)
2424                     ((and output
2425                           (member if-exists '(:overwrite :append)))
2426                      :error)
2427                     ((eq direction :probe)
2428                      nil)
2429                     (t
2430                      :create))))
2431       (ensure-one-of if-does-not-exist
2432                      '(:error :create nil)
2433                      :if-does-not-exist)
2434       (if (eq if-does-not-exist :create)
2435         (setf mask (logior mask sb!unix:o_creat)))
2436
2437       (let ((original (case if-exists
2438                         ((:rename :rename-and-delete)
2439                          (pick-backup-name namestring))
2440                         ((:append :overwrite)
2441                          ;; KLUDGE: Provent CLOSE from deleting
2442                          ;; appending streams when called with :ABORT T
2443                          namestring)))
2444             (delete-original (eq if-exists :rename-and-delete))
2445             (mode #o666))
2446         (when (and original (not (eq original namestring)))
2447           ;; We are doing a :RENAME or :RENAME-AND-DELETE. Determine
2448           ;; whether the file already exists, make sure the original
2449           ;; file is not a directory, and keep the mode.
2450           (let ((exists
2451                  (and namestring
2452                       (multiple-value-bind (okay err/dev inode orig-mode)
2453                           (sb!unix:unix-stat namestring)
2454                         (declare (ignore inode)
2455                                  (type (or index null) orig-mode))
2456                         (cond
2457                          (okay
2458                           (when (and output (= (logand orig-mode #o170000)
2459                                                #o40000))
2460                             (error 'simple-file-error
2461                                    :pathname namestring
2462                                    :format-control
2463                                    "can't open ~S for output: is a directory"
2464                                    :format-arguments (list namestring)))
2465                           (setf mode (logand orig-mode #o777))
2466                           t)
2467                          ((eql err/dev sb!unix:enoent)
2468                           nil)
2469                          (t
2470                           (simple-file-perror "can't find ~S"
2471                                               namestring
2472                                               err/dev)))))))
2473             (unless (and exists
2474                          (rename-the-old-one namestring original))
2475               (setf original nil)
2476               (setf delete-original nil)
2477               ;; In order to use :SUPERSEDE instead, we have to make
2478               ;; sure SB!UNIX:O_CREAT corresponds to
2479               ;; IF-DOES-NOT-EXIST. SB!UNIX:O_CREAT was set before
2480               ;; because of IF-EXISTS being :RENAME.
2481               (unless (eq if-does-not-exist :create)
2482                 (setf mask
2483                       (logior (logandc2 mask sb!unix:o_creat)
2484                               sb!unix:o_trunc)))
2485               (setf if-exists :supersede))))
2486
2487         ;; Now we can try the actual Unix open(2).
2488         (multiple-value-bind (fd errno)
2489             (if namestring
2490                 (sb!unix:unix-open namestring mask mode)
2491                 (values nil sb!unix:enoent))
2492           (labels ((open-error (format-control &rest format-arguments)
2493                      (error 'simple-file-error
2494                             :pathname pathname
2495                             :format-control format-control
2496                             :format-arguments format-arguments))
2497                    (vanilla-open-error ()
2498                      (simple-file-perror "error opening ~S" pathname errno)))
2499             (cond ((numberp fd)
2500                    (case direction
2501                      ((:input :output :io)
2502                       (make-fd-stream fd
2503                                       :input input
2504                                       :output output
2505                                       :element-type element-type
2506                                       :external-format external-format
2507                                       :file namestring
2508                                       :original original
2509                                       :delete-original delete-original
2510                                       :pathname pathname
2511                                       :dual-channel-p nil
2512                                       :input-buffer-p t
2513                                       :auto-close t))
2514                      (:probe
2515                       (let ((stream
2516                              (%make-fd-stream :name namestring
2517                                               :fd fd
2518                                               :pathname pathname
2519                                               :element-type element-type)))
2520                         (close stream)
2521                         stream))))
2522                   ((eql errno sb!unix:enoent)
2523                    (case if-does-not-exist
2524                      (:error (vanilla-open-error))
2525                      (:create
2526                       (open-error "~@<The path ~2I~_~S ~I~_does not exist.~:>"
2527                                   pathname))
2528                      (t nil)))
2529                   ((and (eql errno sb!unix:eexist) (null if-exists))
2530                    nil)
2531                   (t
2532                    (vanilla-open-error)))))))))
2533 \f
2534 ;;;; initialization
2535
2536 ;;; the stream connected to the controlling terminal, or NIL if there is none
2537 (defvar *tty*)
2538
2539 ;;; the stream connected to the standard input (file descriptor 0)
2540 (defvar *stdin*)
2541
2542 ;;; the stream connected to the standard output (file descriptor 1)
2543 (defvar *stdout*)
2544
2545 ;;; the stream connected to the standard error output (file descriptor 2)
2546 (defvar *stderr*)
2547
2548 ;;; This is called when the cold load is first started up, and may also
2549 ;;; be called in an attempt to recover from nested errors.
2550 (defun stream-cold-init-or-reset ()
2551   (stream-reinit)
2552   (setf *terminal-io* (make-synonym-stream '*tty*))
2553   (setf *standard-output* (make-synonym-stream '*stdout*))
2554   (setf *standard-input* (make-synonym-stream '*stdin*))
2555   (setf *error-output* (make-synonym-stream '*stderr*))
2556   (setf *query-io* (make-synonym-stream '*terminal-io*))
2557   (setf *debug-io* *query-io*)
2558   (setf *trace-output* *standard-output*)
2559   (values))
2560
2561 (defun stream-deinit ()
2562   ;; Unbind to make sure we're not accidently dealing with it
2563   ;; before we're ready (or after we think it's been deinitialized).
2564   (with-available-buffers-lock ()
2565     (without-package-locks
2566         (makunbound '*available-buffers*))))
2567
2568 ;;; This is called whenever a saved core is restarted.
2569 (defun stream-reinit (&optional init-buffers-p)
2570   (when init-buffers-p
2571     (with-available-buffers-lock ()
2572       (aver (not (boundp '*available-buffers*)))
2573       (setf *available-buffers* nil)))
2574   (with-output-to-string (*error-output*)
2575     (setf *stdin*
2576           (make-fd-stream 0 :name "standard input" :input t :buffering :line
2577                             #!+win32 :external-format #!+win32 (sb!win32::console-input-codepage)))
2578     (setf *stdout*
2579           (make-fd-stream 1 :name "standard output" :output t :buffering :line
2580                             #!+win32 :external-format #!+win32 (sb!win32::console-output-codepage)))
2581     (setf *stderr*
2582           (make-fd-stream 2 :name "standard error" :output t :buffering :line
2583                             #!+win32 :external-format #!+win32 (sb!win32::console-output-codepage)))
2584     (let* ((ttyname #.(coerce "/dev/tty" 'simple-base-string))
2585            (tty (sb!unix:unix-open ttyname sb!unix:o_rdwr #o666)))
2586       (if tty
2587           (setf *tty*
2588                 (make-fd-stream tty
2589                                 :name "the terminal"
2590                                 :input t
2591                                 :output t
2592                                 :buffering :line
2593                                 :auto-close t))
2594           (setf *tty* (make-two-way-stream *stdin* *stdout*))))
2595     (princ (get-output-stream-string *error-output*) *stderr*))
2596   (values))
2597 \f
2598 ;;;; miscellany
2599
2600 ;;; the Unix way to beep
2601 (defun beep (stream)
2602   (write-char (code-char bell-char-code) stream)
2603   (finish-output stream))
2604
2605 ;;; This is kind of like FILE-POSITION, but is an internal hack used
2606 ;;; by the filesys stuff to get and set the file name.
2607 ;;;
2608 ;;; FIXME: misleading name, screwy interface
2609 (defun file-name (stream &optional new-name)
2610   (when (typep stream 'fd-stream)
2611       (cond (new-name
2612              (setf (fd-stream-pathname stream) new-name)
2613              (setf (fd-stream-file stream)
2614                    (unix-namestring new-name nil))
2615              t)
2616             (t
2617              (fd-stream-pathname stream)))))