src/compiler/knownfun.lisp

   1 ;;;; This file contains stuff for maintaining a database of special
   2 ;;;; information about functions known to the compiler. This includes
   3 ;;;; semantic information such as side effects and type inference
   4 ;;;; functions as well as transforms and IR2 translators.
   5
   6 ;;;; This software is part of the SBCL system. See the README file for
   7 ;;;; more information.
   8 ;;;;
   9 ;;;; This software is derived from the CMU CL system, which was
  10 ;;;; written at Carnegie Mellon University and released into the
  11 ;;;; public domain. The software is in the public domain and is
  12 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  13 ;;;; files for more information.
  14
  15 (in-package "SB!C")
  16
  17 (/show0 "knownfun.lisp 17")
  18
  19 ;;; IR1 boolean function attributes
  20 ;;;
  21 ;;; There are a number of boolean attributes of known functions which
  22 ;;; we like to have in IR1. This information is mostly side effect
  23 ;;; information of a sort, but it is different from the kind of
  24 ;;; information we want in IR2. We aren't interested in a fine
  25 ;;; breakdown of side effects, since we do very little code motion on
  26 ;;; IR1. We are interested in some deeper semantic properties such as
  27 ;;; whether it is safe to pass stack closures to.
  28 ;;;
  29 ;;; FIXME: This whole notion of "bad" explicit attributes is bad for
  30 ;;; maintenance. How confident are we that we have no defknowns for functions
  31 ;;; with functional arguments that are missing the CALL attribute? Much better
  32 ;;; to have NO-CALLS, as it is much less likely to break accidentally.
  33 (!def-boolean-attribute ir1
  34   ;; may call functions that are passed as arguments. In order to
  35   ;; determine what other effects are present, we must find the
  36   ;; effects of all arguments that may be functions.
  37   call
  38   ;; may fail to return during correct execution. Errors are O.K.
  39   ;; UNUSED, BEWARE OF BITROT.
  40   unwind
  41   ;; the (default) worst case. Includes all the other bad things, plus
  42   ;; any other possible bad thing. If this is present, the above bad
  43   ;; attributes will be explicitly present as well.
  44   any
  45   ;; all arguments are safe for dynamic extent.
  46   ;; (We used to have an UNSAFE attribute, which was basically the inverse
  47   ;; of this, but it was unused and bitrotted, so when we started making
  48   ;; use of the information we flipped the name and meaning the safe way
  49   ;; around.)
  50   dx-safe
  51   ;; may be constant-folded. The function has no side effects, but may
  52   ;; be affected by side effects on the arguments. e.g. SVREF, MAPC.
  53   ;; Functions that side-effect their arguments are not considered to
  54   ;; be foldable. Although it would be "legal" to constant fold them
  55   ;; (since it "is an error" to modify a constant), we choose not to
  56   ;; mark these functions as foldable in this database.
  57   foldable
  58   ;; may be eliminated if value is unused. The function has no side
  59   ;; effects except possibly cons. If a function might signal errors,
  60   ;; then it is not flushable even if it is movable, foldable or
  61   ;; unsafely-flushable. Implies UNSAFELY-FLUSHABLE. (In safe code
  62   ;; type checking of arguments is always performed by the caller, so
  63   ;; a function which SHOULD signal an error if arguments are not of
  64   ;; declared types may be FLUSHABLE.)
  65   flushable
  66   ;; unsafe call may be eliminated if value is unused. The function
  67   ;; has no side effects except possibly cons and signalling an error
  68   ;; in the safe code. If a function MUST signal errors, then it is
  69   ;; not unsafely-flushable even if it is movable or foldable.
  70   unsafely-flushable
  71   ;; return value is important, and ignoring it is probably a mistake.
  72   ;; Unlike the other attributes, this is used only for style
  73   ;; warnings and has no effect on optimization.
  74   important-result
  75   ;; may be moved with impunity. Has no side effects except possibly
  76   ;; consing, and is affected only by its arguments.
  77   ;; UNUSED, BEWARE OF BITROT.
  78   movable
  79   ;; The function is a true predicate likely to be open-coded. Convert
  80   ;; any non-conditional uses into (IF <pred> T NIL). Not usually
  81   ;; specified to DEFKNOWN, since this is implementation dependent,
  82   ;; and is usually automatically set by the DEFINE-VOP :CONDITIONAL
  83   ;; option.
  84   predicate
  85   ;; Inhibit any warning for compiling a recursive definition.
  86   ;; (Normally the compiler warns when compiling a recursive
  87   ;; definition for a known function, since it might be a botched
  88   ;; interpreter stub.)
  89   recursive
  90   ;; The function does explicit argument type checking, so the
  91   ;; declared type should not be asserted when a definition is
  92   ;; compiled.
  93   explicit-check
  94   ;; The function should always be translated by a VOP (i.e. it should
  95   ;; should never be converted into a full call).  This is used strictly
  96   ;; as a consistency checking mechanism inside the compiler during IR2
  97   ;; transformation.
  98   always-translatable)
  99
 100 (defstruct (fun-info #-sb-xc-host (:pure t))
 101   ;; boolean attributes of this function.
 102   (attributes (missing-arg) :type attributes)
 103   ;; TRANSFORM structures describing transforms for this function
 104   (transforms () :type list)
 105   ;; a function which computes the derived type for a call to this
 106   ;; function by examining the arguments. This is null when there is
 107   ;; no special method for this function.
 108   (derive-type nil :type (or function null))
 109   ;; a function that does various unspecified code transformations by
 110   ;; directly hacking the IR. Returns true if further optimizations of
 111   ;; the call shouldn't be attempted.
 112   ;;
 113   ;; KLUDGE: This return convention (non-NIL if you shouldn't do
 114   ;; further optimiz'ns) is backwards from the return convention for
 115   ;; transforms. -- WHN 19990917
 116   (optimizer nil :type (or function null))
 117   ;; a function computing the constant or literal arguments which are
 118   ;; destructively modified by the call.
 119   (destroyed-constant-args nil :type (or function null))
 120   ;; If true, a special-case LTN annotation method that is used in
 121   ;; place of the standard type/policy template selection. It may use
 122   ;; arbitrary code to choose a template, decide to do a full call, or
 123   ;; conspire with the IR2-CONVERT method to do almost anything. The
 124   ;; COMBINATION node is passed as the argument.
 125   (ltn-annotate nil :type (or function null))
 126   ;; If true, the special-case IR2 conversion method for this
 127   ;; function. This deals with funny functions, and anything else that
 128   ;; can't be handled using the template mechanism. The COMBINATION
 129   ;; node and the IR2-BLOCK are passed as arguments.
 130   (ir2-convert nil :type (or function null))
 131   ;; If true, the function can stack-allocate the result. The
 132   ;; COMBINATION node is passed as an argument.
 133   (stack-allocate-result nil :type (or function null))
 134   ;; If true, the function can add flow-sensitive type information
 135   ;; about the state of the world after its execution. The COMBINATION
 136   ;; node is passed as an argument, along with the current set of
 137   ;; active constraints for the block.  The function returns a
 138   ;; sequence of constraints; a constraint is a triplet of a
 139   ;; constraint kind (a symbol, see (defstruct (constraint ...)) in
 140   ;; constraint.lisp) and arguments, either LVARs, LAMBDA-VARs, or
 141   ;; CTYPEs.  If any of these arguments is NIL, the constraint is
 142   ;; skipped. This simplifies integration with OK-LVAR-LAMBDA-VAR,
 143   ;; which maps LVARs to LAMBDA-VARs.  An optional fourth value in
 144   ;; each constraint flips the meaning of the constraint if it is
 145   ;; non-NIL.
 146   (constraint-propagate nil :type (or function null))
 147   ;; If true, the function can add flow-sensitive type information
 148   ;; depending on the truthiness of its return value.  Returns two
 149   ;; values, a LVAR and a CTYPE. The LVAR is of that CTYPE iff the
 150   ;; function returns true.
 151   ;; It may also return additional third and fourth values. Each is
 152   ;; a sequence of constraints (see CONSTRAINT-PROPAGATE), for the
 153   ;; consequent and alternative branches, respectively.
 154   (constraint-propagate-if nil :type (or function null))
 155   ;; all the templates that could be used to translate this function
 156   ;; into IR2, sorted by increasing cost.
 157   (templates nil :type list)
 158   ;; If non-null, then this function is a unary type predicate for
 159   ;; this type.
 160   (predicate-type nil :type (or ctype null))
 161   ;; If non-null, the index of the argument which becomes the result
 162   ;; of the function.
 163   (result-arg nil :type (or index null)))
 164
 165 (defprinter (fun-info)
 166   (attributes :test (not (zerop attributes))
 167               :prin1 (decode-ir1-attributes attributes))
 168   (transforms :test transforms)
 169   (derive-type :test derive-type)
 170   (optimizer :test optimizer)
 171   (ltn-annotate :test ltn-annotate)
 172   (ir2-convert :test ir2-convert)
 173   (templates :test templates)
 174   (predicate-type :test predicate-type))
 175 \f
 176 ;;;; interfaces to defining macros
 177
 178 ;;; an IR1 transform
 179 (defstruct (transform (:copier nil))
 180   ;; the function type which enables this transform.
 181   ;;
 182   ;; (Note that declaring this :TYPE FUN-TYPE probably wouldn't
 183   ;; work because some function types, like (SPECIFIER-TYPE 'FUNCTION0
 184   ;; itself, are represented as BUILT-IN-TYPE, and at least as of
 185   ;; sbcl-0.pre7.54 or so, that's inconsistent with being a
 186   ;; FUN-TYPE.)
 187   (type (missing-arg) :type ctype)
 188   ;; the transformation function. Takes the COMBINATION node and
 189   ;; returns a lambda expression, or throws out.
 190   (function (missing-arg) :type function)
 191   ;; string used in efficiency notes
 192   (note (missing-arg) :type string)
 193   ;; T if we should emit a failure note even if SPEED=INHIBIT-WARNINGS.
 194   (important nil :type (member t nil)))
 195
 196 (defprinter (transform) type note important)
 197
 198 ;;; Grab the FUN-INFO and enter the function, replacing any old
 199 ;;; one with the same type and note.
 200 (declaim (ftype (function (t list function &optional (or string null)
 201                              (member t nil))
 202                           *)
 203                 %deftransform))
 204 (defun %deftransform (name type fun &optional note important)
 205   (let* ((ctype (specifier-type type))
 206          (note (or note "optimize"))
 207          (info (fun-info-or-lose name))
 208          (old (find-if (lambda (x)
 209                          (and (type= (transform-type x) ctype)
 210                               (string-equal (transform-note x) note)
 211                               (eq (transform-important x) important)))
 212                        (fun-info-transforms info))))
 213     (cond (old
 214            (style-warn 'sb!kernel:redefinition-with-deftransform
 215                        :transform old)
 216            (setf (transform-function old) fun
 217                  (transform-note old) note))
 218           (t
 219            (push (make-transform :type ctype :function fun :note note
 220                                  :important important)
 221                  (fun-info-transforms info))))
 222     name))
 223
 224 ;;; Make a FUN-INFO structure with the specified type, attributes
 225 ;;; and optimizers.
 226 (declaim (ftype (function (list list attributes &key
 227                                 (:derive-type (or function null))
 228                                 (:optimizer (or function null))
 229                                 (:destroyed-constant-args (or function null))
 230                                 (:result-arg (or index null))
 231                                 (:overwrite-fndb-silently boolean))
 232                           *)
 233                 %defknown))
 234 (defun %defknown (names type attributes
 235                   &key derive-type optimizer destroyed-constant-args result-arg
 236                     overwrite-fndb-silently)
 237   (let ((ctype (specifier-type type))
 238         (info (make-fun-info :attributes attributes
 239                              :derive-type derive-type
 240                              :optimizer optimizer
 241                              :destroyed-constant-args destroyed-constant-args
 242                              :result-arg result-arg)))
 243     (dolist (name names)
 244       (unless overwrite-fndb-silently
 245         (let ((old-fun-info (info :function :info name)))
 246           (when old-fun-info
 247             ;; This is handled as an error because it's generally a bad
 248             ;; thing to blow away all the old optimization stuff. It's
 249             ;; also a potential source of sneaky bugs:
 250             ;;    DEFKNOWN FOO
 251             ;;    DEFTRANSFORM FOO
 252             ;;    DEFKNOWN FOO ; possibly hidden inside some macroexpansion
 253             ;;    ; Now the DEFTRANSFORM doesn't exist in the target Lisp.
 254             ;; However, it's continuable because it might be useful to do
 255             ;; it when testing new optimization stuff interactively.
 256             (cerror "Go ahead, overwrite it."
 257                     "~@<overwriting old FUN-INFO ~2I~_~S ~I~_for ~S~:>"
 258                     old-fun-info name))))
 259       (setf (info :function :type name) ctype)
 260       (setf (info :function :where-from name) :declared)
 261       (setf (info :function :kind name) :function)
 262       (setf (info :function :info name) info)))
 263   names)
 264
 265 ;;; Return the FUN-INFO for NAME or die trying. Since this is
 266 ;;; used by callers who want to modify the info, and the info may be
 267 ;;; shared, we copy it. We don't have to copy the lists, since each
 268 ;;; function that has generators or transforms has already been
 269 ;;; through here.
 270 (declaim (ftype (sfunction (t) fun-info) fun-info-or-lose))
 271 (defun fun-info-or-lose (name)
 272   (let (;; FIXME: Do we need this rebinding here? It's a literal
 273         ;; translation of the old CMU CL rebinding to
 274         ;; (OR *BACKEND-INFO-ENVIRONMENT* *INFO-ENVIRONMENT*),
 275         ;; and it's not obvious whether the rebinding to itself is
 276         ;; needed that SBCL doesn't need *BACKEND-INFO-ENVIRONMENT*.
 277         (*info-environment* *info-environment*))
 278     (let ((old (info :function :info name)))
 279       (unless old (error "~S is not a known function." name))
 280       (setf (info :function :info name) (copy-fun-info old)))))
 281 \f
 282 ;;;; generic type inference methods
 283
 284 ;;; Derive the type to be the type of the xxx'th arg. This can normally
 285 ;;; only be done when the result value is that argument.
 286 (defun result-type-first-arg (call)
 287   (declare (type combination call))
 288   (let ((lvar (first (combination-args call))))
 289     (when lvar (lvar-type lvar))))
 290 (defun result-type-last-arg (call)
 291   (declare (type combination call))
 292   (let ((lvar (car (last (combination-args call)))))
 293     (when lvar (lvar-type lvar))))
 294
 295 ;;; Derive the result type according to the float contagion rules, but
 296 ;;; always return a float. This is used for irrational functions that
 297 ;;; preserve realness of their arguments.
 298 (defun result-type-float-contagion (call)
 299   (declare (type combination call))
 300   (reduce #'numeric-contagion (combination-args call)
 301           :key #'lvar-type
 302           :initial-value (specifier-type 'single-float)))
 303
 304 ;;; Return a closure usable as a derive-type method for accessing the
 305 ;;; N'th argument. If arg is a list, result is a list. If arg is a
 306 ;;; vector, result is a vector with the same element type.
 307 (defun sequence-result-nth-arg (n)
 308   (lambda (call)
 309     (declare (type combination call))
 310     (let ((lvar (nth (1- n) (combination-args call))))
 311       (when lvar
 312         (let ((type (lvar-type lvar)))
 313           (if (array-type-p type)
 314               (specifier-type
 315                `(vector ,(type-specifier (array-type-element-type type))))
 316               (let ((ltype (specifier-type 'list)))
 317                 (when (csubtypep type ltype)
 318                   ltype))))))))
 319
 320 ;;; Derive the type to be the type specifier which is the Nth arg.
 321 (defun result-type-specifier-nth-arg (n)
 322   (lambda (call)
 323     (declare (type combination call))
 324     (let ((lvar (nth (1- n) (combination-args call))))
 325       (when (and lvar (constant-lvar-p lvar))
 326         (careful-specifier-type (lvar-value lvar))))))
 327
 328 ;;; Derive the type to be the type specifier which is the Nth arg,
 329 ;;; with the additional restriptions noted in the CLHS for STRING and
 330 ;;; SIMPLE-STRING, defined to specialize on CHARACTER, and for VECTOR
 331 ;;; (under the page for MAKE-SEQUENCE).
 332 (defun creation-result-type-specifier-nth-arg (n)
 333   (lambda (call)
 334     (declare (type combination call))
 335     (let ((lvar (nth (1- n) (combination-args call))))
 336       (when (and lvar (constant-lvar-p lvar))
 337         (let* ((specifier (lvar-value lvar))
 338                (lspecifier (if (atom specifier) (list specifier) specifier)))
 339           (cond
 340             ((eq (car lspecifier) 'string)
 341              (destructuring-bind (string &rest size)
 342                  lspecifier
 343                (declare (ignore string))
 344                (careful-specifier-type
 345                 `(vector character ,@(when size size)))))
 346             ((eq (car lspecifier) 'simple-string)
 347              (destructuring-bind (simple-string &rest size)
 348                  lspecifier
 349                (declare (ignore simple-string))
 350                (careful-specifier-type
 351                 `(simple-array character ,@(if size (list size) '((*)))))))
 352             (t
 353              (let ((ctype (careful-specifier-type specifier)))
 354                (if (and (array-type-p ctype)
 355                         (eq (array-type-specialized-element-type ctype)
 356                             *wild-type*))
 357                    ;; I don't think I'm allowed to modify what I get
 358                    ;; back from SPECIFIER-TYPE; it is, after all,
 359                    ;; cached.  Better copy it, then.
 360                    (let ((real-ctype (copy-structure ctype)))
 361                      (setf (array-type-element-type real-ctype)
 362                            *universal-type*
 363                            (array-type-specialized-element-type real-ctype)
 364                            *universal-type*)
 365                      real-ctype)
 366                    ctype)))))))))
 367
 368 (defun remove-non-constants-and-nils (fun)
 369   (lambda (list)
 370     (remove-if-not #'lvar-value
 371                    (remove-if-not #'constant-lvar-p (funcall fun list)))))
 372
 373 ;;; FIXME: bad name (first because it uses 1-based indexing; second
 374 ;;; because it doesn't get the nth constant arguments)
 375 (defun nth-constant-args (&rest indices)
 376   (lambda (list)
 377     (let (result)
 378       (do ((i 1 (1+ i))
 379            (list list (cdr list))
 380            (indices indices))
 381           ((null indices) (nreverse result))
 382         (when (= i (car indices))
 383           (when (constant-lvar-p (car list))
 384             (push (car list) result))
 385           (setf indices (cdr indices)))))))
 386
 387 ;;; FIXME: a number of the sequence functions not only do not destroy
 388 ;;; their argument if it is empty, but also leave it alone if :start
 389 ;;; and :end bound a null sequence, or if :count is 0.  This test is a
 390 ;;; bit complicated to implement, verging on the impossible, but for
 391 ;;; extra points (fill #\1 "abc" :start 0 :end 0) should not cause a
 392 ;;; warning.
 393 (defun nth-constant-nonempty-sequence-args (&rest indices)
 394   (lambda (list)
 395     (let (result)
 396       (do ((i 1 (1+ i))
 397            (list list (cdr list))
 398            (indices indices))
 399           ((null indices) (nreverse result))
 400         (when (= i (car indices))
 401           (when (constant-lvar-p (car list))
 402             (let ((value (lvar-value (car list))))
 403               (unless (or (typep value 'null)
 404                           (typep value '(vector * 0)))
 405                 (push (car list) result))))
 406           (setf indices (cdr indices)))))))
 407
 408 (/show0 "knownfun.lisp end of file")