src/check.lisp

   1 ;; -*- lisp -*-
   2
   3 (in-package :it.bese.FiveAM)
   4
   5 ;;;; * Checks
   6
   7 ;;;; At the lowest level testing the system requires that certain
   8 ;;;; forms be evaluated and that certain post conditions are met: the
   9 ;;;; value returned must satisfy a certain predicate, the form must
  10 ;;;; (or must not) signal a certain condition, etc. In FiveAM these
  11 ;;;; low level operations are called 'checks' and are defined using
  12 ;;;; the various checking macros.
  13
  14 ;;;; Checks are the basic operators for collecting results. Tests and
  15 ;;;; test suites on the other hand allow grouping multiple checks into
  16 ;;;; logic collections.
  17
  18 (defvar *test-dribble* t)
  19
  20 (defmacro with-*test-dribble* (stream &body body)
  21   `(let ((*test-dribble* ,stream))
  22      (declare (special *test-dribble*))
  23      ,@body))
  24
  25 (eval-when (:compile-toplevel :load-toplevel :execute)
  26   (def-special-environment run-state ()
  27     result-list
  28     current-test))
  29
  30 ;;;; ** Types of test results
  31
  32 ;;;; Every check produces a result object.
  33
  34 (defclass test-result ()
  35   ((reason :accessor reason :initarg :reason :initform "no reason given")
  36    (test-case :accessor test-case :initarg :test-case)
  37    (test-expr :accessor test-expr :initarg :test-expr))
  38   (:documentation "All checking macros will generate an object of
  39  type TEST-RESULT."))
  40
  41 (defclass test-passed (test-result)
  42   ()
  43   (:documentation "Class for successful checks."))
  44
  45 (defgeneric test-passed-p (object)
  46   (:method ((o t)) nil)
  47   (:method ((o test-passed)) t))
  48
  49 (define-condition check-failure (error)
  50   ((reason :accessor reason :initarg :reason :initform "no reason given")
  51    (test-case :accessor test-case :initarg :test-case)
  52    (test-expr :accessor test-expr :initarg :test-expr))
  53   (:documentation "Signaled when a check fails.")
  54   (:report  (lambda (c stream)
  55               (format stream "The following check failed: ~S~%~A."
  56                       (test-expr c)
  57                       (reason c)))))
  58
  59 (defmacro process-failure (&rest args)
  60   `(progn
  61     (with-simple-restart (ignore-failure "Continue the test run.")
  62       (error 'check-failure ,@args))
  63     (add-result 'test-failure ,@args)))
  64
  65 (defclass test-failure (test-result)
  66   ()
  67   (:documentation "Class for unsuccessful checks."))
  68
  69 (defgeneric test-failure-p (object)
  70   (:method ((o t)) nil)
  71   (:method ((o test-failure)) t))
  72
  73 (defclass unexpected-test-failure (test-failure)
  74   ((actual-condition :accessor actual-condition :initarg :condition))
  75   (:documentation "Represents the result of a test which neither
  76 passed nor failed, but signaled an error we couldn't deal
  77 with.
  78
  79 Note: This is very different than a SIGNALS check which instead
  80 creates a TEST-PASSED or TEST-FAILURE object."))
  81
  82 (defclass test-skipped (test-result)
  83   ()
  84   (:documentation "A test which was not run. Usually this is due
  85 to unsatisfied dependencies, but users can decide to skip test
  86 when appropiate."))
  87
  88 (defgeneric test-skipped-p (object)
  89   (:method ((o t)) nil)
  90   (:method ((o test-skipped)) t))
  91
  92 (defun add-result (result-type &rest make-instance-args)
  93   "Create a TEST-RESULT object of type RESULT-TYPE passing it the
  94   initialize args MAKE-INSTANCE-ARGS and adds the resulting
  95   object to the list of test results."
  96   (with-run-state (result-list current-test)
  97     (let ((result (apply #'make-instance result-type
  98                          (append make-instance-args (list :test-case current-test)))))
  99       (etypecase result
 100         (test-passed  (format *test-dribble* "."))
 101         (unexpected-test-failure (format *test-dribble* "X"))
 102         (test-failure (format *test-dribble* "f"))
 103         (test-skipped (format *test-dribble* "s")))
 104       (push result result-list))))
 105
 106 ;;;; ** The check operators
 107
 108 ;;;; *** The IS check
 109
 110 (defmacro is (test &rest reason-args)
 111   "The DWIM checking operator.
 112
 113 If TEST returns a true value a test-passed result is generated,
 114 otherwise a test-failure result is generated and the reason,
 115 unless REASON-ARGS is provided, is generated based on the form of
 116 TEST:
 117
 118  (predicate expected actual) - Means that we want to check
 119  whether, according to PREDICATE, the ACTUAL value is
 120  in fact what we EXPECTED.
 121
 122  (predicate value) - Means that we want to ensure that VALUE
 123  satisfies PREDICATE.
 124
 125 Wrapping the TEST form in a NOT simply preducse a negated reason string."
 126   (assert (listp test)
 127           (test)
 128           "Argument to IS must be a list, not ~S" test)
 129   (let (bindings effective-test default-reason-args)
 130     (with-unique-names (e a v)
 131       (flet ((process-entry (predicate expected actual &optional negatedp)
 132                ;; make sure EXPECTED is holding the entry that starts with 'values
 133                (when (and (consp actual)
 134                           (eq (car actual) 'values))
 135                  (assert (not (and (consp expected)
 136                                    (eq (car expected) 'values))) ()
 137                                    "Both the expected and actual part is a values expression.")
 138                  (let ((tmp expected))
 139                    (setf expected actual
 140                          actual tmp)))
 141                (let ((setf-forms))
 142                  (if (and (consp expected)
 143                           (eq (car expected) 'values))
 144                      (progn
 145                        (setf expected (copy-list expected))
 146                        (setf setf-forms (loop for cell = (rest expected) then (cdr cell)
 147                                               for i from 0
 148                                               while cell
 149                                               when (eq (car cell) '*)
 150                                               collect `(setf (elt ,a ,i) nil)
 151                                               and do (setf (car cell) nil)))
 152                        (setf bindings (list (list e `(list ,@(rest expected)))
 153                                             (list a `(multiple-value-list ,actual)))))
 154                      (setf bindings (list (list e expected)
 155                                           (list a actual))))
 156                  (setf effective-test `(progn
 157                                         ,@setf-forms
 158                                         ,(if negatedp
 159                                              `(not (,predicate ,e ,a))
 160                                              `(,predicate ,e ,a)))))))
 161         (list-match-case test
 162           ((not (?predicate ?expected ?actual))
 163            (process-entry ?predicate ?expected ?actual t)
 164            (setf default-reason-args (list "~S was ~S to ~S" a `',?predicate e)))
 165           ((not (?satisfies ?value))
 166            (setf bindings (list (list v ?value))
 167                  effective-test `(not (,?satisfies ,v))
 168                  default-reason-args (list  "~S satisfied ~S" v `',?satisfies)))
 169           ((?predicate ?expected ?actual)
 170            (process-entry ?predicate ?expected ?actual)
 171            (setf default-reason-args (list "~S was not ~S to ~S" a `',?predicate e)))
 172           ((?satisfies ?value)
 173            (setf bindings (list (list v ?value))
 174                  effective-test `(,?satisfies ,v)
 175                  default-reason-args (list "~S did not satisfy ~S" v `',?satisfies)))
 176           (?_
 177            (setf bindings '()
 178                  effective-test test
 179                  default-reason-args (list "No reason supplied")))))
 180       `(let ,bindings
 181          (if ,effective-test
 182              (add-result 'test-passed :test-expr ',test)
 183              (process-failure :reason (format nil ,@(or reason-args default-reason-args))
 184                               :test-expr ',test))))))
 185
 186 ;;;; *** Other checks
 187
 188 (defmacro skip (&rest reason)
 189   "Generates a TEST-SKIPPED result."
 190   `(progn
 191      (format *test-dribble* "s")
 192      (add-result 'test-skipped :reason (format nil ,@reason))))
 193
 194 (defmacro is-every (predicate &body clauses)
 195   "The input is either a list of lists, or a list of pairs. Generates (is (,predicate ,expr ,value))
 196    for each pair of elements or (is (,predicate ,expr ,value) ,@reason) for each list."
 197   `(progn
 198     ,@(if (every #'consp clauses)
 199           (loop for (expected actual . reason) in clauses
 200                 collect `(is (,predicate ,expected ,actual) ,@reason))
 201           (progn
 202             (assert (evenp (list-length clauses)))
 203             (loop for (expr value) on clauses by #'cddr
 204                   collect `(is (,predicate ,expr ,value)))))))
 205
 206 (defmacro is-true (condition &rest reason-args)
 207   "Like IS this check generates a pass if CONDITION returns true
 208   and a failure if CONDITION returns false. Unlike IS this check
 209   does not inspect CONDITION to determine how to report the
 210   failure."
 211   `(if ,condition
 212     (add-result 'test-passed :test-expr ',condition)
 213     (process-failure
 214      :reason ,(if reason-args
 215                   `(format nil ,@reason-args)
 216                   `(format nil "~S did not return a true value" ',condition))
 217      :test-expr ',condition)))
 218
 219 (defmacro is-false (condition &rest reason-args)
 220   "Generates a pass if CONDITION returns false, generates a
 221   failure otherwise. Like IS-TRUE, and unlike IS, IS-FALSE does
 222   not inspect CONDITION to determine what reason to give it case
 223   of test failure"
 224   `(if ,condition
 225     (process-failure
 226      :reason ,(if reason-args
 227                   `(format nil ,@reason-args)
 228                   `(format nil "~S returned a true value" ',condition))
 229      :test-expr ',condition)
 230     (add-result 'test-passed :test-expr ',condition)))
 231
 232 (defmacro signals (condition-spec
 233                    &body body)
 234   "Generates a pass if BODY signals a condition of type
 235 CONDITION. BODY is evaluated in a block named NIL, CONDITION is
 236 not evaluated."
 237   (let ((block-name (gensym)))
 238     (destructuring-bind (condition &optional reason-control reason-args)
 239         (ensure-list condition-spec)
 240       `(block ,block-name
 241          (handler-bind ((,condition (lambda (c)
 242                                       (declare (ignore c))
 243                                       ;; ok, body threw condition
 244                                       (add-result 'test-passed
 245                                                   :test-expr ',condition)
 246                                       (return-from ,block-name t))))
 247            (block nil
 248              ,@body))
 249          (process-failure
 250           :reason ,(if reason-control
 251                        `(format nil ,reason-control ,@reason-args)
 252                        `(format nil "Failed to signal a ~S" ',condition))
 253           :test-expr ',condition)
 254          (return-from ,block-name nil)))))
 255
 256 (defmacro finishes (&body body)
 257   "Generates a pass if BODY executes to normal completion. In
 258 other words if body does signal, return-from or throw this test
 259 fails."
 260   `(let ((ok nil))
 261      (unwind-protect
 262          (progn
 263            ,@body
 264            (setf ok t))
 265        (if ok
 266            (add-result 'test-passed :test-expr ',body)
 267            (process-failure
 268             :reason (format nil "Test didn't finish")
 269             :test-expr ',body)))))
 270
 271 (defmacro pass (&rest message-args)
 272   "Simply generate a PASS."
 273   `(add-result 'test-passed
 274                :test-expr ',message-args
 275                ,@(when message-args
 276                        `(:reason (format nil ,@message-args)))))
 277
 278 (defmacro fail (&rest message-args)
 279   "Simply generate a FAIL."
 280   `(process-failure
 281     :test-expr ',message-args
 282     ,@(when message-args
 283             `(:reason (format nil ,@message-args)))))
 284
 285 ;; Copyright (c) 2002-2003, Edward Marco Baringer
 286 ;; All rights reserved.
 287 ;;
 288 ;; Redistribution and use in source and binary forms, with or without
 289 ;; modification, are permitted provided that the following conditions are
 290 ;; met:
 291 ;;
 292 ;;  - Redistributions of source code must retain the above copyright
 293 ;;    notice, this list of conditions and the following disclaimer.
 294 ;;
 295 ;;  - Redistributions in binary form must reproduce the above copyright
 296 ;;    notice, this list of conditions and the following disclaimer in the
 297 ;;    documentation and/or other materials provided with the distribution.
 298 ;;
 299 ;;  - Neither the name of Edward Marco Baringer, nor BESE, nor the names
 300 ;;    of its contributors may be used to endorse or promote products
 301 ;;    derived from this software without specific prior written permission.
 302 ;;
 303 ;; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
 304 ;; "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
 305 ;; LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
 306 ;; A PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE COPYRIGHT
 307 ;; OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
 308 ;; SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
 309 ;; LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
 310 ;; DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
 311 ;; THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
 312 ;; (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
 313 ;; OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE