src/test.lisp

   1 ;; -*- lisp -*-
   2
   3 (in-package :it.bese.FiveAM)
   4
   5 ;;;; * Tests
   6
   7 ;;;; While executing checks and collecting the results is the core job
   8 ;;;; of a testing framework it is also important to be able to
   9 ;;;; organize checks into groups, FiveAM provides two mechanisms for
  10 ;;;; organizing checks: tests and test suites. A test is a named
  11 ;;;; collection of checks which can be run and a test suite is a named
  12 ;;;; collection of tests and test suites.
  13
  14 (deflookup-table test
  15   :at-redefinition nil
  16   :documentation "Lookup table mapping test (and test suite)
  17   names to objects.")
  18
  19 (defun test-names ()
  20   (loop for test being the hash-keys of *test*
  21         collect test))
  22
  23 (defmacro test (name &body body)
  24   "Create a test named NAME. If NAME is a list it must be of the
  25 form:
  26
  27   (name &key depends-on suite)
  28
  29 NAME is the symbol which names the test.
  30
  31 DEPENDS-ON is a list of the form:
  32
  33  (AND . test-names) - This test is run only if all of the tests
  34  in TEST-NAMES have passed, otherwise a single test-skipped
  35  result is generated.
  36
  37  (OR . test-names) - If any of TEST-NAMES has passed this test is
  38  run, otherwise a test-skipped result is generated.
  39
  40  (NOT test-name) - This is test is run only if TEST-NAME failed.
  41
  42 AND, OR and NOT can be combined to produce complex dependencies.
  43
  44 If DEPENDS-ON is a symbol it is interpreted as `(AND
  45 ,depends-on), this is accomadate the common case of one test
  46 depending on another.
  47
  48 SUITE defaults to the current value of *SUITE*."
  49   (destructuring-bind (name &key depends-on (suite nil suite-supplied-p))
  50       (ensure-list name)
  51     (let (description)
  52       (setf description (if (stringp (car body))
  53                             (pop body)
  54                             ""))
  55       `(progn
  56          (setf (get-test ',name) (make-instance 'test-case
  57                                                 :name ',name
  58                                                 :runtime-package ,*package*
  59                                                 :test-lambda
  60                                                 (lambda ()
  61                                                   (funcall (let ((*package* ,*package*))
  62                                                              (compile nil '(lambda () ,@body)))))
  63                                                 :description ,description
  64                                                 :depends-on ',depends-on))
  65          ,(if suite-supplied-p
  66               `(setf (gethash ',name (tests (get-test ',suite)))
  67                      ',name)
  68               `(setf (gethash ',name (tests (or *suite* (get-test 'NIL))))
  69                      ',name))
  70          (when *run-test-when-defined*
  71            (run! ',name))
  72          ',name))))
  73
  74 (defvar *run-test-when-defined* nil
  75   "When non-NIL tests are run as soon as they are defined.")
  76
  77 ;; Copyright (c) 2002-2003, Edward Marco Baringer
  78 ;; All rights reserved.
  79 ;;
  80 ;; Redistribution and use in source and binary forms, with or without
  81 ;; modification, are permitted provided that the following conditions are
  82 ;; met:
  83 ;;
  84 ;;  - Redistributions of source code must retain the above copyright
  85 ;;    notice, this list of conditions and the following disclaimer.
  86 ;;
  87 ;;  - Redistributions in binary form must reproduce the above copyright
  88 ;;    notice, this list of conditions and the following disclaimer in the
  89 ;;    documentation and/or other materials provided with the distribution.
  90 ;;
  91 ;;  - Neither the name of Edward Marco Baringer, nor BESE, nor the names
  92 ;;    of its contributors may be used to endorse or promote products
  93 ;;    derived from this software without specific prior written permission.
  94 ;;
  95 ;; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  96 ;; "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  97 ;; LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  98 ;; A PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE COPYRIGHT
  99 ;; OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
 100 ;; SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
 101 ;; LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
 102 ;; DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
 103 ;; THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
 104 ;; (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
 105 ;; OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.