src/check.lisp

   1 ;;;; -*- Mode: Lisp; indent-tabs-mode: nil -*-
   2
   3 (in-package :it.bese.fiveam)
   4
   5 ;;;; * Checks
   6
   7 ;;;; At the lowest level testing the system requires that certain
   8 ;;;; forms be evaluated and that certain post conditions are met: the
   9 ;;;; value returned must satisfy a certain predicate, the form must
  10 ;;;; (or must not) signal a certain condition, etc. In FiveAM these
  11 ;;;; low level operations are called 'checks' and are defined using
  12 ;;;; the various checking macros.
  13
  14 ;;;; Checks are the basic operators for collecting results. Tests and
  15 ;;;; test suites on the other hand allow grouping multiple checks into
  16 ;;;; logic collections.
  17
  18 (defvar *test-dribble* t)
  19
  20 (defmacro with-*test-dribble* (stream &body body)
  21   `(let ((*test-dribble* ,stream))
  22      (declare (special *test-dribble*))
  23      ,@body))
  24
  25 (eval-when (:compile-toplevel :load-toplevel :execute)
  26   (def-special-environment run-state ()
  27     result-list
  28     current-test))
  29
  30 ;;;; ** Types of test results
  31
  32 ;;;; Every check produces a result object.
  33
  34 (defclass test-result ()
  35   ((reason :accessor reason :initarg :reason :initform "no reason given")
  36    (test-case :accessor test-case :initarg :test-case)
  37    (test-expr :accessor test-expr :initarg :test-expr))
  38   (:documentation "All checking macros will generate an object of
  39  type TEST-RESULT."))
  40
  41 (defclass test-passed (test-result)
  42   ()
  43   (:documentation "Class for successful checks."))
  44
  45 (defgeneric test-passed-p (object)
  46   (:method ((o t)) nil)
  47   (:method ((o test-passed)) t))
  48
  49 (define-condition check-failure (error)
  50   ((reason :accessor reason :initarg :reason :initform "no reason given")
  51    (test-case :accessor test-case :initarg :test-case)
  52    (test-expr :accessor test-expr :initarg :test-expr))
  53   (:documentation "Signaled when a check fails.")
  54   (:report  (lambda (c stream)
  55               (format stream "The following check failed: ~S~%~A."
  56                       (test-expr c)
  57                       (reason c)))))
  58
  59 (defmacro process-failure (&rest args)
  60   `(progn
  61      (with-simple-restart (ignore-failure "Continue the test run.")
  62        (error 'check-failure ,@args))
  63      (add-result 'test-failure ,@args)))
  64
  65 (defclass test-failure (test-result)
  66   ()
  67   (:documentation "Class for unsuccessful checks."))
  68
  69 (defgeneric test-failure-p (object)
  70   (:method ((o t)) nil)
  71   (:method ((o test-failure)) t))
  72
  73 (defclass unexpected-test-failure (test-failure)
  74   ((actual-condition :accessor actual-condition :initarg :condition))
  75   (:documentation "Represents the result of a test which neither
  76 passed nor failed, but signaled an error we couldn't deal
  77 with.
  78
  79 Note: This is very different than a SIGNALS check which instead
  80 creates a TEST-PASSED or TEST-FAILURE object."))
  81
  82 (defclass test-skipped (test-result)
  83   ()
  84   (:documentation "A test which was not run. Usually this is due
  85 to unsatisfied dependencies, but users can decide to skip test
  86 when appropiate."))
  87
  88 (defgeneric test-skipped-p (object)
  89   (:method ((o t)) nil)
  90   (:method ((o test-skipped)) t))
  91
  92 (defun add-result (result-type &rest make-instance-args)
  93   "Create a TEST-RESULT object of type RESULT-TYPE passing it the
  94   initialize args MAKE-INSTANCE-ARGS and adds the resulting
  95   object to the list of test results."
  96   (with-run-state (result-list current-test)
  97     (let ((result (apply #'make-instance result-type
  98                          (append make-instance-args (list :test-case current-test)))))
  99       (etypecase result
 100         (test-passed  (format *test-dribble* "."))
 101         (unexpected-test-failure (format *test-dribble* "X"))
 102         (test-failure (format *test-dribble* "f"))
 103         (test-skipped (format *test-dribble* "s")))
 104       (push result result-list))))
 105
 106 ;;;; ** The check operators
 107
 108 ;;;; *** The IS check
 109
 110 (defmacro is (test &rest reason-args)
 111   "The DWIM checking operator.
 112
 113 If TEST returns a true value a test-passed result is generated,
 114 otherwise a test-failure result is generated. The reason, unless
 115 REASON-ARGS is provided, is generated based on the form of TEST:
 116
 117  (predicate expected actual) - Means that we want to check
 118  whether, according to PREDICATE, the ACTUAL value is
 119  in fact what we EXPECTED.
 120
 121  (predicate value) - Means that we want to ensure that VALUE
 122  satisfies PREDICATE.
 123
 124  Wrapping the TEST form in a NOT simply preducse a negated reason
 125  string."
 126   (assert (listp test)
 127           (test)
 128           "Argument to IS must be a list, not ~S" test)
 129   (let (bindings effective-test default-reason-args)
 130     (with-gensyms (e a v)
 131       (flet ((process-entry (predicate expected actual &optional negatedp)
 132                ;; make sure EXPECTED is holding the entry that starts with 'values
 133                (when (and (consp actual)
 134                           (eq (car actual) 'values))
 135                  (assert (not (and (consp expected)
 136                                    (eq (car expected) 'values))) ()
 137                                    "Both the expected and actual part is a values expression.")
 138                  (rotatef expected actual))
 139                (let ((setf-forms))
 140                  (if (and (consp expected)
 141                           (eq (car expected) 'values))
 142                      (progn
 143                        (setf expected (copy-list expected))
 144                        (setf setf-forms (loop for cell = (rest expected) then (cdr cell)
 145                                               for i from 0
 146                                               while cell
 147                                               when (eq (car cell) '*)
 148                                               collect `(setf (elt ,a ,i) nil)
 149                                               and do (setf (car cell) nil)))
 150                        (setf bindings (list (list e `(list ,@(rest expected)))
 151                                             (list a `(multiple-value-list ,actual)))))
 152                      (setf bindings (list (list e expected)
 153                                           (list a actual))))
 154                  (setf effective-test `(progn
 155                                          ,@setf-forms
 156                                          ,(if negatedp
 157                                               `(not (,predicate ,e ,a))
 158                                               `(,predicate ,e ,a)))))))
 159         (list-match-case test
 160           ((not (?predicate ?expected ?actual))
 161            (process-entry ?predicate ?expected ?actual t)
 162            (setf default-reason-args
 163                  (list "~S evaluated to ~S, which is ~S to ~S (it should not be)"
 164                        `',?actual a `',?predicate e)))
 165           ((not (?satisfies ?value))
 166            (setf bindings (list (list v ?value))
 167                  effective-test `(not (,?satisfies ,v))
 168                  default-reason-args
 169                  (list "~S evaluated to ~S, which satisfies ~S (it should not)"
 170                        `',?value v `',?satisfies)))
 171           ((?predicate ?expected ?actual)
 172            (process-entry ?predicate ?expected ?actual)
 173            (setf default-reason-args
 174                  (list "~S evaluated to ~S, which is not ~S to ~S."
 175                        `',?actual a `',?predicate e)))
 176           ((?satisfies ?value)
 177            (setf bindings (list (list v ?value))
 178                  effective-test `(,?satisfies ,v)
 179                  default-reason-args
 180                  (list "~S evaluated to ~S, which does not satisfy ~S"
 181                        `',?value v `',?satisfies)))
 182           (?_
 183            (setf bindings '()
 184                  effective-test test
 185                  default-reason-args (list "~S was NIL." `',test)))))
 186       `(let ,bindings
 187          (if ,effective-test
 188              (add-result 'test-passed :test-expr ',test)
 189              (process-failure :reason (format nil ,@(or reason-args default-reason-args))
 190                               :test-expr ',test))))))
 191
 192 ;;;; *** Other checks
 193
 194 (defmacro skip (&rest reason)
 195   "Generates a TEST-SKIPPED result."
 196   `(progn
 197      (format *test-dribble* "s")
 198      (add-result 'test-skipped :reason (format nil ,@reason))))
 199
 200 (defmacro is-every (predicate &body clauses)
 201   "The input is either a list of lists, or a list of pairs. Generates (is (,predicate ,expr ,value))
 202    for each pair of elements or (is (,predicate ,expr ,value) ,@reason) for each list."
 203   `(progn
 204      ,@(if (every #'consp clauses)
 205            (loop for (expected actual . reason) in clauses
 206                  collect `(is (,predicate ,expected ,actual) ,@reason))
 207            (progn
 208              (assert (evenp (list-length clauses)))
 209              (loop for (expr value) on clauses by #'cddr
 210                    collect `(is (,predicate ,expr ,value)))))))
 211
 212 (defmacro is-true (condition &rest reason-args)
 213   "Like IS this check generates a pass if CONDITION returns true
 214   and a failure if CONDITION returns false. Unlike IS this check
 215   does not inspect CONDITION to determine how to report the
 216   failure."
 217   `(if ,condition
 218        (add-result 'test-passed :test-expr ',condition)
 219        (process-failure
 220         :reason ,(if reason-args
 221                      `(format nil ,@reason-args)
 222                      `(format nil "~S did not return a true value" ',condition))
 223         :test-expr ',condition)))
 224
 225 (defmacro is-false (condition &rest reason-args)
 226   "Generates a pass if CONDITION returns false, generates a
 227   failure otherwise. Like IS-TRUE, and unlike IS, IS-FALSE does
 228   not inspect CONDITION to determine what reason to give it case
 229   of test failure"
 230
 231   (with-gensyms (value)
 232     `(let ((,value ,condition))
 233        (if ,value
 234            (process-failure
 235             :reason ,(if reason-args
 236                          `(format nil ,@reason-args)
 237                          `(format nil "~S returned the value ~S, which is true" ',condition ,value ))
 238             :test-expr ',condition)
 239            (add-result 'test-passed :test-expr ',condition)))))
 240
 241 (defmacro signals (condition-spec
 242                    &body body)
 243   "Generates a pass if BODY signals a condition of type
 244 CONDITION. BODY is evaluated in a block named NIL, CONDITION is
 245 not evaluated."
 246   (let ((block-name (gensym)))
 247     (destructuring-bind (condition &optional reason-control reason-args)
 248         (ensure-list condition-spec)
 249       `(block ,block-name
 250          (handler-bind ((,condition (lambda (c)
 251                                       (declare (ignore c))
 252                                       ;; ok, body threw condition
 253                                       (add-result 'test-passed
 254                                                   :test-expr ',condition)
 255                                       (return-from ,block-name t))))
 256            (block nil
 257              ,@body))
 258          (process-failure
 259           :reason ,(if reason-control
 260                        `(format nil ,reason-control ,@reason-args)
 261                        `(format nil "Failed to signal a ~S" ',condition))
 262           :test-expr ',condition)
 263          (return-from ,block-name nil)))))
 264
 265 (defmacro finishes (&body body)
 266   "Generates a pass if BODY executes to normal completion. In
 267 other words if body does signal, return-from or throw this test
 268 fails."
 269   `(let ((ok nil))
 270      (unwind-protect
 271           (progn
 272             ,@body
 273             (setf ok t))
 274        (if ok
 275            (add-result 'test-passed :test-expr ',body)
 276            (process-failure
 277             :reason (format nil "Test didn't finish")
 278             :test-expr ',body)))))
 279
 280 (defmacro pass (&rest message-args)
 281   "Simply generate a PASS."
 282   `(add-result 'test-passed
 283                :test-expr ',message-args
 284                ,@(when message-args
 285                        `(:reason (format nil ,@message-args)))))
 286
 287 (defmacro fail (&rest message-args)
 288   "Simply generate a FAIL."
 289   `(process-failure
 290     :test-expr ',message-args
 291     ,@(when message-args
 292             `(:reason (format nil ,@message-args)))))
 293
 294 ;; Copyright (c) 2002-2003, Edward Marco Baringer
 295 ;; All rights reserved.
 296 ;;
 297 ;; Redistribution and use in source and binary forms, with or without
 298 ;; modification, are permitted provided that the following conditions are
 299 ;; met:
 300 ;;
 301 ;;  - Redistributions of source code must retain the above copyright
 302 ;;    notice, this list of conditions and the following disclaimer.
 303 ;;
 304 ;;  - Redistributions in binary form must reproduce the above copyright
 305 ;;    notice, this list of conditions and the following disclaimer in the
 306 ;;    documentation and/or other materials provided with the distribution.
 307 ;;
 308 ;;  - Neither the name of Edward Marco Baringer, nor BESE, nor the names
 309 ;;    of its contributors may be used to endorse or promote products
 310 ;;    derived from this software without specific prior written permission.
 311 ;;
 312 ;; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
 313 ;; "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
 314 ;; LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
 315 ;; A PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE COPYRIGHT
 316 ;; OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
 317 ;; SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
 318 ;; LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
 319 ;; DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
 320 ;; THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
 321 ;; (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
 322 ;; OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE