src/test.lisp

   1 ;;;; -*- Mode: Lisp; indent-tabs-mode: nil -*-
   2
   3 (in-package :it.bese.fiveam)
   4
   5 ;;;; * Tests
   6
   7 ;;;; While executing checks and collecting the results is the core job
   8 ;;;; of a testing framework it is also important to be able to
   9 ;;;; organize checks into groups, fiveam provides two mechanisms for
  10 ;;;; organizing checks: tests and test suites. A test is a named
  11 ;;;; collection of checks which can be run and a test suite is a named
  12 ;;;; collection of tests and test suites.
  13
  14 (defvar *test*
  15   (make-hash-table :test 'eql)
  16   "Lookup table mapping test (and test suite)
  17   names to objects.")
  18
  19 (defun get-test (key &optional default)
  20   (gethash key *test* default))
  21
  22 (defun (setf get-test) (value key)
  23   (setf (gethash key *test*) value))
  24
  25 (defun rem-test (key)
  26   (remhash key *test*))
  27
  28 (defun test-names ()
  29   (loop for test being the hash-keys of *test*
  30         collect test))
  31
  32 (defmacro test (name &body body)
  33   "Create a test named NAME. If NAME is a list it must be of the
  34 form:
  35
  36   (name &key depends-on suite fixture compile-at profile)
  37
  38 NAME is the symbol which names the test.
  39
  40 DEPENDS-ON is a list of the form:
  41
  42  (AND . test-names) - This test is run only if all of the tests
  43  in TEST-NAMES have passed, otherwise a single test-skipped
  44  result is generated.
  45
  46  (OR . test-names) - If any of TEST-NAMES has passed this test is
  47  run, otherwise a test-skipped result is generated.
  48
  49  (NOT test-name) - This is test is run only if TEST-NAME failed.
  50
  51 AND, OR and NOT can be combined to produce complex dependencies.
  52
  53 If DEPENDS-ON is a symbol it is interpreted as `(AND
  54 ,depends-on), this is accomadate the common case of one test
  55 depending on another.
  56
  57 FIXTURE specifies a fixture to wrap the body in.
  58
  59 If PROFILE is T profiling information will be collected as well."
  60   (let* ((tmp (gensym))
  61          (suite-arg (getf (cdr (ensure-list name)) :suite tmp))
  62          (suite-form (cond
  63                        ((eq tmp suite-arg) '*suite*)
  64                        (t                  `(get-test ',suite-arg)))))
  65     (when (consp name)
  66       (remf (cdr name) :suite))
  67     (destructuring-bind (name &key depends-on (compile-at :run-time) fixture profile)
  68         (ensure-list name)
  69       (declare (type (member :run-time :definition-time) compile-at))
  70       (let ((description (if (stringp (car body))
  71                              (pop body)
  72                              ""))
  73             (effective-body (if fixture
  74                                 (destructuring-bind (name &rest args)
  75                                     (ensure-list fixture)
  76                                   `((with-fixture ,name ,args ,@body)))
  77                                 body))
  78             (lambda-name
  79               (format-symbol t "%~A-~A" '#:test name))
  80             (inner-lambda-name
  81               (format-symbol t "%~A-~A" '#:inner-test name)))
  82         `(progn
  83            (setf (get-test ',name)
  84                  (make-instance 'test-case
  85                                 :name ',name
  86                                 :runtime-package (find-package ,(package-name *package*))
  87                                 :test-lambda
  88                                 (named-lambda ,lambda-name ()
  89                                   ,@ (ecase compile-at
  90                                        (:run-time `((funcall
  91                                                      (let ((*package* (find-package ',(package-name *package*))))
  92                                                        (compile ',inner-lambda-name
  93                                                                 '(lambda () ,@effective-body))))))
  94                                        (:definition-time effective-body)))
  95                                 :description ,description
  96                                 :depends-on ',depends-on
  97                                 :collect-profiling-info ,profile))
  98            (setf (gethash ',name (tests ,suite-form)) ',name)
  99            (when *run-test-when-defined*
 100              (run! ',name))
 101            ',name)))))
 102
 103 (defvar *run-test-when-defined* nil
 104   "When non-NIL tests are run as soon as they are defined.")
 105
 106 ;; Copyright (c) 2002-2003, Edward Marco Baringer
 107 ;; All rights reserved.
 108 ;;
 109 ;; Redistribution and use in source and binary forms, with or without
 110 ;; modification, are permitted provided that the following conditions are
 111 ;; met:
 112 ;;
 113 ;;  - Redistributions of source code must retain the above copyright
 114 ;;    notice, this list of conditions and the following disclaimer.
 115 ;;
 116 ;;  - Redistributions in binary form must reproduce the above copyright
 117 ;;    notice, this list of conditions and the following disclaimer in the
 118 ;;    documentation and/or other materials provided with the distribution.
 119 ;;
 120 ;;  - Neither the name of Edward Marco Baringer, nor BESE, nor the names
 121 ;;    of its contributors may be used to endorse or promote products
 122 ;;    derived from this software without specific prior written permission.
 123 ;;
 124 ;; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
 125 ;; "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
 126 ;; LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
 127 ;; A PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE COPYRIGHT
 128 ;; OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
 129 ;; SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
 130 ;; LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
 131 ;; DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
 132 ;; THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
 133 ;; (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
 134 ;; OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.