src/compiler/array-tran.lisp

   1 ;;;; array-specific optimizers and transforms
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!C")
  13 \f
  14 ;;;; utilities for optimizing array operations
  15
  16 ;;; Return UPGRADED-ARRAY-ELEMENT-TYPE for LVAR, or do
  17 ;;; GIVE-UP-IR1-TRANSFORM if the upgraded element type can't be
  18 ;;; determined.
  19 (defun upgraded-element-type-specifier-or-give-up (lvar)
  20   (let ((element-type-specifier (upgraded-element-type-specifier lvar)))
  21     (if (eq element-type-specifier '*)
  22         (give-up-ir1-transform
  23          "upgraded array element type not known at compile time")
  24         element-type-specifier)))
  25
  26 (defun upgraded-element-type-specifier (lvar)
  27   (type-specifier (array-type-upgraded-element-type (lvar-type lvar))))
  28
  29 ;;; Array access functions return an object from the array, hence its type is
  30 ;;; going to be the array upgraded element type. Secondary return value is the
  31 ;;; known supertype of the upgraded-array-element-type, if if the exact
  32 ;;; U-A-E-T is not known. (If it is NIL, the primary return value is as good
  33 ;;; as it gets.)
  34 (defun array-type-upgraded-element-type (type)
  35   (typecase type
  36     ;; Note that this IF mightn't be satisfied even if the runtime
  37     ;; value is known to be a subtype of some specialized ARRAY, because
  38     ;; we can have values declared e.g. (AND SIMPLE-VECTOR UNKNOWN-TYPE),
  39     ;; which are represented in the compiler as INTERSECTION-TYPE, not
  40     ;; array type.
  41     (array-type
  42      (values (array-type-specialized-element-type type) nil))
  43     ;; Deal with intersection types (bug #316078)
  44     (intersection-type
  45      (let ((intersection-types (intersection-type-types type))
  46            (element-type *wild-type*)
  47            (element-supertypes nil))
  48        (dolist (intersection-type intersection-types)
  49          (multiple-value-bind (cur-type cur-supertype)
  50              (array-type-upgraded-element-type intersection-type)
  51            ;; According to ANSI, an array may have only one specialized
  52            ;; element type - e.g. '(and (array foo) (array bar))
  53            ;; is not a valid type unless foo and bar upgrade to the
  54            ;; same element type.
  55            (cond
  56              ((eq cur-type *wild-type*)
  57               nil)
  58              ((eq element-type *wild-type*)
  59               (setf element-type cur-type))
  60              ((or (not (csubtypep cur-type element-type))
  61                   (not (csubtypep element-type cur-type)))
  62               ;; At least two different element types where given, the array
  63               ;; is valid iff they represent the same type.
  64               ;;
  65               ;; FIXME: TYPE-INTERSECTION already takes care of disjoint array
  66               ;; types, so I believe this code should be unreachable. Maybe
  67               ;; signal a warning / error instead?
  68               (setf element-type *empty-type*)))
  69            (push (or cur-supertype (type-*-to-t cur-type))
  70                  element-supertypes)))
  71        (values element-type
  72                (when (and (eq *wild-type* element-type) element-supertypes)
  73                  (apply #'type-intersection element-supertypes)))))
  74     (union-type
  75      (let ((union-types (union-type-types type))
  76            (element-type nil)
  77            (element-supertypes nil))
  78        (dolist (union-type union-types)
  79          (multiple-value-bind (cur-type cur-supertype)
  80              (array-type-upgraded-element-type union-type)
  81            (cond
  82              ((eq element-type *wild-type*)
  83               nil)
  84              ((eq element-type nil)
  85               (setf element-type cur-type))
  86              ((or (eq cur-type *wild-type*)
  87                   ;; If each of the two following tests fail, it is not
  88                   ;; possible to determine the element-type of the array
  89                   ;; because more than one kind of element-type was provided
  90                   ;; like in '(or (array foo) (array bar)) although a
  91                   ;; supertype (or foo bar) may be provided as the second
  92                   ;; returned value returned. See also the KLUDGE below.
  93                   (not (csubtypep cur-type element-type))
  94                   (not (csubtypep element-type cur-type)))
  95               (setf element-type *wild-type*)))
  96            (push (or cur-supertype (type-*-to-t cur-type))
  97                  element-supertypes)))
  98        (values element-type
  99                (when (eq *wild-type* element-type)
 100                  (apply #'type-union element-supertypes)))))
 101     (member-type
 102      ;; Convert member-type to an union-type.
 103      (array-type-upgraded-element-type
 104       (apply #'type-union (mapcar #'ctype-of (member-type-members type)))))
 105     (t
 106      ;; KLUDGE: there is no good answer here, but at least
 107      ;; *wild-type* won't cause HAIRY-DATA-VECTOR-{REF,SET} to be
 108      ;; erroneously optimized (see generic/vm-tran.lisp) -- CSR,
 109      ;; 2002-08-21
 110      (values *wild-type* nil))))
 111
 112 (defun array-type-declared-element-type (type)
 113   (if (array-type-p type)
 114       (array-type-element-type type)
 115       *wild-type*))
 116
 117 ;;; The ``new-value'' for array setters must fit in the array, and the
 118 ;;; return type is going to be the same as the new-value for SETF
 119 ;;; functions.
 120 (defun assert-new-value-type (new-value array)
 121   (let ((type (lvar-type array)))
 122     (when (array-type-p type)
 123       (assert-lvar-type
 124        new-value
 125        (array-type-specialized-element-type type)
 126        (lexenv-policy (node-lexenv (lvar-dest new-value))))))
 127   (lvar-type new-value))
 128
 129 ;;; Return true if ARG is NIL, or is a constant-lvar whose
 130 ;;; value is NIL, false otherwise.
 131 (defun unsupplied-or-nil (arg)
 132   (declare (type (or lvar null) arg))
 133   (or (not arg)
 134       (and (constant-lvar-p arg)
 135            (not (lvar-value arg)))))
 136
 137 (defun supplied-and-true (arg)
 138   (and arg
 139        (constant-lvar-p arg)
 140        (lvar-value arg)
 141        t))
 142 \f
 143 ;;;; DERIVE-TYPE optimizers
 144
 145 ;;; Array operations that use a specific number of indices implicitly
 146 ;;; assert that the array is of that rank.
 147 (defun assert-array-rank (array rank)
 148   (assert-lvar-type
 149    array
 150    (specifier-type `(array * ,(make-list rank :initial-element '*)))
 151    (lexenv-policy (node-lexenv (lvar-dest array)))))
 152
 153 (defun derive-aref-type (array)
 154   (multiple-value-bind (uaet other)
 155       (array-type-upgraded-element-type (lvar-type array))
 156     (or other uaet)))
 157
 158 (defoptimizer (array-in-bounds-p derive-type) ((array &rest indices))
 159   (assert-array-rank array (length indices))
 160   *universal-type*)
 161
 162 (deftransform array-in-bounds-p ((array &rest subscripts))
 163   (flet ((give-up ()
 164            (give-up-ir1-transform
 165             "~@<lower array bounds unknown or negative and upper bounds not ~
 166              negative~:@>"))
 167          (bound-known-p (x)
 168            (integerp x))) ; might be NIL or *
 169     (block nil
 170       (let ((dimensions (array-type-dimensions-or-give-up
 171                          (lvar-conservative-type array))))
 172         ;; Might be *. (Note: currently this is never true, because the type
 173         ;; derivation infers the rank from the call to ARRAY-IN-BOUNDS-P, but
 174         ;; let's keep this future proof.)
 175         (when (eq '* dimensions)
 176           (give-up-ir1-transform "array bounds unknown"))
 177         ;; shortcut for zero dimensions
 178         (when (some (lambda (dim)
 179                       (and (bound-known-p dim) (zerop dim)))
 180                     dimensions)
 181           (return nil))
 182         ;; we first collect the subscripts LVARs' bounds and see whether
 183         ;; we can already decide on the result of the optimization without
 184         ;; even taking a look at the dimensions.
 185         (flet ((subscript-bounds (subscript)
 186                  (let* ((type1 (lvar-type subscript))
 187                         (type2 (if (csubtypep type1 (specifier-type 'integer))
 188                                    (weaken-integer-type type1 :range-only t)
 189                                    (give-up)))
 190                         (low (if (integer-type-p type2)
 191                                  (numeric-type-low type2)
 192                                  (give-up)))
 193                         (high (numeric-type-high type2)))
 194                    (cond
 195                      ((and (or (not (bound-known-p low)) (minusp low))
 196                            (or (not (bound-known-p high)) (not (minusp high))))
 197                       ;; can't be sure about the lower bound and the upper bound
 198                       ;; does not give us a definite clue either.
 199                       (give-up))
 200                      ((and (bound-known-p high) (minusp high))
 201                       (return nil))     ; definitely below lower bound (zero).
 202                      (t
 203                       (cons low high))))))
 204           (let* ((subscripts-bounds (mapcar #'subscript-bounds subscripts))
 205                  (subscripts-lower-bound (mapcar #'car subscripts-bounds))
 206                  (subscripts-upper-bound (mapcar #'cdr subscripts-bounds))
 207                  (in-bounds 0))
 208             (mapcar (lambda (low high dim)
 209                       (cond
 210                         ;; first deal with infinite bounds
 211                         ((some (complement #'bound-known-p) (list low high dim))
 212                          (when (and (bound-known-p dim) (bound-known-p low) (<= dim low))
 213                            (return nil)))
 214                         ;; now we know all bounds
 215                         ((>= low dim)
 216                          (return nil))
 217                         ((< high dim)
 218                          (aver (not (minusp low)))
 219                          (incf in-bounds))
 220                         (t
 221                          (give-up))))
 222                     subscripts-lower-bound
 223                     subscripts-upper-bound
 224                     dimensions)
 225             (if (eql in-bounds (length dimensions))
 226                 t
 227                 (give-up))))))))
 228
 229 (defoptimizer (aref derive-type) ((array &rest indices) node)
 230   (assert-array-rank array (length indices))
 231   (derive-aref-type array))
 232
 233 (defoptimizer ((setf aref) derive-type) ((new-value array &rest subscripts))
 234   (assert-array-rank array (length subscripts))
 235   (assert-new-value-type new-value array))
 236
 237 (macrolet ((define (name)
 238              `(defoptimizer (,name derive-type) ((array index))
 239                 (derive-aref-type array))))
 240   (define hairy-data-vector-ref)
 241   (define hairy-data-vector-ref/check-bounds)
 242   (define data-vector-ref))
 243
 244 #!+(or x86 x86-64)
 245 (defoptimizer (data-vector-ref-with-offset derive-type) ((array index offset))
 246   (derive-aref-type array))
 247
 248 (macrolet ((define (name)
 249              `(defoptimizer (,name derive-type) ((array index new-value))
 250                 (assert-new-value-type new-value array))))
 251   (define hairy-data-vector-set)
 252   (define hairy-data-vector-set/check-bounds)
 253   (define data-vector-set))
 254
 255 #!+(or x86 x86-64)
 256 (defoptimizer (data-vector-set-with-offset derive-type) ((array index offset new-value))
 257   (assert-new-value-type new-value array))
 258
 259 ;;; Figure out the type of the data vector if we know the argument
 260 ;;; element type.
 261 (defun derive-%with-array-data/mumble-type (array)
 262   (let ((atype (lvar-type array)))
 263     (when (array-type-p atype)
 264       (specifier-type
 265        `(simple-array ,(type-specifier
 266                         (array-type-specialized-element-type atype))
 267                       (*))))))
 268 (defoptimizer (%with-array-data derive-type) ((array start end))
 269   (derive-%with-array-data/mumble-type array))
 270 (defoptimizer (%with-array-data/fp derive-type) ((array start end))
 271   (derive-%with-array-data/mumble-type array))
 272
 273 (defoptimizer (array-row-major-index derive-type) ((array &rest indices))
 274   (assert-array-rank array (length indices))
 275   *universal-type*)
 276
 277 (defoptimizer (row-major-aref derive-type) ((array index))
 278   (derive-aref-type array))
 279
 280 (defoptimizer (%set-row-major-aref derive-type) ((array index new-value))
 281   (assert-new-value-type new-value array))
 282
 283 (defun derive-make-array-type (dims element-type adjustable
 284                                fill-pointer displaced-to)
 285   (let* ((simple (and (unsupplied-or-nil adjustable)
 286                       (unsupplied-or-nil displaced-to)
 287                       (unsupplied-or-nil fill-pointer)))
 288          (spec
 289            (or `(,(if simple 'simple-array 'array)
 290                  ,(cond ((not element-type) t)
 291                         ((ctype-p element-type)
 292                          (type-specifier element-type))
 293                         ((constant-lvar-p element-type)
 294                          (let ((ctype (careful-specifier-type
 295                                        (lvar-value element-type))))
 296                            (cond
 297                              ((or (null ctype) (contains-unknown-type-p ctype)) '*)
 298                              (t (sb!xc:upgraded-array-element-type
 299                                  (lvar-value element-type))))))
 300                         (t
 301                          '*))
 302                  ,(cond ((constant-lvar-p dims)
 303                          (let* ((val (lvar-value dims))
 304                                 (cdims (if (listp val) val (list val))))
 305                            (if simple
 306                                cdims
 307                                (length cdims))))
 308                         ((csubtypep (lvar-type dims)
 309                                     (specifier-type 'integer))
 310                          '(*))
 311                         (t
 312                          '*)))
 313                'array)))
 314     (if (and (not simple)
 315              (or (supplied-and-true adjustable)
 316                  (supplied-and-true displaced-to)
 317                  (supplied-and-true fill-pointer)))
 318         (careful-specifier-type `(and ,spec (not simple-array)))
 319         (careful-specifier-type spec))))
 320
 321 (defoptimizer (make-array derive-type)
 322     ((dims &key element-type adjustable fill-pointer displaced-to))
 323   (derive-make-array-type dims element-type adjustable
 324                           fill-pointer displaced-to))
 325
 326 (defoptimizer (%make-array derive-type)
 327     ((dims widetag n-bits &key adjustable fill-pointer displaced-to))
 328   (declare (ignore n-bits))
 329   (let ((saetp (and (constant-lvar-p widetag)
 330                     (find (lvar-value widetag)
 331                           sb!vm:*specialized-array-element-type-properties*
 332                           :key #'sb!vm:saetp-typecode))))
 333     (derive-make-array-type dims (if saetp
 334                                      (sb!vm:saetp-ctype saetp)
 335                                      *wild-type*)
 336                             adjustable fill-pointer displaced-to)))
 337
 338 \f
 339 ;;;; constructors
 340
 341 ;;; Convert VECTOR into a MAKE-ARRAY.
 342 (define-source-transform vector (&rest elements)
 343   `(make-array ,(length elements) :initial-contents (list ,@elements)))
 344
 345 ;;; Just convert it into a MAKE-ARRAY.
 346 (deftransform make-string ((length &key
 347                                    (element-type 'character)
 348                                    (initial-element
 349                                     #.*default-init-char-form*)))
 350   `(the simple-string (make-array (the index length)
 351                        :element-type element-type
 352                        ,@(when initial-element
 353                            '(:initial-element initial-element)))))
 354
 355 (defun rewrite-initial-contents (rank initial-contents env)
 356   (if (plusp rank)
 357       (if (and (consp initial-contents)
 358                (member (car initial-contents) '(list vector sb!impl::backq-list)))
 359           `(list ,@(mapcar (lambda (dim)
 360                              (rewrite-initial-contents (1- rank) dim env))
 361                            (cdr initial-contents)))
 362           initial-contents)
 363       ;; This is the important bit: once we are past the level of
 364       ;; :INITIAL-CONTENTS that relates to the array structure, reinline LIST
 365       ;; and VECTOR so that nested DX isn't screwed up.
 366       `(locally (declare (inline list vector))
 367          ,initial-contents)))
 368
 369 ;;; Prevent open coding DIMENSION and :INITIAL-CONTENTS arguments, so that we
 370 ;;; can pick them apart in the DEFTRANSFORMS, and transform '(3) style
 371 ;;; dimensions to integer args directly.
 372 (define-source-transform make-array (dimensions &rest keyargs &environment env)
 373   (if (or (and (fun-lexically-notinline-p 'list)
 374                (fun-lexically-notinline-p 'vector))
 375           (oddp (length keyargs)))
 376       (values nil t)
 377       (multiple-value-bind (new-dimensions rank)
 378           (flet ((constant-dims (dimensions)
 379                    (let* ((dims (constant-form-value dimensions env))
 380                           (canon (if (listp dims) dims (list dims)))
 381                           (rank (length canon)))
 382                      (values (if (= rank 1)
 383                                  (list 'quote (car canon))
 384                                  (list 'quote canon))
 385                              rank))))
 386             (cond ((sb!xc:constantp dimensions env)
 387                    (constant-dims dimensions))
 388                   ((and (consp dimensions) (eq 'list dimensions))
 389                    (values dimensions (length (cdr dimensions))))
 390                   (t
 391                    (values dimensions nil))))
 392         (let ((initial-contents (getf keyargs :initial-contents)))
 393           (when (and initial-contents rank)
 394             (setf keyargs (copy-list keyargs)
 395                   (getf keyargs :initial-contents)
 396                   (rewrite-initial-contents rank initial-contents env))))
 397         `(locally (declare (notinline list vector))
 398            (make-array ,new-dimensions ,@keyargs)))))
 399
 400 ;;; This baby is a bit of a monster, but it takes care of any MAKE-ARRAY
 401 ;;; call which creates a vector with a known element type -- and tries
 402 ;;; to do a good job with all the different ways it can happen.
 403 (defun transform-make-array-vector (length element-type initial-element
 404                                     initial-contents call)
 405   (aver (or (not element-type) (constant-lvar-p element-type)))
 406   (let* ((c-length (when (constant-lvar-p length)
 407                      (lvar-value length)))
 408          (elt-spec (if element-type
 409                        (lvar-value element-type)
 410                        t))
 411          (elt-ctype (ir1-transform-specifier-type elt-spec))
 412          (saetp (if (unknown-type-p elt-ctype)
 413                     (give-up-ir1-transform "~S is an unknown type: ~S"
 414                                            :element-type elt-spec)
 415                     (find-saetp-by-ctype elt-ctype)))
 416          (default-initial-element (sb!vm:saetp-initial-element-default saetp))
 417          (n-bits (sb!vm:saetp-n-bits saetp))
 418          (typecode (sb!vm:saetp-typecode saetp))
 419          (n-pad-elements (sb!vm:saetp-n-pad-elements saetp))
 420          (n-words-form
 421           (if c-length
 422               (ceiling (* (+ c-length n-pad-elements) n-bits)
 423                        sb!vm:n-word-bits)
 424               (let ((padded-length-form (if (zerop n-pad-elements)
 425                                             'length
 426                                             `(+ length ,n-pad-elements))))
 427                 (cond
 428                   ((= n-bits 0) 0)
 429                   ((>= n-bits sb!vm:n-word-bits)
 430                    `(* ,padded-length-form
 431                        ;; i.e., not RATIO
 432                        ,(the fixnum (/ n-bits sb!vm:n-word-bits))))
 433                   (t
 434                    (let ((n-elements-per-word (/ sb!vm:n-word-bits n-bits)))
 435                      (declare (type index n-elements-per-word)) ; i.e., not RATIO
 436                      `(ceiling (truly-the index ,padded-length-form)
 437                                ,n-elements-per-word)))))))
 438          (result-spec
 439           `(simple-array ,(sb!vm:saetp-specifier saetp) (,(or c-length '*))))
 440          (alloc-form
 441            `(truly-the ,result-spec
 442                        (allocate-vector ,typecode (the index length) ,n-words-form))))
 443     (cond ((and initial-element initial-contents)
 444            (abort-ir1-transform "Both ~S and ~S specified."
 445                                 :initial-contents :initial-element))
 446           ;; :INITIAL-CONTENTS (LIST ...), (VECTOR ...) and `(1 1 ,x) with a
 447           ;; constant LENGTH.
 448           ((and initial-contents c-length
 449                 (lvar-matches initial-contents
 450                               :fun-names '(list vector sb!impl::backq-list)
 451                               :arg-count c-length))
 452            (let ((parameters (eliminate-keyword-args
 453                               call 1 '((:element-type element-type)
 454                                        (:initial-contents initial-contents))))
 455                  (elt-vars (make-gensym-list c-length))
 456                  (lambda-list '(length)))
 457              (splice-fun-args initial-contents :any c-length)
 458              (dolist (p parameters)
 459                (setf lambda-list
 460                      (append lambda-list
 461                              (if (eq p 'initial-contents)
 462                                  elt-vars
 463                                  (list p)))))
 464              `(lambda ,lambda-list
 465                 (declare (type ,elt-spec ,@elt-vars)
 466                          (ignorable ,@lambda-list))
 467                 (truly-the ,result-spec
 468                  (initialize-vector ,alloc-form ,@elt-vars)))))
 469           ;; constant :INITIAL-CONTENTS and LENGTH
 470           ((and initial-contents c-length (constant-lvar-p initial-contents))
 471            (let ((contents (lvar-value initial-contents)))
 472              (unless (= c-length (length contents))
 473                (abort-ir1-transform "~S has ~S elements, vector length is ~S."
 474                                     :initial-contents (length contents) c-length))
 475              (let ((parameters (eliminate-keyword-args
 476                                 call 1 '((:element-type element-type)
 477                                          (:initial-contents initial-contents)))))
 478                `(lambda (length ,@parameters)
 479                   (declare (ignorable ,@parameters))
 480                   (truly-the ,result-spec
 481                    (initialize-vector ,alloc-form
 482                                       ,@(map 'list (lambda (elt)
 483                                                      `(the ,elt-spec ',elt))
 484                                              contents)))))))
 485           ;; any other :INITIAL-CONTENTS
 486           (initial-contents
 487            (let ((parameters (eliminate-keyword-args
 488                               call 1 '((:element-type element-type)
 489                                        (:initial-contents initial-contents)))))
 490              `(lambda (length ,@parameters)
 491                 (declare (ignorable ,@parameters))
 492                 (unless (= length (length initial-contents))
 493                   (error "~S has ~S elements, vector length is ~S."
 494                          :initial-contents (length initial-contents) length))
 495                 (truly-the ,result-spec
 496                            (replace ,alloc-form initial-contents)))))
 497           ;; :INITIAL-ELEMENT, not EQL to the default
 498           ((and initial-element
 499                 (or (not (constant-lvar-p initial-element))
 500                     (not (eql default-initial-element (lvar-value initial-element)))))
 501            (let ((parameters (eliminate-keyword-args
 502                               call 1 '((:element-type element-type)
 503                                        (:initial-element initial-element))))
 504                  (init (if (constant-lvar-p initial-element)
 505                            (list 'quote (lvar-value initial-element))
 506                            'initial-element)))
 507              `(lambda (length ,@parameters)
 508                 (declare (ignorable ,@parameters))
 509                 (truly-the ,result-spec
 510                            (fill ,alloc-form (the ,elt-spec ,init))))))
 511           ;; just :ELEMENT-TYPE, or maybe with :INITIAL-ELEMENT EQL to the
 512           ;; default
 513           (t
 514            #-sb-xc-host
 515            (unless (ctypep default-initial-element elt-ctype)
 516              ;; This situation arises e.g. in (MAKE-ARRAY 4 :ELEMENT-TYPE
 517              ;; '(INTEGER 1 5)) ANSI's definition of MAKE-ARRAY says "If
 518              ;; INITIAL-ELEMENT is not supplied, the consequences of later
 519              ;; reading an uninitialized element of new-array are undefined,"
 520              ;; so this could be legal code as long as the user plans to
 521              ;; write before he reads, and if he doesn't we're free to do
 522              ;; anything we like. But in case the user doesn't know to write
 523              ;; elements before he reads elements (or to read manuals before
 524              ;; he writes code:-), we'll signal a STYLE-WARNING in case he
 525              ;; didn't realize this.
 526              (if initial-element
 527                  (compiler-warn "~S ~S is not a ~S"
 528                                 :initial-element default-initial-element
 529                                 elt-spec)
 530                  (compiler-style-warn "The default initial element ~S is not a ~S."
 531                                       default-initial-element
 532                                       elt-spec)))
 533            (let ((parameters (eliminate-keyword-args
 534                               call 1 '((:element-type element-type)
 535                                        (:initial-element initial-element)))))
 536              `(lambda (length ,@parameters)
 537                 (declare (ignorable ,@parameters))
 538                 ,alloc-form))))))
 539
 540 ;;; IMPORTANT: The order of these three MAKE-ARRAY forms matters: the least
 541 ;;; specific must come first, otherwise suboptimal transforms will result for
 542 ;;; some forms.
 543
 544 (deftransform make-array ((dims &key initial-element element-type
 545                                      adjustable fill-pointer)
 546                           (t &rest *) *
 547                           :node node)
 548   (delay-ir1-transform node :constraint)
 549   (let* ((eltype (cond ((not element-type) t)
 550                        ((not (constant-lvar-p element-type))
 551                         (give-up-ir1-transform
 552                          "ELEMENT-TYPE is not constant."))
 553                        (t
 554                         (lvar-value element-type))))
 555          (eltype-type (ir1-transform-specifier-type eltype))
 556          (saetp (if (unknown-type-p eltype-type)
 557                     (give-up-ir1-transform
 558                      "ELEMENT-TYPE ~s is not a known type"
 559                      eltype-type)
 560                     (find eltype-type
 561                           sb!vm:*specialized-array-element-type-properties*
 562                           :key #'sb!vm:saetp-ctype
 563                           :test #'csubtypep)))
 564          (creation-form `(%make-array
 565                           dims
 566                           ,(if saetp
 567                                (sb!vm:saetp-typecode saetp)
 568                                (give-up-ir1-transform))
 569                           ,(sb!vm:saetp-n-bits saetp)
 570                           ,@(when fill-pointer
 571                               '(:fill-pointer fill-pointer))
 572                           ,@(when adjustable
 573                               '(:adjustable adjustable)))))
 574     (cond ((or (not initial-element)
 575                (and (constant-lvar-p initial-element)
 576                     (eql (lvar-value initial-element)
 577                          (sb!vm:saetp-initial-element-default saetp))))
 578            creation-form)
 579           (t
 580            ;; error checking for target, disabled on the host because
 581            ;; (CTYPE-OF #\Null) is not possible.
 582            #-sb-xc-host
 583            (when (constant-lvar-p initial-element)
 584              (let ((value (lvar-value initial-element)))
 585                (cond
 586                  ((not (ctypep value (sb!vm:saetp-ctype saetp)))
 587                   ;; this case will cause an error at runtime, so we'd
 588                   ;; better WARN about it now.
 589                   (warn 'array-initial-element-mismatch
 590                         :format-control "~@<~S is not a ~S (which is the ~
 591                                          ~S of ~S).~@:>"
 592                         :format-arguments
 593                         (list
 594                          value
 595                          (type-specifier (sb!vm:saetp-ctype saetp))
 596                          'upgraded-array-element-type
 597                          eltype)))
 598                  ((not (ctypep value eltype-type))
 599                   ;; this case will not cause an error at runtime, but
 600                   ;; it's still worth STYLE-WARNing about.
 601                   (compiler-style-warn "~S is not a ~S."
 602                                        value eltype)))))
 603            `(let ((array ,creation-form))
 604               (multiple-value-bind (vector)
 605                   (%data-vector-and-index array 0)
 606                 (fill vector (the ,(sb!vm:saetp-specifier saetp) initial-element)))
 607               array)))))
 608
 609 ;;; The list type restriction does not ensure that the result will be a
 610 ;;; multi-dimensional array. But the lack of adjustable, fill-pointer,
 611 ;;; and displaced-to keywords ensures that it will be simple.
 612 ;;;
 613 ;;; FIXME: should we generalize this transform to non-simple (though
 614 ;;; non-displaced-to) arrays, given that we have %WITH-ARRAY-DATA to
 615 ;;; deal with those? Maybe when the DEFTRANSFORM
 616 ;;; %DATA-VECTOR-AND-INDEX in the VECTOR case problem is solved? --
 617 ;;; CSR, 2002-07-01
 618 (deftransform make-array ((dims &key
 619                                 element-type initial-element initial-contents)
 620                           (list &key
 621                                 (:element-type (constant-arg *))
 622                                 (:initial-element *)
 623                                 (:initial-contents *))
 624                           *
 625                           :node call)
 626   (block make-array
 627     (when (lvar-matches dims :fun-names '(list) :arg-count 1)
 628       (let ((length (car (splice-fun-args dims :any 1))))
 629         (return-from make-array
 630           (transform-make-array-vector length
 631                                        element-type
 632                                        initial-element
 633                                        initial-contents
 634                                        call))))
 635     (unless (constant-lvar-p dims)
 636       (give-up-ir1-transform
 637        "The dimension list is not constant; cannot open code array creation."))
 638     (let ((dims (lvar-value dims))
 639           (element-type-ctype (and (constant-lvar-p element-type)
 640                                    (ir1-transform-specifier-type
 641                                     (lvar-value element-type)))))
 642       (when (contains-unknown-type-p element-type-ctype)
 643         (give-up-ir1-transform))
 644       (unless (every #'integerp dims)
 645         (give-up-ir1-transform
 646          "The dimension list contains something other than an integer: ~S"
 647          dims))
 648       (if (= (length dims) 1)
 649           `(make-array ',(car dims)
 650                        ,@(when element-type
 651                                '(:element-type element-type))
 652                        ,@(when initial-element
 653                                '(:initial-element initial-element))
 654                        ,@(when initial-contents
 655                                '(:initial-contents initial-contents)))
 656           (let* ((total-size (reduce #'* dims))
 657                  (rank (length dims))
 658                  (spec `(simple-array
 659                          ,(cond ((null element-type) t)
 660                                 (element-type-ctype
 661                                  (sb!xc:upgraded-array-element-type
 662                                   (lvar-value element-type)))
 663                                 (t '*))
 664                          ,(make-list rank :initial-element '*))))
 665             `(let ((header (make-array-header sb!vm:simple-array-widetag ,rank))
 666                    (data (make-array ,total-size
 667                                      ,@(when element-type
 668                                              '(:element-type element-type))
 669                                      ,@(when initial-element
 670                                              '(:initial-element initial-element)))))
 671                ,@(when initial-contents
 672                        ;; FIXME: This is could be open coded at least a bit too
 673                        `((sb!impl::fill-data-vector data ',dims initial-contents)))
 674                (setf (%array-fill-pointer header) ,total-size)
 675                (setf (%array-fill-pointer-p header) nil)
 676                (setf (%array-available-elements header) ,total-size)
 677                (setf (%array-data-vector header) data)
 678                (setf (%array-displaced-p header) nil)
 679                (setf (%array-displaced-from header) nil)
 680                ,@(let ((axis -1))
 681                       (mapcar (lambda (dim)
 682                                 `(setf (%array-dimension header ,(incf axis))
 683                                        ,dim))
 684                               dims))
 685                (truly-the ,spec header)))))))
 686
 687 (deftransform make-array ((dims &key element-type initial-element initial-contents)
 688                           (integer &key
 689                                    (:element-type (constant-arg *))
 690                                    (:initial-element *)
 691                                    (:initial-contents *))
 692                           *
 693                           :node call)
 694   (transform-make-array-vector dims
 695                                element-type
 696                                initial-element
 697                                initial-contents
 698                                call))
 699 \f
 700 ;;;; miscellaneous properties of arrays
 701
 702 ;;; Transforms for various array properties. If the property is know
 703 ;;; at compile time because of a type spec, use that constant value.
 704
 705 ;;; Most of this logic may end up belonging in code/late-type.lisp;
 706 ;;; however, here we also need the -OR-GIVE-UP for the transforms, and
 707 ;;; maybe this is just too sloppy for actual type logic.  -- CSR,
 708 ;;; 2004-02-18
 709 (defun array-type-dimensions-or-give-up (type)
 710   (labels ((maybe-array-type-dimensions (type)
 711              (typecase type
 712                (array-type
 713                 (array-type-dimensions type))
 714                (union-type
 715                 (let* ((types (remove nil (mapcar #'maybe-array-type-dimensions
 716                                                   (union-type-types type))))
 717                        (result (car types)))
 718                   (dolist (other (cdr types) result)
 719                     (unless (equal result other)
 720                       (give-up-ir1-transform
 721                        "~@<dimensions of arrays in union type ~S do not match~:@>"
 722                        (type-specifier type))))))
 723                (intersection-type
 724                 (let* ((types (remove nil (mapcar #'maybe-array-type-dimensions
 725                                                   (intersection-type-types type))))
 726                        (result (car types)))
 727                   (dolist (other (cdr types) result)
 728                     (unless (equal result other)
 729                       (abort-ir1-transform
 730                        "~@<dimensions of arrays in intersection type ~S do not match~:@>"
 731                        (type-specifier type)))))))))
 732     (or (maybe-array-type-dimensions type)
 733         (give-up-ir1-transform
 734          "~@<don't know how to extract array dimensions from type ~S~:@>"
 735          (type-specifier type)))))
 736
 737 (defun conservative-array-type-complexp (type)
 738   (typecase type
 739     (array-type (array-type-complexp type))
 740     (union-type
 741      (let ((types (union-type-types type)))
 742        (aver (> (length types) 1))
 743        (let ((result (conservative-array-type-complexp (car types))))
 744          (dolist (type (cdr types) result)
 745            (unless (eq (conservative-array-type-complexp type) result)
 746              (return-from conservative-array-type-complexp :maybe))))))
 747     ;; FIXME: intersection type
 748     (t :maybe)))
 749
 750 ;;; If we can tell the rank from the type info, use it instead.
 751 (deftransform array-rank ((array) (array) * :node node)
 752   (let ((array-type (lvar-type array)))
 753     (let ((dims (array-type-dimensions-or-give-up array-type)))
 754       (cond ((listp dims)
 755              (length dims))
 756             ((eq t (and (array-type-p array-type)
 757                         (array-type-complexp array-type)))
 758              '(%array-rank array))
 759             (t
 760              (delay-ir1-transform node :constraint)
 761              `(if (array-header-p array)
 762                   (%array-rank array)
 763                   1))))))
 764
 765 ;;; If we know the dimensions at compile time, just use it. Otherwise,
 766 ;;; if we can tell that the axis is in bounds, convert to
 767 ;;; %ARRAY-DIMENSION (which just indirects the array header) or length
 768 ;;; (if it's simple and a vector).
 769 (deftransform array-dimension ((array axis)
 770                                (array index))
 771   (unless (constant-lvar-p axis)
 772     (give-up-ir1-transform "The axis is not constant."))
 773   ;; Dimensions may change thanks to ADJUST-ARRAY, so we need the
 774   ;; conservative type.
 775   (let ((array-type (lvar-conservative-type array))
 776         (axis (lvar-value axis)))
 777     (let ((dims (array-type-dimensions-or-give-up array-type)))
 778       (unless (listp dims)
 779         (give-up-ir1-transform
 780          "The array dimensions are unknown; must call ARRAY-DIMENSION at runtime."))
 781       (unless (> (length dims) axis)
 782         (abort-ir1-transform "The array has dimensions ~S, ~W is too large."
 783                              dims
 784                              axis))
 785       (let ((dim (nth axis dims)))
 786         (cond ((integerp dim)
 787                dim)
 788               ((= (length dims) 1)
 789                (ecase (conservative-array-type-complexp array-type)
 790                  ((t)
 791                   '(%array-dimension array 0))
 792                  ((nil)
 793                   '(vector-length array))
 794                  ((:maybe)
 795                   `(if (array-header-p array)
 796                        (%array-dimension array axis)
 797                        (vector-length array)))))
 798               (t
 799                '(%array-dimension array axis)))))))
 800
 801 ;;; If the length has been declared and it's simple, just return it.
 802 (deftransform length ((vector)
 803                       ((simple-array * (*))))
 804   (let ((type (lvar-type vector)))
 805     (let ((dims (array-type-dimensions-or-give-up type)))
 806       (unless (and (listp dims) (integerp (car dims)))
 807         (give-up-ir1-transform
 808          "Vector length is unknown, must call LENGTH at runtime."))
 809       (car dims))))
 810
 811 ;;; All vectors can get their length by using VECTOR-LENGTH. If it's
 812 ;;; simple, it will extract the length slot from the vector. It it's
 813 ;;; complex, it will extract the fill pointer slot from the array
 814 ;;; header.
 815 (deftransform length ((vector) (vector))
 816   '(vector-length vector))
 817
 818 ;;; If a simple array with known dimensions, then VECTOR-LENGTH is a
 819 ;;; compile-time constant.
 820 (deftransform vector-length ((vector))
 821   (let ((vtype (lvar-type vector)))
 822     (let ((dim (first (array-type-dimensions-or-give-up vtype))))
 823       (when (eq dim '*)
 824         (give-up-ir1-transform))
 825       (when (conservative-array-type-complexp vtype)
 826         (give-up-ir1-transform))
 827       dim)))
 828
 829 ;;; Again, if we can tell the results from the type, just use it.
 830 ;;; Otherwise, if we know the rank, convert into a computation based
 831 ;;; on array-dimension. We can wrap a TRULY-THE INDEX around the
 832 ;;; multiplications because we know that the total size must be an
 833 ;;; INDEX.
 834 (deftransform array-total-size ((array)
 835                                 (array))
 836   (let ((array-type (lvar-type array)))
 837     (let ((dims (array-type-dimensions-or-give-up array-type)))
 838       (unless (listp dims)
 839         (give-up-ir1-transform "can't tell the rank at compile time"))
 840       (if (member '* dims)
 841           (do ((form 1 `(truly-the index
 842                                    (* (array-dimension array ,i) ,form)))
 843                (i 0 (1+ i)))
 844               ((= i (length dims)) form))
 845           (reduce #'* dims)))))
 846
 847 ;;; Only complex vectors have fill pointers.
 848 (deftransform array-has-fill-pointer-p ((array))
 849   (let ((array-type (lvar-type array)))
 850     (let ((dims (array-type-dimensions-or-give-up array-type)))
 851       (if (and (listp dims) (not (= (length dims) 1)))
 852           nil
 853           (ecase (conservative-array-type-complexp array-type)
 854             ((t)
 855              t)
 856             ((nil)
 857              nil)
 858             ((:maybe)
 859              (give-up-ir1-transform
 860               "The array type is ambiguous; must call ~
 861                ARRAY-HAS-FILL-POINTER-P at runtime.")))))))
 862
 863 ;;; Primitive used to verify indices into arrays. If we can tell at
 864 ;;; compile-time or we are generating unsafe code, don't bother with
 865 ;;; the VOP.
 866 (deftransform %check-bound ((array dimension index) * * :node node)
 867   (cond ((policy node (= insert-array-bounds-checks 0))
 868          'index)
 869         ((not (constant-lvar-p dimension))
 870          (give-up-ir1-transform))
 871         (t
 872          (let ((dim (lvar-value dimension)))
 873            ;; FIXME: Can SPEED > SAFETY weaken this check to INTEGER?
 874            `(the (integer 0 (,dim)) index)))))
 875 \f
 876 ;;;; WITH-ARRAY-DATA
 877
 878 ;;; This checks to see whether the array is simple and the start and
 879 ;;; end are in bounds. If so, it proceeds with those values.
 880 ;;; Otherwise, it calls %WITH-ARRAY-DATA. Note that %WITH-ARRAY-DATA
 881 ;;; may be further optimized.
 882 ;;;
 883 ;;; Given any ARRAY, bind DATA-VAR to the array's data vector and
 884 ;;; START-VAR and END-VAR to the start and end of the designated
 885 ;;; portion of the data vector. SVALUE and EVALUE are any start and
 886 ;;; end specified to the original operation, and are factored into the
 887 ;;; bindings of START-VAR and END-VAR. OFFSET-VAR is the cumulative
 888 ;;; offset of all displacements encountered, and does not include
 889 ;;; SVALUE.
 890 ;;;
 891 ;;; When FORCE-INLINE is set, the underlying %WITH-ARRAY-DATA form is
 892 ;;; forced to be inline, overriding the ordinary judgment of the
 893 ;;; %WITH-ARRAY-DATA DEFTRANSFORMs. Ordinarily the DEFTRANSFORMs are
 894 ;;; fairly picky about their arguments, figuring that if you haven't
 895 ;;; bothered to get all your ducks in a row, you probably don't care
 896 ;;; that much about speed anyway! But in some cases it makes sense to
 897 ;;; do type testing inside %WITH-ARRAY-DATA instead of outside, and
 898 ;;; the DEFTRANSFORM can't tell that that's going on, so it can make
 899 ;;; sense to use FORCE-INLINE option in that case.
 900 (def!macro with-array-data (((data-var array &key offset-var)
 901                              (start-var &optional (svalue 0))
 902                              (end-var &optional (evalue nil))
 903                              &key force-inline check-fill-pointer)
 904                             &body forms
 905                             &environment env)
 906   (once-only ((n-array array)
 907               (n-svalue `(the index ,svalue))
 908               (n-evalue `(the (or index null) ,evalue)))
 909     (let ((check-bounds (policy env (plusp insert-array-bounds-checks))))
 910       `(multiple-value-bind (,data-var
 911                              ,start-var
 912                              ,end-var
 913                              ,@(when offset-var `(,offset-var)))
 914            (if (not (array-header-p ,n-array))
 915                (let ((,n-array ,n-array))
 916                  (declare (type (simple-array * (*)) ,n-array))
 917                  ,(once-only ((n-len (if check-fill-pointer
 918                                          `(length ,n-array)
 919                                          `(array-total-size ,n-array)))
 920                               (n-end `(or ,n-evalue ,n-len)))
 921                              (if check-bounds
 922                                  `(if (<= 0 ,n-svalue ,n-end ,n-len)
 923                                       (values ,n-array ,n-svalue ,n-end 0)
 924                                       ,(if check-fill-pointer
 925                                            `(sequence-bounding-indices-bad-error ,n-array ,n-svalue ,n-evalue)
 926                                            `(array-bounding-indices-bad-error ,n-array ,n-svalue ,n-evalue)))
 927                                  `(values ,n-array ,n-svalue ,n-end 0))))
 928                ,(if force-inline
 929                     `(%with-array-data-macro ,n-array ,n-svalue ,n-evalue
 930                                              :check-bounds ,check-bounds
 931                                              :check-fill-pointer ,check-fill-pointer)
 932                     (if check-fill-pointer
 933                         `(%with-array-data/fp ,n-array ,n-svalue ,n-evalue)
 934                         `(%with-array-data ,n-array ,n-svalue ,n-evalue))))
 935          ,@forms))))
 936
 937 ;;; This is the fundamental definition of %WITH-ARRAY-DATA, for use in
 938 ;;; DEFTRANSFORMs and DEFUNs.
 939 (def!macro %with-array-data-macro (array
 940                                    start
 941                                    end
 942                                    &key
 943                                    (element-type '*)
 944                                    check-bounds
 945                                    check-fill-pointer)
 946   (with-unique-names (size defaulted-end data cumulative-offset)
 947     `(let* ((,size ,(if check-fill-pointer
 948                         `(length ,array)
 949                         `(array-total-size ,array)))
 950             (,defaulted-end (or ,end ,size)))
 951        ,@(when check-bounds
 952                `((unless (<= ,start ,defaulted-end ,size)
 953                    ,(if check-fill-pointer
 954                         `(sequence-bounding-indices-bad-error ,array ,start ,end)
 955                         `(array-bounding-indices-bad-error ,array ,start ,end)))))
 956        (do ((,data ,array (%array-data-vector ,data))
 957             (,cumulative-offset 0
 958                                 (+ ,cumulative-offset
 959                                    (%array-displacement ,data))))
 960            ((not (array-header-p ,data))
 961             (values (the (simple-array ,element-type 1) ,data)
 962                     (the index (+ ,cumulative-offset ,start))
 963                     (the index (+ ,cumulative-offset ,defaulted-end))
 964                     (the index ,cumulative-offset)))
 965          (declare (type index ,cumulative-offset))))))
 966
 967 (defun transform-%with-array-data/muble (array node check-fill-pointer)
 968   (let ((element-type (upgraded-element-type-specifier-or-give-up array))
 969         (type (lvar-type array))
 970         (check-bounds (policy node (plusp insert-array-bounds-checks))))
 971     (if (and (array-type-p type)
 972              (not (array-type-complexp type))
 973              (listp (array-type-dimensions type))
 974              (not (null (cdr (array-type-dimensions type)))))
 975         ;; If it's a simple multidimensional array, then just return
 976         ;; its data vector directly rather than going through
 977         ;; %WITH-ARRAY-DATA-MACRO. SBCL doesn't generally generate
 978         ;; code that would use this currently, but we have encouraged
 979         ;; users to use WITH-ARRAY-DATA and we may use it ourselves at
 980         ;; some point in the future for optimized libraries or
 981         ;; similar.
 982         (if check-bounds
 983             `(let* ((data (truly-the (simple-array ,element-type (*))
 984                                      (%array-data-vector array)))
 985                     (len (length data))
 986                     (real-end (or end len)))
 987                (unless (<= 0 start data-end lend)
 988                  (sequence-bounding-indices-bad-error array start end))
 989                (values data 0 real-end 0))
 990             `(let ((data (truly-the (simple-array ,element-type (*))
 991                                     (%array-data-vector array))))
 992                (values data 0 (or end (length data)) 0)))
 993         `(%with-array-data-macro array start end
 994                                  :check-fill-pointer ,check-fill-pointer
 995                                  :check-bounds ,check-bounds
 996                                  :element-type ,element-type))))
 997
 998 ;; It might very well be reasonable to allow general ARRAY here, I
 999 ;; just haven't tried to understand the performance issues involved.
1000 ;; -- WHN, and also CSR 2002-05-26
1001 (deftransform %with-array-data ((array start end)
1002                                 ((or vector simple-array) index (or index null) t)
1003                                 *
1004                                 :node node
1005                                 :policy (> speed space))
1006   "inline non-SIMPLE-vector-handling logic"
1007   (transform-%with-array-data/muble array node nil))
1008 (deftransform %with-array-data/fp ((array start end)
1009                                 ((or vector simple-array) index (or index null) t)
1010                                 *
1011                                 :node node
1012                                 :policy (> speed space))
1013   "inline non-SIMPLE-vector-handling logic"
1014   (transform-%with-array-data/muble array node t))
1015 \f
1016 ;;;; array accessors
1017
1018 ;;; We convert all typed array accessors into AREF and (SETF AREF) with type
1019 ;;; assertions on the array.
1020 (macrolet ((define-bit-frob (reffer simplep)
1021              `(progn
1022                 (define-source-transform ,reffer (a &rest i)
1023                   `(aref (the (,',(if simplep 'simple-array 'array)
1024                                   bit
1025                                   ,(mapcar (constantly '*) i))
1026                            ,a) ,@i))
1027                 (define-source-transform (setf ,reffer) (value a &rest i)
1028                   `(setf (aref (the (,',(if simplep 'simple-array 'array)
1029                                      bit
1030                                      ,(mapcar (constantly '*) i))
1031                                     ,a) ,@i)
1032                          ,value)))))
1033   (define-bit-frob sbit t)
1034   (define-bit-frob bit nil))
1035
1036 (macrolet ((define-frob (reffer setter type)
1037              `(progn
1038                 (define-source-transform ,reffer (a i)
1039                   `(aref (the ,',type ,a) ,i))
1040                 (define-source-transform ,setter (a i v)
1041                   `(setf (aref (the ,',type ,a) ,i) ,v)))))
1042   (define-frob schar %scharset simple-string)
1043   (define-frob char %charset string))
1044
1045 ;;; We transform SVREF and %SVSET directly into DATA-VECTOR-REF/SET: this is
1046 ;;; around 100 times faster than going through the general-purpose AREF
1047 ;;; transform which ends up doing a lot of work -- and introducing many
1048 ;;; intermediate lambdas, each meaning a new trip through the compiler -- to
1049 ;;; get the same result.
1050 ;;;
1051 ;;; FIXME: [S]CHAR, and [S]BIT above would almost certainly benefit from a similar
1052 ;;; treatment.
1053 (define-source-transform svref (vector index)
1054   (let ((elt-type (or (when (symbolp vector)
1055                         (let ((var (lexenv-find vector vars)))
1056                           (when (lambda-var-p var)
1057                             (type-specifier
1058                              (array-type-declared-element-type (lambda-var-type var))))))
1059                       t)))
1060     (with-unique-names (n-vector)
1061       `(let ((,n-vector ,vector))
1062          (the ,elt-type (data-vector-ref
1063                          (the simple-vector ,n-vector)
1064                          (%check-bound ,n-vector (length ,n-vector) ,index)))))))
1065
1066 (define-source-transform %svset (vector index value)
1067   (let ((elt-type (or (when (symbolp vector)
1068                         (let ((var (lexenv-find vector vars)))
1069                           (when (lambda-var-p var)
1070                             (type-specifier
1071                              (array-type-declared-element-type (lambda-var-type var))))))
1072                       t)))
1073     (with-unique-names (n-vector)
1074       `(let ((,n-vector ,vector))
1075          (truly-the ,elt-type (data-vector-set
1076                                (the simple-vector ,n-vector)
1077                                (%check-bound ,n-vector (length ,n-vector) ,index)
1078                                (the ,elt-type ,value)))))))
1079
1080 (macrolet (;; This is a handy macro for computing the row-major index
1081            ;; given a set of indices. We wrap each index with a call
1082            ;; to %CHECK-BOUND to ensure that everything works out
1083            ;; correctly. We can wrap all the interior arithmetic with
1084            ;; TRULY-THE INDEX because we know the resultant
1085            ;; row-major index must be an index.
1086            (with-row-major-index ((array indices index &optional new-value)
1087                                   &rest body)
1088              `(let (n-indices dims)
1089                 (dotimes (i (length ,indices))
1090                   (push (make-symbol (format nil "INDEX-~D" i)) n-indices)
1091                   (push (make-symbol (format nil "DIM-~D" i)) dims))
1092                 (setf n-indices (nreverse n-indices))
1093                 (setf dims (nreverse dims))
1094                 `(lambda (,@',(when new-value (list new-value))
1095                           ,',array ,@n-indices)
1096                    (declare (ignorable ,',array))
1097                    (let* (,@(let ((,index -1))
1098                               (mapcar (lambda (name)
1099                                         `(,name (array-dimension
1100                                                  ,',array
1101                                                  ,(incf ,index))))
1102                                       dims))
1103                             (,',index
1104                              ,(if (null dims)
1105                                   0
1106                                 (do* ((dims dims (cdr dims))
1107                                       (indices n-indices (cdr indices))
1108                                       (last-dim nil (car dims))
1109                                       (form `(%check-bound ,',array
1110                                                            ,(car dims)
1111                                                            ,(car indices))
1112                                             `(truly-the
1113                                               index
1114                                               (+ (truly-the index
1115                                                             (* ,form
1116                                                                ,last-dim))
1117                                                  (%check-bound
1118                                                   ,',array
1119                                                   ,(car dims)
1120                                                   ,(car indices))))))
1121                                     ((null (cdr dims)) form)))))
1122                      ,',@body)))))
1123
1124   ;; Just return the index after computing it.
1125   (deftransform array-row-major-index ((array &rest indices))
1126     (with-row-major-index (array indices index)
1127       index))
1128
1129   ;; Convert AREF and (SETF AREF) into a HAIRY-DATA-VECTOR-REF (or
1130   ;; HAIRY-DATA-VECTOR-SET) with the set of indices replaced with the an
1131   ;; expression for the row major index.
1132   (deftransform aref ((array &rest indices))
1133     (with-row-major-index (array indices index)
1134       (hairy-data-vector-ref array index)))
1135
1136   (deftransform (setf aref) ((new-value array &rest subscripts))
1137     (with-row-major-index (array subscripts index new-value)
1138                           (hairy-data-vector-set array index new-value))))
1139
1140 ;; For AREF of vectors we do the bounds checking in the callee. This
1141 ;; lets us do a significantly more efficient check for simple-arrays
1142 ;; without bloating the code. If we already know the type of the array
1143 ;; with sufficient precision, skip directly to DATA-VECTOR-REF.
1144 (deftransform aref ((array index) (t t) * :node node)
1145   (let* ((type (lvar-type array))
1146          (element-ctype (array-type-upgraded-element-type type)))
1147     (cond
1148       ((and (array-type-p type)
1149             (null (array-type-complexp type))
1150             (not (eql element-ctype *wild-type*))
1151             (eql (length (array-type-dimensions type)) 1))
1152        (let* ((declared-element-ctype (array-type-declared-element-type type))
1153               (bare-form
1154                `(data-vector-ref array
1155                  (%check-bound array (array-dimension array 0) index))))
1156          (if (type= declared-element-ctype element-ctype)
1157              bare-form
1158              `(the ,(type-specifier declared-element-ctype) ,bare-form))))
1159       ((policy node (zerop insert-array-bounds-checks))
1160        `(hairy-data-vector-ref array index))
1161       (t `(hairy-data-vector-ref/check-bounds array index)))))
1162
1163 (deftransform (setf aref) ((new-value array index) (t t t) * :node node)
1164   (if (policy node (zerop insert-array-bounds-checks))
1165       `(hairy-data-vector-set array index new-value)
1166       `(hairy-data-vector-set/check-bounds array index new-value)))
1167
1168 ;;; But if we find out later that there's some useful type information
1169 ;;; available, switch back to the normal one to give other transforms
1170 ;;; a stab at it.
1171 (macrolet ((define (name transform-to extra extra-type)
1172              (declare (ignore extra-type))
1173              `(deftransform ,name ((array index ,@extra))
1174                 (let* ((type (lvar-type array))
1175                        (element-type (array-type-upgraded-element-type type))
1176                        (declared-type (type-specifier
1177                                        (array-type-declared-element-type type))))
1178                   ;; If an element type has been declared, we want to
1179                   ;; use that information it for type checking (even
1180                   ;; if the access can't be optimized due to the array
1181                   ;; not being simple).
1182                   (when (and (eql element-type *wild-type*)
1183                              ;; This type logic corresponds to the special
1184                              ;; case for strings in HAIRY-DATA-VECTOR-REF
1185                              ;; (generic/vm-tran.lisp)
1186                              (not (csubtypep type (specifier-type 'simple-string))))
1187                     (when (or (not (array-type-p type))
1188                               ;; If it's a simple array, we might be able
1189                               ;; to inline the access completely.
1190                               (not (null (array-type-complexp type))))
1191                       (give-up-ir1-transform
1192                        "Upgraded element type of array is not known at compile time.")))
1193                   ,(if extra
1194                        ``(truly-the ,declared-type
1195                                     (,',transform-to array
1196                                                      (%check-bound array
1197                                                                    (array-dimension array 0)
1198                                                                    index)
1199                                                      (the ,declared-type ,@',extra)))
1200                        ``(the ,declared-type
1201                            (,',transform-to array
1202                                             (%check-bound array
1203                                                           (array-dimension array 0)
1204                                                           index))))))))
1205   (define hairy-data-vector-ref/check-bounds
1206       hairy-data-vector-ref nil nil)
1207   (define hairy-data-vector-set/check-bounds
1208       hairy-data-vector-set (new-value) (*)))
1209
1210 ;;; Just convert into a HAIRY-DATA-VECTOR-REF (or
1211 ;;; HAIRY-DATA-VECTOR-SET) after checking that the index is inside the
1212 ;;; array total size.
1213 (deftransform row-major-aref ((array index))
1214   `(hairy-data-vector-ref array
1215                           (%check-bound array (array-total-size array) index)))
1216 (deftransform %set-row-major-aref ((array index new-value))
1217   `(hairy-data-vector-set array
1218                           (%check-bound array (array-total-size array) index)
1219                           new-value))
1220 \f
1221 ;;;; bit-vector array operation canonicalization
1222 ;;;;
1223 ;;;; We convert all bit-vector operations to have the result array
1224 ;;;; specified. This allows any result allocation to be open-coded,
1225 ;;;; and eliminates the need for any VM-dependent transforms to handle
1226 ;;;; these cases.
1227
1228 (macrolet ((def (fun)
1229              `(progn
1230                (deftransform ,fun ((bit-array-1 bit-array-2
1231                                                 &optional result-bit-array)
1232                                    (bit-vector bit-vector &optional null) *
1233                                    :policy (>= speed space))
1234                  `(,',fun bit-array-1 bit-array-2
1235                    (make-array (array-dimension bit-array-1 0) :element-type 'bit)))
1236                ;; If result is T, make it the first arg.
1237                (deftransform ,fun ((bit-array-1 bit-array-2 result-bit-array)
1238                                    (bit-vector bit-vector (eql t)) *)
1239                  `(,',fun bit-array-1 bit-array-2 bit-array-1)))))
1240   (def bit-and)
1241   (def bit-ior)
1242   (def bit-xor)
1243   (def bit-eqv)
1244   (def bit-nand)
1245   (def bit-nor)
1246   (def bit-andc1)
1247   (def bit-andc2)
1248   (def bit-orc1)
1249   (def bit-orc2))
1250
1251 ;;; Similar for BIT-NOT, but there is only one arg...
1252 (deftransform bit-not ((bit-array-1 &optional result-bit-array)
1253                        (bit-vector &optional null) *
1254                        :policy (>= speed space))
1255   '(bit-not bit-array-1
1256             (make-array (array-dimension bit-array-1 0) :element-type 'bit)))
1257 (deftransform bit-not ((bit-array-1 result-bit-array)
1258                        (bit-vector (eql t)))
1259   '(bit-not bit-array-1 bit-array-1))
1260 \f
1261 ;;; Pick off some constant cases.
1262 (defoptimizer (array-header-p derive-type) ((array))
1263   (let ((type (lvar-type array)))
1264     (cond ((not (array-type-p type))
1265            ;; FIXME: use analogue of ARRAY-TYPE-DIMENSIONS-OR-GIVE-UP
1266            nil)
1267           (t
1268            (let ((dims (array-type-dimensions type)))
1269              (cond ((csubtypep type (specifier-type '(simple-array * (*))))
1270                     ;; no array header
1271                     (specifier-type 'null))
1272                    ((and (listp dims) (/= (length dims) 1))
1273                     ;; multi-dimensional array, will have a header
1274                     (specifier-type '(eql t)))
1275                    ((eql (array-type-complexp type) t)
1276                     (specifier-type '(eql t)))
1277                    (t
1278                     nil)))))))