make-host-2.lisp

   1 ;;; Set up the cross-compiler.
   2 (setf *print-level* 5 *print-length* 5)
   3 (load "src/cold/shared.lisp")
   4 (in-package "SB-COLD")
   5 ;;; FIXME: these prefixes look like non-pathnamy ways of defining a
   6 ;;; relative pathname.  Investigate whether they can be made relative
   7 ;;; pathnames.
   8 (setf *host-obj-prefix* "obj/from-host/"
   9       *target-obj-prefix* "obj/from-xc/")
  10 (load "src/cold/set-up-cold-packages.lisp")
  11 (load "src/cold/defun-load-or-cload-xcompiler.lisp")
  12 (load-or-cload-xcompiler #'host-load-stem)
  13
  14 (defun proclaim-target-optimization ()
  15   (let ((debug (if (position :sb-show *shebang-features*) 2 1)))
  16     (sb-xc:proclaim
  17      `(optimize
  18        (compilation-speed 1) (debug ,debug)
  19        ;; CLISP's pretty-printer is fragile and tends to cause stack
  20        ;; corruption or fail internal assertions, as of 2003-04-20; we
  21        ;; therefore turn off as many notes as possible.
  22        (sb!ext:inhibit-warnings #-clisp 2 #+clisp 3)
  23        ;; SAFETY = SPEED (and < 3) should provide reasonable safety,
  24        ;; but might skip some unreasonably expensive stuff
  25        ;; (e.g. %DETECT-STACK-EXHAUSTION in sbcl-0.7.2).
  26        (safety 2) (space 1) (speed 2)
  27        ;; sbcl-internal optimization declarations:
  28        ;;
  29        ;; never insert stepper conditions
  30        (sb!c:insert-step-conditions 0)))))
  31 (compile 'proclaim-target-optimization)
  32
  33 (defun in-target-cross-compilation-mode (fun)
  34   "Call FUN with everything set up appropriately for cross-compiling
  35    a target file."
  36   (let (;; In order to increase microefficiency of the target Lisp,
  37         ;; enable old CMU CL defined-function-types-never-change
  38         ;; optimizations. (ANSI says users aren't supposed to
  39         ;; redefine our functions anyway; and developers can
  40         ;; fend for themselves.)
  41         #!-sb-fluid
  42         (sb!ext:*derive-function-types* t)
  43         ;; Let the target know that we're the cross-compiler.
  44         (*features* (cons :sb-xc *features*))
  45         ;; We need to tweak the readtable..
  46         (*readtable* (copy-readtable)))
  47     ;; ..in order to make backquotes expand into target code
  48     ;; instead of host code.
  49     ;; FIXME: Isn't this now taken care of automatically by
  50     ;; toplevel forms in the xcompiler backq.lisp file?
  51     (set-macro-character #\` #'sb!impl::backquote-macro)
  52     (set-macro-character #\, #'sb!impl::comma-macro)
  53
  54     (set-dispatch-macro-character #\# #\+ #'she-reader)
  55     (set-dispatch-macro-character #\# #\- #'she-reader)
  56     ;; Control optimization policy.
  57     (proclaim-target-optimization)
  58     ;; Specify where target machinery lives.
  59     (with-additional-nickname ("SB-XC" "SB!XC")
  60       (funcall fun))))
  61 (compile 'in-target-cross-compilation-mode)
  62
  63
  64 ;; Supress function/macro redefinition warnings under clisp.
  65 #+clisp (setf custom:*suppress-check-redefinition* t)
  66
  67 (setf *target-compile-file* #'sb-xc:compile-file)
  68 (setf *target-assemble-file* #'sb!c:assemble-file)
  69 (setf *in-target-compilation-mode-fn* #'in-target-cross-compilation-mode)
  70 \f
  71 ;;; Run the cross-compiler to produce cold fasl files.
  72 (load "src/cold/compile-cold-sbcl.lisp")
  73
  74
  75 ;;; miscellaneous tidying up and saving results
  76 (let ((filename "output/object-filenames-for-genesis.lisp-expr"))
  77   (ensure-directories-exist filename :verbose t)
  78   (with-open-file (s filename :direction :output :if-exists :supersede)
  79     (write *target-object-file-names* :stream s :readably t)))
  80
  81 ;;; Let's check that the type system was reasonably sane. (It's easy
  82 ;;; to spend a long time wandering around confused trying to debug
  83 ;;; cold init if it wasn't.)
  84 (when (position :sb-test *shebang-features*)
  85   (load "tests/type.after-xc.lisp"))
  86
  87 ;;; If you're experimenting with the system under a cross-compilation
  88 ;;; host which supports CMU-CL-style SAVE-LISP, this can be a good
  89 ;;; time to run it. The resulting core isn't used in the normal build,
  90 ;;; but can be handy for experimenting with the system. (See slam.sh
  91 ;;; for an example.)
  92 (when (position :sb-after-xc-core *shebang-features*)
  93   #+cmu (ext:save-lisp "output/after-xc.core" :load-init-file nil)
  94   #+sbcl (sb-ext:save-lisp-and-die "output/after-xc.core")
  95   #+openmcl (ccl::save-application "output/after-xc.core")
  96   #+clisp (ext:saveinitmem "output/after-xc.core"))
  97 #+cmu (ext:quit)
  98 #+clisp (ext:quit)
  99 #+abcl (ext:quit)