src/list.lisp

   1 ;;; list.lisp ---
   2
   3 ;; JSCL is free software: you can redistribute it and/or
   4 ;; modify it under the terms of the GNU General Public License as
   5 ;; published by the Free Software Foundation, either version 3 of the
   6 ;; License, or (at your option) any later version.
   7 ;;
   8 ;; JSCL is distributed in the hope that it will be useful, but
   9 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  10 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  11 ;; General Public License for more details.
  12 ;;
  13 ;; You should have received a copy of the GNU General Public License
  14 ;; along with JSCL.  If not, see <http://www.gnu.org/licenses/>.
  15
  16 (/debug "loading list.lisp!")
  17
  18 ;;;; Various list functions
  19
  20 (defun cons (x y) (cons x y))
  21 (defun consp (x) (consp x))
  22
  23 (defun listp (x)
  24   (or (consp x) (null x)))
  25
  26 (defun null (x)
  27   (eq x nil))
  28
  29 (defun endp (x)
  30   (if (null x)
  31       t
  32       (if (consp x)
  33           nil
  34           (error "The value `~S' is not a type list." x))))
  35
  36 (defun car (x)
  37   "Return the CAR part of a cons, or NIL if X is null."
  38   (car x))
  39
  40 (defun cdr (x) (cdr x))
  41
  42 (defun rplaca (cons x)
  43   (rplaca cons x))
  44
  45 (defun rplacd (cons x)
  46   (rplacd cons x))
  47
  48 (defun first   (x) (car    x))
  49 (defun second  (x) (cadr   x))
  50 (defun third   (x) (caddr  x))
  51 (defun fourth  (x) (cadddr x))
  52 (defun fifth   (x) (car    (cddddr x)))
  53 (defun sixth   (x) (cadr   (cddddr x)))
  54 (defun seventh (x) (caddr  (cddddr x)))
  55 (defun eighth  (x) (cadddr (cddddr x)))
  56 (defun ninth   (x) (car  (cddddr (cddddr x))))
  57 (defun tenth   (x) (cadr (cddddr (cddddr x))))
  58 (defun rest    (x) (cdr x))
  59
  60 (defun list (&rest args)
  61   args)
  62
  63 (defun list* (arg &rest others)
  64   (cond ((null others) arg)
  65         ((null (cdr others)) (cons arg (car others)))
  66         (t (do ((x others (cdr x)))
  67                ((null (cddr x)) (rplacd x (cadr x))))
  68            (cons arg others))))
  69
  70 (defun list-length (list)
  71   (let ((l 0))
  72     (while (not (null list))
  73       (incf l)
  74       (setq list (cdr list)))
  75     l))
  76
  77 (defun nthcdr (n list)
  78   (while (and (plusp n) list)
  79     (setq n (1- n))
  80     (setq list (cdr list)))
  81   list)
  82
  83 (defun nth (n list)
  84   (car (nthcdr n list)))
  85
  86 (define-setf-expander nth (n list)
  87   (let ((g!list (gensym))
  88         (g!index (gensym))
  89         (g!value (gensym)))
  90     (values (list g!list g!index)
  91             (list list n)
  92             (list g!value)
  93             `(rplaca (nthcdr ,g!index ,g!list) ,g!value)
  94             `(nth ,g!index ,g!list))))
  95
  96 (defun caar (x) (car (car x)))
  97 (defun cadr (x) (car (cdr x)))
  98 (defun cdar (x) (cdr (car x)))
  99 (defun cddr (x) (cdr (cdr x)))
 100
 101 (defun caaar (x) (car (caar x)))
 102 (defun caadr (x) (car (cadr x)))
 103 (defun cadar (x) (car (cdar x)))
 104 (defun caddr (x) (car (cddr x)))
 105 (defun cdaar (x) (cdr (caar x)))
 106 (defun cdadr (x) (cdr (cadr x)))
 107 (defun cddar (x) (cdr (cdar x)))
 108 (defun cdddr (x) (cdr (cddr x)))
 109
 110 (defun caaaar (x) (car (caaar x)))
 111 (defun caaadr (x) (car (caadr x)))
 112 (defun caadar (x) (car (cadar x)))
 113 (defun caaddr (x) (car (caddr x)))
 114 (defun cadaar (x) (car (cdaar x)))
 115 (defun cadadr (x) (car (cdadr x)))
 116 (defun caddar (x) (car (cddar x)))
 117 (defun cadddr (x) (car (cdddr x)))
 118 (defun cdaaar (x) (cdr (caaar x)))
 119 (defun cdaadr (x) (cdr (caadr x)))
 120 (defun cdadar (x) (cdr (cadar x)))
 121 (defun cdaddr (x) (cdr (caddr x)))
 122 (defun cddaar (x) (cdr (cdaar x)))
 123 (defun cddadr (x) (cdr (cdadr x)))
 124 (defun cdddar (x) (cdr (cddar x)))
 125 (defun cddddr (x) (cdr (cdddr x)))
 126
 127 (defun append-two (list1 list2)
 128   (if (null list1)
 129       list2
 130       (cons (car list1)
 131             (append (cdr list1) list2))))
 132
 133 (defun append (&rest lists)
 134   (!reduce #'append-two lists nil))
 135
 136 (defun revappend (list1 list2)
 137   (while list1
 138     (push (car list1) list2)
 139     (setq list1 (cdr list1)))
 140   list2)
 141
 142 (defun reverse (list)
 143   (revappend list '()))
 144
 145 (defun sublis (alist tree &key key (test #'eql testp) (test-not #'eql test-not-p))
 146   (when (and testp test-not-p)
 147     (error "Both test and test-not are set"))
 148   (labels ((s (tree)
 149              (let* ((key-val (if key (funcall key tree) tree))
 150                     (replace (if test-not-p
 151                                  (assoc key-val alist :test-not test-not)
 152                                  (assoc key-val alist :test test)))
 153                     (x (if replace (cdr replace) tree)))
 154                (if (atom x)
 155                    x
 156                    (cons (s (car x)) (s (cdr x)))))))
 157     (s tree)))
 158
 159 (defun subst (new old tree &key key (test #'eql testp) (test-not #'eql test-not-p))
 160   (labels ((s (x)
 161              (cond ((satisfies-test-p old x :key key :test test :testp testp
 162                                       :test-not test-not :test-not-p test-not-p)
 163                     new)
 164                    ((atom x) x)
 165                    (t (let ((a (s (car x)))
 166                             (b (s (cdr x))))
 167                         (if (and (eq a (car x))
 168                                  (eq b (cdr x)))
 169                             x
 170                             (cons a b)))))))
 171     (s tree)))
 172
 173 (defun copy-list (x)
 174   (mapcar #'identity x))
 175
 176 (defun copy-tree (tree)
 177   (if (consp tree)
 178     (cons (copy-tree (car tree))
 179           (copy-tree (cdr tree)))
 180     tree))
 181
 182 (defun tree-equal (tree1 tree2 &key (test #'eql testp)
 183                          (test-not #'eql test-not-p))
 184   (when (and testp test-not-p) (error "Both test and test-not are set"))
 185   (let ((func (if test-not-p (complement test-not) test)))
 186     (labels ((%tree-equal (tree1 tree2)
 187                (if (atom tree1)
 188                  (and (atom tree2) (funcall func tree1 tree2))
 189                  (and (consp tree2)
 190                       (%tree-equal (car tree1) (car tree2))
 191                       (%tree-equal (cdr tree1) (cdr tree2))))))
 192       (%tree-equal tree1 tree2))))
 193
 194 (defun tailp (object list)
 195   (do ((tail list (cdr tail)))
 196     ((atom tail) (eq object tail))
 197     (when (eql tail object)
 198       (return-from tailp t))))
 199
 200 (defun make-list (size &key (initial-element nil))
 201   "Create a list of size `size` of `initial-element`s."
 202   (when (< size 0)
 203     (error "Size must be non-negative"))
 204   (let ((newlist))
 205     (do ((i 0))
 206         ((= i size))
 207       (push initial-element newlist)
 208       (incf i))
 209     newlist))
 210
 211 (defun map1 (func list)
 212   (with-collect
 213     (while list
 214       (collect (funcall func (car list)))
 215       (setq list (cdr list)))))
 216
 217 (defun mapcar (func list &rest lists)
 218   (let ((lists (cons list lists)))
 219     (with-collect
 220       (block loop
 221         (loop
 222            (let ((elems (map1 #'car lists)))
 223              (do ((tail lists (cdr tail)))
 224                  ((null tail))
 225                (when (null (car tail)) (return-from loop))
 226                (rplaca tail (cdar tail)))
 227              (collect (apply func elems))))))))
 228
 229 (defun mapn (func list)
 230   (with-collect
 231     (while list
 232       (collect (funcall func list))
 233       (setq list (cdr list)))))
 234
 235 (defun maplist (func list &rest lists)
 236   (let ((lists (cons list lists)))
 237     (with-collect
 238       (block loop
 239         (loop
 240            (let ((elems (mapn #'car lists)))
 241              (do ((tail lists (cdr tail)))
 242                  ((null tail))
 243                (when (null (car tail)) (return-from loop))
 244                (rplaca tail (cdar tail)))
 245              (collect (apply func elems))))))))
 246
 247 (defun mapc (func &rest lists)
 248   (do* ((tails lists (map1 #'cdr tails))
 249         (elems (map1 #'car tails)
 250                (map1 #'car tails)))
 251        ((dolist (x tails) (when (null x) (return t)))
 252         (car lists))
 253     (apply func elems)))
 254
 255 (defun last (x)
 256   (while (consp (cdr x))
 257     (setq x (cdr x)))
 258   x)
 259
 260 (defun butlast (x &optional (n 1))
 261   "Returns x, less the n last elements in the list."
 262   (cond
 263       ;; trivial optimizations
 264     ((not x) x)
 265     ((zerop n) x)
 266
 267     ;; Base case
 268     ((= n 1)
 269      (and (consp (cdr x))
 270           (cons (car x)
 271                 (butlast (cdr x) n))))
 272     ;; O(n * (length x)) butlast for n > 1.
 273     (t
 274      (let ((temp x))
 275        (do
 276         ((iter 0))
 277         ;; quit when we reach the top or we ran out
 278         ((or (= iter n)
 279              (not temp)))
 280          (setf temp (butlast temp 1))
 281          (incf iter))
 282        temp))))
 283
 284 (defun member (x list &key key (test #'eql testp) (test-not #'eql test-not-p))
 285   (while list
 286     (when (satisfies-test-p x (car list) :key key :test test :testp testp
 287                             :test-not test-not :test-not-p test-not-p)
 288       (return list))
 289     (setq list (cdr list))))
 290
 291
 292 (defun assoc (x alist &key key (test #'eql testp) (test-not #'eql test-not-p))
 293   (while alist
 294     (if (satisfies-test-p x (caar alist) :key key :test test :testp testp
 295                           :test-not test-not :test-not-p test-not-p)
 296       (return)
 297       (setq alist (cdr alist))))
 298   (car alist))
 299
 300 (defun rassoc (x alist &key key (test #'eql) (test #'eql testp)
 301                  (test-not #'eql test-not-p))
 302   (while alist
 303     (if (satisfies-test-p x (cdar alist) :key key :test test :testp testp
 304                           :test-not test-not :test-not-p test-not-p)
 305       (return)
 306       (setq alist (cdr alist))))
 307   (car alist))
 308
 309 (defun acons (key datum alist)
 310   (cons (cons key datum) alist))
 311
 312 (defun pairlis (keys data &optional (alist ()))
 313   (while keys
 314     (setq alist (acons (car keys) (car data) alist))
 315     (setq keys (cdr keys))
 316     (setq data (cdr data)))
 317   alist)
 318
 319 (defun copy-alist (alist)
 320   (let ((new-alist ()))
 321     (while alist
 322       (push (cons (caar alist) (cdar alist)) new-alist)
 323       (setq alist (cdr alist)))
 324     (reverse new-alist)))
 325
 326
 327 (define-setf-expander car (x)
 328   (let ((cons (gensym))
 329         (new-value (gensym)))
 330     (values (list cons)
 331             (list x)
 332             (list new-value)
 333             `(progn (rplaca ,cons ,new-value) ,new-value)
 334             `(car ,cons))))
 335
 336 (define-setf-expander cdr (x)
 337   (let ((cons (gensym))
 338         (new-value (gensym)))
 339     (values (list cons)
 340             (list x)
 341             (list new-value)
 342             `(progn (rplacd ,cons ,new-value) ,new-value)
 343             `(cdr ,cons))))
 344
 345
 346 ;; The NCONC function is based on the SBCL's one.
 347 (defun nconc (&rest lists)
 348   (flet ((fail (object)
 349            (error "type-error in nconc")))
 350     (do ((top lists (cdr top)))
 351         ((null top) nil)
 352       (let ((top-of-top (car top)))
 353         (typecase top-of-top
 354           (cons
 355            (let* ((result top-of-top)
 356                   (splice result))
 357              (do ((elements (cdr top) (cdr elements)))
 358                  ((endp elements))
 359                (let ((ele (car elements)))
 360                  (typecase ele
 361                    (cons (rplacd (last splice) ele)
 362                          (setf splice ele))
 363                    (null (rplacd (last splice) nil))
 364                    (atom (if (cdr elements)
 365                              (fail ele)
 366                              (rplacd (last splice) ele))))))
 367              (return result)))
 368           (null)
 369           (atom
 370            (if (cdr top)
 371                (fail top-of-top)
 372                (return top-of-top))))))))
 373
 374
 375 (defun nreconc (x y)
 376   (do ((1st (cdr x) (if (endp 1st) 1st (cdr 1st)))
 377        (2nd x 1st)                ; 2nd follows first down the list.
 378        (3rd y 2nd))               ;3rd follows 2nd down the list.
 379       ((atom 2nd) 3rd)
 380     (rplacd 2nd 3rd)))
 381
 382
 383 (defun adjoin (item list &key (test #'eql) (key #'identity))
 384   (if (member item list :key key :test test)
 385     list
 386     (cons item list)))
 387
 388 (defun intersection (list1 list2 &key (test #'eql) (key #'identity))
 389   (let ((new-list ()))
 390     (dolist (x list1)
 391       (when (member (funcall key x) list2 :test test :key key)
 392         (push x new-list)))
 393     new-list))
 394
 395 (defun get-properties (plist indicator-list)
 396   (do* ((plist plist (cddr plist))
 397         (cdr (cdr plist) (cdr plist))
 398         (car (car plist) (car plist)))
 399       ((null plist) (values nil nil nil))
 400     (when (null cdr)
 401       (error "malformed property list ~S" plist))
 402     (let ((found (member car indicator-list :test #'eq)))
 403       (when found
 404         (return (values car (cadr plist) plist))))))
 405
 406 (defun getf (plist indicator &optional default)
 407   (do* ((plist plist (cddr plist))
 408         (cdr (cdr plist) (cdr plist))
 409         (car (car plist) (car plist)))
 410       ((null plist) default)
 411     (when (null cdr)
 412       (error "malformed property list ~S" plist))
 413     (when (eq indicator car)
 414       (return (cadr plist)))))
 415
 416 (defun %putf (plist indicator new-value)
 417   (do* ((tail plist (cddr tail))
 418         (cdr (cdr tail) (cdr tail))
 419         (car (car tail) (car tail)))
 420       ((null tail) (list* indicator new-value plist))
 421     (when (null cdr)
 422       (error "malformed property list ~S" tail))
 423     (when (eq indicator car)
 424       ;; TODO: should be cadr, needs a defsetf for that
 425       (setf (car (cdr tail)) new-value)
 426       (return tail))))
 427
 428 (define-setf-expander getf (plist indicator &optional default)
 429   (multiple-value-bind (dummies vals newval setter getter)
 430       (get-setf-expansion plist)
 431     (let ((store (gensym))
 432           (indicator-sym (gensym))
 433           (default-sym (and default (gensym))))
 434       (values `(,indicator-sym ,@(and default `(,default-sym)) ,@dummies)
 435               `(,indicator ,@(and default `(,default)) ,@vals)
 436               `(,store)
 437               `(let ((,(car newval) (%putf ,getter ,indicator-sym ,store))
 438                      ,@(cdr newval))
 439                  ,setter
 440                  ,store)
 441               `(getf ,getter ,indicator-sym ,@(and default `(,default-sym)))))))