src/test.lisp

   1 ;; -*- lisp -*-
   2
   3 (in-package :it.bese.FiveAM)
   4
   5 ;;;; * Tests
   6
   7 ;;;; While executing checks and collecting the results is the core job
   8 ;;;; of a testing framework it is also important to be able to
   9 ;;;; organize checks into groups, FiveAM provides two mechanisms for
  10 ;;;; organizing checks: tests and test suites. A test is a named
  11 ;;;; collection of checks which can be run and a test suite is a named
  12 ;;;; collection of tests and test suites.
  13
  14 (deflookup-table test
  15   :at-redefinition nil
  16   :documentation "Lookup table mapping test (and test suite)
  17   names to objects.")
  18
  19 (defun test-names ()
  20   (loop for test being the hash-keys of *test*
  21         collect test))
  22
  23 (defmacro test (name &body body)
  24   "Create a test named NAME. If NAME is a list it must be of the
  25 form:
  26
  27   (name &key depends-on suite fixture compile-at)
  28
  29 NAME is the symbol which names the test.
  30
  31 DEPENDS-ON is a list of the form:
  32
  33  (AND . test-names) - This test is run only if all of the tests
  34  in TEST-NAMES have passed, otherwise a single test-skipped
  35  result is generated.
  36
  37  (OR . test-names) - If any of TEST-NAMES has passed this test is
  38  run, otherwise a test-skipped result is generated.
  39
  40  (NOT test-name) - This is test is run only if TEST-NAME failed.
  41
  42 AND, OR and NOT can be combined to produce complex dependencies.
  43
  44 If DEPENDS-ON is a symbol it is interpreted as `(AND
  45 ,depends-on), this is accomadate the common case of one test
  46 depending on another.
  47
  48 SUITE defaults to the current value of *SUITE*.
  49
  50 FIXTURE specifies a fixtrue to wrap the body in."
  51   (destructuring-bind (name &key depends-on (suite nil suite-supplied-p)
  52                                  (compile-at :run-time) fixture)
  53       (ensure-list name)
  54     (declare (type (member :run-time :definition-time) compile-at))
  55     (let ((description (if (stringp (car body))
  56                            (pop body)
  57                            ""))
  58           (effective-body (if fixture
  59                               (destructuring-bind (name &rest args)
  60                                   (ensure-list fixture)
  61                                 `((with-fixture ,name ,args ,@body)))
  62                               body)))
  63       `(progn
  64          (setf (get-test ',name) (make-instance 'test-case
  65                                                 :name ',name
  66                                                 :runtime-package ,*package*
  67                                                 :test-lambda
  68                                                 (lambda ()
  69                                                   ,@ (ecase compile-at
  70                                                        (:run-time `((funcall
  71                                                                      (let ((*package* (find-package ',(package-name *package*))))
  72                                                                        (compile nil '(lambda ()
  73                                                                                       ,@effective-body))))))
  74                                                        (:definition-time effective-body)))
  75                                                 :description ,description
  76                                                 :depends-on ',depends-on))
  77          ,(if suite-supplied-p
  78               `(setf (gethash ',name (tests (get-test ',suite)))
  79                      ',name)
  80               `(setf (gethash ',name (tests (or *suite* (get-test 'NIL))))
  81                      ',name))
  82          (when *run-test-when-defined*
  83            (run! ',name))
  84          ',name))))
  85
  86 (defvar *run-test-when-defined* nil
  87   "When non-NIL tests are run as soon as they are defined.")
  88
  89 ;; Copyright (c) 2002-2003, Edward Marco Baringer
  90 ;; All rights reserved.
  91 ;;
  92 ;; Redistribution and use in source and binary forms, with or without
  93 ;; modification, are permitted provided that the following conditions are
  94 ;; met:
  95 ;;
  96 ;;  - Redistributions of source code must retain the above copyright
  97 ;;    notice, this list of conditions and the following disclaimer.
  98 ;;
  99 ;;  - Redistributions in binary form must reproduce the above copyright
 100 ;;    notice, this list of conditions and the following disclaimer in the
 101 ;;    documentation and/or other materials provided with the distribution.
 102 ;;
 103 ;;  - Neither the name of Edward Marco Baringer, nor BESE, nor the names
 104 ;;    of its contributors may be used to endorse or promote products
 105 ;;    derived from this software without specific prior written permission.
 106 ;;
 107 ;; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
 108 ;; "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
 109 ;; LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
 110 ;; A PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE COPYRIGHT
 111 ;; OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
 112 ;; SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
 113 ;; LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
 114 ;; DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
 115 ;; THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
 116 ;; (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
 117 ;; OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.