block/return-from uses BlockNLX instead of plain object
[jscl.git] / src / compiler / compiler.lisp
1 ;;; compiler.lisp ---
2
3 ;; Copyright (C) 2012, 2013 David Vazquez
4 ;; Copyright (C) 2012 Raimon Grau
5
6 ;; JSCL is free software: you can redistribute it and/or
7 ;; modify it under the terms of the GNU General Public License as
8 ;; published by the Free Software Foundation, either version 3 of the
9 ;; License, or (at your option) any later version.
10 ;;
11 ;; JSCL is distributed in the hope that it will be useful, but
12 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
13 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
14 ;; General Public License for more details.
15 ;;
16 ;; You should have received a copy of the GNU General Public License
17 ;; along with JSCL.  If not, see <http://www.gnu.org/licenses/>.
18
19 ;;;; Compiler
20
21 (/debug "loading compiler.lisp!")
22
23 ;;; Translate the Lisp code to Javascript. It will compile the special
24 ;;; forms. Some primitive functions are compiled as special forms
25 ;;; too. The respective real functions are defined in the target (see
26 ;;; the beginning of this file) as well as some primitive functions.
27
28 (define-js-macro selfcall (&body body)
29   `(call (function () ,@body)))
30
31 (define-js-macro bool (expr)
32   `(if ,expr ,(convert t) ,(convert nil)))
33
34 (define-js-macro method-call (x method &rest args)
35   `(call (get ,x ,method) ,@args))
36
37 ;;; A Form can return a multiple values object calling VALUES, like
38 ;;; values(arg1, arg2, ...). It will work in any context, as well as
39 ;;; returning an individual object. However, if the special variable
40 ;;; `*multiple-value-p*' is NIL, is granted that only the primary
41 ;;; value will be used, so we can optimize to avoid the VALUES
42 ;;; function call.
43 (defvar *multiple-value-p* nil)
44
45 ;;; It is bound dinamically to the number of nested calls to
46 ;;; `convert'. Therefore, a form is being compiled as toplevel if it
47 ;;; is zero.
48 (defvar *convert-level* -1)
49
50
51 ;;; Environment
52
53 (def!struct binding
54   name
55   type
56   value
57   declarations)
58
59 (def!struct lexenv
60   variable
61   function
62   block
63   gotag)
64
65 (defun lookup-in-lexenv (name lexenv namespace)
66   (find name (ecase namespace
67                 (variable (lexenv-variable lexenv))
68                 (function (lexenv-function lexenv))
69                 (block    (lexenv-block    lexenv))
70                 (gotag    (lexenv-gotag    lexenv)))
71         :key #'binding-name))
72
73 (defun push-to-lexenv (binding lexenv namespace)
74   (ecase namespace
75     (variable (push binding (lexenv-variable lexenv)))
76     (function (push binding (lexenv-function lexenv)))
77     (block    (push binding (lexenv-block    lexenv)))
78     (gotag    (push binding (lexenv-gotag    lexenv)))))
79
80 (defun extend-lexenv (bindings lexenv namespace)
81   (let ((env (copy-lexenv lexenv)))
82     (dolist (binding (reverse bindings) env)
83       (push-to-lexenv binding env namespace))))
84
85
86 (defvar *environment* (make-lexenv))
87 (defvar *variable-counter* 0)
88
89 (defun gvarname (symbol)
90   (declare (ignore symbol))
91   (incf *variable-counter*)
92   (make-symbol (concat "v" (integer-to-string *variable-counter*))))
93
94 (defun translate-variable (symbol)
95   (awhen (lookup-in-lexenv symbol *environment* 'variable)
96     (binding-value it)))
97
98 (defun extend-local-env (args)
99   (let ((new (copy-lexenv *environment*)))
100     (dolist (symbol args new)
101       (let ((b (make-binding :name symbol :type 'variable :value (gvarname symbol))))
102         (push-to-lexenv b new 'variable)))))
103
104 ;;; Toplevel compilations
105 (defvar *toplevel-compilations* nil)
106
107 (defun toplevel-compilation (string)
108   (push string *toplevel-compilations*))
109
110 (defun get-toplevel-compilations ()
111   (reverse *toplevel-compilations*))
112
113 (defun %compile-defmacro (name lambda)
114   (toplevel-compilation (convert `',name))
115   (let ((binding (make-binding :name name :type 'macro :value lambda)))
116     (push-to-lexenv binding  *environment* 'function))
117   name)
118
119 (defun global-binding (name type namespace)
120   (or (lookup-in-lexenv name *environment* namespace)
121       (let ((b (make-binding :name name :type type :value nil)))
122         (push-to-lexenv b *environment* namespace)
123         b)))
124
125 (defun claimp (symbol namespace claim)
126   (let ((b (lookup-in-lexenv symbol *environment* namespace)))
127     (and b (member claim (binding-declarations b)))))
128
129 (defun !proclaim (decl)
130   (case (car decl)
131     (special
132      (dolist (name (cdr decl))
133        (let ((b (global-binding name 'variable 'variable)))
134          (push 'special (binding-declarations b)))))
135     (notinline
136      (dolist (name (cdr decl))
137        (let ((b (global-binding name 'function 'function)))
138          (push 'notinline (binding-declarations b)))))
139     (constant
140      (dolist (name (cdr decl))
141        (let ((b (global-binding name 'variable 'variable)))
142          (push 'constant (binding-declarations b)))))))
143
144 #+jscl
145 (fset 'proclaim #'!proclaim)
146
147 (defun %define-symbol-macro (name expansion)
148   (let ((b (make-binding :name name :type 'macro :value expansion)))
149     (push-to-lexenv b *environment* 'variable)
150     name))
151
152 #+jscl
153 (defmacro define-symbol-macro (name expansion)
154   `(%define-symbol-macro ',name ',expansion))
155
156
157
158 ;;; Report functions which are called but not defined
159
160 (defvar *fn-info* '())
161
162 (def!struct fn-info
163   symbol
164   defined
165   called)
166
167 (defun find-fn-info (symbol)
168   (let ((entry (find symbol *fn-info* :key #'fn-info-symbol)))
169     (unless entry
170       (setq entry (make-fn-info :symbol symbol))
171       (push entry *fn-info*))
172     entry))
173
174 (defun fn-info (symbol &key defined called)
175   (let ((info (find-fn-info symbol)))
176     (when defined
177       (setf (fn-info-defined info) defined))
178     (when called
179       (setf (fn-info-called info) called))))
180
181 (defun report-undefined-functions ()
182   (dolist (info *fn-info*)
183     (let ((symbol (fn-info-symbol info)))
184       (when (and (fn-info-called info)
185                  (not (fn-info-defined info)))
186         (warn "The function `~a' is undefined.~%" symbol))))
187   (setq *fn-info* nil))
188
189
190
191 ;;; Special forms
192
193 (defvar *compilations* nil)
194
195 (defmacro define-compilation (name args &body body)
196   ;; Creates a new primitive `name' with parameters args and
197   ;; @body. The body can access to the local environment through the
198   ;; variable *ENVIRONMENT*.
199   `(push (list ',name (lambda ,args (block ,name ,@body)))
200          *compilations*))
201
202 (define-compilation if (condition true &optional false)
203   `(if (!== ,(convert condition) ,(convert nil))
204        ,(convert true *multiple-value-p*)
205        ,(convert false *multiple-value-p*)))
206
207 (defvar *ll-keywords* '(&optional &rest &key))
208
209 (defun list-until-keyword (list)
210   (if (or (null list) (member (car list) *ll-keywords*))
211       nil
212       (cons (car list) (list-until-keyword (cdr list)))))
213
214 (defun ll-section (keyword ll)
215   (list-until-keyword (cdr (member keyword ll))))
216
217 (defun ll-required-arguments (ll)
218   (list-until-keyword ll))
219
220 (defun ll-optional-arguments-canonical (ll)
221   (mapcar #'ensure-list (ll-section '&optional ll)))
222
223 (defun ll-optional-arguments (ll)
224   (mapcar #'car (ll-optional-arguments-canonical ll)))
225
226 (defun ll-rest-argument (ll)
227   (let ((rest (ll-section '&rest ll)))
228     (when (cdr rest)
229       (error "Bad lambda-list `~S'." ll))
230     (car rest)))
231
232 (defun ll-keyword-arguments-canonical (ll)
233   (flet ((canonicalize (keyarg)
234            ;; Build a canonical keyword argument descriptor, filling
235            ;; the optional fields. The result is a list of the form
236            ;; ((keyword-name var) init-form svar).
237            (let ((arg (ensure-list keyarg)))
238              (cons (if (listp (car arg))
239                        (car arg)
240                        (list (intern (symbol-name (car arg)) "KEYWORD") (car arg)))
241                    (cdr arg)))))
242     (mapcar #'canonicalize (ll-section '&key ll))))
243
244 (defun ll-keyword-arguments (ll)
245   (mapcar (lambda (keyarg) (second (first keyarg)))
246           (ll-keyword-arguments-canonical ll)))
247
248 (defun ll-svars (lambda-list)
249   (let ((args
250          (append
251           (ll-keyword-arguments-canonical lambda-list)
252           (ll-optional-arguments-canonical lambda-list))))
253     (remove nil (mapcar #'third args))))
254
255 (defun lambda-name/docstring-wrapper (name docstring code)
256   (if (or name docstring)
257       `(selfcall
258         (var (func ,code))
259         ,(when name `(= (get func "fname") ,name))
260         ,(when docstring `(= (get func "docstring") ,docstring))
261         (return func))
262       code))
263
264 (defun lambda-check-argument-count
265     (n-required-arguments n-optional-arguments rest-p)
266   ;; Note: Remember that we assume that the number of arguments of a
267   ;; call is at least 1 (the values argument).
268   (let ((min n-required-arguments)
269         (max (if rest-p 'n/a (+ n-required-arguments n-optional-arguments))))
270     (block nil
271       ;; Special case: a positive exact number of arguments.
272       (when (and (< 0 min) (eql min max))
273         (return `(call |checkArgs| |nargs| ,min)))
274       ;; General case:
275       `(progn
276          ,(when (< 0 min)     `(call |checkArgsAtLeast| |nargs| ,min))
277          ,(when (numberp max) `(call |checkArgsAtMost|  |nargs| ,max))))))
278
279 (defun compile-lambda-optional (ll)
280   (let* ((optional-arguments (ll-optional-arguments-canonical ll))
281          (n-required-arguments (length (ll-required-arguments ll)))
282          (n-optional-arguments (length optional-arguments)))
283     (when optional-arguments
284       `(switch |nargs|
285                ,@(with-collect
286                   (dotimes (idx n-optional-arguments)
287                     (let ((arg (nth idx optional-arguments)))
288                       (collect `(case ,(+ idx n-required-arguments)))
289                       (collect `(= ,(translate-variable (car arg))
290                                    ,(convert (cadr arg))))
291                       (collect (when (third arg)
292                                  `(= ,(translate-variable (third arg))
293                                      ,(convert nil))))))
294                   (collect 'default)
295                   (collect '(break)))))))
296
297 (defun compile-lambda-rest (ll)
298   (let ((n-required-arguments (length (ll-required-arguments ll)))
299         (n-optional-arguments (length (ll-optional-arguments ll)))
300         (rest-argument (ll-rest-argument ll)))
301     (when rest-argument
302       (let ((js!rest (translate-variable rest-argument)))
303         `(progn
304            (var (,js!rest ,(convert nil)))
305            (var i)
306            (for ((= i (- |nargs| 1))
307                  (>= i ,(+ n-required-arguments n-optional-arguments))
308                  (post-- i))
309                 (= ,js!rest (object "car" (property |arguments| (+ i 2))
310                                     "cdr" ,js!rest))))))))
311
312 (defun compile-lambda-parse-keywords (ll)
313   (let ((n-required-arguments
314          (length (ll-required-arguments ll)))
315         (n-optional-arguments
316          (length (ll-optional-arguments ll)))
317         (keyword-arguments
318          (ll-keyword-arguments-canonical ll)))
319     `(progn
320        ;; Declare variables
321        ,@(with-collect
322           (dolist (keyword-argument keyword-arguments)
323             (destructuring-bind ((keyword-name var) &optional initform svar)
324                 keyword-argument
325               (declare (ignore keyword-name initform))
326               (collect `(var ,(translate-variable var)))
327               (when svar
328                 (collect
329                     `(var (,(translate-variable svar)
330                             ,(convert nil))))))))
331
332        ;; Parse keywords
333        ,(flet ((parse-keyword (keyarg)
334                 (destructuring-bind ((keyword-name var) &optional initform svar) keyarg
335                   ;; ((keyword-name var) init-form svar)
336                   `(progn
337                      (for ((= i ,(+ n-required-arguments n-optional-arguments))
338                            (< i |nargs|)
339                            (+= i 2))
340                           ;; ....
341                           (if (=== (property |arguments| (+ i 2))
342                                    ,(convert keyword-name))
343                               (progn
344                                 (= ,(translate-variable var)
345                                    (property |arguments| (+ i 3)))
346                                 ,(when svar `(= ,(translate-variable svar)
347                                                 ,(convert t)))
348                                 (break))))
349                      (if (== i |nargs|)
350                          (= ,(translate-variable var) ,(convert initform)))))))
351          (when keyword-arguments
352            `(progn
353               (var i)
354               ,@(mapcar #'parse-keyword keyword-arguments))))
355
356        ;; Check for unknown keywords
357        ,(when keyword-arguments
358          `(progn
359             (var (start ,(+ n-required-arguments n-optional-arguments)))
360             (if (== (% (- |nargs| start) 2) 1)
361                 (throw "Odd number of keyword arguments."))
362             (for ((= i start) (< i |nargs|) (+= i 2))
363                  (if (and ,@(mapcar (lambda (keyword-argument)
364                                  (destructuring-bind ((keyword-name var) &optional initform svar)
365                                      keyword-argument
366                                    (declare (ignore var initform svar))
367                                    `(!== (property |arguments| (+ i 2)) ,(convert keyword-name))))
368                                keyword-arguments))
369                      (throw (+ "Unknown keyword argument "
370                                (call |xstring|
371                                      (property
372                                       (property |arguments| (+ i 2))
373                                       "name")))))))))))
374
375 (defun parse-lambda-list (ll)
376   (values (ll-required-arguments ll)
377           (ll-optional-arguments ll)
378           (ll-keyword-arguments  ll)
379           (ll-rest-argument      ll)))
380
381 ;;; Process BODY for declarations and/or docstrings. Return as
382 ;;; multiple values the BODY without docstrings or declarations, the
383 ;;; list of declaration forms and the docstring.
384 (defun parse-body (body &key declarations docstring)
385   (let ((value-declarations)
386         (value-docstring))
387     ;; Parse declarations
388     (when declarations
389       (do* ((rest body (cdr rest))
390             (form (car rest) (car rest)))
391            ((or (atom form) (not (eq (car form) 'declare)))
392             (setf body rest))
393         (push form value-declarations)))
394     ;; Parse docstring
395     (when (and docstring
396                (stringp (car body))
397                (not (null (cdr body))))
398       (setq value-docstring (car body))
399       (setq body (cdr body)))
400     (values body value-declarations value-docstring)))
401
402 ;;; Compile a lambda function with lambda list LL and body BODY. If
403 ;;; NAME is given, it should be a constant string and it will become
404 ;;; the name of the function. If BLOCK is non-NIL, a named block is
405 ;;; created around the body. NOTE: No block (even anonymous) is
406 ;;; created if BLOCk is NIL.
407 (defun compile-lambda (ll body &key name block)
408   (multiple-value-bind (required-arguments
409                         optional-arguments
410                         keyword-arguments
411                         rest-argument)
412       (parse-lambda-list ll)
413     (multiple-value-bind (body decls documentation)
414         (parse-body body :declarations t :docstring t)
415       (declare (ignore decls))
416       (let ((n-required-arguments (length required-arguments))
417             (n-optional-arguments (length optional-arguments))
418             (*environment* (extend-local-env
419                             (append (ensure-list rest-argument)
420                                     required-arguments
421                                     optional-arguments
422                                     keyword-arguments
423                                     (ll-svars ll)))))
424         (lambda-name/docstring-wrapper name documentation
425          `(function (|values| |nargs| ,@(mapcar (lambda (x)
426                                                   (translate-variable x))
427                                                 (append required-arguments optional-arguments)))
428                      ;; Check number of arguments
429                     ,(lambda-check-argument-count n-required-arguments
430                                                   n-optional-arguments
431                                                   (or rest-argument keyword-arguments))
432                     ,(compile-lambda-optional ll)
433                     ,(compile-lambda-rest ll)
434                     ,(compile-lambda-parse-keywords ll)
435
436                     ,(let ((*multiple-value-p* t))
437                           (if block
438                               (convert-block `((block ,block ,@body)) t)
439                               (convert-block body t)))))))))
440
441
442 (defun setq-pair (var val)
443   (unless (symbolp var)
444     (error "~a is not a symbol" var))
445   (let ((b (lookup-in-lexenv var *environment* 'variable)))
446     (cond
447       ((and b
448             (eq (binding-type b) 'variable)
449             (not (member 'special (binding-declarations b)))
450             (not (member 'constant (binding-declarations b))))
451        `(= ,(binding-value b) ,(convert val)))
452       ((and b (eq (binding-type b) 'macro))
453        (convert `(setf ,var ,val)))
454       (t
455        (convert `(set ',var ,val))))))
456
457
458 (define-compilation setq (&rest pairs)
459   (let ((result nil))
460     (when (null pairs)
461       (return-from setq (convert nil)))
462     (while t
463       (cond
464         ((null pairs)
465          (return))
466         ((null (cdr pairs))
467          (error "Odd pairs in SETQ"))
468         (t
469          (push `,(setq-pair (car pairs) (cadr pairs)) result)
470          (setq pairs (cddr pairs)))))
471     `(progn ,@(reverse result))))
472
473
474 ;;; Compilation of literals an object dumping
475
476 ;;; BOOTSTRAP MAGIC: We record the macro definitions as lists during
477 ;;; the bootstrap. Once everything is compiled, we want to dump the
478 ;;; whole global environment to the output file to reproduce it in the
479 ;;; run-time. However, the environment must contain expander functions
480 ;;; rather than lists. We do not know how to dump function objects
481 ;;; itself, so we mark the list definitions with this object and the
482 ;;; compiler will be called when this object has to be dumped.
483 ;;; Backquote/unquote does a similar magic, but this use is exclusive.
484 ;;;
485 ;;; Indeed, perhaps to compile the object other macros need to be
486 ;;; evaluated. For this reason we define a valid macro-function for
487 ;;; this symbol.
488 (defvar *magic-unquote-marker* (gensym "MAGIC-UNQUOTE"))
489
490 #-jscl
491 (setf (macro-function *magic-unquote-marker*)
492       (lambda (form &optional environment)
493         (declare (ignore environment))
494         (second form)))
495
496 (defvar *literal-table* nil)
497 (defvar *literal-counter* 0)
498
499 (defun genlit ()
500   (incf *literal-counter*)
501   (make-symbol (concat "l" (integer-to-string *literal-counter*))))
502
503 (defun dump-symbol (symbol)
504   #-jscl
505   (let ((package (symbol-package symbol)))
506     (if (eq package (find-package "KEYWORD"))
507         `(new (call |Symbol| ,(dump-string (symbol-name symbol)) ,(dump-string (package-name package))))
508         `(new (call |Symbol| ,(dump-string (symbol-name symbol))))))
509   #+jscl
510   (let ((package (symbol-package symbol)))
511     (if (null package)
512         `(new (call |Symbol| ,(dump-string (symbol-name symbol))))
513         (convert `(intern ,(symbol-name symbol) ,(package-name package))))))
514
515 (defun dump-cons (cons)
516   (let ((head (butlast cons))
517         (tail (last cons)))
518     `(call |QIList|
519            ,@(mapcar (lambda (x) (literal x t)) head)
520            ,(literal (car tail) t)
521            ,(literal (cdr tail) t))))
522
523 (defun dump-array (array)
524   (let ((elements (vector-to-list array)))
525     (list-to-vector (mapcar #'literal elements))))
526
527 (defun dump-string (string)
528   `(call |make_lisp_string| ,string))
529
530 (defun literal (sexp &optional recursive)
531   (cond
532     ((integerp sexp) sexp)
533     ((floatp sexp) sexp)
534     ((characterp sexp) (string sexp))
535     (t
536      (or (cdr (assoc sexp *literal-table* :test #'eql))
537          (let ((dumped (typecase sexp
538                          (symbol (dump-symbol sexp))
539                          (string (dump-string sexp))
540                          (cons
541                           ;; BOOTSTRAP MAGIC: See the root file
542                           ;; jscl.lisp and the function
543                           ;; `dump-global-environment' for futher
544                           ;; information.
545                           (if (eq (car sexp) *magic-unquote-marker*)
546                               (convert (second sexp))
547                               (dump-cons sexp)))
548                          (array (dump-array sexp)))))
549            (if (and recursive (not (symbolp sexp)))
550                dumped
551                (let ((jsvar (genlit)))
552                  (push (cons sexp jsvar) *literal-table*)
553                  (toplevel-compilation `(var (,jsvar ,dumped)))
554                  (when (keywordp sexp)
555                    (toplevel-compilation `(= (get ,jsvar "value") ,jsvar)))
556                  jsvar)))))))
557
558
559 (define-compilation quote (sexp)
560   (literal sexp))
561
562 (define-compilation %while (pred &rest body)
563   `(selfcall
564     (while (!== ,(convert pred) ,(convert nil))
565       ,(convert-block body))
566     (return ,(convert nil))))
567
568 (define-compilation function (x)
569   (cond
570     ((and (listp x) (eq (car x) 'lambda))
571      (compile-lambda (cadr x) (cddr x)))
572     ((and (listp x) (eq (car x) 'named-lambda))
573      (destructuring-bind (name ll &rest body) (cdr x)
574        (compile-lambda ll body
575                        :name (symbol-name name)
576                        :block name)))
577     ((symbolp x)
578      (let ((b (lookup-in-lexenv x *environment* 'function)))
579        (if b
580            (binding-value b)
581            (convert `(symbol-function ',x)))))))
582
583 (defun make-function-binding (fname)
584   (make-binding :name fname :type 'function :value (gvarname fname)))
585
586 (defun compile-function-definition (list)
587   (compile-lambda (car list) (cdr list)))
588
589 (defun translate-function (name)
590   (let ((b (lookup-in-lexenv name *environment* 'function)))
591     (and b (binding-value b))))
592
593 (define-compilation flet (definitions &rest body)
594   (let* ((fnames (mapcar #'car definitions))
595          (cfuncs (mapcar (lambda (def)
596                            (compile-lambda (cadr def)
597                                            `((block ,(car def)
598                                                ,@(cddr def)))))
599                          definitions))
600          (*environment*
601           (extend-lexenv (mapcar #'make-function-binding fnames)
602                          *environment*
603                          'function)))
604     `(call (function ,(mapcar #'translate-function fnames)
605                 ,(convert-block body t))
606            ,@cfuncs)))
607
608 (define-compilation labels (definitions &rest body)
609   (let* ((fnames (mapcar #'car definitions))
610          (*environment*
611           (extend-lexenv (mapcar #'make-function-binding fnames)
612                          *environment*
613                          'function)))
614     `(selfcall
615       ,@(mapcar (lambda (func)
616                   `(var (,(translate-function (car func))
617                           ,(compile-lambda (cadr func)
618                                            `((block ,(car func) ,@(cddr func)))))))
619                 definitions)
620       ,(convert-block body t))))
621
622
623 ;;; Was the compiler invoked from !compile-file?
624 (defvar *compiling-file* nil)
625
626 ;;; NOTE: It is probably wrong in many cases but we will not use this
627 ;;; heavily. Please, do not rely on wrong cases of this
628 ;;; implementation.
629 (define-compilation eval-when (situations &rest body)
630   ;; TODO: Error checking
631   (cond
632     ;; Toplevel form compiled by !compile-file.
633     ((and *compiling-file* (zerop *convert-level*))
634      ;; If the situation `compile-toplevel' is given. The form is
635      ;; evaluated at compilation-time.
636      (when (find :compile-toplevel situations)
637        (eval (cons 'progn body)))
638      ;; `load-toplevel' is given, then just compile the subforms as usual.
639      (when (find :load-toplevel situations)
640        (convert-toplevel `(progn ,@body) *multiple-value-p*)))
641     ((find :execute situations)
642      (convert `(progn ,@body) *multiple-value-p*))
643     (t
644      (convert nil))))
645
646 (defmacro define-transformation (name args form)
647   `(define-compilation ,name ,args
648      (convert ,form)))
649
650 (define-compilation progn (&rest body)
651   (if (null (cdr body))
652       (convert (car body) *multiple-value-p*)
653       `(progn
654          ,@(append (mapcar #'convert (butlast body))
655                    (list (convert (car (last body)) t))))))
656
657 (define-compilation macrolet (definitions &rest body)
658   (let ((*environment* (copy-lexenv *environment*)))
659     (dolist (def definitions)
660       (destructuring-bind (name lambda-list &body body) def
661         (let ((binding (make-binding :name name :type 'macro :value
662                                      (let ((g!form (gensym)))
663                                        `(lambda (,g!form)
664                                           (destructuring-bind ,lambda-list ,g!form
665                                             ,@body))))))
666           (push-to-lexenv binding  *environment* 'function))))
667     (convert `(progn ,@body) *multiple-value-p*)))
668
669
670 (defun special-variable-p (x)
671   (and (claimp x 'variable 'special) t))
672
673 ;;; Wrap CODE to restore the symbol values of the dynamic
674 ;;; bindings. BINDINGS is a list of pairs of the form
675 ;;; (SYMBOL . PLACE),  where PLACE is a Javascript variable
676 ;;; name to initialize the symbol value and where to stored
677 ;;; the old value.
678 (defun let-binding-wrapper (bindings body)
679   (when (null bindings)
680     (return-from let-binding-wrapper body))
681   `(progn
682      (try (var tmp)
683           ,@(with-collect
684              (dolist (b bindings)
685                (let ((s (convert `',(car b))))
686                  (collect `(= tmp (get ,s "value")))
687                  (collect `(= (get ,s "value") ,(cdr b)))
688                  (collect `(= ,(cdr b) tmp)))))
689           ,body)
690      (finally
691       ,@(with-collect
692          (dolist (b bindings)
693            (let ((s (convert `(quote ,(car b)))))
694              (collect `(= (get ,s "value") ,(cdr b)))))))))
695
696 (define-compilation let (bindings &rest body)
697   (let* ((bindings (mapcar #'ensure-list bindings))
698          (variables (mapcar #'first bindings))
699          (cvalues (mapcar #'convert (mapcar #'second bindings)))
700          (*environment* (extend-local-env (remove-if #'special-variable-p variables)))
701          (dynamic-bindings))
702     `(call (function ,(mapcar (lambda (x)
703                                 (if (special-variable-p x)
704                                     (let ((v (gvarname x)))
705                                       (push (cons x v) dynamic-bindings)
706                                       v)
707                                     (translate-variable x)))
708                               variables)
709                      ,(let ((body (convert-block body t t)))
710                            `,(let-binding-wrapper dynamic-bindings body)))
711            ,@cvalues)))
712
713
714 ;;; Return the code to initialize BINDING, and push it extending the
715 ;;; current lexical environment if the variable is not special.
716 (defun let*-initialize-value (binding)
717   (let ((var (first binding))
718         (value (second binding)))
719     (if (special-variable-p var)
720         (convert `(setq ,var ,value))
721         (let* ((v (gvarname var))
722                (b (make-binding :name var :type 'variable :value v)))
723           (prog1 `(var (,v ,(convert value)))
724             (push-to-lexenv b *environment* 'variable))))))
725
726 ;;; Wrap BODY to restore the symbol values of SYMBOLS after body. It
727 ;;; DOES NOT generate code to initialize the value of the symbols,
728 ;;; unlike let-binding-wrapper.
729 (defun let*-binding-wrapper (symbols body)
730   (when (null symbols)
731     (return-from let*-binding-wrapper body))
732   (let ((store (mapcar (lambda (s) (cons s (gvarname s)))
733                        (remove-if-not #'special-variable-p symbols))))
734     `(progn
735        (try
736         ,@(mapcar (lambda (b)
737                     (let ((s (convert `(quote ,(car b)))))
738                       `(var (,(cdr b) (get ,s "value")))))
739                   store)
740         ,body)
741        (finally
742         ,@(mapcar (lambda (b)
743                     (let ((s (convert `(quote ,(car b)))))
744                       `(= (get ,s "value") ,(cdr b))))
745                   store)))))
746
747 (define-compilation let* (bindings &rest body)
748   (let ((bindings (mapcar #'ensure-list bindings))
749         (*environment* (copy-lexenv *environment*)))
750     (let ((specials (remove-if-not #'special-variable-p (mapcar #'first bindings)))
751           (body `(progn
752                    ,@(mapcar #'let*-initialize-value bindings)
753                    ,(convert-block body t t))))
754       `(selfcall ,(let*-binding-wrapper specials body)))))
755
756
757 (define-compilation block (name &rest body)
758   ;; We use Javascript exceptions to implement non local control
759   ;; transfer. Exceptions has dynamic scoping, so we use a uniquely
760   ;; generated object to identify the block. The instance of a empty
761   ;; array is used to distinguish between nested dynamic Javascript
762   ;; exceptions. See https://github.com/davazp/jscl/issues/64 for
763   ;; futher details.
764   (let* ((idvar (gvarname name))
765          (b (make-binding :name name :type 'block :value idvar)))
766     (when *multiple-value-p*
767       (push 'multiple-value (binding-declarations b)))
768     (let* ((*environment* (extend-lexenv (list b) *environment* 'block))
769            (cbody (convert-block body t)))
770       (if (member 'used (binding-declarations b))
771           `(selfcall
772             (try
773              (var (,idvar #()))
774              ,cbody)
775             (catch (cf)
776               (if (and (instanceof cf |BlockNLX|) (== (get cf "id") ,idvar))
777                   ,(if *multiple-value-p*
778                        `(return (method-call |values| "apply" this (call |forcemv| (get cf "values"))))
779                        `(return (get cf "values")))
780                   (throw cf))))
781           `(selfcall ,cbody)))))
782
783 (define-compilation return-from (name &optional value)
784   (let* ((b (lookup-in-lexenv name *environment* 'block))
785          (multiple-value-p (member 'multiple-value (binding-declarations b))))
786     (when (null b)
787       (error "Return from unknown block `~S'." (symbol-name name)))
788     (push 'used (binding-declarations b))
789     ;; The binding value is the name of a variable, whose value is the
790     ;; unique identifier of the block as exception. We can't use the
791     ;; variable name itself, because it could not to be unique, so we
792     ;; capture it in a closure.
793     `(selfcall
794       ,(when multiple-value-p `(var (|values| |mv|)))
795       (throw (new (call |BlockNLX|
796                         ,(binding-value b)
797                         ,(convert value multiple-value-p)
798                         ,(symbol-name name)))))))
799
800 (define-compilation catch (id &rest body)
801   (let ((values (if *multiple-value-p* '|values| '|pv|)))
802     `(selfcall
803       (var (id ,(convert id)))
804       (try
805        ,(convert-block body t))
806       (catch (cf)
807         (if (and (instanceof cf |CatchNLX|) (== (get cf "id") id))
808             (return (method-call ,values "apply" this (call |forcemv| (get cf "values"))))
809             (throw cf))))))
810
811 (define-compilation throw (id value)
812   `(selfcall
813     (var (|values| |mv|))
814     (throw (new (call |CatchNLX| ,(convert id) ,(convert value t))))))
815
816
817 (defun go-tag-p (x)
818   (or (integerp x) (symbolp x)))
819
820 (defun declare-tagbody-tags (tbidx body)
821   (let* ((go-tag-counter 0)
822          (bindings
823           (mapcar (lambda (label)
824                     (let ((tagidx (incf go-tag-counter)))
825                       (make-binding :name label :type 'gotag :value (list tbidx tagidx))))
826                   (remove-if-not #'go-tag-p body))))
827     (extend-lexenv bindings *environment* 'gotag)))
828
829 (define-compilation tagbody (&rest body)
830   ;; Ignore the tagbody if it does not contain any go-tag. We do this
831   ;; because 1) it is easy and 2) many built-in forms expand to a
832   ;; implicit tagbody, so we save some space.
833   (unless (some #'go-tag-p body)
834     (return-from tagbody (convert `(progn ,@body nil))))
835   ;; The translation assumes the first form in BODY is a label
836   (unless (go-tag-p (car body))
837     (push (gensym "START") body))
838   ;; Tagbody compilation
839   (let ((branch (gvarname 'branch))
840         (tbidx (gvarname 'tbidx)))
841     (let ((*environment* (declare-tagbody-tags tbidx body))
842           initag)
843       (let ((b (lookup-in-lexenv (first body) *environment* 'gotag)))
844         (setq initag (second (binding-value b))))
845       `(selfcall
846         ;; TAGBODY branch to take
847         (var (,branch ,initag))
848         (var (,tbidx #()))
849         (label tbloop
850                (while true
851                  (try
852                   (switch ,branch
853                           ,@(with-collect
854                              (collect `(case ,initag))
855                              (dolist (form (cdr body))
856                                (if (go-tag-p form)
857                                    (let ((b (lookup-in-lexenv form *environment* 'gotag)))
858                                      (collect `(case ,(second (binding-value b)))))
859                                    (collect (convert form)))))
860                           default
861                           (break tbloop)))
862                  (catch (jump)
863                    (if (and (== (get jump "type") "tagbody")
864                             (== (get jump "id") ,tbidx))
865                        (= ,branch (get jump "label"))
866                        (throw jump)))))
867         (return ,(convert nil))))))
868
869 (define-compilation go (label)
870   (let ((b (lookup-in-lexenv label *environment* 'gotag))
871         (n (cond
872              ((symbolp label) (symbol-name label))
873              ((integerp label) (integer-to-string label)))))
874     (when (null b)
875       (error "Unknown tag `~S'" label))
876     `(selfcall
877       (throw
878           (object
879            "type" "tagbody"
880            "id" ,(first (binding-value b))
881            "label" ,(second (binding-value b))
882            "message" ,(concat "Attempt to GO to non-existing tag " n))))))
883
884 (define-compilation unwind-protect (form &rest clean-up)
885   `(selfcall
886     (var (ret ,(convert nil)))
887     (try
888      (= ret ,(convert form)))
889     (finally
890      ,(convert-block clean-up))
891     (return ret)))
892
893 (define-compilation multiple-value-call (func-form &rest forms)
894   `(selfcall
895     (var (func ,(convert func-form)))
896     (var (args ,(vector (if *multiple-value-p* '|values| '|pv|) 0)))
897     (return
898       (selfcall
899        (var (|values| |mv|))
900        (var vs)
901        (progn
902          ,@(with-collect
903             (dolist (form forms)
904               (collect `(= vs ,(convert form t)))
905               (collect `(if (and (=== (typeof vs) "object")
906                                  (in "multiple-value" vs))
907                             (= args (method-call args "concat" vs))
908                             (method-call args "push" vs))))))
909        (= (property args 1) (- (property args "length") 2))
910        (return (method-call func "apply" |window| args))))))
911
912 (define-compilation multiple-value-prog1 (first-form &rest forms)
913   `(selfcall
914     (var (args ,(convert first-form *multiple-value-p*)))
915     (progn ,@(mapcar #'convert forms))
916     (return args)))
917
918 (define-transformation backquote (form)
919   (bq-completely-process form))
920
921
922 ;;; Primitives
923
924 (defvar *builtins* nil)
925
926 (defmacro define-raw-builtin (name args &body body)
927   ;; Creates a new primitive function `name' with parameters args and
928   ;; @body. The body can access to the local environment through the
929   ;; variable *ENVIRONMENT*.
930   `(push (list ',name (lambda ,args (block ,name ,@body)))
931          *builtins*))
932
933 (defmacro define-builtin (name args &body body)
934   `(define-raw-builtin ,name ,args
935      (let ,(mapcar (lambda (arg) `(,arg (convert ,arg))) args)
936        ,@body)))
937
938 ;;; VARIABLE-ARITY compiles variable arity operations. ARGS stands for
939 ;;; a variable which holds a list of forms. It will compile them and
940 ;;; store the result in some Javascript variables. BODY is evaluated
941 ;;; with ARGS bound to the list of these variables to generate the
942 ;;; code which performs the transformation on these variables.
943 (defun variable-arity-call (args function)
944   (unless (consp args)
945     (error "ARGS must be a non-empty list"))
946   (let ((counter 0)
947         (fargs '())
948         (prelude '()))
949     (dolist (x args)
950       (if (or (floatp x) (numberp x))
951           (push x fargs)
952           (let ((v (make-symbol (concat "x" (integer-to-string (incf counter))))))
953             (push v fargs)
954             (push `(var (,v ,(convert x)))
955                   prelude)
956             (push `(if (!= (typeof ,v) "number")
957                        (throw "Not a number!"))
958                   prelude))))
959     `(selfcall
960       (progn ,@(reverse prelude))
961       ,(funcall function (reverse fargs)))))
962
963
964 (defmacro variable-arity (args &body body)
965   (unless (symbolp args)
966     (error "`~S' is not a symbol." args))
967   `(variable-arity-call ,args (lambda (,args) `(return  ,,@body))))
968
969 (define-raw-builtin + (&rest numbers)
970   (if (null numbers)
971       0
972       (variable-arity numbers
973         `(+ ,@numbers))))
974
975 (define-raw-builtin - (x &rest others)
976   (let ((args (cons x others)))
977     (variable-arity args `(- ,@args))))
978
979 (define-raw-builtin * (&rest numbers)
980   (if (null numbers)
981       1
982       (variable-arity numbers `(* ,@numbers))))
983
984 (define-raw-builtin / (x &rest others)
985   (let ((args (cons x others)))
986     (variable-arity args
987       (if (null others)
988           `(/ 1 ,(car args))
989           (reduce (lambda (x y) `(/ ,x ,y))
990                   args)))))
991
992 (define-builtin mod (x y)
993   `(% ,x ,y))
994
995
996 (defun comparison-conjuntion (vars op)
997   (cond
998     ((null (cdr vars))
999      'true)
1000     ((null (cddr vars))
1001      `(,op ,(car vars) ,(cadr vars)))
1002     (t
1003      `(and (,op ,(car vars) ,(cadr vars))
1004            ,(comparison-conjuntion (cdr vars) op)))))
1005
1006 (defmacro define-builtin-comparison (op sym)
1007   `(define-raw-builtin ,op (x &rest args)
1008      (let ((args (cons x args)))
1009        (variable-arity args
1010          `(bool ,(comparison-conjuntion args ',sym))))))
1011
1012 (define-builtin-comparison > >)
1013 (define-builtin-comparison < <)
1014 (define-builtin-comparison >= >=)
1015 (define-builtin-comparison <= <=)
1016 (define-builtin-comparison = ==)
1017 (define-builtin-comparison /= !=)
1018
1019 (define-builtin numberp (x)
1020   `(bool (== (typeof ,x) "number")))
1021
1022 (define-builtin floor (x)
1023   `(method-call |Math| "floor" ,x))
1024
1025 (define-builtin expt (x y)
1026   `(method-call |Math| "pow" ,x ,y))
1027
1028 (define-builtin float-to-string (x)
1029   `(call |make_lisp_string| (method-call ,x |toString|)))
1030
1031 (define-builtin cons (x y)
1032   `(object "car" ,x "cdr" ,y))
1033
1034 (define-builtin consp (x)
1035   `(selfcall
1036     (var (tmp ,x))
1037     (return (bool (and (== (typeof tmp) "object")
1038                        (in "car" tmp))))))
1039
1040 (define-builtin car (x)
1041   `(selfcall
1042     (var (tmp ,x))
1043     (return (if (=== tmp ,(convert nil))
1044                 ,(convert nil)
1045                 (get tmp "car")))))
1046
1047 (define-builtin cdr (x)
1048   `(selfcall
1049     (var (tmp ,x))
1050     (return (if (=== tmp ,(convert nil))
1051                 ,(convert nil)
1052                 (get tmp "cdr")))))
1053
1054 (define-builtin rplaca (x new)
1055   `(selfcall
1056      (var (tmp ,x))
1057      (= (get tmp "car") ,new)
1058      (return tmp)))
1059
1060 (define-builtin rplacd (x new)
1061   `(selfcall
1062      (var (tmp ,x))
1063      (= (get tmp "cdr") ,new)
1064      (return tmp)))
1065
1066 (define-builtin symbolp (x)
1067   `(bool (instanceof ,x |Symbol|)))
1068
1069 (define-builtin make-symbol (name)
1070   `(new (call |Symbol| ,name)))
1071
1072 (define-builtin symbol-name (x)
1073   `(get ,x "name"))
1074
1075 (define-builtin set (symbol value)
1076   `(= (get ,symbol "value") ,value))
1077
1078 (define-builtin fset (symbol value)
1079   `(= (get ,symbol "fvalue") ,value))
1080
1081 (define-builtin boundp (x)
1082   `(bool (!== (get ,x "value") undefined)))
1083
1084 (define-builtin fboundp (x)
1085   `(bool (!== (get ,x "fvalue") undefined)))
1086
1087 (define-builtin symbol-value (x)
1088   `(selfcall
1089     (var (symbol ,x)
1090          (value (get symbol "value")))
1091     (if (=== value undefined)
1092         (throw (+ "Variable `" (call |xstring| (get symbol "name")) "' is unbound.")))
1093     (return value)))
1094
1095 (define-builtin symbol-function (x)
1096   `(selfcall
1097     (var (symbol ,x)
1098          (func (get symbol "fvalue")))
1099     (if (=== func undefined)
1100         (throw (+ "Function `" (call |xstring| (get symbol "name")) "' is undefined.")))
1101     (return func)))
1102
1103 (define-builtin lambda-code (x)
1104   `(call |make_lisp_string| (method-call ,x "toString")))
1105
1106 (define-builtin eq (x y)
1107   `(bool (=== ,x ,y)))
1108
1109 (define-builtin char-code (x)
1110   `(call |char_to_codepoint| ,x))
1111
1112 (define-builtin code-char (x)
1113   `(call |char_from_codepoint| ,x))
1114
1115 (define-builtin characterp (x)
1116   `(selfcall
1117     (var (x ,x))
1118     (return (bool
1119              (and (== (typeof x) "string")
1120                   (or (== (get x "length") 1)
1121                       (== (get x "length") 2)))))))
1122
1123 (define-builtin char-upcase (x)
1124   `(call |safe_char_upcase| ,x))
1125
1126 (define-builtin char-downcase (x)
1127   `(call |safe_char_downcase| ,x))
1128
1129 (define-builtin stringp (x)
1130   `(selfcall
1131     (var (x ,x))
1132     (return (bool
1133              (and (and (===(typeof x) "object")
1134                        (in "length" x))
1135                   (== (get x "stringp") 1))))))
1136
1137 (define-raw-builtin funcall (func &rest args)
1138   `(selfcall
1139     (var (f ,(convert func)))
1140     (return (call (if (=== (typeof f) "function")
1141                       f
1142                       (get f "fvalue"))
1143                   ,@(list* (if *multiple-value-p* '|values| '|pv|)
1144                            (length args)
1145                            (mapcar #'convert args))))))
1146
1147 (define-raw-builtin apply (func &rest args)
1148   (if (null args)
1149       (convert func)
1150       (let ((args (butlast args))
1151             (last (car (last args))))
1152         `(selfcall
1153            (var (f ,(convert func)))
1154            (var (args ,(list-to-vector
1155                         (list* (if *multiple-value-p* '|values| '|pv|)
1156                                (length args)
1157                                (mapcar #'convert args)))))
1158            (var (tail ,(convert last)))
1159            (while (!= tail ,(convert nil))
1160              (method-call args "push" (get tail "car"))
1161              (post++ (property args 1))
1162              (= tail (get tail "cdr")))
1163            (return (method-call (if (=== (typeof f) "function")
1164                                     f
1165                                     (get f "fvalue"))
1166                                 "apply"
1167                                 this
1168                                 args))))))
1169
1170 (define-builtin js-eval (string)
1171   (if *multiple-value-p*
1172       `(selfcall
1173         (var (v (call |globalEval| (call |xstring| ,string))))
1174         (return (method-call |values| "apply" this (call |forcemv| v))))
1175       `(call |globalEval| (call |xstring| ,string))))
1176
1177 (define-builtin %throw (string)
1178   `(selfcall (throw ,string)))
1179
1180 (define-builtin functionp (x)
1181   `(bool (=== (typeof ,x) "function")))
1182
1183 (define-builtin /debug (x)
1184   `(method-call |console| "log" (call |xstring| ,x)))
1185
1186
1187 ;;; Storage vectors. They are used to implement arrays and (in the
1188 ;;; future) structures.
1189
1190 (define-builtin storage-vector-p (x)
1191   `(selfcall
1192     (var (x ,x))
1193     (return (bool (and (=== (typeof x) "object") (in "length" x))))))
1194
1195 (define-builtin make-storage-vector (n)
1196   `(selfcall
1197     (var (r #()))
1198     (= (get r "length") ,n)
1199     (return r)))
1200
1201 (define-builtin storage-vector-size (x)
1202   `(get ,x "length"))
1203
1204 (define-builtin resize-storage-vector (vector new-size)
1205   `(= (get ,vector "length") ,new-size))
1206
1207 (define-builtin storage-vector-ref (vector n)
1208   `(selfcall
1209     (var (x (property ,vector ,n)))
1210     (if (=== x undefined) (throw "Out of range."))
1211     (return x)))
1212
1213 (define-builtin storage-vector-set (vector n value)
1214   `(selfcall
1215     (var (x ,vector))
1216     (var (i ,n))
1217     (if (or (< i 0) (>= i (get x "length")))
1218         (throw "Out of range."))
1219     (return (= (property x i) ,value))))
1220
1221 (define-builtin concatenate-storage-vector (sv1 sv2)
1222   `(selfcall
1223      (var (sv1 ,sv1))
1224      (var (r (method-call sv1 "concat" ,sv2)))
1225      (= (get r "type") (get sv1 "type"))
1226      (= (get r "stringp") (get sv1 "stringp"))
1227      (return r)))
1228
1229 (define-builtin get-internal-real-time ()
1230   `(method-call (new (call |Date|)) "getTime"))
1231
1232 (define-builtin values-array (array)
1233   (if *multiple-value-p*
1234       `(method-call |values| "apply" this ,array)
1235       `(method-call |pv| "apply" this ,array)))
1236
1237 (define-raw-builtin values (&rest args)
1238   (if *multiple-value-p*
1239       `(call |values| ,@(mapcar #'convert args))
1240       `(call |pv| ,@(mapcar #'convert args))))
1241
1242 ;;; Javascript FFI
1243
1244 (define-builtin new ()
1245   '(object))
1246
1247 (define-raw-builtin oget* (object key &rest keys)
1248   `(selfcall
1249     (progn
1250       (var (tmp (property ,(convert object) (call |xstring| ,(convert key)))))
1251       ,@(mapcar (lambda (key)
1252                   `(progn
1253                      (if (=== tmp undefined) (return ,(convert nil)))
1254                      (= tmp (property tmp (call |xstring| ,(convert key))))))
1255                 keys))
1256     (return (if (=== tmp undefined) ,(convert nil) tmp))))
1257
1258 (define-raw-builtin oset* (value object key &rest keys)
1259   (let ((keys (cons key keys)))
1260     `(selfcall
1261       (progn
1262         (var (obj ,(convert object)))
1263         ,@(mapcar (lambda (key)
1264                     `(progn
1265                        (= obj (property obj (call |xstring| ,(convert key))))
1266                        (if (=== obj undefined)
1267                            (throw "Impossible to set object property."))))
1268                   (butlast keys))
1269         (var (tmp
1270               (= (property obj (call |xstring| ,(convert (car (last keys)))))
1271                  ,(convert value))))
1272         (return (if (=== tmp undefined)
1273                     ,(convert nil)
1274                     tmp))))))
1275
1276 (define-raw-builtin oget (object key &rest keys)
1277   `(call |js_to_lisp| ,(convert `(oget* ,object ,key ,@keys))))
1278
1279 (define-raw-builtin oset (value object key &rest keys)
1280   (convert `(oset* (lisp-to-js ,value) ,object ,key ,@keys)))
1281
1282 (define-builtin objectp (x)
1283   `(bool (=== (typeof ,x) "object")))
1284
1285 (define-builtin lisp-to-js (x) `(call |lisp_to_js| ,x))
1286 (define-builtin js-to-lisp (x) `(call |js_to_lisp| ,x))
1287
1288
1289 (define-builtin in (key object)
1290   `(bool (in (call |xstring| ,key) ,object)))
1291
1292 (define-builtin delete-property (key object)
1293   `(selfcall
1294     (delete (property ,object (call |xstring| ,key)))))
1295
1296 (define-builtin map-for-in (function object)
1297   `(selfcall
1298     (var (f ,function)
1299          (g (if (=== (typeof f) "function") f (get f "fvalue")))
1300          (o ,object))
1301     (for-in (key o)
1302             (call g ,(if *multiple-value-p* '|values| '|pv|) 1 (property o key)))
1303     (return ,(convert nil))))
1304
1305 (define-compilation %js-vref (var)
1306   `(call |js_to_lisp| ,(make-symbol var)))
1307
1308 (define-compilation %js-vset (var val)
1309   `(= ,(make-symbol var) (call |lisp_to_js| ,(convert val))))
1310
1311 (define-setf-expander %js-vref (var)
1312   (let ((new-value (gensym)))
1313     (unless (stringp var)
1314       (error "`~S' is not a string." var))
1315     (values nil
1316             (list var)
1317             (list new-value)
1318             `(%js-vset ,var ,new-value)
1319             `(%js-vref ,var))))
1320
1321
1322 #-jscl
1323 (defvar *macroexpander-cache*
1324   (make-hash-table :test #'eq))
1325
1326 (defun !macro-function (symbol)
1327   (unless (symbolp symbol)
1328     (error "`~S' is not a symbol." symbol))
1329   (let ((b (lookup-in-lexenv symbol *environment* 'function)))
1330     (if (and b (eq (binding-type b) 'macro))
1331         (let ((expander (binding-value b)))
1332           (cond
1333             #-jscl
1334             ((gethash b *macroexpander-cache*)
1335              (setq expander (gethash b *macroexpander-cache*)))
1336             ((listp expander)
1337              (let ((compiled (eval expander)))
1338                ;; The list representation are useful while
1339                ;; bootstrapping, as we can dump the definition of the
1340                ;; macros easily, but they are slow because we have to
1341                ;; evaluate them and compile them now and again. So, let
1342                ;; us replace the list representation version of the
1343                ;; function with the compiled one.
1344                ;;
1345                #+jscl (setf (binding-value b) compiled)
1346                #-jscl (setf (gethash b *macroexpander-cache*) compiled)
1347                (setq expander compiled))))
1348           expander)
1349         nil)))
1350
1351 (defun !macroexpand-1 (form)
1352   (cond
1353     ((symbolp form)
1354      (let ((b (lookup-in-lexenv form *environment* 'variable)))
1355        (if (and b (eq (binding-type b) 'macro))
1356            (values (binding-value b) t)
1357            (values form nil))))
1358     ((and (consp form) (symbolp (car form)))
1359      (let ((macrofun (!macro-function (car form))))
1360        (if macrofun
1361            (values (funcall macrofun (cdr form)) t)
1362            (values form nil))))
1363     (t
1364      (values form nil))))
1365
1366 (defun compile-funcall (function args)
1367   (let* ((arglist (list* (if *multiple-value-p* '|values| '|pv|)
1368                          (length args)
1369                          (mapcar #'convert args))))
1370     (unless (or (symbolp function)
1371                 (and (consp function)
1372                      (member (car function) '(lambda oget))))
1373       (error "Bad function designator `~S'" function))
1374     (cond
1375       ((translate-function function)
1376        `(call ,(translate-function function) ,@arglist))
1377       ((and (symbolp function)
1378             #+jscl (eq (symbol-package function) (find-package "COMMON-LISP"))
1379             #-jscl t)
1380        (fn-info function :called t)
1381        `(method-call ,(convert `',function) "fvalue" ,@arglist))
1382       #+jscl
1383       ((symbolp function)
1384        `(call ,(convert `#',function) ,@arglist))
1385       ((and (consp function) (eq (car function) 'lambda))
1386        `(call ,(convert `(function ,function)) ,@arglist))
1387       ((and (consp function) (eq (car function) 'oget))
1388        `(call |js_to_lisp|
1389               (call ,(reduce (lambda (obj p)
1390                                `(property ,obj (call |xstring| ,p)))
1391                              (mapcar #'convert (cdr function)))
1392                     ,@(mapcar (lambda (s)
1393                                 `(call |lisp_to_js| ,(convert s)))
1394                               args))))
1395       (t
1396        (error "Bad function descriptor")))))
1397
1398 (defun convert-block (sexps &optional return-last-p decls-allowed-p)
1399   (multiple-value-bind (sexps decls)
1400       (parse-body sexps :declarations decls-allowed-p)
1401     (declare (ignore decls))
1402     (if return-last-p
1403         `(progn
1404            ,@(mapcar #'convert (butlast sexps))
1405            (return ,(convert (car (last sexps)) *multiple-value-p*)))
1406         `(progn ,@(mapcar #'convert sexps)))))
1407
1408 (defun convert (sexp &optional multiple-value-p)
1409   (multiple-value-bind (sexp expandedp) (!macroexpand-1 sexp)
1410     (when expandedp
1411       (return-from convert (convert sexp multiple-value-p)))
1412     ;; The expression has been macroexpanded. Now compile it!
1413     (let ((*multiple-value-p* multiple-value-p)
1414           (*convert-level* (1+ *convert-level*)))
1415       (cond
1416         ((symbolp sexp)
1417          (let ((b (lookup-in-lexenv sexp *environment* 'variable)))
1418            (cond
1419              ((and b (not (member 'special (binding-declarations b))))
1420               (binding-value b))
1421              ((or (keywordp sexp)
1422                   (and b (member 'constant (binding-declarations b))))
1423               `(get ,(convert `',sexp) "value"))
1424              (t
1425               (convert `(symbol-value ',sexp))))))
1426         ((or (integerp sexp) (floatp sexp) (characterp sexp) (stringp sexp) (arrayp sexp))
1427          (literal sexp))
1428         ((listp sexp)
1429          (let ((name (car sexp))
1430                (args (cdr sexp)))
1431            (cond
1432              ;; Special forms
1433              ((assoc name *compilations*)
1434               (let ((comp (second (assoc name *compilations*))))
1435                 (apply comp args)))
1436              ;; Built-in functions
1437              ((and (assoc name *builtins*)
1438                    (not (claimp name 'function 'notinline)))
1439               (let ((comp (second (assoc name *builtins*))))
1440                 (apply comp args)))
1441              (t
1442               (compile-funcall name args)))))
1443         (t
1444          (error "How should I compile `~S'?" sexp))))))
1445
1446
1447 (defvar *compile-print-toplevels* nil)
1448
1449 (defun truncate-string (string &optional (width 60))
1450   (let ((n (or (position #\newline string)
1451                (min width (length string)))))
1452     (subseq string 0 n)))
1453
1454 (defun convert-toplevel (sexp &optional multiple-value-p)
1455   ;; Macroexpand sexp as much as possible
1456   (multiple-value-bind (sexp expandedp) (!macroexpand-1 sexp)
1457     (when expandedp
1458       (return-from convert-toplevel (convert-toplevel sexp multiple-value-p))))
1459   ;; Process as toplevel
1460   (let ((*convert-level* -1)
1461         (*toplevel-compilations* nil))
1462     (cond
1463       ;; Non-empty toplevel progn
1464       ((and (consp sexp)
1465             (eq (car sexp) 'progn)
1466             (cdr sexp))
1467        `(progn
1468           ,@(mapcar (lambda (s) (convert-toplevel s t))
1469                     (cdr sexp))))
1470       (t
1471        (when *compile-print-toplevels*
1472          (let ((form-string (prin1-to-string sexp)))
1473            (format t "Compiling ~a..." (truncate-string form-string))))
1474        (let ((code (convert sexp multiple-value-p)))
1475          `(progn
1476             ,@(get-toplevel-compilations)
1477             ,code))))))
1478
1479 (defun compile-toplevel (sexp &optional multiple-value-p)
1480   (with-output-to-string (*standard-output*)
1481     (js (convert-toplevel sexp multiple-value-p))))