dev/graph.lisp

   1 ;;;-*- Mode: Lisp; Package: metabang.graph -*-
   2
   3 #|
   4 $Id: graph.lisp,v 1.30 2005/09/07 16:17:06 gwking Exp $
   5
   6 Author: Gary W. King, et. al.
   7
   8 |#
   9
  10 #| NOTES
  11
  12 something is putting something on the vertexes plist's
  13
  14 |#
  15
  16
  17 (in-package #:metabang.graph)
  18
  19 ;;; ---------------------------------------------------------------------------
  20 ;;; classes
  21 ;;; ---------------------------------------------------------------------------
  22
  23 (defcondition graph-error (error)
  24   ((graph nil ir))
  25   (:export-p t)
  26   (:export-slots-p t)
  27   (:documentation "This is the root condition for errors that occur while running code in CL-Graph."))
  28
  29 ;;; ---------------------------------------------------------------------------
  30
  31 (defcondition edge-error (graph-error)
  32   ((edge nil ir "The `edge` that is implicated in the condition."))
  33   (:export-p t)
  34   (:export-slots-p t)
  35   (:documentation "This is the root condition for graph errors that have to do with edges."))
  36
  37 ;;; ---------------------------------------------------------------------------
  38
  39 (defcondition graph-vertex-not-found-error (graph-error)
  40   ((vertex nil ir "The vertex or value that could not be found in the graph."))
  41   (:report (lambda (c s)
  42              (format s "Vertex ~S not found in ~A" (vertex c) (graph c))))
  43   (:export-p t)
  44   (:export-slots-p t)
  45   (:documentation "This condition is signaled when a vertex can not be found in a graph."))
  46
  47 ;;; ---------------------------------------------------------------------------
  48
  49 (defcondition graph-vertex-not-found-in-edge-error (edge-error)
  50   ((vertex nil ir))
  51   (:report (lambda (c s)
  52              (format s "Vertex ~S not found in ~A" (vertex c) (edge c))))
  53   (:export-p t)
  54   (:documentation "This condition is signaled when a vertex can not be found in an edge."))
  55
  56 ;;; ---------------------------------------------------------------------------
  57
  58 (defcondition graph-edge-not-found-error (graph-error)
  59   ((vertex-1 nil ir "One of the vertexes for which no connecting edge could be found.")
  60    (vertex-2 nil ir "One of the vertexes for which no connecting edge could be found."))
  61   (:report (lambda (c s)
  62              (format s "Edge between ~S and ~S not found in ~A"
  63                      (vertex-1 c) (vertex-2 c) (graph c))))
  64   (:export-p t)
  65   (:export-slots-p t)
  66   (:documentation "This condition is signaled when an edge cannot be found in a graph."))
  67
  68 ;;; ---------------------------------------------------------------------------
  69
  70 (defclass* basic-vertex (container-node-mixin)
  71   ((depth-level 0 ia :type number "`Depth-level` is used by some algorithms for bookkeeping.  [?? Should be in a mixin]")
  72    (vertex-id 0 ir "`Vertex-id` is used internally to keep track of vertexes.")
  73    (element :unbound ia :accessor value "The `element` is the value that this vertex represents.")
  74    (tag nil ia "The `tag` slot is used by some algorithms to keep track of which vertexes have been visited.")
  75    (graph nil ia "The graph in which this vertex is contained.")
  76    (color nil ia "The `color` slot is used by some algorithms for bookkeeping.")
  77    (rank nil ia "The `rank` is used by some algorithms for bookkeeping.  [?? Should be in a mixin]")
  78    (previous-node nil ia "`Previous-node` is used by some algorithms for bookkeeping. [?? Should be in a mixin]")
  79    (next-node nil ia "`Next-node` is used by some algorithms for bookkeeping.  [?? Should be in a mixin]")
  80    (discovery-time -1 ia "`Discovery-time` is used by some algorithms for bookkeeping.  [?? Should be in a mixin]")
  81    (finish-time -1 ia "`Finish-time` is used by some algorithms for bookkeeping.  [?? Should be in a mixin]"))
  82   (:export-p t)
  83   (:export-slots vertex-id tag rank color previous-node next-node
  84                  discovery-time finish-time)
  85   (:make-load-form-p t)
  86   (:documentation "This is the root class for all vertexes in CL-Graph."))
  87
  88 ;;; ---------------------------------------------------------------------------
  89
  90 (defmethod initialize-instance :after ((object basic-vertex) &key graph vertex-id)
  91   (when (and graph (not vertex-id))
  92     (setf (slot-value object 'vertex-id)
  93           (largest-vertex-id graph))
  94     (incf (slot-value graph 'largest-vertex-id))))
  95
  96 ;;; ---------------------------------------------------------------------------
  97
  98 (defmethod print-object ((vertex basic-vertex) stream)
  99   (print-unreadable-object (vertex stream :identity nil)
 100     (format stream "~A"
 101             (if (and (slot-exists-p vertex 'element) (slot-boundp vertex 'element))
 102               (element vertex) "#unbound#"))))
 103
 104 ;;; ---------------------------------------------------------------------------
 105
 106 (defclass* basic-edge ()
 107   ((edge-id 0 ia "The `edge-id` is used internally by CL-Graph for bookkeeping.")
 108    (element nil ia :accessor value :initarg :value)
 109    (tag nil ia "The `tag` is used by some algorithms for bookkeeping. [?? Should probably be in a mixin]")
 110    (graph nil ir "The `graph` of which this edge is a part.")
 111    (color nil ia "The `color` is used by some algorithms for bookkeeping. [?? Should probably be in a mixin]"))
 112   (:export-p t)
 113   (:export-slots edge-id element tag color)
 114   (:make-load-form-p t)
 115   (:documentation "This is the root class for all edges in CL-Graph."))
 116
 117 ;;; ---------------------------------------------------------------------------
 118
 119 (defmethod initialize-instance :after ((object basic-edge) &key graph edge-id)
 120   (when (and graph (not edge-id))
 121     (setf (slot-value object 'edge-id)
 122           (largest-edge-id graph))
 123     (incf (slot-value graph 'largest-edge-id))))
 124
 125 ;;; ---------------------------------------------------------------------------
 126
 127 (defmethod print-object ((object basic-edge) stream)
 128   (print-unreadable-object (object stream :type t)
 129     (format stream "<~A ~A>" (vertex-1 object) (vertex-2 object))))
 130
 131 ;;; ---------------------------------------------------------------------------
 132
 133 (defclass* directed-edge-mixin () ()
 134   (:export-p t)
 135   (:documentation "This mixin class is used to indicate that an edge is directed."))
 136
 137 ;;; ---------------------------------------------------------------------------
 138
 139 (defclass* weighted-edge-mixin ()
 140   ((weight 1d0 ia "The value of the weight of this edge. Defaults to 1.0d0"))
 141   :export-slots
 142   (:export-p t)
 143   (:documentation "This mixin class adds a `weight` slot to an edge."))
 144
 145 ;;; ---------------------------------------------------------------------------
 146
 147 (defmethod weight ((edge basic-edge)) (values 1.0))
 148
 149 ;;; ---------------------------------------------------------------------------
 150
 151 (defclass* basic-graph ()
 152   ((graph-vertexes :unbound ir)
 153    (graph-edges :unbound ir)
 154    (largest-vertex-id 0 r)
 155    (largest-edge-id 0 r)
 156    (vertex-class 'basic-vertex ir
 157                  "The class of the vertexes in the graph. This must extend the base-class for vertexes of the graph type. E.g., all vertexes of a graph-container must extend graph-container-vertex.")
 158    (directed-edge-class 'basic-directed-edge ir
 159                         "The class used to create directed edges in the graph. This must extend the base-class for edges of the graph type and directed-edge-mixin. E.g., the directed-edge-class of a graph-container must extend graph-container-edge and directed-edge-mixin.")
 160    (undirected-edge-class 'basic-edge ir
 161                           "The class used to create undirected edges in the graph. This must extend the base-class for edges of the graph type. E.g., all edges of a graph-container must extend graph-container-edge")
 162    (contains-directed-edge-p nil ar
 163                              "Returns true if graph contains at least one directed edge. [?? Not sure if this is really keep up-to-date.]")
 164    (contains-undirected-edge-p nil ar
 165                                "Returns true if graph contains at least one undirected edge. [?? Not sure if this is really keep up-to-date.]")
 166    (vertex-test #'eq ir)
 167    (vertex-key #'identity ir)
 168    (edge-test #'eq ir)
 169    (edge-key #'identity ir)
 170    (default-edge-type nil ir
 171      "The default edge type for the graph. This should be one of :undirected or :directed.")
 172    (default-edge-class nil ir
 173      "The default edge class for the graph."))
 174   (:make-load-form-p t)
 175   (:export-slots vertex-class directed-edge-class undirected-edge-class
 176                  default-edge-type default-edge-class)
 177   (:default-initargs
 178     :initial-size 25)
 179   (:documentation "This is the root class for all graphs in CL-Graph."))
 180
 181 ;;; ---------------------------------------------------------------------------
 182
 183 (defmethod initialize-instance :after ((object basic-graph) &key initial-size
 184                                        &allow-other-keys)
 185   (setf (slot-value object 'graph-vertexes)
 186         (make-vertex-container object initial-size))
 187   (setf (slot-value object 'graph-edges)
 188         (make-edge-container object initial-size)))
 189
 190 ;;; ---------------------------------------------------------------------------
 191
 192 (defmethod print-object ((graph basic-graph) stream)
 193   (print-unreadable-object (graph stream :type t :identity t)
 194     (format stream "[~A,~A]" (size graph) (edge-count graph))))
 195
 196
 197 ;;; ---------------------------------------------------------------------------
 198 ;;; internals
 199 ;;; ---------------------------------------------------------------------------
 200
 201 (defmethod add-vertex ((graph basic-graph) (value basic-vertex) &key if-duplicate-do)
 202   (declare (ignore if-duplicate-do))
 203   (values value))
 204
 205 ;;; ---------------------------------------------------------------------------
 206
 207 (defmethod make-vertex-for-graph ((graph basic-graph) &rest args &key
 208                                   (vertex-class (vertex-class graph))
 209                                   &allow-other-keys)
 210   (remf args :vertex-class)
 211   (assert (subtypep vertex-class (vertex-class graph)) nil
 212           "Vertex class '~A' must be a subtype of ~A" vertex-class (vertex-class graph))
 213   (apply #'make-instance vertex-class :graph graph args))
 214
 215 ;;; ---------------------------------------------------------------------------
 216
 217 (defmethod make-edge-for-graph ((graph basic-graph)
 218                                 (vertex-1 basic-vertex) (vertex-2 basic-vertex)
 219                                 &rest args &key
 220                                 (edge-type (default-edge-type graph))
 221                                 (edge-class (default-edge-class graph))
 222                                 &allow-other-keys)
 223   (remf args :edge-class)
 224   (remf args :edge-type)
 225   (assert (or (null edge-type)
 226               (eq edge-type :directed)
 227               (eq edge-type :undirected)) nil
 228           "Edge-type must be nil, :directed or :undirected.")
 229
 230   (assert (or (null edge-class)
 231               (subtypep edge-class (directed-edge-class graph))
 232               (subtypep edge-class (undirected-edge-class graph))) nil
 233           "Edge-class must be nil or a subtype of ~A or ~A"
 234           (undirected-edge-class graph)
 235           (directed-edge-class graph))
 236
 237   (apply #'make-instance
 238          (or edge-class
 239              (ecase edge-type
 240                (:directed (directed-edge-class graph))
 241                (:undirected (undirected-edge-class graph))
 242                ((nil) nil))
 243              (undirected-edge-class graph))
 244          :graph graph
 245          :vertex-1 vertex-1 :vertex-2 vertex-2 args))
 246
 247 ;;; ---------------------------------------------------------------------------
 248
 249 (defmethod make-graph ((graph-type symbol) &rest args &key &allow-other-keys)
 250   (apply #'make-instance graph-type args))
 251
 252 ;;; ---------------------------------------------------------------------------
 253
 254 (defmethod make-graph ((classes list) &rest args)
 255   (let ((name (find-or-create-class 'basic-graph classes)))
 256     (apply #'make-instance name args)))
 257
 258 ;;; ---------------------------------------------------------------------------
 259 ;;; generic implementation
 260 ;;; ---------------------------------------------------------------------------
 261
 262 (defmethod undirected-edge-p ((edge basic-edge))
 263   (not (directed-edge-p edge)))
 264
 265 ;;; ---------------------------------------------------------------------------
 266
 267 (defmethod directed-edge-p ((edge basic-edge))
 268   (typep edge 'directed-edge-mixin))
 269
 270 ;;; ---------------------------------------------------------------------------
 271
 272 (defmethod tagged-edge-p ((edge basic-edge))
 273   (tag edge))
 274
 275 ;;; ---------------------------------------------------------------------------
 276
 277 (defmethod untagged-edge-p ((edge basic-edge))
 278   (null (tag edge)))
 279
 280 ;;; ---------------------------------------------------------------------------
 281
 282 (defmethod tag-all-edges ((graph basic-graph))
 283   (iterate-edges
 284    graph
 285    (lambda (e)
 286      (setf (tag e) t))))
 287
 288 ;;; ---------------------------------------------------------------------------
 289
 290 (defmethod tag-all-edges ((vertex basic-vertex))
 291   (iterate-edges
 292    vertex
 293    (lambda (e)
 294      (setf (tag e) t))))
 295
 296 ;;; ---------------------------------------------------------------------------
 297
 298 (defmethod untag-all-edges ((graph basic-graph))
 299   (iterate-edges
 300    graph
 301    (lambda (e)
 302      (setf (tag e) nil))))
 303
 304 ;;; ---------------------------------------------------------------------------
 305
 306 (defmethod untag-all-edges ((vertex basic-vertex))
 307   (iterate-edges
 308    vertex
 309    (lambda (e)
 310      (setf (tag e) nil))))
 311
 312 ;;; ---------------------------------------------------------------------------
 313
 314 (defmethod untag-edges ((edges list))
 315   (iterate-nodes
 316    edges
 317    (lambda (e)
 318      (setf (tag e) nil))))
 319
 320 ;;; ---------------------------------------------------------------------------
 321
 322 (defmethod tag-edges ((edges list))
 323   (iterate-nodes
 324    edges
 325    (lambda (e)
 326      (setf (tag e) t))))
 327
 328
 329 ;;; ---------------------------------------------------------------------------
 330
 331 (defmethod (setf element) :around ((value t) (vertex basic-vertex))
 332   (with-changing-vertex (vertex)
 333     (call-next-method)))
 334
 335 ;;; ---------------------------------------------------------------------------
 336
 337 ;; :ignore, :force, :replace, <function>
 338
 339 (defmethod add-vertex ((graph basic-graph) (value t) &rest args &key
 340                        (if-duplicate-do :ignore) &allow-other-keys)
 341   (remf args :if-duplicate-do)
 342   (let ((existing-vertex (find-vertex graph value nil)))
 343     (labels ((make-it ()
 344                (apply #'make-vertex-for-graph graph :element value args))
 345              (add-it (why)
 346                (values (add-vertex graph (make-it)) why)))
 347       (if existing-vertex
 348         (cond ((eq if-duplicate-do :ignore)
 349                (values existing-vertex :ignore))
 350
 351               ((eq if-duplicate-do :force)
 352                (add-it :force))
 353
 354               ((eq if-duplicate-do :replace)
 355                (replace-vertex graph existing-vertex (make-it)))
 356
 357               ((eq if-duplicate-do :replace-value)
 358                (setf (element existing-vertex) value)
 359                (values existing-vertex :replace-value))
 360
 361               (t
 362                (values (funcall if-duplicate-do existing-vertex)
 363                        :duplicate)))
 364
 365         ;; not found, add
 366         (add-it :new)))))
 367
 368 ;;; ---------------------------------------------------------------------------
 369
 370 (defmethod replace-vertex ((graph basic-graph) (old basic-vertex) (new basic-vertex))
 371   ;; we need the graph and the new vertex to reference each other
 372   ;; we need every edge of the old vertex to use the new-vertex
 373   ;; we need to remove the old vertex
 374   ;;
 375   ;; since I'm tired today, let's ignore trying to make this elegant
 376
 377   ;; first, we connect the edges to the new vertex so that they don't get deleted
 378   ;; when we delete the old vertex
 379   (iterate-edges
 380    old
 381    (lambda (e)
 382      (if (eq (vertex-1 e) old)
 383        (setf (slot-value e 'vertex-1) new) (setf (slot-value e 'vertex-2) new))
 384      (add-edge-to-vertex e new)))
 385
 386   (delete-vertex graph old)
 387   (add-vertex graph new))
 388
 389 ;;; ---------------------------------------------------------------------------
 390
 391 (defmethod add-edge-between-vertexes ((graph basic-graph) (value-1 t) (value-2 t)
 392                                       &rest args &key (if-duplicate-do :ignore)
 393                                       &allow-other-keys)
 394   (declare (ignore if-duplicate-do)
 395            (dynamic-extent args))
 396   (let ((v1 (or (find-vertex graph value-1 nil)
 397                 (add-vertex graph value-1 :if-duplicate-do :ignore)))
 398         (v2 (or (find-vertex graph value-2 nil)
 399                 (add-vertex graph value-2  :if-duplicate-do :replace))))
 400     (apply #'add-edge-between-vertexes graph v1 v2 args)))
 401
 402 ;;; ---------------------------------------------------------------------------
 403 ;;; to-do - add-edge-between-vertexes needs to be able to grab the weight and
 404 ;;; color from edges that inherit from weight and color mixins
 405 ;;; ---------------------------------------------------------------------------
 406
 407 (defmethod add-edge-between-vertexes ((graph basic-graph)
 408                                       (v-1 basic-vertex) (v-2 basic-vertex)
 409                                       &rest args &key
 410                                       (value nil) (if-duplicate-do :ignore)
 411                                       &allow-other-keys)
 412   (declare (dynamic-extent args))
 413   (remf args :if-duplicate-do)
 414
 415   (let ((edge (find-edge-between-vertexes graph v-1 v-2 :error-if-not-found? nil)))
 416     (flet ((add-it (why)
 417              (values (add-edge
 418                       graph
 419                       (apply #'make-edge-for-graph graph v-1 v-2 args))
 420                      why)))
 421       (if edge
 422         (cond
 423          ((eq if-duplicate-do :ignore)
 424           (values edge :ignore))
 425
 426          ((eq if-duplicate-do :force)
 427           (add-it :force))
 428
 429          ((eq if-duplicate-do :force-if-different-value)
 430           (if (equal (value edge) value)
 431             (values :ignore)
 432             (add-it :force)))
 433
 434
 435          ((eq if-duplicate-do :replace)
 436           (warn "replace edges isn't really implemented, maybe you can use :replace-value")
 437           (delete-edge graph edge)
 438           (add-it :replace))
 439
 440          ((eq if-duplicate-do :replace-value)
 441           (setf (element edge) value)
 442           (values edge :replace-value))
 443
 444          (t
 445           (setf edge (funcall if-duplicate-do edge))
 446           (values edge :duplicate)))
 447
 448         ;; not found, add
 449         (add-it :new)))))
 450
 451
 452 ;;; ---------------------------------------------------------------------------
 453
 454 (defmethod add-edge-to-vertex ((edge basic-edge) (vertex basic-vertex))
 455   (values))
 456
 457 ;;; ---------------------------------------------------------------------------
 458
 459 (defmethod find-edge-between-vertexes ((graph basic-graph) (value-1 t) (value-2 t)
 460                                        &key (error-if-not-found? t))
 461   (let ((v1 (find-vertex graph value-1 error-if-not-found?))
 462         (v2 (find-vertex graph value-2 error-if-not-found?)))
 463     (aif (and v1 v2 (find-edge-between-vertexes graph v1 v2))
 464          it
 465          (when error-if-not-found?
 466            (error 'graph-edge-not-found-error :vertex-1 v1 :vertex-2 v2)))))
 467
 468 ;;; ---------------------------------------------------------------------------
 469
 470 (defmethod delete-edge-between-vertexes ((graph basic-graph)
 471                                          (value-or-vertex-1 t)
 472                                          (value-or-vertex-2 t) &rest args)
 473   (let ((edge (apply #'find-edge-between-vertexes
 474                      graph value-or-vertex-1 value-or-vertex-2 args)))
 475     (when edge
 476       (delete-edge graph edge))))
 477
 478 ;;; ---------------------------------------------------------------------------
 479
 480 (defmethod delete-edge :after ((graph basic-graph) (edge basic-edge))
 481   (delete-item (graph-edges graph) edge)
 482   edge)
 483
 484
 485 (defmethod delete-all-edges :after ((graph basic-graph))
 486   (empty! (graph-edges graph))
 487   graph)
 488
 489 ;;; ---------------------------------------------------------------------------
 490
 491 (defmethod delete-vertex ((graph basic-graph) value-or-vertex)
 492   (delete-vertex graph (find-vertex graph value-or-vertex)))
 493
 494 ;;; ---------------------------------------------------------------------------
 495
 496 (defmethod delete-vertex ((graph basic-graph) (vertex basic-vertex))
 497   (unless (eq graph (graph vertex))
 498     (error 'graph-vertex-not-found-error
 499            :graph graph :vertex vertex))
 500
 501   (iterate-edges
 502    vertex
 503    (lambda (edge)
 504      (delete-edge graph edge)))
 505
 506   (empty! (vertex-edges vertex))
 507   (values vertex graph))
 508
 509 ;;; ---------------------------------------------------------------------------
 510
 511 (defmethod delete-vertex :after ((graph basic-graph)
 512                                  (vertex basic-vertex))
 513   (setf (slot-value vertex 'graph) nil)
 514   (delete-item-at (graph-vertexes graph)
 515                   (funcall (vertex-key graph) (element vertex))))
 516
 517 ;;; ---------------------------------------------------------------------------
 518
 519 (defmethod insert-item ((graph basic-graph) value)
 520   (add-vertex graph value))
 521
 522 ;;; ---------------------------------------------------------------------------
 523
 524 (defmethod source-edges ((vertex basic-vertex) &optional filter)
 525   (collect-using #'iterate-source-edges filter vertex))
 526
 527 ;;; ---------------------------------------------------------------------------
 528
 529 (defmethod target-edges ((vertex basic-vertex) &optional filter)
 530   (collect-using #'iterate-target-edges filter vertex))
 531
 532 ;;; ---------------------------------------------------------------------------
 533
 534 (defmethod child-vertexes (vertex &optional filter)
 535   (collect-using #'iterate-children filter vertex))
 536
 537 ;;; ---------------------------------------------------------------------------
 538
 539 (defmethod parent-vertexes (vertex &optional filter)
 540   (collect-using #'iterate-parents filter vertex))
 541
 542 ;;; ---------------------------------------------------------------------------
 543
 544 (defmethod neighbor-vertexes (vertex &optional filter)
 545   (collect-using #'iterate-neighbors filter vertex))
 546
 547 ;;; ---------------------------------------------------------------------------
 548
 549 (defmethod adjacentp ((graph basic-graph) vertex-1 vertex-2)
 550   (adjacentp graph (find-vertex graph vertex-1) (find-vertex graph vertex-2)))
 551
 552 ;;; ---------------------------------------------------------------------------
 553
 554 (defmethod adjacentp ((graph basic-graph) (vertex-1 basic-vertex) (vertex-2 basic-vertex))
 555   (iterate-neighbors
 556    vertex-1
 557    (lambda (vertex)
 558      (when (eq vertex vertex-2)
 559        (return-from adjacentp t))))
 560   (values nil))
 561
 562 ;;; ---------------------------------------------------------------------------
 563
 564 (defmethod number-of-neighbors (vertex)
 565   (count-using #'iterate-neighbors nil vertex))
 566
 567 ;;; ---------------------------------------------------------------------------
 568
 569 (defmethod in-cycle-p ((graph basic-graph) (vertex t))
 570   (in-cycle-p graph (find-vertex graph vertex)))
 571
 572 ;;; ---------------------------------------------------------------------------
 573
 574 (defmethod renumber-vertexes ((graph basic-graph))
 575   (let ((count 0))
 576     (iterate-vertexes graph (lambda (vertex)
 577                               (setf (slot-value vertex 'vertex-id) count)
 578                               (incf count)))
 579     (setf (slot-value graph 'largest-vertex-id) count)))
 580
 581 ;;; ---------------------------------------------------------------------------
 582
 583 (defmethod renumber-edges ((graph basic-graph))
 584   (let ((count 0))
 585     (iterate-edges graph (lambda (vertex)
 586                            (setf (slot-value vertex 'edge-id) count)
 587                            (incf count)))
 588     (setf (slot-value graph 'largest-edge-id) count)))
 589
 590 ;;; ---------------------------------------------------------------------------
 591
 592 (deprecated
 593   (defmethod container->list ((graph basic-graph))
 594     (collect-elements (graph-vertexes graph))))
 595
 596 ;;; ---------------------------------------------------------------------------
 597
 598 (defmethod add-vertex :before ((graph basic-graph) (vertex basic-vertex)
 599                                &key &allow-other-keys)
 600
 601   (assert (typep vertex (vertex-class graph)))
 602   (setf (item-at (graph-vertexes graph)
 603                  (funcall (vertex-key graph) (element vertex))) vertex
 604         (slot-value vertex 'graph) graph))
 605
 606 ;;; ---------------------------------------------------------------------------
 607
 608 (defmethod add-edge :before ((graph basic-graph) (edge basic-edge) &key force-new?)
 609   (declare (ignore force-new?))
 610   (insert-item (graph-edges graph) edge)
 611   (setf (slot-value edge 'graph) graph)
 612   (if (subtypep (class-name (class-of edge)) 'directed-edge-mixin)
 613     (progn (setf (contains-directed-edge-p graph) t))
 614     (progn (setf (contains-undirected-edge-p graph) t))))
 615
 616 ;;; ---------------------------------------------------------------------------
 617
 618 (defmethod find-vertex ((graph basic-graph) (value t)
 619                         &optional (error-if-not-found? t))
 620   (aif (find-item (graph-vertexes graph) (funcall (vertex-key graph) value))
 621        it
 622        (when error-if-not-found?
 623          (error 'graph-vertex-not-found-error :vertex value :graph graph))))
 624
 625 ;;; ---------------------------------------------------------------------------
 626
 627 (defmethod find-vertex ((edge basic-edge) (value t)
 628                         &optional (error-if-not-found? t))
 629   (iterate-vertexes
 630    edge
 631    (lambda (vertex)
 632      (when (funcall (vertex-test (graph edge))
 633                     (funcall (vertex-key (graph edge)) (element vertex)) value)
 634        (return-from find-vertex vertex))))
 635   (when error-if-not-found?
 636     (error 'graph-vertex-not-found-in-edge-error :vertex value :edge edge)))
 637
 638 ;;; ---------------------------------------------------------------------------
 639
 640 (defmethod search-for-vertex ((graph basic-graph) (value t)
 641                               &key (key (vertex-key graph)) (test 'equal)
 642                               (error-if-not-found? t))
 643   (aif (search-for-node graph value :test test :key key)
 644        it
 645        (when error-if-not-found?
 646          (error "~S not found in ~A using key ~S and test ~S" value graph key
 647                 test))))
 648
 649 ;;; ---------------------------------------------------------------------------
 650
 651 (defmethod search-for-vertex ((graph basic-graph) (vertex basic-vertex)
 652                               &key (key (vertex-key graph)) (test 'equal)
 653                               (error-if-not-found? t))
 654   (aif (search-for-node (graph-vertexes graph) vertex :test test :key key)
 655        it
 656        (when error-if-not-found?
 657          (error "~A not found in ~A" vertex graph))))
 658
 659 ;;; ---------------------------------------------------------------------------
 660 ;; TODO !!! dispatch is the same as the second method above
 661 (defmethod search-for-vertex ((graph basic-graph) (vertex t)
 662                               &key (key (vertex-key graph)) (test 'equal)
 663                               (error-if-not-found? t))
 664   (aif (search-for-element (graph-vertexes graph) vertex :test test :key key)
 665        it
 666        (when error-if-not-found?
 667          (error "~A not found in ~A" vertex graph))))
 668
 669 ;;; ---------------------------------------------------------------------------
 670
 671 (defmethod iterate-elements ((graph basic-graph) fn)
 672    (iterate-elements (graph-vertexes graph)
 673                      (lambda (vertex) (funcall fn (element vertex)))))
 674
 675 ;;; ---------------------------------------------------------------------------
 676
 677 (defmethod iterate-nodes ((graph basic-graph) fn)
 678    (iterate-nodes (graph-vertexes graph) fn))
 679
 680 ;;; ---------------------------------------------------------------------------
 681
 682 (defmethod iterate-vertexes ((graph basic-graph) fn)
 683    (iterate-nodes (graph-vertexes graph) fn))
 684
 685 ;;; ---------------------------------------------------------------------------
 686
 687 (defmethod iterate-vertexes ((edge basic-edge) fn)
 688   (funcall fn (vertex-1 edge))
 689   (funcall fn (vertex-2 edge)))
 690
 691 ;;; ---------------------------------------------------------------------------
 692
 693 (defmethod size ((graph basic-graph))
 694   (size (graph-vertexes graph)))
 695
 696 ;;; ---------------------------------------------------------------------------
 697
 698 (defmethod edges ((graph basic-graph))
 699   (collect-using #'iterate-edges nil graph))
 700
 701 ;;; ---------------------------------------------------------------------------
 702
 703 (defmethod edges ((vertex basic-vertex))
 704   (collect-using #'iterate-edges nil vertex))
 705
 706 ;;; ---------------------------------------------------------------------------
 707
 708 (deprecated
 709   "Use size instead"
 710   (defmethod vertex-count ((graph basic-graph))
 711     (size graph)))
 712
 713 ;;; ---------------------------------------------------------------------------
 714
 715 (defmethod vertexes ((graph basic-graph))
 716   (collect-elements (graph-vertexes graph)))
 717
 718 ;;; ---------------------------------------------------------------------------
 719
 720 (defmethod source-edge-count ((vertex basic-vertex))
 721   (count-using 'iterate-source-edges nil vertex))
 722
 723 ;;; ---------------------------------------------------------------------------
 724
 725 (defmethod target-edge-count ((vertex basic-vertex))
 726   (count-using 'iterate-target-edges nil vertex))
 727
 728 ;;; ---------------------------------------------------------------------------
 729
 730 (defmethod graph-roots ((graph basic-graph))
 731   (collect-elements (graph-vertexes graph) :filter #'rootp))
 732
 733 ;;; ---------------------------------------------------------------------------
 734
 735 (defmethod rootp ((vertex basic-vertex))
 736   ;;?? this is inefficient in the same way that (zerop (length <list>)) is...
 737   (zerop (source-edge-count vertex)))
 738
 739 ;;; ---------------------------------------------------------------------------
 740
 741 (defmethod find-vertex-if ((graph basic-graph) fn &key key)
 742   (iterate-vertexes graph
 743                     (lambda (v)
 744                       (when (funcall fn (if key (funcall key v) v))
 745                         (return-from find-vertex-if v))))
 746   (values nil))
 747
 748 ;;; ---------------------------------------------------------------------------
 749
 750 (defmethod find-vertex-if ((edge basic-edge) fn &key key)
 751   (iterate-vertexes edge
 752                     (lambda (v)
 753                       (when (funcall fn (if key (funcall key v) v))
 754                         (return-from find-vertex-if v))))
 755   (values nil))
 756
 757 ;;; ---------------------------------------------------------------------------
 758
 759 (defmethod find-edge-if ((graph basic-graph) fn &key key)
 760   (iterate-edges graph
 761                  (lambda (e)
 762                    (when (funcall fn (if key (funcall key e) e))
 763                      (return-from find-edge-if e))))
 764   (values nil))
 765
 766 ;;; ---------------------------------------------------------------------------
 767
 768 (defmethod find-edges-if ((graph basic-graph) fn)
 769   (collect-using 'iterate-edges fn graph))
 770
 771 ;;; ---------------------------------------------------------------------------
 772
 773 (defmethod find-vertexes-if ((graph basic-graph) fn)
 774   (collect-using 'iterate-vertexes fn graph))
 775
 776 ;;; ---------------------------------------------------------------------------
 777
 778 (defmethod empty! ((graph basic-graph))
 779   (empty! (graph-edges graph))
 780   (empty! (graph-vertexes graph))
 781   (renumber-edges graph)
 782   (renumber-vertexes graph)
 783   (values))
 784
 785 ;;; ---------------------------------------------------------------------------
 786
 787 (defun neighbors-to-children (new-graph root &optional visited-list)
 788   (pushnew root visited-list)
 789   (iterate-neighbors
 790    root
 791    (lambda (c)
 792      (when (not (member c visited-list))
 793        (add-edge-between-vertexes
 794         new-graph (value root) (value c) :edge-type :directed)
 795        (neighbors-to-children new-graph c visited-list)))))
 796
 797 ;;; ---------------------------------------------------------------------------
 798
 799 (defmethod generate-directed-free-tree ((graph basic-graph) root)
 800   (generate-directed-free-tree graph (find-vertex graph root)))
 801
 802 ;;; ---------------------------------------------------------------------------
 803
 804 (defmethod force-undirected ((graph basic-graph))
 805   (iterate-edges
 806    graph
 807    (lambda (edge)
 808      (change-class edge (undirected-edge-class graph)))))
 809
 810
 811
 812 ;;; ---------------------------------------------------------------------------
 813 ;;; traversal
 814 ;;; ---------------------------------------------------------------------------
 815
 816 (defmethod traverse-elements ((thing basic-graph) (style symbol) fn)
 817   (let ((marker (gensym)))
 818     (iterate-vertexes
 819      thing
 820      (lambda (vertex)
 821        (setf (tag vertex) marker)))
 822
 823     (iterate-elements
 824      (graph-roots thing)
 825      (lambda (vertex)
 826        (traverse-elements-helper vertex style marker fn)))))
 827
 828 ;;; ---------------------------------------------------------------------------
 829
 830 (defmethod traverse-elements-helper ((thing basic-vertex) (style (eql :depth)) marker fn)
 831   (when (eq (tag thing) marker)
 832     (nilf (tag thing))
 833     (iterate-children
 834      thing
 835      (lambda (vertex)
 836        (traverse-elements-helper vertex style marker fn)))
 837
 838     (funcall fn thing)))
 839
 840 ;;; ---------------------------------------------------------------------------
 841
 842 (defmethod traverse-elements-helper ((thing basic-vertex) (style (eql :breadth)) marker fn)
 843   (when (eq (tag thing) marker)
 844     (nilf (tag thing))
 845     (funcall fn thing))
 846
 847   (iterate-neighbors
 848    thing
 849    (lambda (vertex)
 850      (when (eq (tag vertex) marker)
 851        (funcall fn vertex))))
 852
 853   (iterate-neighbors
 854    thing
 855    (lambda (vertex)
 856      (when (eq (tag vertex) marker)
 857        (nilf (tag vertex))
 858        (traverse-elements-helper vertex style marker fn)))))
 859
 860 ;;; ---------------------------------------------------------------------------
 861
 862 (defmethod in-cycle-p ((graph basic-graph) (start-vertex basic-vertex))
 863   (let ((first-time? t))
 864     (not (null
 865           (graph-search
 866            (list start-vertex)
 867            (lambda (v)
 868              (if first-time?
 869                (nilf first-time?)
 870                (eq (find-vertex graph v) start-vertex)))
 871            (lambda (v)
 872              (child-vertexes v))
 873            #'append
 874            :new-state-fn
 875            (lambda (states successors state= old-states)
 876              ;; Generate successor states that have not been seen before but
 877              ;; don't remove the start state.
 878              (remove-if
 879               #'(lambda (state)
 880                   (and (not (eq start-vertex state))
 881                        (or (member state states :test state=)
 882                            (member state old-states :test state=))))
 883               (funcall successors (first states)))))))))
 884
 885 ;;; ---------------------------------------------------------------------------
 886
 887 (defmethod in-undirected-cycle-p
 888            ((graph basic-graph) (current basic-vertex)
 889             &optional (marked (make-container 'simple-associative-container))
 890             (previous nil))
 891   (block do-it
 892     (tf (item-at-1 marked current))
 893     (iterate-children current
 894                       (lambda (child)
 895                         (cond
 896                          ((eq child previous) nil)
 897                          ((item-at-1 marked child) (return-from do-it t))
 898                          (t
 899                           (in-undirected-cycle-p graph child marked current)))))))
 900
 901 ;;; ---------------------------------------------------------------------------
 902
 903 (defmethod any-undirected-cycle-p ((graph basic-graph))
 904   (let ((marked (make-container 'simple-associative-container)))
 905     (iterate-vertexes graph (lambda (v)
 906                               (unless (item-at-1 marked v)
 907                                 (when (in-undirected-cycle-p graph v marked)
 908                                   (return-from any-undirected-cycle-p v)))))
 909     (values nil)))
 910
 911 ;;; ---------------------------------------------------------------------------
 912
 913 (defun remove-list (original target)
 914   "Removes all elements in original from target."
 915   (remove-if (lambda (target-element)
 916                (member target-element original))
 917              target))
 918
 919 ;;; ---------------------------------------------------------------------------
 920
 921 (defun get-nodelist-relatives (node-list)
 922   "Collects set of unique relatives of nodes in node-list."
 923   (let ((unique-relatives nil))
 924     (dolist (node node-list)
 925       (setf unique-relatives
 926             (append-unique (neighbor-vertexes node) unique-relatives)))
 927     unique-relatives))
 928
 929 ;;; ---------------------------------------------------------------------------
 930
 931 (defun get-transitive-closure (vertex-list &optional (depth nil))
 932   "Given a list of vertices, returns a combined list of all of the nodes
 933 in the transitive closure(s) of each of the vertices in the list
 934 (without duplicates).  Optional DEPTH limits the depth (in _both_ the
 935 child and parent directions) to which the closure is gathered; default
 936 nil gathers the entire closure(s)."
 937   (labels ((collect-transitive-closure (remaining visited depth)
 938              (if (and remaining
 939                       (typecase depth
 940                         (null t)
 941                         (fixnum (>= (decf depth) 0))))
 942
 943               (let* ((non-visited-relatives     ;; list of relatives not yet visited
 944                        (remove-list visited
 945                                     (get-nodelist-relatives remaining)))
 946                       (visited-nodes            ;; list of nodes visited so far
 947                        (append-unique non-visited-relatives visited)))
 948                  (collect-transitive-closure non-visited-relatives
 949                                              visited-nodes
 950                                              depth))
 951                (values visited))))
 952     (collect-transitive-closure vertex-list vertex-list depth)))
 953
 954 ;;; ---------------------------------------------------------------------------
 955 ;;; make-filtered-graph
 956 ;;; ---------------------------------------------------------------------------
 957
 958 (defmethod complete-links ((new-graph basic-graph)
 959                            (old-graph basic-graph))
 960   ;; Copy links from old-graph ONLY for nodes already in new-graph
 961   (iterate-vertexes
 962    new-graph
 963    (lambda (vertex)
 964      (let ((old-graph-vertex (find-vertex old-graph (value vertex))))
 965        (iterate-edges
 966         old-graph-vertex
 967         (lambda (old-edge)
 968           (let* ((old-other-vertex (other-vertex old-edge old-graph-vertex))
 969                  (new-other-vertex (find-vertex new-graph (value old-other-vertex) nil)))
 970             (when (and new-other-vertex
 971                        (< (vertex-id vertex) (vertex-id new-other-vertex)))
 972               (let* ((new-edge (copy-template old-edge)))
 973                 (if (eq old-graph-vertex (vertex-1 old-edge))
 974                   (setf (slot-value new-edge 'vertex-1) vertex
 975                         (slot-value new-edge 'vertex-2) new-other-vertex)
 976                   (setf (slot-value new-edge 'vertex-2) vertex
 977                         (slot-value new-edge 'vertex-1) new-other-vertex))
 978                 (add-edge new-graph new-edge))))))))))
 979
 980 #+Old
 981 (defmethod complete-links ((new-graph basic-graph)
 982                            (old-graph basic-graph))
 983   ;; Copy links from old-graph ONLY for nodes already in new-graph
 984   (iterate-vertexes
 985    new-graph
 986    (lambda (vertex)
 987      (let ((old-graph-vertex (find-vertex old-graph (value vertex))))
 988        (iterate-edges
 989         old-graph-vertex
 990         (lambda (edge)
 991           (let* ((old-other-vertex (other-vertex edge old-graph-vertex))
 992                  (new-other-vertex (find-vertex new-graph (value old-other-vertex) nil))
 993                  (edge-type (if (directed-edge-p edge)
 994                               :directed :undirected)))
 995             (when new-other-vertex
 996               (if (and (directed-edge-p edge)
 997                        (eq old-graph-vertex (target-vertex edge)))
 998                 (add-edge-between-vertexes new-graph new-other-vertex vertex
 999                                            :value (value edge)
1000                                            :edge-type edge-type)
1001                 (add-edge-between-vertexes new-graph vertex new-other-vertex
1002                                            :value (value edge)
1003                                            :edge-type edge-type))))))))))
1004
1005 ;;; ---------------------------------------------------------------------------
1006
1007 (defmethod make-filtered-graph ((old-graph basic-graph)
1008                                 test-fn
1009                                 &optional
1010                                 (graph-completion-method nil)
1011                                 (depth nil))
1012   (let ((new-graph
1013          (copy-template old-graph)))
1014     (ecase graph-completion-method
1015       ((nil
1016         :complete-links)
1017        (iterate-vertexes old-graph
1018                          (lambda (vertex)
1019                            (when (funcall test-fn vertex)
1020                              (add-vertex new-graph (value vertex))))))
1021       ((:complete-closure-nodes-only
1022         :complete-closure-with-links)
1023        (let* ((old-graph-vertexes  (collect-items old-graph :filter test-fn))
1024               (closure-vertexes
1025                (get-transitive-closure old-graph-vertexes depth)))
1026          (dolist (vertex closure-vertexes)
1027            (add-vertex new-graph (copy-template vertex))))))
1028
1029     (ecase graph-completion-method
1030       ((nil :complete-closure-nodes-only) nil)
1031       ((:complete-links
1032         :complete-closure-with-links)
1033        (complete-links new-graph old-graph)))
1034
1035     new-graph))
1036
1037 ;;; ---------------------------------------------------------------------------
1038
1039 (defmethod subgraph-containing ((graph basic-graph) (vertex basic-vertex)
1040                                 &optional (depth nil))
1041   (make-filtered-graph graph
1042                        #'(lambda (v)
1043                            (equal v vertex))
1044                        :complete-closure-with-links
1045                        depth))
1046
1047 ;;; ---------------------------------------------------------------------------
1048
1049 (defmethod edge-count ((graph basic-graph))
1050   (count-using #'iterate-edges nil graph))
1051
1052 ;;; ---------------------------------------------------------------------------
1053
1054 (defmethod edge-count ((vertex basic-vertex))
1055   (size (vertex-edges vertex)))
1056
1057 ;;; ---------------------------------------------------------------------------
1058
1059 (defmethod topological-sort ((graph basic-graph))
1060   (assign-level graph 0)
1061   (sort (collect-elements (graph-vertexes graph))  #'<
1062         :key (lambda (x) (depth-level x))))
1063
1064 ;;; ---------------------------------------------------------------------------
1065
1066 (defmethod assign-level ((graph basic-graph) (level number))
1067   (loop for node in (graph-roots graph)
1068         do (assign-level node 0)))
1069
1070 ;;; ---------------------------------------------------------------------------
1071
1072 (defmethod assign-level ((node basic-vertex) (level number))
1073   (if (or (not (depth-level node))
1074           (> level (depth-level node)))
1075     (setf (depth-level node) level))
1076   (iterate-children node (lambda (x) (assign-level x (1+ level)))))
1077
1078 ;;; ---------------------------------------------------------------------------
1079
1080 (defmethod depth ((graph basic-graph))
1081   (assign-level graph 0)
1082   (let ((depth 0))
1083     (iterate-vertexes graph (lambda (vertex)
1084                               (maxf depth (depth-level vertex))))
1085     depth))
1086
1087 ;;; ---------------------------------------------------------------------------
1088 ;;; mapping
1089 ;;; ---------------------------------------------------------------------------
1090
1091 (defun map-paths (graph start-vertex length fn &key (filter (constantly t)))
1092   "Apply fn to each path that starts at start-vertex and is of exactly length
1093 length"
1094   ;; a sort of depth first search
1095   (labels ((follow-path (next-vertex current-path length)
1096              (when (zerop length)
1097                (funcall fn (reverse current-path)))
1098              ; (format t "~%~A ~A ~A" current-path next-vertex length)
1099              (when (plusp length)
1100                (iterate-neighbors
1101                 next-vertex
1102                 (lambda (v)
1103                   (when (funcall filter v)
1104                     ;; no repeats
1105                     (unless (find-item current-path v)
1106                       (let ((new-path  (copy-list current-path)))
1107                         (follow-path v (push v new-path) (1- length))))))))))
1108     (iterate-neighbors
1109      start-vertex
1110      (lambda (v)
1111        (when (funcall filter v)
1112          (follow-path v (list v start-vertex) (1- length))))))
1113   (values graph))
1114
1115 ;;; ---------------------------------------------------------------------------
1116
1117 (defun map-shortest-paths (graph start-vertex depth fn &key (filter (constantly t)))
1118   "Apply fn to each shortest path starting at `start-vertex` of depth `depth`. The `filter` predicate is used to remove vertexes from consideration."
1119   (bind ((visited (make-container 'simple-associative-container
1120                                   :test #'equal)))
1121     (labels ((visit (p)
1122                (setf (item-at-1 visited p) t))
1123              (visited-p (p)
1124                (item-at-1 visited p))
1125              )
1126       (loop for n from 1 to (1- depth) do
1127             (map-paths graph start-vertex n
1128                        (lambda (p)
1129                          (visit (first (last p))))
1130                        :filter filter))
1131       ;(break)
1132       (visit start-vertex)
1133       (map-paths graph start-vertex depth
1134                  (lambda (p)
1135                    (unless (visited-p (first (last p)))
1136                      (funcall fn p)))
1137                  :filter filter))))
1138
1139
1140 ;;; ---------------------------------------------------------------------------
1141 ;;; utilities
1142 ;;; ---------------------------------------------------------------------------
1143
1144 (defun append-unique (list1 list2)
1145   (remove-duplicates (append list1 list2)))
1146
1147 ;;; ---------------------------------------------------------------------------
1148 ;;; project-bipartite-graph
1149 ;;; ---------------------------------------------------------------------------
1150
1151 (defmethod project-bipartite-graph
1152            ((new-graph symbol) graph vertex-class vertex-classifier)
1153   (project-bipartite-graph
1154    (make-instance new-graph) graph vertex-class  vertex-classifier))
1155
1156 ;;; ---------------------------------------------------------------------------
1157
1158 (defmethod project-bipartite-graph
1159            ((new-graph basic-graph) graph vertex-class vertex-classifier)
1160   (iterate-vertexes
1161    graph
1162    (lambda (v)
1163      (when (eq (funcall vertex-classifier v) vertex-class)
1164        (add-vertex new-graph (element v)))))
1165
1166   (iterate-vertexes
1167    graph
1168    (lambda (v)
1169      (when (eq (funcall vertex-classifier v) vertex-class)
1170        (iterate-neighbors
1171         v
1172         (lambda (other-class-vertex)
1173           (iterate-neighbors
1174            other-class-vertex
1175            (lambda (this-class-vertex)
1176              (when (< (vertex-id v) (vertex-id this-class-vertex))
1177                (add-edge-between-vertexes
1178                 new-graph (element v) (element this-class-vertex)
1179                 :if-duplicate-do (lambda (e) (incf (weight e))))))))))))
1180
1181   new-graph)
1182
1183 #+Test
1184 (pro:with-profiling
1185   (setf (ds :g-5000-m-projection)
1186         (project-bipartite-graph
1187          'undirected-graph-container
1188          (ds :g-5000)
1189          :m
1190          (lambda (v)
1191            (let ((vertex-class (aref (symbol-name (element v)) 0)))
1192              (cond ((member vertex-class '(#\a #\b) :test #'char-equal)
1193                     :m)
1194                    ((member vertex-class '(#\x #\y #\z) :test #'char-equal)
1195                     :h)))))))
1196
1197 #+Test
1198 (pro:with-profiling
1199   (setf (ds :g-5000-h-projection)
1200         (project-bipartite-graph
1201          'undirected-graph-container
1202          (ds :g-5000)
1203          :h
1204          (lambda (v)
1205            (let ((vertex-class (aref (symbol-name (element v)) 0)))
1206              (cond ((member vertex-class '(#\a #\b) :test #'char-equal)
1207                     :m)
1208                    ((member vertex-class '(#\x #\y #\z) :test #'char-equal)
1209                     :h)))))))
1210
1211 #+Test
1212 (pro:with-profiling
1213   (project-bipartite-graph
1214    'undirected-graph-container
1215    (ds :g-1000)
1216    :m
1217    (lambda (v)
1218      (let ((vertex-class (aref (symbol-name (element v)) 0)))
1219        (cond ((member vertex-class '(#\x #\y) :test #'char-equal)
1220               :m)
1221              ((member vertex-class '(#\a #\b #\c) :test #'char-equal)
1222               :h))))))
1223
1224
1225
1226