dev/graph.lisp

   1 ;;;-*- Mode: Lisp; Package: metabang.graph -*-
   2
   3 #|
   4 $Id: graph.lisp,v 1.30 2005/09/07 16:17:06 gwking Exp $
   5
   6 Author: Gary W. King, et. al.
   7
   8 |#
   9
  10 #| NOTES
  11
  12 something is putting something on the vertexes plist's
  13
  14 |#
  15
  16
  17 (in-package #:metabang.graph)
  18
  19 ;;; ---------------------------------------------------------------------------
  20 ;;; classes
  21 ;;; ---------------------------------------------------------------------------
  22
  23 (defcondition graph-error (error)
  24   ((graph nil ir))
  25   (:export-p t)
  26   (:export-slots-p t)
  27   (:documentation "This is the root condition for errors that occur while running code in CL-Graph."))
  28
  29 ;;; ---------------------------------------------------------------------------
  30
  31 (defcondition edge-error (graph-error)
  32   ((edge nil ir "The `edge` that is implicated in the condition."))
  33   (:export-p t)
  34   (:export-slots-p t)
  35   (:documentation "This is the root condition for graph errors that have to do with edges."))
  36
  37 ;;; ---------------------------------------------------------------------------
  38
  39 (defcondition graph-vertex-not-found-error (graph-error)
  40   ((vertex nil ir "The vertex or value that could not be found in the graph."))
  41   (:report (lambda (c s)
  42              (format s "Vertex ~S not found in ~A" (vertex c) (graph c))))
  43   (:export-p t)
  44   (:export-slots-p t)
  45   (:documentation "This condition is signaled when a vertex can not be found in a graph."))
  46
  47 ;;; ---------------------------------------------------------------------------
  48
  49 (defcondition graph-vertex-not-found-in-edge-error (edge-error)
  50   ((vertex nil ir))
  51   (:report (lambda (c s)
  52              (format s "Vertex ~S not found in ~A" (vertex c) (edge c))))
  53   (:export-p t)
  54   (:documentation "This condition is signaled when a vertex can not be found in an edge."))
  55
  56 ;;; ---------------------------------------------------------------------------
  57
  58 (defcondition graph-edge-not-found-error (graph-error)
  59   ((vertex-1 nil ir "One of the vertexes for which no connecting edge could be found.")
  60    (vertex-2 nil ir "One of the vertexes for which no connecting edge could be found."))
  61   (:report (lambda (c s)
  62              (format s "Edge between ~S and ~S not found in ~A"
  63                      (vertex-1 c) (vertex-2 c) (graph c))))
  64   (:export-p t)
  65   (:export-slots-p t)
  66   (:documentation "This condition is signaled when an edge cannot be found in a graph."))
  67
  68 ;;; ---------------------------------------------------------------------------
  69
  70 (defclass* basic-vertex (container-node-mixin)
  71   ((depth-level 0 ia :type number "`Depth-level` is used by some algorithms for bookkeeping.  [?? Should be in a mixin]")
  72    (vertex-id 0 ir "`Vertex-id` is used internally to keep track of vertexes.")
  73    (element :unbound ia :accessor value "The `element` is the value that this vertex represents.")
  74    (tag nil ia "The `tag` slot is used by some algorithms to keep track of which vertexes have been visited.")
  75    (graph nil ia "The graph in which this vertex is contained.")
  76    (color nil ia "The `color` slot is used by some algorithms for bookkeeping.")
  77    (rank nil ia "The `rank` is used by some algorithms for bookkeeping.  [?? Should be in a mixin]")
  78    (previous-node nil ia "`Previous-node` is used by some algorithms for bookkeeping. [?? Should be in a mixin]")
  79    (next-node nil ia "`Next-node` is used by some algorithms for bookkeeping.  [?? Should be in a mixin]")
  80    (discovery-time -1 ia "`Discovery-time` is used by some algorithms for bookkeeping.  [?? Should be in a mixin]")
  81    (finish-time -1 ia "`Finish-time` is used by some algorithms for bookkeeping.  [?? Should be in a mixin]"))
  82   (:export-p t)
  83   (:export-slots vertex-id tag rank color previous-node next-node
  84                  discovery-time finish-time)
  85   (:make-load-form-p t)
  86   (:documentation "This is the root class for all vertexes in CL-Graph."))
  87
  88 ;;; ---------------------------------------------------------------------------
  89
  90 (defmethod initialize-instance :after ((object basic-vertex) &key graph vertex-id)
  91   (when (and graph (not vertex-id))
  92     (setf (slot-value object 'vertex-id)
  93           (largest-vertex-id graph))
  94     (incf (slot-value graph 'largest-vertex-id))))
  95
  96 ;;; ---------------------------------------------------------------------------
  97
  98 (defmethod print-object ((vertex basic-vertex) stream)
  99   (print-unreadable-object (vertex stream :identity nil)
 100     (format stream "~A"
 101             (if (and (slot-exists-p vertex 'element) (slot-boundp vertex 'element))
 102               (element vertex) "#unbound#"))))
 103
 104 ;;; ---------------------------------------------------------------------------
 105
 106 (defclass* basic-edge ()
 107   ((edge-id 0 ia "The `edge-id` is used internally by CL-Graph for bookkeeping.")
 108    (element nil ia :accessor value :initarg :value)
 109    (tag nil ia "The `tag` is used by some algorithms for bookkeeping. [?? Should probably be in a mixin]")
 110    (graph nil ir "The `graph` of which this edge is a part.")
 111    (color nil ia "The `color` is used by some algorithms for bookkeeping. [?? Should probably be in a mixin]"))
 112   (:export-p t)
 113   (:export-slots edge-id element tag color)
 114   (:make-load-form-p t)
 115   (:documentation "This is the root class for all edges in CL-Graph."))
 116
 117 ;;; ---------------------------------------------------------------------------
 118
 119 (defmethod initialize-instance :after ((object basic-edge) &key graph edge-id)
 120   (when (and graph (not edge-id))
 121     (setf (slot-value object 'edge-id)
 122           (largest-edge-id graph))
 123     (incf (slot-value graph 'largest-edge-id))))
 124
 125 ;;; ---------------------------------------------------------------------------
 126
 127 (defmethod print-object ((object basic-edge) stream)
 128   (print-unreadable-object (object stream :type t)
 129     (format stream "<~A ~A>" (vertex-1 object) (vertex-2 object))))
 130
 131 ;;; ---------------------------------------------------------------------------
 132
 133 (defclass* directed-edge-mixin () ()
 134   (:export-p t)
 135   (:documentation "This mixin class is used to indicate that an edge is directed."))
 136
 137 ;;; ---------------------------------------------------------------------------
 138
 139 (defclass* weighted-edge-mixin ()
 140   ((weight 1d0 ia "The value of the weight of this edge. Defaults to 1.0d0"))
 141   :export-slots
 142   (:export-p t)
 143   (:documentation "This mixin class adds a `weight` slot to an edge."))
 144
 145 ;;; ---------------------------------------------------------------------------
 146
 147 (defmethod weight ((edge basic-edge)) (values 1.0))
 148
 149 ;;; ---------------------------------------------------------------------------
 150
 151 (defclass* basic-graph ()
 152   ((graph-vertexes :unbound ir)
 153    (graph-edges :unbound ir)
 154    (largest-vertex-id 0 r)
 155    (largest-edge-id 0 r)
 156    (vertex-class 'basic-vertex ir
 157                  "The class of the vertexes in the graph. This must extend the base-class for vertexes of the graph type. E.g., all vertexes of a graph-container must extend graph-container-vertex.")
 158    (directed-edge-class 'basic-directed-edge ir
 159                         "The class used to create directed edges in the graph. This must extend the base-class for edges of the graph type and directed-edge-mixin. E.g., the directed-edge-class of a graph-container must extend graph-container-edge and directed-edge-mixin.")
 160    (undirected-edge-class 'basic-edge ir
 161                           "The class used to create undirected edges in the graph. This must extend the base-class for edges of the graph type. E.g., all edges of a graph-container must extend graph-container-edge")
 162    (contains-directed-edge-p nil ar
 163                              "Returns true if graph contains at least one directed edge. [?? Not sure if this is really keep up-to-date.]")
 164    (contains-undirected-edge-p nil ar
 165                                "Returns true if graph contains at least one undirected edge. [?? Not sure if this is really keep up-to-date.]")
 166    (vertex-test #'eq ir)
 167    (vertex-key #'identity ir)
 168    (edge-test #'eq ir)
 169    (edge-key #'identity ir)
 170    (default-edge-type nil ir
 171      "The default edge type for the graph. This should be one of :undirected or :directed.")
 172    (default-edge-class nil ir
 173      "The default edge class for the graph."))
 174   (:make-load-form-p t)
 175   (:export-slots vertex-class directed-edge-class undirected-edge-class
 176                  default-edge-type default-edge-class)
 177   (:default-initargs
 178     :initial-size 25)
 179   (:documentation "This is the root class for all graphs in CL-Graph."))
 180
 181 ;;; ---------------------------------------------------------------------------
 182
 183 (defmethod initialize-instance :after ((object basic-graph) &key initial-size
 184                                        &allow-other-keys)
 185   (setf (slot-value object 'graph-vertexes)
 186         (make-vertex-container object initial-size))
 187   (setf (slot-value object 'graph-edges)
 188         (make-edge-container object initial-size)))
 189
 190 ;;; ---------------------------------------------------------------------------
 191
 192 (defmethod print-object ((graph basic-graph) stream)
 193   (print-unreadable-object (graph stream :type t :identity t)
 194     (format stream "[~A,~A]" (size graph) (edge-count graph))))
 195
 196
 197 ;;; ---------------------------------------------------------------------------
 198 ;;; internals
 199 ;;; ---------------------------------------------------------------------------
 200
 201 (defmethod add-vertex ((graph basic-graph) (value basic-vertex) &key if-duplicate-do)
 202   (declare (ignore if-duplicate-do))
 203   (values value))
 204
 205 ;;; ---------------------------------------------------------------------------
 206
 207 (defmethod make-vertex-for-graph ((graph basic-graph) &rest args &key
 208                                   (vertex-class (vertex-class graph))
 209                                   &allow-other-keys)
 210   (remf args :vertex-class)
 211   (assert (subtypep vertex-class (vertex-class graph)) nil
 212           "Vertex class '~A' must be a subtype of ~A" vertex-class (vertex-class graph))
 213   (apply #'make-instance vertex-class :graph graph args))
 214
 215 ;;; ---------------------------------------------------------------------------
 216
 217 (defmethod make-edge-for-graph ((graph basic-graph)
 218                                 (vertex-1 basic-vertex) (vertex-2 basic-vertex)
 219                                 &rest args &key
 220                                 (edge-type (default-edge-type graph))
 221                                 (edge-class (default-edge-class graph))
 222                                 &allow-other-keys)
 223   (remf args :edge-class)
 224   (remf args :edge-type)
 225   (assert (or (null edge-type)
 226               (eq edge-type :directed)
 227               (eq edge-type :undirected)) nil
 228           "Edge-type must be nil, :directed or :undirected.")
 229
 230   (assert (or (null edge-class)
 231               (subtypep edge-class (directed-edge-class graph))
 232               (subtypep edge-class (undirected-edge-class graph))) nil
 233           "Edge-class must be nil or a subtype of ~A or ~A"
 234           (undirected-edge-class graph)
 235           (directed-edge-class graph))
 236
 237   (apply #'make-instance
 238          (or edge-class
 239              (ecase edge-type
 240                (:directed (directed-edge-class graph))
 241                (:undirected (undirected-edge-class graph))
 242                ((nil) nil))
 243              (undirected-edge-class graph))
 244          :graph graph
 245          :vertex-1 vertex-1 :vertex-2 vertex-2 args))
 246
 247 ;;; ---------------------------------------------------------------------------
 248
 249 (defmethod make-graph ((graph-type symbol) &rest args &key &allow-other-keys)
 250   (apply #'make-instance graph-type args))
 251
 252 ;;; ---------------------------------------------------------------------------
 253
 254 (defmethod make-graph ((classes list) &rest args)
 255   (let ((name (dynamic-classes:find-or-create-class 'basic-graph classes)))
 256     (apply #'make-instance name args)))
 257
 258 ;;; ---------------------------------------------------------------------------
 259 ;;; generic implementation
 260 ;;; ---------------------------------------------------------------------------
 261
 262 (defmethod undirected-edge-p ((edge basic-edge))
 263   (not (directed-edge-p edge)))
 264
 265 ;;; ---------------------------------------------------------------------------
 266
 267 (defmethod directed-edge-p ((edge basic-edge))
 268   (typep edge 'directed-edge-mixin))
 269
 270 ;;; ---------------------------------------------------------------------------
 271
 272 (defmethod tagged-edge-p ((edge basic-edge))
 273   (tag edge))
 274
 275 ;;; ---------------------------------------------------------------------------
 276
 277 (defmethod untagged-edge-p ((edge basic-edge))
 278   (null (tag edge)))
 279
 280 ;;; ---------------------------------------------------------------------------
 281
 282 (defmethod tag-all-edges ((graph basic-graph))
 283   (iterate-edges
 284    graph
 285    (lambda (e)
 286      (setf (tag e) t))))
 287
 288 ;;; ---------------------------------------------------------------------------
 289
 290 (defmethod tag-all-edges ((vertex basic-vertex))
 291   (iterate-edges
 292    vertex
 293    (lambda (e)
 294      (setf (tag e) t))))
 295
 296 ;;; ---------------------------------------------------------------------------
 297
 298 (defmethod untag-all-edges ((graph basic-graph))
 299   (iterate-edges
 300    graph
 301    (lambda (e)
 302      (setf (tag e) nil))))
 303
 304 ;;; ---------------------------------------------------------------------------
 305
 306 (defmethod untag-all-edges ((vertex basic-vertex))
 307   (iterate-edges
 308    vertex
 309    (lambda (e)
 310      (setf (tag e) nil))))
 311
 312 ;;; ---------------------------------------------------------------------------
 313
 314 (defmethod untag-edges ((edges list))
 315   (iterate-nodes
 316    edges
 317    (lambda (e)
 318      (setf (tag e) nil))))
 319
 320 ;;; ---------------------------------------------------------------------------
 321
 322 (defmethod tag-edges ((edges list))
 323   (iterate-nodes
 324    edges
 325    (lambda (e)
 326      (setf (tag e) t))))
 327
 328
 329 ;;; ---------------------------------------------------------------------------
 330
 331 (defmethod (setf element) :around ((value t) (vertex basic-vertex))
 332   (with-changing-vertex (vertex)
 333     (call-next-method)))
 334
 335 ;;; ---------------------------------------------------------------------------
 336
 337 ;; :ignore, :force, :replace, <function>
 338
 339 (defmethod add-vertex ((graph basic-graph) (value t) &rest args &key
 340                        (if-duplicate-do :ignore) &allow-other-keys)
 341   (remf args :if-duplicate-do)
 342   (let ((existing-vertex (find-vertex graph value nil)))
 343     (labels ((make-it ()
 344                (apply #'make-vertex-for-graph graph :element value args))
 345              (add-it (why)
 346                (values (add-vertex graph (make-it)) why)))
 347       (if existing-vertex
 348         (cond ((eq if-duplicate-do :ignore)
 349                (values existing-vertex :ignore))
 350
 351               ((eq if-duplicate-do :force)
 352                (add-it :force))
 353
 354               ((eq if-duplicate-do :replace)
 355                (replace-vertex graph existing-vertex (make-it)))
 356
 357               ((eq if-duplicate-do :replace-value)
 358                (setf (element existing-vertex) value)
 359                (values existing-vertex :replace-value))
 360
 361               (t
 362                (values (funcall if-duplicate-do existing-vertex)
 363                        :duplicate)))
 364
 365         ;; not found, add
 366         (add-it :new)))))
 367
 368 ;;; ---------------------------------------------------------------------------
 369
 370 (defmethod replace-vertex ((graph basic-graph) (old basic-vertex) (new basic-vertex))
 371   ;; we need the graph and the new vertex to reference each other
 372   ;; we need every edge of the old vertex to use the new-vertex
 373   ;; we need to remove the old vertex
 374   ;;
 375   ;; since I'm tired today, let's ignore trying to make this elegant
 376
 377   ;; first, we connect the edges to the new vertex so that they don't get deleted
 378   ;; when we delete the old vertex
 379   (iterate-edges
 380    old
 381    (lambda (e)
 382      (if (eq (vertex-1 e) old)
 383        (setf (slot-value e 'vertex-1) new) (setf (slot-value e 'vertex-2) new))
 384      (add-edge-to-vertex e new)))
 385
 386   (delete-vertex graph old)
 387   (add-vertex graph new))
 388
 389 ;;; ---------------------------------------------------------------------------
 390
 391 (defmethod add-edge-between-vertexes ((graph basic-graph) (value-1 t) (value-2 t)
 392                                       &rest args &key (if-duplicate-do :ignore)
 393                                       &allow-other-keys)
 394   (declare (ignore if-duplicate-do)
 395            (dynamic-extent args))
 396   (let ((v1 (or (find-vertex graph value-1 nil)
 397                 (add-vertex graph value-1 :if-duplicate-do :ignore)))
 398         (v2 (or (find-vertex graph value-2 nil)
 399                 (add-vertex graph value-2  :if-duplicate-do :replace))))
 400     (apply #'add-edge-between-vertexes graph v1 v2 args)))
 401
 402 ;;; ---------------------------------------------------------------------------
 403 ;;; to-do - add-edge-between-vertexes needs to be able to grab the weight and
 404 ;;; color from edges that inherit from weight and color mixins
 405 ;;; ---------------------------------------------------------------------------
 406
 407 (defmethod add-edge-between-vertexes ((graph basic-graph)
 408                                       (v-1 basic-vertex) (v-2 basic-vertex)
 409                                       &rest args &key
 410                                       (value nil) (if-duplicate-do :ignore)
 411                                       &allow-other-keys)
 412   (declare (dynamic-extent args))
 413   (remf args :if-duplicate-do)
 414
 415   (let ((edge (find-edge-between-vertexes graph v-1 v-2 :error-if-not-found? nil)))
 416     (flet ((add-it (why)
 417              (values (add-edge
 418                       graph
 419                       (apply #'make-edge-for-graph graph v-1 v-2 args))
 420                      why)))
 421       (if edge
 422         (cond
 423          ((eq if-duplicate-do :ignore)
 424           (values edge :ignore))
 425
 426          ((eq if-duplicate-do :force)
 427           (add-it :force))
 428
 429          ((eq if-duplicate-do :force-if-different-value)
 430           (if (equal (value edge) value)
 431             (values :ignore)
 432             (add-it :force)))
 433
 434
 435          ((eq if-duplicate-do :replace)
 436           (warn "replace edges isn't really implemented, maybe you can use :replace-value")
 437           (delete-edge graph edge)
 438           (add-it :replace))
 439
 440          ((eq if-duplicate-do :replace-value)
 441           (setf (element edge) value)
 442           (values edge :replace-value))
 443
 444          (t
 445           (setf edge (funcall if-duplicate-do edge))
 446           (values edge :duplicate)))
 447
 448         ;; not found, add
 449         (add-it :new)))))
 450
 451
 452 ;;; ---------------------------------------------------------------------------
 453
 454 (defmethod add-edge-to-vertex ((edge basic-edge) (vertex basic-vertex))
 455   (values))
 456
 457 ;;; ---------------------------------------------------------------------------
 458
 459 (defmethod find-edge-between-vertexes
 460     ((graph basic-graph) (value-1 t) (value-2 t)
 461      &key (error-if-not-found? t))
 462   (let* ((v1 (find-vertex graph value-1 error-if-not-found?))
 463          (v2 (find-vertex graph value-2 error-if-not-found?)))
 464     (or (and v1 v2 (find-edge-between-vertexes graph v1 v2)))
 465     (when error-if-not-found?
 466       (error 'graph-edge-not-found-error :vertex-1 v1 :vertex-2 v2))))
 467
 468 ;;; ---------------------------------------------------------------------------
 469
 470 (defmethod delete-edge-between-vertexes ((graph basic-graph)
 471                                          (value-or-vertex-1 t)
 472                                          (value-or-vertex-2 t) &rest args)
 473   (let ((edge (apply #'find-edge-between-vertexes
 474                      graph value-or-vertex-1 value-or-vertex-2 args)))
 475     (when edge
 476       (delete-edge graph edge))))
 477
 478 ;;; ---------------------------------------------------------------------------
 479
 480 (defmethod delete-edge :after ((graph basic-graph) (edge basic-edge))
 481   (delete-item (graph-edges graph) edge)
 482   edge)
 483
 484
 485 (defmethod delete-all-edges :after ((graph basic-graph))
 486   (empty! (graph-edges graph))
 487   graph)
 488
 489 ;;; ---------------------------------------------------------------------------
 490
 491 (defmethod delete-vertex ((graph basic-graph) value-or-vertex)
 492   (delete-vertex graph (find-vertex graph value-or-vertex)))
 493
 494 ;;; ---------------------------------------------------------------------------
 495
 496 (defmethod delete-vertex ((graph basic-graph) (vertex basic-vertex))
 497   (unless (eq graph (graph vertex))
 498     (error 'graph-vertex-not-found-error
 499            :graph graph :vertex vertex))
 500
 501   (iterate-edges
 502    vertex
 503    (lambda (edge)
 504      (delete-edge graph edge)))
 505
 506   (empty! (vertex-edges vertex))
 507   (values vertex graph))
 508
 509 ;;; ---------------------------------------------------------------------------
 510
 511 (defmethod delete-vertex :after ((graph basic-graph)
 512                                  (vertex basic-vertex))
 513   (setf (slot-value vertex 'graph) nil)
 514   (delete-item-at (graph-vertexes graph)
 515                   (funcall (vertex-key graph) (element vertex))))
 516
 517 ;;; ---------------------------------------------------------------------------
 518
 519 (defmethod insert-item ((graph basic-graph) value)
 520   (add-vertex graph value))
 521
 522 ;;; ---------------------------------------------------------------------------
 523
 524 (defmethod source-edges ((vertex basic-vertex) &optional filter)
 525   (collect-using #'iterate-source-edges filter vertex))
 526
 527 ;;; ---------------------------------------------------------------------------
 528
 529 (defmethod target-edges ((vertex basic-vertex) &optional filter)
 530   (collect-using #'iterate-target-edges filter vertex))
 531
 532 ;;; ---------------------------------------------------------------------------
 533
 534 (defmethod child-vertexes (vertex &optional filter)
 535   (collect-using #'iterate-children filter vertex))
 536
 537 ;;; ---------------------------------------------------------------------------
 538
 539 (defmethod parent-vertexes (vertex &optional filter)
 540   (collect-using #'iterate-parents filter vertex))
 541
 542 ;;; ---------------------------------------------------------------------------
 543
 544 (defmethod neighbor-vertexes (vertex &optional filter)
 545   (collect-using #'iterate-neighbors filter vertex))
 546
 547 ;;; ---------------------------------------------------------------------------
 548
 549 (defmethod adjacentp ((graph basic-graph) vertex-1 vertex-2)
 550   (adjacentp graph (find-vertex graph vertex-1) (find-vertex graph vertex-2)))
 551
 552 ;;; ---------------------------------------------------------------------------
 553
 554 (defmethod adjacentp ((graph basic-graph) (vertex-1 basic-vertex) (vertex-2 basic-vertex))
 555   (iterate-neighbors
 556    vertex-1
 557    (lambda (vertex)
 558      (when (eq vertex vertex-2)
 559        (return-from adjacentp t))))
 560   (values nil))
 561
 562 ;;; ---------------------------------------------------------------------------
 563
 564 (defmethod number-of-neighbors (vertex)
 565   (count-using #'iterate-neighbors nil vertex))
 566
 567 ;;; ---------------------------------------------------------------------------
 568
 569 (defmethod in-cycle-p ((graph basic-graph) (vertex t))
 570   (in-cycle-p graph (find-vertex graph vertex)))
 571
 572 ;;; ---------------------------------------------------------------------------
 573
 574 (defmethod renumber-vertexes ((graph basic-graph))
 575   (let ((count 0))
 576     (iterate-vertexes graph (lambda (vertex)
 577                               (setf (slot-value vertex 'vertex-id) count)
 578                               (incf count)))
 579     (setf (slot-value graph 'largest-vertex-id) count)))
 580
 581 ;;; ---------------------------------------------------------------------------
 582
 583 (defmethod renumber-edges ((graph basic-graph))
 584   (let ((count 0))
 585     (iterate-edges graph (lambda (vertex)
 586                            (setf (slot-value vertex 'edge-id) count)
 587                            (incf count)))
 588     (setf (slot-value graph 'largest-edge-id) count)))
 589
 590 ;;; ---------------------------------------------------------------------------
 591
 592 (deprecated
 593   (defmethod container->list ((graph basic-graph))
 594     (collect-elements (graph-vertexes graph))))
 595
 596 ;;; ---------------------------------------------------------------------------
 597
 598 (defmethod add-vertex :before ((graph basic-graph) (vertex basic-vertex)
 599                                &key &allow-other-keys)
 600
 601   (assert (typep vertex (vertex-class graph)))
 602   (setf (item-at (graph-vertexes graph)
 603                  (funcall (vertex-key graph) (element vertex))) vertex
 604         (slot-value vertex 'graph) graph))
 605
 606 ;;; ---------------------------------------------------------------------------
 607
 608 (defmethod add-edge :before ((graph basic-graph) (edge basic-edge) &key force-new?)
 609   (declare (ignore force-new?))
 610   (insert-item (graph-edges graph) edge)
 611   (setf (slot-value edge 'graph) graph)
 612   (if (subtypep (class-name (class-of edge)) 'directed-edge-mixin)
 613     (progn (setf (contains-directed-edge-p graph) t))
 614     (progn (setf (contains-undirected-edge-p graph) t))))
 615
 616 ;;; ---------------------------------------------------------------------------
 617
 618 (defmethod find-vertex ((graph basic-graph) (value t)
 619                         &optional (error-if-not-found? t))
 620   (or (find-item (graph-vertexes graph) (funcall (vertex-key graph) value))
 621       (when error-if-not-found?
 622         (error 'graph-vertex-not-found-error :vertex value :graph graph))))
 623
 624 (defmethod find-vertex ((graph basic-graph) (vertex basic-vertex)
 625                         &optional (error-if-not-found? t))
 626   (cond ((eq graph (graph vertex))
 627          vertex)
 628         (t
 629          (when error-if-not-found?
 630            (error 'graph-vertex-not-found-error
 631                   :vertex vertex :graph graph)))))
 632
 633 (defmethod find-vertex ((edge basic-edge) (value t)
 634                         &optional (error-if-not-found? t))
 635   (iterate-vertexes
 636    edge
 637    (lambda (vertex)
 638      (when (funcall (vertex-test (graph edge))
 639                     (funcall (vertex-key (graph edge)) (element vertex)) value)
 640        (return-from find-vertex vertex))))
 641   (when error-if-not-found?
 642     (error 'graph-vertex-not-found-in-edge-error :vertex value :edge edge)))
 643
 644
 645 (defmethod search-for-vertex ((graph basic-graph) (vertex basic-vertex)
 646                               &key (key (vertex-key graph)) (test 'equal)
 647                               (error-if-not-found? t))
 648   (or (search-for-node (graph-vertexes graph) vertex :test test :key key)
 649       (when error-if-not-found?
 650         (error "~A not found in ~A" vertex graph))))
 651
 652 (defmethod search-for-vertex ((graph basic-graph) (vertex t)
 653                               &key (key (vertex-key graph)) (test 'equal)
 654                               (error-if-not-found? t))
 655   (or (search-for-element (graph-vertexes graph) vertex :test test :key key)
 656       (when error-if-not-found?
 657         (error "~A not found in ~A" vertex graph))))
 658
 659 (defmethod iterate-elements ((graph basic-graph) fn)
 660    (iterate-elements (graph-vertexes graph)
 661                      (lambda (vertex) (funcall fn (element vertex)))))
 662
 663 ;;; ---------------------------------------------------------------------------
 664
 665 (defmethod iterate-nodes ((graph basic-graph) fn)
 666    (iterate-nodes (graph-vertexes graph) fn))
 667
 668 ;;; ---------------------------------------------------------------------------
 669
 670 (defmethod iterate-vertexes ((graph basic-graph) fn)
 671    (iterate-nodes (graph-vertexes graph) fn))
 672
 673 ;;; ---------------------------------------------------------------------------
 674
 675 (defmethod iterate-vertexes ((edge basic-edge) fn)
 676   (funcall fn (vertex-1 edge))
 677   (funcall fn (vertex-2 edge)))
 678
 679 ;;; ---------------------------------------------------------------------------
 680
 681 (defmethod size ((graph basic-graph))
 682   (size (graph-vertexes graph)))
 683
 684 ;;; ---------------------------------------------------------------------------
 685
 686 (defmethod edges ((graph basic-graph))
 687   (collect-using #'iterate-edges nil graph))
 688
 689 ;;; ---------------------------------------------------------------------------
 690
 691 (defmethod edges ((vertex basic-vertex))
 692   (collect-using #'iterate-edges nil vertex))
 693
 694 ;;; ---------------------------------------------------------------------------
 695
 696 (deprecated
 697   "Use size instead"
 698   (defmethod vertex-count ((graph basic-graph))
 699     (size graph)))
 700
 701 ;;; ---------------------------------------------------------------------------
 702
 703 (defmethod vertexes ((graph basic-graph))
 704   (collect-elements (graph-vertexes graph)))
 705
 706 ;;; ---------------------------------------------------------------------------
 707
 708 (defmethod source-edge-count ((vertex basic-vertex))
 709   (count-using 'iterate-source-edges nil vertex))
 710
 711 ;;; ---------------------------------------------------------------------------
 712
 713 (defmethod target-edge-count ((vertex basic-vertex))
 714   (count-using 'iterate-target-edges nil vertex))
 715
 716 ;;; ---------------------------------------------------------------------------
 717
 718 (defmethod graph-roots ((graph basic-graph))
 719   (collect-elements (graph-vertexes graph) :filter #'rootp))
 720
 721 ;;; ---------------------------------------------------------------------------
 722
 723 (defmethod rootp ((vertex basic-vertex))
 724   ;;?? this is inefficient in the same way that (zerop (length <list>)) is...
 725   (zerop (source-edge-count vertex)))
 726
 727 ;;; ---------------------------------------------------------------------------
 728
 729 (defmethod find-vertex-if ((graph basic-graph) fn &key key)
 730   (iterate-vertexes graph
 731                     (lambda (v)
 732                       (when (funcall fn (if key (funcall key v) v))
 733                         (return-from find-vertex-if v))))
 734   (values nil))
 735
 736 ;;; ---------------------------------------------------------------------------
 737
 738 (defmethod find-vertex-if ((edge basic-edge) fn &key key)
 739   (iterate-vertexes edge
 740                     (lambda (v)
 741                       (when (funcall fn (if key (funcall key v) v))
 742                         (return-from find-vertex-if v))))
 743   (values nil))
 744
 745 ;;; ---------------------------------------------------------------------------
 746
 747 (defmethod find-edge-if ((graph basic-graph) fn &key key)
 748   (iterate-edges graph
 749                  (lambda (e)
 750                    (when (funcall fn (if key (funcall key e) e))
 751                      (return-from find-edge-if e))))
 752   (values nil))
 753
 754 ;;; ---------------------------------------------------------------------------
 755
 756 (defmethod find-edges-if ((graph basic-graph) fn)
 757   (collect-using 'iterate-edges fn graph))
 758
 759 ;;; ---------------------------------------------------------------------------
 760
 761 (defmethod find-vertexes-if ((graph basic-graph) fn)
 762   (collect-using 'iterate-vertexes fn graph))
 763
 764 ;;; ---------------------------------------------------------------------------
 765
 766 (defmethod empty! ((graph basic-graph))
 767   (empty! (graph-edges graph))
 768   (empty! (graph-vertexes graph))
 769   (renumber-edges graph)
 770   (renumber-vertexes graph)
 771   (values))
 772
 773 ;;; ---------------------------------------------------------------------------
 774
 775 (defun neighbors-to-children (new-graph root &optional visited-list)
 776   (pushnew root visited-list)
 777   (iterate-neighbors
 778    root
 779    (lambda (c)
 780      (when (not (member c visited-list))
 781        (add-edge-between-vertexes
 782         new-graph (value root) (value c) :edge-type :directed)
 783        (neighbors-to-children new-graph c visited-list)))))
 784
 785 ;;; ---------------------------------------------------------------------------
 786
 787 (defmethod generate-directed-free-tree ((graph basic-graph) root)
 788   (generate-directed-free-tree graph (find-vertex graph root)))
 789
 790 ;;; ---------------------------------------------------------------------------
 791
 792 (defmethod force-undirected ((graph basic-graph))
 793   (iterate-edges
 794    graph
 795    (lambda (edge)
 796      (change-class edge (undirected-edge-class graph)))))
 797
 798
 799
 800 ;;; ---------------------------------------------------------------------------
 801 ;;; traversal
 802 ;;; ---------------------------------------------------------------------------
 803
 804 (defmethod traverse-elements ((thing basic-graph) (style symbol) fn)
 805   (let ((marker (gensym)))
 806     (iterate-vertexes
 807      thing
 808      (lambda (vertex)
 809        (setf (tag vertex) marker)))
 810
 811     (iterate-elements
 812      (graph-roots thing)
 813      (lambda (vertex)
 814        (traverse-elements-helper vertex style marker fn)))))
 815
 816 ;;; ---------------------------------------------------------------------------
 817
 818 (defmethod traverse-elements-helper ((thing basic-vertex) (style (eql :depth)) marker fn)
 819   (when (eq (tag thing) marker)
 820     (setf (tag thing) nil)
 821     (iterate-children
 822      thing
 823      (lambda (vertex)
 824        (traverse-elements-helper vertex style marker fn)))
 825
 826     (funcall fn thing)))
 827
 828 ;;; ---------------------------------------------------------------------------
 829
 830 (defmethod traverse-elements-helper ((thing basic-vertex) (style (eql :breadth)) marker fn)
 831   (when (eq (tag thing) marker)
 832     (setf (tag thing) nil)
 833     (funcall fn thing))
 834
 835   (iterate-neighbors
 836    thing
 837    (lambda (vertex)
 838      (when (eq (tag vertex) marker)
 839        (funcall fn vertex))))
 840
 841   (iterate-neighbors
 842    thing
 843    (lambda (vertex)
 844      (when (eq (tag vertex) marker)
 845        (setf (tag vertex) nil)
 846        (traverse-elements-helper vertex style marker fn)))))
 847
 848 ;;; ---------------------------------------------------------------------------
 849
 850 ;; also in metatilites
 851 (defun graph-search-for-cl-graph (states goal-p successors combiner
 852                                   &key (state= #'eql) old-states
 853                                   (new-state-fn #'new-states))
 854   "Find a state that satisfies goal-p.  Start with states,
 855   and search according to successors and combiner.
 856   Don't try the same state twice."
 857   (cond ((null states) nil)
 858         ((funcall goal-p (first states)) (first states))
 859         (t (graph-search-for-cl-graph
 860              (funcall
 861                combiner
 862                (funcall new-state-fn states successors state= old-states)
 863                (rest states))
 864              goal-p successors combiner
 865              :state= state=
 866              :old-states (adjoin (first states) old-states
 867                                  :test state=)
 868              :new-state-fn new-state-fn))))
 869
 870 (defmethod in-cycle-p ((graph basic-graph) (start-vertex basic-vertex))
 871   (let ((first-time? t))
 872     (not (null
 873           (graph-search-for-cl-graph
 874            (list start-vertex)
 875            (lambda (v)
 876              (if first-time?
 877                (setf first-time? nil)
 878                (eq (find-vertex graph v) start-vertex)))
 879            (lambda (v)
 880              (child-vertexes v))
 881            #'append
 882            :new-state-fn
 883            (lambda (states successors state= old-states)
 884              ;; Generate successor states that have not been seen before but
 885              ;; don't remove the start state.
 886              (remove-if
 887               #'(lambda (state)
 888                   (and (not (eq start-vertex state))
 889                        (or (member state states :test state=)
 890                            (member state old-states :test state=))))
 891               (funcall successors (first states)))))))))
 892
 893 ;;; ---------------------------------------------------------------------------
 894
 895 (defmethod in-undirected-cycle-p
 896            ((graph basic-graph) (current basic-vertex)
 897             &optional (marked (make-container 'simple-associative-container))
 898             (previous nil))
 899   (block do-it
 900     (setf (item-at-1 marked current) t)
 901     (iterate-children current
 902                       (lambda (child)
 903                         (cond
 904                          ((eq child previous) nil)
 905                          ((item-at-1 marked child) (return-from do-it t))
 906                          (t
 907                           (in-undirected-cycle-p graph child marked current)))))))
 908
 909 ;;; ---------------------------------------------------------------------------
 910
 911 (defmethod any-undirected-cycle-p ((graph basic-graph))
 912   (let ((marked (make-container 'simple-associative-container)))
 913     (iterate-vertexes graph (lambda (v)
 914                               (unless (item-at-1 marked v)
 915                                 (when (in-undirected-cycle-p graph v marked)
 916                                   (return-from any-undirected-cycle-p v)))))
 917     (values nil)))
 918
 919 ;;; ---------------------------------------------------------------------------
 920
 921 (defun remove-list (original target)
 922   "Removes all elements in original from target."
 923   (remove-if (lambda (target-element)
 924                (member target-element original))
 925              target))
 926
 927 ;;; ---------------------------------------------------------------------------
 928
 929 (defun get-nodelist-relatives (node-list)
 930   "Collects set of unique relatives of nodes in node-list."
 931   (let ((unique-relatives nil))
 932     (dolist (node node-list)
 933       (setf unique-relatives
 934             (append-unique (neighbor-vertexes node) unique-relatives)))
 935     unique-relatives))
 936
 937 ;;; ---------------------------------------------------------------------------
 938
 939 (defun get-transitive-closure (vertex-list &optional (depth nil))
 940   "Given a list of vertices, returns a combined list of all of the nodes
 941 in the transitive closure(s) of each of the vertices in the list
 942 (without duplicates).  Optional DEPTH limits the depth (in _both_ the
 943 child and parent directions) to which the closure is gathered; default
 944 nil gathers the entire closure(s)."
 945   (labels ((collect-transitive-closure (remaining visited depth)
 946              (if (and remaining
 947                       (typecase depth
 948                         (null t)
 949                         (fixnum (>= (decf depth) 0))))
 950
 951               (let* ((non-visited-relatives     ;; list of relatives not yet visited
 952                        (remove-list visited
 953                                     (get-nodelist-relatives remaining)))
 954                       (visited-nodes            ;; list of nodes visited so far
 955                        (append-unique non-visited-relatives visited)))
 956                  (collect-transitive-closure non-visited-relatives
 957                                              visited-nodes
 958                                              depth))
 959                (values visited))))
 960     (collect-transitive-closure vertex-list vertex-list depth)))
 961
 962 ;;; ---------------------------------------------------------------------------
 963 ;;; make-filtered-graph
 964 ;;; ---------------------------------------------------------------------------
 965
 966 (defmethod complete-links ((new-graph basic-graph)
 967                            (old-graph basic-graph))
 968   ;; Copy links from old-graph ONLY for nodes already in new-graph
 969   (iterate-vertexes
 970    new-graph
 971    (lambda (vertex)
 972      (let ((old-graph-vertex (find-vertex old-graph (value vertex))))
 973        (iterate-edges
 974         old-graph-vertex
 975         (lambda (old-edge)
 976           (let* ((old-other-vertex (other-vertex old-edge old-graph-vertex))
 977                  (new-other-vertex (find-vertex new-graph (value old-other-vertex) nil)))
 978             (when (and new-other-vertex
 979                        (< (vertex-id vertex) (vertex-id new-other-vertex)))
 980               (let* ((new-edge (copy-template old-edge)))
 981                 (if (eq old-graph-vertex (vertex-1 old-edge))
 982                   (setf (slot-value new-edge 'vertex-1) vertex
 983                         (slot-value new-edge 'vertex-2) new-other-vertex)
 984                   (setf (slot-value new-edge 'vertex-2) vertex
 985                         (slot-value new-edge 'vertex-1) new-other-vertex))
 986                 (add-edge new-graph new-edge))))))))))
 987
 988 #+Old
 989 (defmethod complete-links ((new-graph basic-graph)
 990                            (old-graph basic-graph))
 991   ;; Copy links from old-graph ONLY for nodes already in new-graph
 992   (iterate-vertexes
 993    new-graph
 994    (lambda (vertex)
 995      (let ((old-graph-vertex (find-vertex old-graph (value vertex))))
 996        (iterate-edges
 997         old-graph-vertex
 998         (lambda (edge)
 999           (let* ((old-other-vertex (other-vertex edge old-graph-vertex))
1000                  (new-other-vertex (find-vertex new-graph (value old-other-vertex) nil))
1001                  (edge-type (if (directed-edge-p edge)
1002                               :directed :undirected)))
1003             (when new-other-vertex
1004               (if (and (directed-edge-p edge)
1005                        (eq old-graph-vertex (target-vertex edge)))
1006                 (add-edge-between-vertexes new-graph new-other-vertex vertex
1007                                            :value (value edge)
1008                                            :edge-type edge-type)
1009                 (add-edge-between-vertexes new-graph vertex new-other-vertex
1010                                            :value (value edge)
1011                                            :edge-type edge-type))))))))))
1012
1013 ;;; ---------------------------------------------------------------------------
1014
1015 (defmethod make-filtered-graph ((old-graph basic-graph)
1016                                 test-fn
1017                                 &key
1018                                 (graph-completion-method nil)
1019                                 (depth nil)
1020                                 (new-graph
1021                                  (copy-template old-graph)))
1022   (ecase graph-completion-method
1023     ((nil
1024       :complete-links)
1025      (iterate-vertexes old-graph
1026                        (lambda (vertex)
1027                          (when (funcall test-fn vertex)
1028                            (add-vertex new-graph (value vertex))))))
1029     ((:complete-closure-nodes-only
1030       :complete-closure-with-links)
1031      (let* ((old-graph-vertexes  (collect-items old-graph :filter test-fn))
1032             (closure-vertexes
1033              (get-transitive-closure old-graph-vertexes depth)))
1034        (dolist (vertex closure-vertexes)
1035          (add-vertex new-graph (copy-template vertex))))))
1036   (ecase graph-completion-method
1037       ((nil :complete-closure-nodes-only) nil)
1038       ((:complete-links
1039         :complete-closure-with-links)
1040        (complete-links new-graph old-graph)))
1041   new-graph)
1042
1043 ;;; ---------------------------------------------------------------------------
1044
1045 (defmethod subgraph-containing ((graph basic-graph) (vertex basic-vertex)
1046                                 &rest args &key (depth nil) (new-graph nil))
1047   (declare (ignore depth new-graph))
1048   (apply #'make-filtered-graph
1049          graph
1050          #'(lambda (v)
1051              (equal v vertex))
1052          :graph-completion-method :complete-closure-with-links
1053          args))
1054
1055 ;;; ---------------------------------------------------------------------------
1056
1057 (defmethod edge-count ((graph basic-graph))
1058   (count-using #'iterate-edges nil graph))
1059
1060 ;;; ---------------------------------------------------------------------------
1061
1062 (defmethod edge-count ((vertex basic-vertex))
1063   (size (vertex-edges vertex)))
1064
1065 ;;; ---------------------------------------------------------------------------
1066
1067 (defmethod topological-sort ((graph basic-graph))
1068   (assign-level graph 0)
1069   (sort (collect-elements (graph-vertexes graph))  #'<
1070         :key (lambda (x) (depth-level x))))
1071
1072 ;;; ---------------------------------------------------------------------------
1073
1074 (defmethod assign-level ((graph basic-graph) (level number))
1075   (loop for node in (graph-roots graph)
1076         do (assign-level node 0)))
1077
1078 ;;; ---------------------------------------------------------------------------
1079
1080 (defmethod assign-level ((node basic-vertex) (level number))
1081   (if (or (not (depth-level node))
1082           (> level (depth-level node)))
1083     (setf (depth-level node) level))
1084   (iterate-children node (lambda (x) (assign-level x (1+ level)))))
1085
1086 ;;; ---------------------------------------------------------------------------
1087
1088 (defmethod depth ((graph basic-graph))
1089   (assign-level graph 0)
1090   (let ((depth 0))
1091     (iterate-vertexes graph (lambda (vertex)
1092                               (when (> (depth-level vertex) depth)
1093                                 (setf depth (depth-level vertex)))))
1094     depth))
1095
1096 ;;; ---------------------------------------------------------------------------
1097 ;;; mapping
1098 ;;; ---------------------------------------------------------------------------
1099
1100 (defun map-paths (graph start-vertex length fn &key (filter (constantly t)))
1101   "Apply fn to each path that starts at start-vertex and is of exactly length
1102 length"
1103   ;; a sort of depth first search
1104   (labels ((follow-path (next-vertex current-path length)
1105              (when (zerop length)
1106                (funcall fn (reverse current-path)))
1107              ; (format t "~%~A ~A ~A" current-path next-vertex length)
1108              (when (plusp length)
1109                (iterate-neighbors
1110                 next-vertex
1111                 (lambda (v)
1112                   (when (funcall filter v)
1113                     ;; no repeats
1114                     (unless (find-item current-path v)
1115                       (let ((new-path  (copy-list current-path)))
1116                         (follow-path v (push v new-path) (1- length))))))))))
1117     (iterate-neighbors
1118      start-vertex
1119      (lambda (v)
1120        (when (funcall filter v)
1121          (follow-path v (list v start-vertex) (1- length))))))
1122   (values graph))
1123
1124 ;;; ---------------------------------------------------------------------------
1125
1126 (defun map-shortest-paths (graph start-vertex depth fn &key (filter (constantly t)))
1127   "Apply fn to each shortest path starting at `start-vertex` of depth `depth`. The `filter` predicate is used to remove vertexes from consideration."
1128   (bind ((visited (make-container 'simple-associative-container
1129                                   :test #'equal)))
1130     (labels ((visit (p)
1131                (setf (item-at-1 visited p) t))
1132              (visited-p (p)
1133                (item-at-1 visited p))
1134              )
1135       (loop for n from 1 to (1- depth) do
1136             (map-paths graph start-vertex n
1137                        (lambda (p)
1138                          (visit (first (last p))))
1139                        :filter filter))
1140       ;(break)
1141       (visit start-vertex)
1142       (map-paths graph start-vertex depth
1143                  (lambda (p)
1144                    (unless (visited-p (first (last p)))
1145                      (funcall fn p)))
1146                  :filter filter))))
1147
1148
1149 ;;; ---------------------------------------------------------------------------
1150 ;;; utilities
1151 ;;; ---------------------------------------------------------------------------
1152
1153 (defun append-unique (list1 list2)
1154   (remove-duplicates (append list1 list2)))
1155
1156 ;;; ---------------------------------------------------------------------------
1157 ;;; project-bipartite-graph
1158 ;;; ---------------------------------------------------------------------------
1159
1160 (defmethod project-bipartite-graph
1161            ((new-graph symbol) graph vertex-class vertex-classifier)
1162   (project-bipartite-graph
1163    (make-instance new-graph) graph vertex-class  vertex-classifier))
1164
1165 ;;; ---------------------------------------------------------------------------
1166
1167 (defmethod project-bipartite-graph
1168            ((new-graph basic-graph) graph vertex-class vertex-classifier)
1169   (iterate-vertexes
1170    graph
1171    (lambda (v)
1172      (when (eq (funcall vertex-classifier v) vertex-class)
1173        (add-vertex new-graph (element v)))))
1174
1175   (iterate-vertexes
1176    graph
1177    (lambda (v)
1178      (when (eq (funcall vertex-classifier v) vertex-class)
1179        (iterate-neighbors
1180         v
1181         (lambda (other-class-vertex)
1182           (iterate-neighbors
1183            other-class-vertex
1184            (lambda (this-class-vertex)
1185              (when (< (vertex-id v) (vertex-id this-class-vertex))
1186                (add-edge-between-vertexes
1187                 new-graph (element v) (element this-class-vertex)
1188                 :if-duplicate-do (lambda (e) (incf (weight e))))))))))))
1189
1190   new-graph)
1191
1192 #+Test
1193 (pro:with-profiling
1194   (setf (ds :g-5000-m-projection)
1195         (project-bipartite-graph
1196          'undirected-graph-container
1197          (ds :g-5000)
1198          :m
1199          (lambda (v)
1200            (let ((vertex-class (aref (symbol-name (element v)) 0)))
1201              (cond ((member vertex-class '(#\a #\b) :test #'char-equal)
1202                     :m)
1203                    ((member vertex-class '(#\x #\y #\z) :test #'char-equal)
1204                     :h)))))))
1205
1206 #+Test
1207 (pro:with-profiling
1208   (setf (ds :g-5000-h-projection)
1209         (project-bipartite-graph
1210          'undirected-graph-container
1211          (ds :g-5000)
1212          :h
1213          (lambda (v)
1214            (let ((vertex-class (aref (symbol-name (element v)) 0)))
1215              (cond ((member vertex-class '(#\a #\b) :test #'char-equal)
1216                     :m)
1217                    ((member vertex-class '(#\x #\y #\z) :test #'char-equal)
1218                     :h)))))))
1219
1220 #+Test
1221 (pro:with-profiling
1222   (project-bipartite-graph
1223    'undirected-graph-container
1224    (ds :g-1000)
1225    :m
1226    (lambda (v)
1227      (let ((vertex-class (aref (symbol-name (element v)) 0)))
1228        (cond ((member vertex-class '(#\x #\y) :test #'char-equal)
1229               :m)
1230              ((member vertex-class '(#\a #\b #\c) :test #'char-equal)
1231               :h))))))
1232
1233
1234
1235