src/run.lisp

   1 ;; -*- lisp -*-
   2
   3 (in-package :it.bese.FiveAM)
   4
   5 ;;;; * Running Tests
   6
   7 ;;;; Once the programmer has defined what the tests are these need to
   8 ;;;; be run and the expected effects should be compared with the
   9 ;;;; actual effects. FiveAM provides the function RUN for this
  10 ;;;; purpose, RUN executes a number of tests and collects the results
  11 ;;;; of each individual check into a list which is then
  12 ;;;; returned. There are three types of test results: passed, failed
  13 ;;;; and skipped, these are represented by TEST-RESULT objects.
  14
  15 ;;;; Generally running a test will return normally, but there are two
  16 ;;;; exceptional situations which can occur:
  17
  18 ;;;; - An exception is signaled while running the test. If the
  19 ;;;;   variable *debug-on-error* is T than FiveAM will enter the
  20 ;;;;   debugger, otherwise a test failure (of type
  21 ;;;;   unexpected-test-failure) is returned. When entering the
  22 ;;;;   debugger two restarts are made available, one simply reruns the
  23 ;;;;   current test and another signals a test-failure and continues
  24 ;;;;   with the remaining tests.
  25
  26 ;;;; - A circular dependency is detected. An error is signaled and a
  27 ;;;;   restart is made available which signals a test-skipped and
  28 ;;;;   continues with the remaining tests. This restart also sets the
  29 ;;;;   dependency status of the test to nil, so any tests which depend
  30 ;;;;   on this one (even if the dependency is not circular) will be
  31 ;;;;   skipped.
  32
  33 ;;;; The functions RUN!, !, !! and !!! are convenient wrappers around
  34 ;;;; RUN and EXPLAIN.
  35
  36 (defparameter *debug-on-error* nil
  37   "T if we should drop into a debugger on error, NIL otherwise.")
  38
  39 (defparameter *debug-on-failure* nil
  40   "T if we should drop into a debugger on a failing check, NIL otherwise.")
  41
  42 (defun import-testing-symbols (package-designator)
  43   (import '(5am::is 5am::is-true 5am::is-false 5am::signals 5am::finishes)
  44           package-designator))
  45
  46 (defparameter *run-queue* '()
  47   "List of test waiting to be run.")
  48
  49 (define-condition circular-dependency (error)
  50   ((test-case :initarg :test-case))
  51   (:report (lambda (cd stream)
  52              (format stream "A circular dependency wes detected in ~S." (slot-value cd 'test-case))))
  53   (:documentation "Condition signaled when a circular dependency
  54 between test-cases has been detected."))
  55
  56 (defgeneric run-resolving-dependencies (test)
  57   (:documentation "Given a dependency spec determine if the spec
  58 is satisfied or not, this will generally involve running other
  59 tests. If the dependency spec can be satisfied the test is alos
  60 run."))
  61
  62 (defmethod run-resolving-dependencies ((test test-case))
  63   "Return true if this test, and its dependencies, are satisfied,
  64   NIL otherwise."
  65   (case (status test)
  66     (:unknown
  67      (setf (status test) :resolving)
  68      (if (or (not (depends-on test))
  69              (resolve-dependencies (depends-on test)))
  70          (progn
  71            (run-test-lambda test)
  72            (status test))
  73          (with-run-state (result-list)
  74            (unless (eql :circular (status test))
  75              (push (make-instance 'test-skipped
  76                                   :test-case test
  77                                   :reason "Dependencies not satisfied")
  78                    result-list)
  79              (setf (status test) :depends-not-satisfied)))))
  80     (:resolving
  81      (restart-case
  82          (error 'circular-dependency :test-case test)
  83        (skip ()
  84          :report (lambda (s)
  85                    (format s "Skip the test ~S and all its dependencies." (name test)))
  86          (with-run-state (result-list)
  87            (push (make-instance 'test-skipped :reason "Circular dependencies" :test-case test)
  88                  result-list))
  89          (setf (status test) :circular))))
  90     (t (status test))))
  91
  92 (defmethod resolve-dependencies ((depends-on symbol))
  93   "A test which depends on a symbol is interpreted as `(AND
  94   ,DEPENDS-ON)."
  95   (run-resolving-dependencies (get-test depends-on)))
  96
  97 (defmethod resolve-dependencies ((depends-on list))
  98   "Return true if the dependency spec DEPENDS-ON is satisfied,
  99   nil otherwise."
 100   (if (null depends-on)
 101       t
 102       (flet ((satisfies-depends-p (test)
 103                (funcall test (lambda (dep)
 104                                (eql t (resolve-dependencies dep)))
 105                              (cdr depends-on))))
 106         (ecase (car depends-on)
 107           (and (satisfies-depends-p #'every))
 108           (or  (satisfies-depends-p #'some))
 109           (not (satisfies-depends-p #'notany))))))
 110
 111 (defun results-status (result-list)
 112   "Given a list of test results (generated while running a test)
 113   return true if all of the results are of type TEST-PASSED,
 114   faile otherwise."
 115   (every (lambda (res)
 116            (typep res 'test-passed))
 117          result-list))
 118
 119 (defun return-result-list (test-lambda)
 120   "Run the test function TEST-LAMBDA and return a list of all
 121   test results generated, does not modify the special environment
 122   variable RESULT-LIST."
 123   (bind-run-state ((result-list '()))
 124     (funcall test-lambda)
 125     result-list))
 126
 127 (defmethod run-test-lambda ((test test-case))
 128   (with-run-state (result-list)
 129     (bind-run-state ((current-test test))
 130       (labels ((abort-test (e)
 131                  (add-result 'unexpected-test-failure
 132                              :test-expr nil
 133                              :test-case test
 134                              :reason (format nil "Unexpected Error: ~S~%~A." e e)
 135                              :condition e))
 136                (run-it ()
 137                  (let ((result-list '()))
 138                    (declare (special result-list))
 139                    (handler-bind ((check-failure (lambda (e)
 140                                                    (declare (ignore e))
 141                                                    (unless *debug-on-failure*
 142                                                      (invoke-restart
 143                                                       (find-restart 'ignore-failure)))))
 144                                   (error (lambda (e)
 145                                            (unless (or *debug-on-error*
 146                                                        (typep e 'check-failure))
 147                                              (abort-test e)
 148                                              (return-from run-it result-list)))))
 149                      (restart-case
 150                          (let ((*readtable* (copy-readtable))
 151                                (*package* (runtime-package test)))
 152                            (funcall (test-lambda test)))
 153                        (retest ()
 154                          :report (lambda (stream)
 155                                    (format stream "~@<Rerun the test ~S~@:>" test))
 156                          (return-from run-it (run-it)))
 157                        (ignore ()
 158                          :report (lambda (stream)
 159                                    (format stream "~@<Signal an exceptional test failure and abort the test ~S.~@:>" test))
 160                          (abort-test (make-instance 'test-failure :test-case test
 161                                                     :reason "Failure restart."))))
 162                      result-list))))
 163         (let ((results (run-it)))
 164           (setf (status test) (results-status results)
 165                 result-list (nconc result-list results)))))))
 166
 167 (defgeneric %run (test-spec)
 168   (:documentation "Internal method for running a test. Does not
 169   update the status of the tests nor the special vairables !,
 170   !!, !!!"))
 171
 172 (defmethod %run ((test test-case))
 173   (run-resolving-dependencies test))
 174
 175 (defmethod %run ((tests list))
 176   (mapc #'%run tests))
 177
 178 (defmethod %run ((suite test-suite))
 179   (let ((suite-results '()))
 180     (bind-run-state ((result-list '()))
 181       (loop for test being the hash-values of (tests suite)
 182             do (%run test)
 183             finally (setf suite-results result-list)))
 184     (setf (status suite) (every (lambda (res)
 185                                   (typep res 'test-passed))
 186                                   suite-results))
 187     (with-run-state (result-list)
 188       (setf result-list (nconc result-list suite-results)))))
 189
 190 (defmethod %run ((test-name symbol))
 191   (when-bind test (get-test test-name)
 192     (%run test)))
 193
 194 (defvar *initial-!* (lambda () (format t "Haven't run that many tests yet.~%")))
 195
 196 (defvar *!* *initial-!*)
 197 (defvar *!!* *initial-!*)
 198 (defvar *!!!* *initial-!*)
 199
 200 ;;;; ** Public entry points
 201
 202 (defun run! (&optional (test-spec *suite*))
 203   "Equivalent to (explain (run TEST-SPEC))."
 204   (explain! (run test-spec)))
 205
 206 (defun explain! (result-list)
 207   "Explain the results of RESULT-LIST using a
 208 detailed-text-explainer with output going to *test-dribble*"
 209   (explain (make-instance 'detailed-text-explainer) result-list *test-dribble*))
 210
 211 (defun debug! (&optional (test-spec *suite*))
 212   "Calls (run! test-spec) but enters the debugger if any kind of error happens."
 213   (let ((*debug-on-error* t)
 214         (*debug-on-failure* t))
 215     (run! test-spec)))
 216
 217 (defun run (test-spec)
 218     "Run the test specified by TEST-SPEC.
 219
 220 TEST-SPEC can be either a symbol naming a test or test suite, or
 221 a testable-object object. This function changes the operations
 222 performed by the !, !! and !!! functions."
 223     (psetf *!* (lambda ()
 224                  (loop for test being the hash-keys of *test*
 225                     do (setf (status (get-test test)) :unknown))
 226                  (bind-run-state ((result-list '()))
 227                    (%run test-spec)
 228                    result-list))
 229            *!!* *!*
 230            *!!!* *!!*)
 231     (funcall *!*))
 232
 233 (defun ! ()
 234   "Rerun the most recently run test and explain the results."
 235   (explain! (funcall *!*)))
 236
 237 (defun !! ()
 238   "Rerun the second most recently run test and explain the results."
 239   (explain! (funcall *!!*)))
 240
 241 (defun !!! ()
 242   "Rerun the third most recently run test and explain the results."
 243   (explain! (funcall *!!!*)))
 244
 245 ;; Copyright (c) 2002-2003, Edward Marco Baringer
 246 ;; All rights reserved.
 247 ;;
 248 ;; Redistribution and use in source and binary forms, with or without
 249 ;; modification, are permitted provided that the following conditions are
 250 ;; met:
 251 ;;
 252 ;;  - Redistributions of source code must retain the above copyright
 253 ;;    notice, this list of conditions and the following disclaimer.
 254 ;;
 255 ;;  - Redistributions in binary form must reproduce the above copyright
 256 ;;    notice, this list of conditions and the following disclaimer in the
 257 ;;    documentation and/or other materials provided with the distribution.
 258 ;;
 259 ;;  - Neither the name of Edward Marco Baringer, nor BESE, nor the names
 260 ;;    of its contributors may be used to endorse or promote products
 261 ;;    derived from this software without specific prior written permission.
 262 ;;
 263 ;; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
 264 ;; "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
 265 ;; LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
 266 ;; A PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE COPYRIGHT
 267 ;; OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
 268 ;; SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
 269 ;; LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
 270 ;; DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
 271 ;; THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
 272 ;; (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
 273 ;; OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.