glib/gobject.signals.lisp

   1 (in-package :gobject)
   2
   3 ;;; Signal handler closures
   4
   5 (defcstruct lisp-signal-handler-closure
   6   (:parent-instance g-closure)
   7   (:object :pointer)
   8   (:function-id :int))
   9 (defctype lisp-signal-handler-closure (:struct lisp-signal-handler-closure))
  10
  11 (defun finalize-lisp-signal-handler-closure (closure)
  12   (let* ((function-id (foreign-slot-value closure 'lisp-signal-handler-closure :function-id))
  13          (addr (pointer-address (foreign-slot-value closure 'lisp-signal-handler-closure :object)))
  14          (object (or (gethash addr *foreign-gobjects-strong*)
  15                      (gethash addr *foreign-gobjects-weak*))))
  16     (when object
  17       (delete-handler-from-object object function-id))))
  18
  19 (defcallback lisp-signal-handler-closure-finalize :void
  20     ((data :pointer) (closure (:pointer lisp-signal-handler-closure)))
  21   (declare (ignore data))
  22   (finalize-lisp-signal-handler-closure closure))
  23
  24 (defun call-with-restarts (fn args)
  25   (restart-case
  26       (apply fn args)
  27     (return-from-g-closure (&optional v) :report "Return value from closure" v)))
  28
  29 (defcallback lisp-signal-handler-closure-marshal :void
  30     ((closure (:pointer lisp-signal-handler-closure))
  31      (return-value (:pointer g-value))
  32      (count-of-args :uint)
  33      (args (:pointer g-value))
  34      (invocation-hint :pointer)
  35      (marshal-data :pointer))
  36   (declare (ignore invocation-hint marshal-data))
  37   (let* ((args (parse-closure-arguments count-of-args args))
  38          (function-id (foreign-slot-value closure 'lisp-signal-handler-closure :function-id))
  39          (addr (pointer-address (foreign-slot-value closure 'lisp-signal-handler-closure :object)))
  40          (object (or (gethash addr *foreign-gobjects-strong*)
  41                      (gethash addr *foreign-gobjects-weak*)))
  42          (return-type (and (not (null-pointer-p return-value))
  43                            (g-value-type return-value)))
  44          (fn (retrieve-handler-from-object object function-id))
  45          (fn-result (call-with-restarts fn args)))
  46     (when return-type
  47       (set-g-value return-value fn-result return-type :g-value-init nil))))
  48
  49 (defun parse-closure-arguments (count-of-args args)
  50   (loop
  51      for i from 0 below count-of-args
  52      collect (parse-g-value (mem-aref args 'g-value i))))
  53
  54 (defun create-signal-handler-closure (object fn)
  55   (let ((function-id (save-handler-to-object object fn))
  56         (closure (g-closure-new-simple (foreign-type-size 'lisp-signal-handler-closure) (null-pointer))))
  57     (setf (foreign-slot-value closure 'lisp-signal-handler-closure :function-id) function-id
  58           (foreign-slot-value closure 'lisp-signal-handler-closure :object) (pointer object))
  59     (g-closure-add-finalize-notifier closure (null-pointer)
  60                                      (callback lisp-signal-handler-closure-finalize))
  61     (g-closure-set-marshal closure (callback lisp-signal-handler-closure-marshal))
  62     closure))
  63
  64 (defun find-free-signal-handler-id (object)
  65   (iter (with handlers = (g-object-signal-handlers object))
  66         (for i from 0 below (length handlers))
  67         (finding i such-that (null (aref handlers i)))))
  68
  69 (defun save-handler-to-object (object handler)
  70   (assert handler)
  71   (let ((id (find-free-signal-handler-id object))
  72         (handlers (g-object-signal-handlers object)))
  73     (if id
  74         (progn (setf (aref handlers id) handler) id)
  75         (progn (vector-push-extend handler handlers) (1- (length handlers))))))
  76
  77 (defun retrieve-handler-from-object (object handler-id)
  78   (aref (g-object-signal-handlers object) handler-id))
  79
  80 (defun delete-handler-from-object (object handler-id)
  81   (let ((handlers (g-object-signal-handlers object)))
  82     (setf (aref handlers handler-id) nil)
  83     (iter (while (plusp (length handlers)))
  84           (while (null (aref handlers (1- (length handlers)))))
  85           (vector-pop handlers))
  86     nil))
  87
  88 (defun connect-signal (object signal handler &key after)
  89   "Connects the function to a signal for a particular object.
  90 If @code{after} is true, then the function will be called after the default handler of the signal.
  91
  92 @arg[object]{an instance of @class{gobject}}
  93 @arg[signal]{a string; names the signal}
  94 @arg[handler]{a function; handles the signal. Number (and type) of arguments and return value type depends on the signal}
  95 @arg[after]{a boolean}"
  96   (g-signal-connect-closure (pointer object)
  97                             signal
  98                             (create-signal-handler-closure object handler)
  99                             after))
 100
 101 (defun g-signal-connect (object signal handler &key after)
 102   "Deprecated alias for @fun{connect-signal}"
 103   (connect-signal object signal handler :after after))
 104
 105 (defun emit-signal (object signal-name &rest args)
 106   "Emits the signal.
 107 @arg[object]{an instance of @class{g-object}. Signal is emitted on this object}
 108 @arg[signal-name]{a string specifying the signal}
 109 @arg[args]{arguments for the signal}
 110 @return{none}"
 111   (let* ((object-type (g-type-from-object (pointer object)))
 112          (signal-info (parse-signal-name object-type signal-name)))
 113     (unless signal-info
 114       (error "Signal ~A not found on object ~A" signal-name object))
 115     (let ((params-count (length (signal-info-param-types signal-info))))
 116       (with-foreign-object (params 'g-value (1+ params-count))
 117         (set-g-value (mem-aref params 'g-value 0) object object-type :zero-g-value t)
 118         (iter (for i from 0 below params-count)
 119               (for arg in args)
 120               (for type in (signal-info-param-types signal-info))
 121               (set-g-value (mem-aref params 'g-value (1+ i)) arg type :zero-g-value t))
 122         (prog1
 123             (if (eq (signal-info-return-type signal-info) (gtype +g-type-void+))
 124                 (g-signal-emitv params (signal-info-id signal-info) signal-name (null-pointer))
 125                 (with-foreign-object (return-value 'g-value)
 126                   (g-value-zero return-value)
 127                   (g-value-init return-value (signal-info-return-type signal-info))
 128                   (prog1 (parse-g-value return-value)
 129                     (g-value-unset return-value))))
 130           (iter (for i from 0 below (1+ params-count))
 131                 (g-value-unset (mem-aref params 'g-value i))))))))
 132
 133 (defcfun (disconnect-signal "g_signal_handler_disconnect") :void
 134   (object g-object)
 135   (handler-id :ulong))