src/compiler-codegen.lisp

   1 ;;; compiler-codege.lisp --- Naive Javascript unparser
   2
   3 ;; copyright (C) 2013 David Vazquez
   4
   5 ;; JSCL is free software: you can redistribute it and/or
   6 ;; modify it under the terms of the GNU General Public License as
   7 ;; published by the Free Software Foundation, either version 3 of the
   8 ;; License, or (at your option) any later version.
   9 ;;
  10 ;; JSCL is distributed in the hope that it will be useful, but
  11 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 ;; General Public License for more details.
  14 ;;
  15 ;; You should have received a copy of the GNU General Public License
  16 ;; along with JSCL.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 ;;; This code generator takes as input a S-expression representation
  19 ;;; of the Javascript AST and generates Javascript code without
  20 ;;; redundant syntax constructions like extra parenthesis.
  21 ;;;
  22 ;;; It is intended to be used with the new compiler. However, it is
  23 ;;; quite independent so it has been integrated early in JSCL.
  24
  25 (/debug "loading compiler-codegen.lisp!")
  26
  27 (defvar *js-macros* nil)
  28 (defmacro define-js-macro (name lambda-list &body body)
  29   (let ((form (gensym)))
  30     `(push (cons ',name
  31                  (lambda (,form)
  32                    (block ,name
  33                      (destructuring-bind ,lambda-list ,form
  34                        ,@body))))
  35            *js-macros*)))
  36
  37 (defun js-macroexpand (js)
  38   (if (and (consp js) (assoc (car js) *js-macros*))
  39       (let ((expander (cdr (assoc (car js) *js-macros*))))
  40         (multiple-value-bind (expansion stop-expand-p)
  41             (funcall expander (cdr js))
  42           (if stop-expand-p
  43               expansion
  44               (js-macroexpand expansion))))
  45       js))
  46
  47
  48 (defconstant no-comma 12)
  49
  50 (defvar *js-output* t)
  51
  52 ;;; Two seperate functions are needed for escaping strings:
  53 ;;;  One for producing JavaScript string literals (which are singly or
  54 ;;;   doubly quoted)
  55 ;;;  And one for producing Lisp strings (which are only doubly quoted)
  56 ;;;
  57 ;;; The same function would suffice for both, but for javascript string
  58 ;;; literals it is neater to use either depending on the context, e.g:
  59 ;;;  foo's => "foo's"
  60 ;;;  "foo" => '"foo"'
  61 ;;; which avoids having to escape quotes where possible
  62 (defun js-escape-string (string)
  63   (let ((index 0)
  64         (size (length string))
  65         (seen-single-quote nil)
  66         (seen-double-quote nil))
  67     (flet ((%js-escape-string (string escape-single-quote-p)
  68              (let ((output "")
  69                    (index 0))
  70                (while (< index size)
  71                  (let ((ch (char string index)))
  72                    (when (char= ch #\\)
  73                      (setq output (concat output "\\")))
  74                    (when (and escape-single-quote-p (char= ch #\'))
  75                      (setq output (concat output "\\")))
  76                    (when (char= ch #\newline)
  77                      (setq output (concat output "\\"))
  78                      (setq ch #\n))
  79                    (setq output (concat output (string ch))))
  80                  (incf index))
  81                output)))
  82       ;; First, scan the string for single/double quotes
  83       (while (< index size)
  84         (let ((ch (char string index)))
  85           (when (char= ch #\')
  86             (setq seen-single-quote t))
  87           (when (char= ch #\")
  88             (setq seen-double-quote t)))
  89         (incf index))
  90       ;; Then pick the appropriate way to escape the quotes
  91       (cond
  92         ((not seen-single-quote)
  93          (concat "'"   (%js-escape-string string nil) "'"))
  94         ((not seen-double-quote)
  95          (concat "\""  (%js-escape-string string nil) "\""))
  96         (t (concat "'" (%js-escape-string string t)   "'"))))))
  97
  98
  99 (defun js-format (fmt &rest args)
 100   (apply #'format *js-output* fmt args))
 101
 102 (defun valid-js-identifier (string-designator)
 103   (let ((string (typecase string-designator
 104                   (symbol (symbol-name string-designator))
 105                   (string string-designator)
 106                   (t
 107                    (return-from valid-js-identifier (values nil nil))))))
 108     (flet ((constitutentp (ch)
 109              (or (alphanumericp ch) (member ch '(#\$ #\_)))))
 110       (if (and (every #'constitutentp string)
 111                (if (plusp (length string))
 112                    (not (digit-char-p (char string 0)))
 113                    t))
 114           (values (format nil "~a" string) t)
 115           (values nil nil)))))
 116
 117 (defun js-identifier (string-designator)
 118   (multiple-value-bind (string valid)
 119       (valid-js-identifier string-designator)
 120     (unless valid
 121       (error "~S is not a valid Javascript identifier." string))
 122     (js-format "~a" string)))
 123
 124 (defun js-primary-expr (form)
 125   (cond
 126     ((numberp form)
 127      (if (<= 0 form)
 128          (js-format "~a" form)
 129          (js-expr `(- ,(abs form)))))
 130     ((stringp form)
 131      (js-format "~a" (js-escape-string form)))
 132     ((symbolp form)
 133      (case form
 134        (true      (js-format "true"))
 135        (false     (js-format "false"))
 136        (null      (js-format "null"))
 137        (this      (js-format "this"))
 138        (undefined (js-format "undefined"))
 139        (otherwise
 140         (js-identifier form))))
 141     (t
 142      (error "Unknown Javascript syntax ~S." form))))
 143
 144 (defun js-vector-initializer (vector)
 145   (let ((size (length vector)))
 146     (js-format "[")
 147     (dotimes (i (1- size))
 148       (let ((elt (aref vector i)))
 149         (unless (eq elt 'null)
 150           (js-expr elt no-comma))
 151         (js-format ",")))
 152     (when (plusp size)
 153       (js-expr (aref vector (1- size)) no-comma))
 154     (js-format "]")))
 155
 156 (defun js-object-initializer (plist)
 157   (js-format "{")
 158   (do* ((tail plist (cddr tail)))
 159        ((null tail))
 160     (let ((key (car tail))
 161           (value (cadr tail)))
 162       (multiple-value-bind (identifier identifier-p) (valid-js-identifier key)
 163         (declare (ignore identifier))
 164         (if identifier-p
 165             (js-identifier key)
 166             (js-expr (string key) no-comma)))
 167       (js-format ": ")
 168       (js-expr value no-comma)
 169       (unless (null (cddr tail))
 170         (js-format ","))))
 171   (js-format "}"))
 172
 173 (defun js-function (arguments &rest body)
 174   (js-format "function(")
 175   (when arguments
 176     (js-identifier (car arguments))
 177     (dolist (arg (cdr arguments))
 178       (js-format ",")
 179       (js-identifier arg)))
 180   (js-format ")")
 181   (js-stmt `(group ,@body) t))
 182
 183 (defun check-lvalue (x)
 184   (unless (or (symbolp x)
 185               (nth-value 1 (valid-js-identifier x))
 186               (and (consp x)
 187                    (member (car x) '(get = property))))
 188     (error "Bad Javascript lvalue ~S" x)))
 189
 190 ;;; Process the Javascript AST to reduce some syntax sugar.
 191 (defun js-expand-expr (form)
 192   (if (consp form)
 193       (case (car form)
 194         (+
 195          (case (length (cdr form))
 196            (1 `(unary+ ,(cadr form)))
 197            (t (reduce (lambda (x y) `(+ ,x ,y)) (cdr form)))))
 198         (-
 199          (case (length (cdr form))
 200            (1 `(unary- ,(cadr form)))
 201            (t (reduce (lambda (x y) `(- ,x ,y)) (cdr form)))))
 202         ((and or)
 203          (reduce (lambda (x y) `(,(car form) ,x ,y)) (cdr form)))
 204         ((progn comma)
 205          (reduce (lambda (x y) `(comma ,x ,y)) (cdr form) :from-end t))
 206         (t
 207          (js-macroexpand form)))
 208       form))
 209
 210 (defun js-operator-expression (op args precedence associativity operand-order)
 211   (let ((op1 (car args))
 212         (op2 (cadr args)))
 213     (case op
 214       ;; Accessors
 215       (property
 216        (js-expr (car args) 0)
 217        (js-format "[")
 218        (js-expr (cadr args) no-comma)
 219        (js-format "]"))
 220       (get
 221        (multiple-value-bind (accessor accessorp)
 222            (valid-js-identifier (cadr args))
 223          (unless accessorp
 224            (error "Invalid accessor ~S" (cadr args)))
 225          (js-expr (car args) 0)
 226          (js-format ".")
 227          (js-identifier accessor)))
 228       ;; Function call
 229       (call
 230        (js-expr (car args) 1)
 231        (js-format "(")
 232        (when (cdr args)
 233          (js-expr (cadr args) no-comma)
 234          (dolist (operand (cddr args))
 235            (js-format ",")
 236            (js-expr operand no-comma)))
 237        (js-format ")"))
 238       ;; Object syntax
 239       (object
 240        (js-object-initializer args))
 241       ;; Function expressions
 242       (function
 243        (js-format "(")
 244        (apply #'js-function args)
 245        (js-format ")"))
 246       (t
 247        (labels ((low-precedence-p (op-precedence)
 248                   (cond
 249                     ((> op-precedence precedence))
 250                     ((< op-precedence precedence) nil)
 251                     (t (not (eq operand-order associativity)))))
 252
 253                 (%unary-op (operator string operator-precedence operator-associativity post lvalue)
 254                   (when (eq op operator)
 255                     (when lvalue (check-lvalue op1))
 256                     (when (low-precedence-p operator-precedence) (js-format "("))
 257                     (cond
 258                       (post
 259                        (js-expr op1 operator-precedence operator-associativity 'left)
 260                        (js-format "~a" string))
 261                       (t
 262                        (js-format "~a" string)
 263                        (js-expr op1 operator-precedence operator-associativity 'right)))
 264                     (when (low-precedence-p operator-precedence) (js-format ")"))
 265                     (return-from js-operator-expression)))
 266
 267                 (%binary-op (operator string operator-precedence operator-associativity lvalue)
 268                   (when (eq op operator)
 269                     (when lvalue (check-lvalue op1))
 270                     (when (low-precedence-p operator-precedence) (js-format "("))
 271                     (js-expr op1 operator-precedence operator-associativity 'left)
 272                     (js-format "~a" string)
 273                     (js-expr op2 operator-precedence operator-associativity 'right)
 274                     (when (low-precedence-p operator-precedence) (js-format ")"))
 275                     (return-from js-operator-expression))))
 276
 277          (macrolet ((unary-op (operator string precedence associativity &key post lvalue)
 278                       `(%unary-op ',operator ',string ',precedence ',associativity ',post ',lvalue))
 279                     (binary-op (operator string precedence associativity &key lvalue)
 280                       `(%binary-op ',operator ',string ',precedence ',associativity ',lvalue)))
 281
 282            (unary-op pre++       "++"            2    right :lvalue t)
 283            (unary-op pre--       "--"            2    right :lvalue t)
 284            (unary-op post++      "++"            2    right :lvalue t :post t)
 285            (unary-op post--      "--"            2    right :lvalue t :post t)
 286            (unary-op not         "!"             2    right)
 287            (unary-op bit-not     "~"             2    right)
 288            ;; Note that the leading space is necessary because it
 289            ;; could break with post++, for example. TODO: Avoid
 290            ;; leading space when it's possible.
 291            (unary-op unary+      " +"            2    right)
 292            (unary-op unary-      " -"            2    right)
 293            (unary-op delete      "delete "       2    right)
 294            (unary-op void        "void "         2    right)
 295            (unary-op typeof      "typeof "       2    right)
 296            (unary-op new         "new "          2    right)
 297
 298            (binary-op *          "*"             3    left)
 299            (binary-op /          "/"             3    left)
 300            (binary-op mod        "%"             3    left)
 301            (binary-op %          "%"             3    left)
 302            (binary-op +          "+"             4    left)
 303            (binary-op -          "-"             5    left)
 304            (binary-op <<         "<<"            5    left)
 305            (binary-op >>         "<<"            5    left)
 306            (binary-op >>>        ">>>"           5    left)
 307            (binary-op <=         "<="            6    left)
 308            (binary-op <          "<"             6    left)
 309            (binary-op >          ">"             6    left)
 310            (binary-op >=         ">="            6    left)
 311            (binary-op instanceof " instanceof "  6    left)
 312            (binary-op in         " in "          6    left)
 313            (binary-op ==         "=="            7    left)
 314            (binary-op !=         "!="            7    left)
 315            (binary-op ===        "==="           7    left)
 316            (binary-op !==        "!=="           7    left)
 317            (binary-op bit-and    "&"             8    left)
 318            (binary-op bit-xor    "^"             9    left)
 319            (binary-op bit-or     "|"            10    left)
 320            (binary-op and        "&&"           11    left)
 321            (binary-op or         "||"           12    left)
 322            (binary-op =          "="            13    right :lvalue t)
 323            (binary-op +=         "+="           13    right :lvalue t)
 324            (binary-op incf       "+="           13    right :lvalue t)
 325            (binary-op -=         "-="           13    right :lvalue t)
 326            (binary-op decf       "-="           13    right :lvalue t)
 327            (binary-op *=         "*="           13    right :lvalue t)
 328            (binary-op /=         "*="           13    right :lvalue t)
 329            (binary-op bit-xor=   "^="           13    right :lvalue t)
 330            (binary-op bit-and=   "&="           13    right :lvalue t)
 331            (binary-op bit-or=    "|="           13    right :lvalue t)
 332            (binary-op <<=        "<<="          13    right :lvalue t)
 333            (binary-op >>=        ">>="          13    right :lvalue t)
 334            (binary-op >>>=       ">>>="         13    right :lvalue t)
 335
 336            (binary-op comma      ","            13    right)
 337            (binary-op progn      ","            13    right)
 338
 339            (when (member op '(? if))
 340              (when (low-precedence-p 12) (js-format "("))
 341              (js-expr (first args) 12 'right 'left)
 342              (js-format "?")
 343              (js-expr (second args) 12 'right 'right)
 344              (js-format ":")
 345              (js-expr (third args) 12 'right 'right)
 346              (when (low-precedence-p 12) (js-format ")"))
 347              (return-from js-operator-expression))
 348
 349            (error "Unknown operator `~S'" op)))))))
 350
 351 (defun js-expr (form &optional (precedence 1000) associativity operand-order)
 352   (let ((form (js-expand-expr form)))
 353     (cond
 354       ((or (symbolp form) (numberp form) (stringp form))
 355        (js-primary-expr form))
 356       ((vectorp form)
 357        (js-vector-initializer form))
 358       (t
 359        (js-operator-expression (car form) (cdr form) precedence associativity operand-order)))))
 360
 361 (defun js-expand-stmt (form)
 362   (cond
 363     ((and (consp form) (eq (car form) 'progn))
 364      (destructuring-bind (&body body) (cdr form)
 365        (cond
 366          ((null body)
 367           nil)
 368          ((null (cdr body))
 369           (js-expand-stmt (car body)))
 370          (t
 371           `(group ,@(cdr form))))))
 372     (t
 373      (js-macroexpand form))))
 374
 375 (defun js-stmt (form &optional parent)
 376   (let ((form (js-expand-stmt form)))
 377     (flet ((js-stmt (x) (js-stmt x form)))
 378       (cond
 379         ((null form)
 380          (unless (or (and (consp parent) (eq (car parent) 'group))
 381                      (null parent))
 382            (js-format ";")))
 383         ((atom form)
 384          (progn
 385            (js-expr form)
 386            (js-format ";")))
 387         (t
 388          (case (car form)
 389            (label
 390             (destructuring-bind (label &body body) (cdr form)
 391               (js-identifier label)
 392               (js-format ":")
 393               (js-stmt `(progn ,@body))))
 394            (break
 395             (destructuring-bind (&optional label) (cdr form)
 396               (js-format "break")
 397               (when label
 398                 (js-format " ")
 399                 (js-identifier label))
 400               (js-format ";")))
 401            (return
 402              (destructuring-bind (value) (cdr form)
 403                (js-format "return ")
 404                (js-expr value)
 405                (js-format ";")))
 406            (var
 407             (flet ((js-var (spec)
 408                      (destructuring-bind (variable &optional initial)
 409                          (ensure-list spec)
 410                        (js-identifier variable)
 411                        (when initial
 412                          (js-format "=")
 413                          (js-expr initial no-comma)))))
 414               (destructuring-bind (var &rest vars) (cdr form)
 415                 (js-format "var ")
 416                 (js-var var)
 417                 (dolist (var vars)
 418                   (js-format ",")
 419                   (js-var var))
 420                 (js-format ";"))))
 421            (if
 422             (destructuring-bind (condition true &optional false) (cdr form)
 423               (js-format "if (")
 424               (js-expr condition)
 425               (js-format ") ")
 426               (js-stmt true)
 427               (when false
 428                 (js-format " else ")
 429                 (js-stmt false))))
 430            (group
 431             (let ((in-group-p
 432                    (or (null parent)
 433                        (and (consp parent) (eq (car parent) 'group)))))
 434               (unless  in-group-p (js-format "{"))
 435               (mapc #'js-stmt (cdr form))
 436               (unless in-group-p (js-format "}"))))
 437            (while
 438                (destructuring-bind (condition &body body) (cdr form)
 439                  (js-format "while (")
 440                  (js-expr condition)
 441                  (js-format ")")
 442                  (js-stmt `(progn ,@body))))
 443            (switch
 444             (destructuring-bind (value &rest cases) (cdr form)
 445               (js-format "switch(")
 446               (js-expr value)
 447               (js-format "){")
 448               (dolist (case cases)
 449                 (cond
 450                   ((and (consp case) (eq (car case) 'case))
 451                    (js-format "case ")
 452                    (let ((value (cadr case)))
 453                      (unless (or (stringp value) (integerp value))
 454                        (error "Non-constant switch case `~S'." value))
 455                      (js-expr value))
 456                    (js-format ":"))
 457                   ((eq case 'default)
 458                    (js-format "default:"))
 459                   (t
 460                    (js-stmt case))))
 461               (js-format "}")))
 462            (for
 463             (destructuring-bind ((start condition step) &body body) (cdr form)
 464               (js-format "for (")
 465               (js-expr start)
 466               (js-format ";")
 467               (js-expr condition)
 468               (js-format ";")
 469               (js-expr step)
 470               (js-format ")")
 471               (js-stmt `(progn ,@body))))
 472            (for-in
 473             (destructuring-bind ((x object) &body body) (cdr form)
 474               (js-format "for (")
 475               (js-identifier x)
 476               (js-format " in ")
 477               (js-expr object)
 478               (js-format ")")
 479               (js-stmt `(progn ,@body))))
 480            (try
 481             (destructuring-bind (&rest body) (cdr form)
 482               (js-format "try")
 483               (js-stmt `(group ,@body))))
 484            (catch
 485                (destructuring-bind ((var) &rest body) (cdr form)
 486                  (js-format "catch (")
 487                  (js-identifier var)
 488                  (js-format ")")
 489                  (js-stmt `(group ,@body))))
 490            (finally
 491             (destructuring-bind (&rest body) (cdr form)
 492               (js-format "finally")
 493               (js-stmt `(group ,@body))))
 494            (throw
 495                (destructuring-bind (object) (cdr form)
 496                  (js-format "throw ")
 497                  (js-expr object)
 498                  (js-format ";")))
 499            (t
 500             (js-expr form)
 501             (js-format ";"))))))))
 502
 503 (defun js (&rest stmts)
 504   (mapc #'js-stmt stmts)
 505   nil)