src/test.lisp

   1 ;; -*- lisp -*-
   2
   3 (in-package :it.bese.FiveAM)
   4
   5 ;;;; * Tests
   6
   7 ;;;; While executing checks and collecting the results is the core job
   8 ;;;; of a testing framework it is also important to be able to
   9 ;;;; organize checks into groups, FiveAM provides two mechanisms for
  10 ;;;; organizing checks: tests and test suites. A test is a named
  11 ;;;; collection of checks which can be run and a test suite is a named
  12 ;;;; collection of tests and test suites.
  13
  14 (deflookup-table test
  15   :at-redefinition nil
  16   :documentation "Lookup table mapping test (and test suite)
  17   names to objects.")
  18
  19 (defun test-names ()
  20   (loop for test being the hash-keys of *test*
  21         collect test))
  22
  23 (defmacro test (name &body body)
  24   "Create a test named NAME. If NAME is a list it must be of the
  25 form:
  26
  27   (name &key depends-on suite fixture compile-at)
  28
  29 NAME is the symbol which names the test.
  30
  31 DEPENDS-ON is a list of the form:
  32
  33  (AND . test-names) - This test is run only if all of the tests
  34  in TEST-NAMES have passed, otherwise a single test-skipped
  35  result is generated.
  36
  37  (OR . test-names) - If any of TEST-NAMES has passed this test is
  38  run, otherwise a test-skipped result is generated.
  39
  40  (NOT test-name) - This is test is run only if TEST-NAME failed.
  41
  42 AND, OR and NOT can be combined to produce complex dependencies.
  43
  44 If DEPENDS-ON is a symbol it is interpreted as `(AND
  45 ,depends-on), this is accomadate the common case of one test
  46 depending on another.
  47
  48 FIXTURE specifies a fixtrue to wrap the body in."
  49
  50   (let* ((tmp (gensym))
  51          (suite-arg (getf (cdr (ensure-list name)) :suite tmp))
  52          (suite (cond
  53                   ((eq tmp suite-arg) *suite*)
  54                   (t (get-test suite-arg)))))
  55     (when (consp name)
  56       (remf (cdr name) :suite))
  57     (destructuring-bind (name &key depends-on (compile-at :run-time) fixture)
  58         (append (ensure-list name) (default-test-args suite))
  59       (declare (type (member :run-time :definition-time) compile-at))
  60       (let ((description (if (stringp (car body))
  61                              (pop body)
  62                              ""))
  63             (effective-body (if fixture
  64                                 (destructuring-bind (name &rest args)
  65                                     (ensure-list fixture)
  66                                   `((with-fixture ,name ,args ,@body)))
  67                                 body)))
  68         `(progn
  69            (setf (get-test ',name) (make-instance 'test-case
  70                                                   :name ',name
  71                                                   :runtime-package ,*package*
  72                                                   :test-lambda
  73                                                   (lambda ()
  74                                                     ,@ (ecase compile-at
  75                                                          (:run-time `((funcall
  76                                                                        (let ((*package* (find-package ',(package-name *package*))))
  77                                                                          (compile nil '(lambda ()
  78                                                                                         ,@effective-body))))))
  79                                                          (:definition-time effective-body)))
  80                                                   :description ,description
  81                                                   :depends-on ',depends-on))
  82            (setf (gethash ',name (tests ,suite)) ',name)
  83            (when *run-test-when-defined*
  84              (run! ',name))
  85            ',name)))))
  86
  87 (defvar *run-test-when-defined* nil
  88   "When non-NIL tests are run as soon as they are defined.")
  89
  90 ;; Copyright (c) 2002-2003, Edward Marco Baringer
  91 ;; All rights reserved.
  92 ;;
  93 ;; Redistribution and use in source and binary forms, with or without
  94 ;; modification, are permitted provided that the following conditions are
  95 ;; met:
  96 ;;
  97 ;;  - Redistributions of source code must retain the above copyright
  98 ;;    notice, this list of conditions and the following disclaimer.
  99 ;;
 100 ;;  - Redistributions in binary form must reproduce the above copyright
 101 ;;    notice, this list of conditions and the following disclaimer in the
 102 ;;    documentation and/or other materials provided with the distribution.
 103 ;;
 104 ;;  - Neither the name of Edward Marco Baringer, nor BESE, nor the names
 105 ;;    of its contributors may be used to endorse or promote products
 106 ;;    derived from this software without specific prior written permission.
 107 ;;
 108 ;; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
 109 ;; "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
 110 ;; LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
 111 ;; A PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE COPYRIGHT
 112 ;; OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
 113 ;; SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
 114 ;; LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
 115 ;; DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
 116 ;; THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
 117 ;; (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
 118 ;; OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.