src/compiler/pack.lisp

   1 ;;;; This file contains the implementation-independent code for Pack
   2 ;;;; phase in the compiler. Pack is responsible for assigning TNs to
   3 ;;;; storage allocations or "register allocation".
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!C")
  15
  16 ;;; for debugging: some parameters controlling which optimizations we
  17 ;;; attempt
  18 (defvar *pack-assign-costs* t)
  19 (defvar *pack-optimize-saves* t)
  20 ;;; FIXME: Perhaps SB-FLUID should be renamed to SB-TWEAK and these
  21 ;;; should be made conditional on SB-TWEAK.
  22
  23 (declaim (ftype (function (component) index) ir2-block-count))
  24 \f
  25 ;;;; conflict determination
  26
  27 ;;; Return true if the element at the specified offset, or in any of
  28 ;;; the [size-1] subsequent offsets, in SB has a conflict with TN:
  29 ;;; -- If a component-live TN (:COMPONENT kind), then iterate over
  30 ;;;    all the blocks. If the element at OFFSET is used anywhere in
  31 ;;;    any of the component's blocks (always-live /= 0), then there
  32 ;;;    is a conflict.
  33 ;;; -- If TN is global (Confs true), then iterate over the blocks TN
  34 ;;;    is live in (using TN-GLOBAL-CONFLICTS). If the TN is live
  35 ;;;    everywhere in the block (:LIVE), then there is a conflict
  36 ;;;    if the element at offset is used anywhere in the block
  37 ;;;    (Always-Live /= 0). Otherwise, we use the local TN number for
  38 ;;;    TN in block to find whether TN has a conflict at Offset in
  39 ;;;    that block.
  40 ;;; -- If TN is local, then we just check for a conflict in the block
  41 ;;;    it is local to.
  42 ;;;
  43 ;;; If there is a conflict, returns the first such conflicting offset.
  44 (defun offset-conflicts-in-sb (tn sb offset &key (size 1))
  45   (declare (type tn tn) (type finite-sb sb) (type index offset size))
  46   (let ((confs (tn-global-conflicts tn))
  47         (kind (tn-kind tn))
  48         (sb-conflicts (finite-sb-conflicts sb))
  49         (sb-always-live (finite-sb-always-live sb)))
  50     (macrolet ((do-offsets (&body body)
  51                  `(loop repeat size
  52                         for offset upfrom offset
  53                         thereis (progn ,@body))))
  54       (cond
  55         ((eq kind :component)
  56          (do-offsets
  57              (let ((loc-live (svref sb-always-live offset)))
  58                (dotimes (i (ir2-block-count *component-being-compiled*))
  59                  (when (/= (sbit loc-live i) 0)
  60                    (return offset))))))
  61         (confs
  62          ;; TN is global, iterate over the blocks TN is live in.
  63          (do ((conf confs (global-conflicts-next-tnwise conf)))
  64              ((null conf)
  65               nil)
  66            (let* ((block (global-conflicts-block conf))
  67                   (num (ir2-block-number block)))
  68              (if (eq (global-conflicts-kind conf) :live)
  69                  (do-offsets
  70                      (let ((loc-live (svref sb-always-live offset)))
  71                        (when (/= (sbit loc-live num) 0)
  72                          (return-from offset-conflicts-in-sb offset))))
  73                  (do-offsets
  74                      (let ((loc-confs (svref sb-conflicts offset)))
  75                        (when (/= (sbit (svref loc-confs num)
  76                                        (global-conflicts-number conf))
  77                                  0)
  78                          (return-from offset-conflicts-in-sb offset))))))))
  79         (t
  80          (do-offsets
  81              (and (/= (sbit (svref (svref sb-conflicts offset)
  82                                    (ir2-block-number (tn-local tn)))
  83                             (tn-local-number tn))
  84                       0)
  85                   offset)))))))
  86
  87 ;;; Return true if TN has a conflict in SC at the specified offset.
  88 (declaim (ftype (function (tn sc index) (values (or null index) &optional))
  89                 conflicts-in-sc))
  90 (defun conflicts-in-sc (tn sc offset)
  91   (declare (type tn tn) (type sc sc) (type index offset))
  92   (offset-conflicts-in-sb tn (sc-sb sc) offset
  93                           :size (sc-element-size sc)))
  94
  95 ;;; Add TN's conflicts into the conflicts for the location at OFFSET
  96 ;;; in SC. We iterate over each location in TN, adding to the
  97 ;;; conflicts for that location:
  98 ;;; -- If TN is a :COMPONENT TN, then iterate over all the blocks,
  99 ;;;    setting all of the local conflict bits and the always-live bit.
 100 ;;;    This records a conflict with any TN that has a LTN number in
 101 ;;;    the block, as well as with :ALWAYS-LIVE and :ENVIRONMENT TNs.
 102 ;;; -- If TN is global, then iterate over the blocks TN is live in. In
 103 ;;;    addition to setting the always-live bit to represent the conflict
 104 ;;;    with TNs live throughout the block, we also set bits in the
 105 ;;;    local conflicts. If TN is :ALWAYS-LIVE in the block, we set all
 106 ;;;    the bits, otherwise we OR in the local conflict bits.
 107 ;;; -- If the TN is local, then we just do the block it is local to,
 108 ;;;    setting always-live and OR'ing in the local conflicts.
 109 (defun add-location-conflicts (tn sc offset optimize)
 110   (declare (type tn tn) (type sc sc) (type index offset))
 111   (let ((confs (tn-global-conflicts tn))
 112         (sb (sc-sb sc))
 113         (kind (tn-kind tn)))
 114     (dotimes (i (sc-element-size sc))
 115       (declare (type index i))
 116       (let* ((this-offset (+ offset i))
 117              (loc-confs (svref (finite-sb-conflicts sb) this-offset))
 118              (loc-live (svref (finite-sb-always-live sb) this-offset)))
 119         (cond
 120          ((eq kind :component)
 121           (dotimes (num (ir2-block-count *component-being-compiled*))
 122             (declare (type index num))
 123             (setf (sbit loc-live num) 1)
 124             (set-bit-vector (svref loc-confs num))))
 125          (confs
 126           (do ((conf confs (global-conflicts-next-tnwise conf)))
 127               ((null conf))
 128             (let* ((block (global-conflicts-block conf))
 129                    (num (ir2-block-number block))
 130                    (local-confs (svref loc-confs num)))
 131               (declare (type local-tn-bit-vector local-confs))
 132               (setf (sbit loc-live num) 1)
 133               (if (eq (global-conflicts-kind conf) :live)
 134                   (set-bit-vector local-confs)
 135                   (bit-ior local-confs (global-conflicts-conflicts conf) t)))))
 136          (t
 137           (let ((num (ir2-block-number (tn-local tn))))
 138             (setf (sbit loc-live num) 1)
 139             (bit-ior (the local-tn-bit-vector (svref loc-confs num))
 140                      (tn-local-conflicts tn) t))))
 141         ;; Calculating ALWAYS-LIVE-COUNT is moderately expensive, and
 142         ;; currently the information isn't used unless (> SPEED
 143         ;; COMPILE-SPEED).
 144         (when optimize
 145           (setf (svref (finite-sb-always-live-count sb) this-offset)
 146                 (find-location-usage sb this-offset))))))
 147   (values))
 148
 149 ;; A rought measure of how much a given OFFSET in SB is currently
 150 ;; used. Current implementation counts the amount of blocks where the
 151 ;; offset has been marked as ALWAYS-LIVE.
 152 (defun find-location-usage (sb offset)
 153   (declare (optimize speed))
 154   (declare (type sb sb) (type index offset))
 155   (let* ((always-live (svref (finite-sb-always-live sb) offset)))
 156     (declare (simple-bit-vector always-live))
 157     (count 1 always-live)))
 158
 159 ;;; Return the total number of IR2-BLOCKs in COMPONENT.
 160 (defun ir2-block-count (component)
 161   (declare (type component component))
 162   (do ((2block (block-info (block-next (component-head component)))
 163                (ir2-block-next 2block)))
 164       ((null 2block)
 165        (error "What?  No ir2 blocks have a non-nil number?"))
 166     (when (ir2-block-number 2block)
 167       (return (1+ (ir2-block-number 2block))))))
 168
 169 ;;; Ensure that the conflicts vectors for each :FINITE SB are large
 170 ;;; enough for the number of blocks allocated. Also clear any old
 171 ;;; conflicts and reset the current size to the initial size.
 172 (defun init-sb-vectors (component)
 173   (let ((nblocks (ir2-block-count component)))
 174     (dolist (sb *backend-sb-list*)
 175       (unless (eq (sb-kind sb) :non-packed)
 176         (let* ((conflicts (finite-sb-conflicts sb))
 177                (always-live (finite-sb-always-live sb))
 178                (always-live-count (finite-sb-always-live-count sb))
 179                (max-locs (length conflicts))
 180                (last-count (finite-sb-last-block-count sb)))
 181           (unless (zerop max-locs)
 182             (let ((current-size (length (the simple-vector
 183                                              (svref conflicts 0)))))
 184               (cond
 185                ((> nblocks current-size)
 186                 (let ((new-size (max nblocks (* current-size 2))))
 187                   (declare (type index new-size))
 188                   (dotimes (i max-locs)
 189                     (declare (type index i))
 190                     (let ((new-vec (make-array new-size)))
 191                       (let ((old (svref conflicts i)))
 192                         (declare (simple-vector old))
 193                         (dotimes (j current-size)
 194                           (declare (type index j))
 195                           (setf (svref new-vec j)
 196                                 (clear-bit-vector (svref old j)))))
 197
 198                       (do ((j current-size (1+ j)))
 199                           ((= j new-size))
 200                         (declare (type index j))
 201                         (setf (svref new-vec j)
 202                               (make-array local-tn-limit :element-type 'bit
 203                                           :initial-element 0)))
 204                       (setf (svref conflicts i) new-vec))
 205                     (setf (svref always-live i)
 206                           (make-array new-size :element-type 'bit
 207                                       :initial-element 0))
 208                     (setf (svref always-live-count i) 0))))
 209                (t
 210                 (dotimes (i (finite-sb-current-size sb))
 211                   (declare (type index i))
 212                   (let ((conf (svref conflicts i)))
 213                     (declare (simple-vector conf))
 214                     (dotimes (j last-count)
 215                       (declare (type index j))
 216                       (clear-bit-vector (svref conf j))))
 217                   (clear-bit-vector (svref always-live i))
 218                   (setf (svref always-live-count i) 0))))))
 219
 220           (setf (finite-sb-last-block-count sb) nblocks)
 221           (setf (finite-sb-current-size sb) (sb-size sb))
 222           (setf (finite-sb-last-offset sb) 0))))))
 223
 224 ;;; Expand the :UNBOUNDED SB backing SC by either the initial size or
 225 ;;; the SC element size, whichever is larger. If NEEDED-SIZE is
 226 ;;; larger, then use that size.
 227 (defun grow-sc (sc &optional (needed-size 0))
 228   (declare (type sc sc) (type index needed-size))
 229   (let* ((sb (sc-sb sc))
 230          (size (finite-sb-current-size sb))
 231          (align-mask (1- (sc-alignment sc)))
 232          (inc (max (finite-sb-size-increment sb)
 233                    (+ (sc-element-size sc)
 234                       (- (logandc2 (+ size align-mask) align-mask)
 235                          size))
 236                    (- needed-size size)))
 237          (new-size (let ((align-mask (1- (finite-sb-size-alignment sb))))
 238                      (logandc2 (+  size inc align-mask) align-mask)))
 239          (conflicts (finite-sb-conflicts sb))
 240          (block-size (if (zerop (length conflicts))
 241                          (ir2-block-count *component-being-compiled*)
 242                          (length (the simple-vector (svref conflicts 0)))))
 243          (padded-size (ash 1 (integer-length (1- new-size)))))
 244     (declare (type index inc new-size padded-size))
 245     (aver (eq (sb-kind sb) :unbounded))
 246
 247     (when (> padded-size (length conflicts))
 248       (let ((new-conf (make-array padded-size)))
 249         (replace new-conf conflicts)
 250         (do ((i size (1+ i)))
 251             ((= i padded-size))
 252           (declare (type index i))
 253           (let ((loc-confs (make-array block-size)))
 254             (dotimes (j block-size)
 255               (setf (svref loc-confs j)
 256                     (make-array local-tn-limit
 257                                 :initial-element 0
 258                                 :element-type 'bit)))
 259             (setf (svref new-conf i) loc-confs)))
 260         (setf (finite-sb-conflicts sb) new-conf))
 261
 262       (let ((new-live (make-array padded-size)))
 263         (replace new-live (finite-sb-always-live sb))
 264         (do ((i size (1+ i)))
 265             ((= i padded-size))
 266           (setf (svref new-live i)
 267                 (make-array block-size
 268                             :initial-element 0
 269                             :element-type 'bit)))
 270         (setf (finite-sb-always-live sb) new-live))
 271
 272       (let ((new-live-count (make-array padded-size)))
 273         (declare (optimize speed)) ;; FILL deftransform
 274         (replace new-live-count (finite-sb-always-live-count sb))
 275         (fill new-live-count 0 :start size)
 276         (setf (finite-sb-always-live-count sb) new-live-count))
 277
 278       (let ((new-tns (make-array padded-size :initial-element nil)))
 279         (replace new-tns (finite-sb-live-tns sb))
 280         (fill (finite-sb-live-tns sb) nil)
 281         (setf (finite-sb-live-tns sb) new-tns)))
 282
 283     (setf (finite-sb-current-size sb) new-size))
 284   (values))
 285
 286 \f
 287 ;;;; internal errors
 288
 289 ;;; Give someone a hard time because there isn't any load function
 290 ;;; defined to move from SRC to DEST.
 291 (defun no-load-fun-error (src dest)
 292   (let* ((src-sc (tn-sc src))
 293          (src-name (sc-name src-sc))
 294          (dest-sc (tn-sc dest))
 295          (dest-name (sc-name dest-sc)))
 296     (cond ((eq (sb-kind (sc-sb src-sc)) :non-packed)
 297            (unless (member src-sc (sc-constant-scs dest-sc))
 298              (error "loading from an invalid constant SC?~@
 299                      VM definition inconsistent, try recompiling."))
 300            (error "no load function defined to load SC ~S ~
 301                    from its constant SC ~S"
 302                   dest-name src-name))
 303           ((member src-sc (sc-alternate-scs dest-sc))
 304            (error "no load function defined to load SC ~S from its ~
 305                    alternate SC ~S"
 306                   dest-name src-name))
 307           ((member dest-sc (sc-alternate-scs src-sc))
 308            (error "no load function defined to save SC ~S in its ~
 309                    alternate SC ~S"
 310                   src-name dest-name))
 311           (t
 312            ;; FIXME: "VM definition is inconsistent" shouldn't be a
 313            ;; possibility in SBCL.
 314            (error "loading to/from SCs that aren't alternates?~@
 315                    VM definition is inconsistent, try recompiling.")))))
 316
 317 ;;; Called when we failed to pack TN. If RESTRICTED is true, then we
 318 ;;; are restricted to pack TN in its SC.
 319 (defun failed-to-pack-error (tn restricted)
 320   (declare (type tn tn))
 321   (let* ((sc (tn-sc tn))
 322          (scs (cons sc (sc-alternate-scs sc))))
 323     (cond
 324      (restricted
 325       (error "failed to pack restricted TN ~S in its SC ~S"
 326              tn (sc-name sc)))
 327      (t
 328       (aver (not (find :unbounded scs
 329                        :key (lambda (x) (sb-kind (sc-sb x))))))
 330       (let ((ptype (tn-primitive-type tn)))
 331         (cond
 332          (ptype
 333           (aver (member (sc-number sc) (primitive-type-scs ptype)))
 334           (error "SC ~S doesn't have any :UNBOUNDED alternate SCs, but is~@
 335                   a SC for primitive-type ~S."
 336                  (sc-name sc) (primitive-type-name ptype)))
 337          (t
 338           (error "SC ~S doesn't have any :UNBOUNDED alternate SCs."
 339                  (sc-name sc)))))))))
 340
 341 ;;; Return a list of format arguments describing how TN is used in
 342 ;;; OP's VOP.
 343 (defun describe-tn-use (loc tn op)
 344   (let* ((vop (tn-ref-vop op))
 345          (args (vop-args vop))
 346          (results (vop-results vop))
 347          (name (with-output-to-string (stream)
 348                  (print-tn-guts tn stream)))
 349          (2comp (component-info *component-being-compiled*))
 350          temp)
 351     (cond
 352      ((setq temp (position-in #'tn-ref-across tn args :key #'tn-ref-tn))
 353       `("~2D: ~A (~:R argument)" ,loc ,name ,(1+ temp)))
 354      ((setq temp (position-in #'tn-ref-across tn results :key #'tn-ref-tn))
 355       `("~2D: ~A (~:R result)" ,loc ,name ,(1+ temp)))
 356      ((setq temp (position-in #'tn-ref-across tn args :key #'tn-ref-load-tn))
 357       `("~2D: ~A (~:R argument load TN)" ,loc ,name ,(1+ temp)))
 358      ((setq temp (position-in #'tn-ref-across tn results :key
 359                               #'tn-ref-load-tn))
 360       `("~2D: ~A (~:R result load TN)" ,loc ,name ,(1+ temp)))
 361      ((setq temp (position-in #'tn-ref-across tn (vop-temps vop)
 362                               :key #'tn-ref-tn))
 363       `("~2D: ~A (temporary ~A)" ,loc ,name
 364         ,(operand-parse-name (elt (vop-parse-temps
 365                                    (vop-parse-or-lose
 366                                     (vop-info-name  (vop-info vop))))
 367                                   temp))))
 368      ((eq (tn-kind tn) :component)
 369       `("~2D: ~A (component live)" ,loc ,name))
 370      ((position-in #'tn-next tn (ir2-component-wired-tns 2comp))
 371       `("~2D: ~A (wired)" ,loc ,name))
 372      ((position-in #'tn-next tn (ir2-component-restricted-tns 2comp))
 373       `("~2D: ~A (restricted)" ,loc ,name))
 374      (t
 375       `("~2D: not referenced?" ,loc)))))
 376
 377 ;;; If load TN packing fails, try to give a helpful error message. We
 378 ;;; find a TN in each location that conflicts, and print it.
 379 (defun failed-to-pack-load-tn-error (scs op)
 380   (declare (list scs) (type tn-ref op))
 381   (collect ((used)
 382             (unused))
 383     (dolist (sc scs)
 384       (let* ((sb (sc-sb sc))
 385              (confs (finite-sb-live-tns sb)))
 386         (aver (eq (sb-kind sb) :finite))
 387         (dolist (el (sc-locations sc))
 388           (declare (type index el))
 389           (let ((conf (load-tn-conflicts-in-sc op sc el t)))
 390             (if conf
 391                 (used (describe-tn-use el conf op))
 392                 (do ((i el (1+ i))
 393                      (end (+ el (sc-element-size sc))))
 394                     ((= i end)
 395                      (unused el))
 396                   (declare (type index i end))
 397                   (let ((victim (svref confs i)))
 398                     (when victim
 399                       (used (describe-tn-use el victim op))
 400                       (return t)))))))))
 401
 402     (multiple-value-bind (arg-p n more-p costs load-scs incon)
 403         (get-operand-info op)
 404       (declare (ignore costs load-scs))
 405         (aver (not more-p))
 406         (error "unable to pack a Load-TN in SC ~{~A~#[~^~;, or ~:;,~]~} ~
 407                 for the ~:R ~:[result~;argument~] to~@
 408                 the ~S VOP,~@
 409                 ~:[since all SC elements are in use:~:{~%~@?~}~%~;~
 410                 ~:*but these SC elements are not in use:~%  ~S~%Bug?~*~]~
 411                 ~:[~;~@
 412                 Current cost info inconsistent with that in effect at compile ~
 413                 time. Recompile.~%Compilation order may be incorrect.~]"
 414                (mapcar #'sc-name scs)
 415                n arg-p
 416                (vop-info-name (vop-info (tn-ref-vop op)))
 417                (unused) (used)
 418                incon))))
 419
 420 ;;; This is called when none of the SCs that we can load OP into are
 421 ;;; allowed by OP's primitive-type.
 422 (defun no-load-scs-allowed-by-primitive-type-error (ref)
 423   (declare (type tn-ref ref))
 424   (let* ((tn (tn-ref-tn ref))
 425          (ptype (tn-primitive-type tn)))
 426     (multiple-value-bind (arg-p pos more-p costs load-scs incon)
 427         (get-operand-info ref)
 428       (declare (ignore costs))
 429       (aver (not more-p))
 430       (error "~S is not valid as the ~:R ~:[result~;argument~] to VOP:~
 431               ~%  ~S,~@
 432               since the TN's primitive type ~S doesn't allow any of the SCs~@
 433               allowed by the operand restriction:~%  ~S~
 434               ~:[~;~@
 435               Current cost info inconsistent with that in effect at compile ~
 436               time. Recompile.~%Compilation order may be incorrect.~]"
 437              tn pos arg-p
 438              (template-name (vop-info (tn-ref-vop ref)))
 439              (primitive-type-name ptype)
 440              (mapcar #'sc-name (listify-restrictions load-scs))
 441              incon))))
 442 \f
 443 ;;;; register saving
 444
 445 ;;; Do stuff to note that TN is spilled at VOP for the debugger's benefit.
 446 (defun note-spilled-tn (tn vop)
 447   (when (and (tn-leaf tn) (vop-save-set vop))
 448     (let ((2comp (component-info *component-being-compiled*)))
 449       (setf (gethash tn (ir2-component-spilled-tns 2comp)) t)
 450       (pushnew tn (gethash vop (ir2-component-spilled-vops 2comp)))))
 451   (values))
 452
 453 ;;; Make a save TN for TN, pack it, and return it. We copy various
 454 ;;; conflict information from the TN so that pack does the right
 455 ;;; thing.
 456 (defun pack-save-tn (tn)
 457   (declare (type tn tn))
 458   (let ((res (make-tn 0 :save nil nil)))
 459     (dolist (alt (sc-alternate-scs (tn-sc tn))
 460                  (error "no unbounded alternate for SC ~S"
 461                         (sc-name (tn-sc tn))))
 462       (when (eq (sb-kind (sc-sb alt)) :unbounded)
 463         (setf (tn-save-tn tn) res)
 464         (setf (tn-save-tn res) tn)
 465         (setf (tn-sc res) alt)
 466         (pack-tn res t nil)
 467         (return res)))))
 468
 469 ;;; Find the load function for moving from SRC to DEST and emit a
 470 ;;; MOVE-OPERAND VOP with that function as its info arg.
 471 (defun emit-operand-load (node block src dest before)
 472   (declare (type node node) (type ir2-block block)
 473            (type tn src dest) (type (or vop null) before))
 474   (emit-load-template node block
 475                       (template-or-lose 'move-operand)
 476                       src dest
 477                       (list (or (svref (sc-move-funs (tn-sc dest))
 478                                        (sc-number (tn-sc src)))
 479                                 (no-load-fun-error src dest)))
 480                       before)
 481   (values))
 482
 483 ;;; Find the preceding use of the VOP NAME in the emit order, starting
 484 ;;; with VOP. We must find the VOP in the same IR1 block.
 485 (defun reverse-find-vop (name vop)
 486   (do* ((block (vop-block vop) (ir2-block-prev block))
 487         (last vop (ir2-block-last-vop block)))
 488        (nil)
 489     (aver (eq (ir2-block-block block) (ir2-block-block (vop-block vop))))
 490     (do ((current last (vop-prev current)))
 491         ((null current))
 492       (when (eq (vop-info-name (vop-info current)) name)
 493         (return-from reverse-find-vop current)))))
 494
 495 ;;; For TNs that have other than one writer, we save the TN before
 496 ;;; each call. If a local call (MOVE-ARGS is :LOCAL-CALL), then we
 497 ;;; scan back for the ALLOCATE-FRAME VOP, and emit the save there.
 498 ;;; This is necessary because in a self-recursive local call, the
 499 ;;; registers holding the current arguments may get trashed by setting
 500 ;;; up the call arguments. The ALLOCATE-FRAME VOP marks a place at
 501 ;;; which the values are known to be good.
 502 (defun save-complex-writer-tn (tn vop)
 503   (let ((save (or (tn-save-tn tn)
 504                   (pack-save-tn tn)))
 505         (node (vop-node vop))
 506         (block (vop-block vop))
 507         (next (vop-next vop)))
 508     (when (eq (tn-kind save) :specified-save)
 509       (setf (tn-kind save) :save))
 510     (aver (eq (tn-kind save) :save))
 511     (emit-operand-load node block tn save
 512                        (if (eq (vop-info-move-args (vop-info vop))
 513                                :local-call)
 514                            (reverse-find-vop 'allocate-frame vop)
 515                            vop))
 516     (emit-operand-load node block save tn next)))
 517
 518 ;;; Return a VOP after which is an OK place to save the value of TN.
 519 ;;; For correctness, it is only required that this location be after
 520 ;;; any possible write and before any possible restore location.
 521 ;;;
 522 ;;; In practice, we return the unique writer VOP, but give up if the
 523 ;;; TN is ever read by a VOP with MOVE-ARGS :LOCAL-CALL. This prevents
 524 ;;; us from being confused by non-tail local calls.
 525 ;;;
 526 ;;; When looking for writes, we have to ignore uses of MOVE-OPERAND,
 527 ;;; since they will correspond to restores that we have already done.
 528 (defun find-single-writer (tn)
 529   (declare (type tn tn))
 530   (do ((write (tn-writes tn) (tn-ref-next write))
 531        (res nil))
 532       ((null write)
 533        (when (and res
 534                   (do ((read (tn-reads tn) (tn-ref-next read)))
 535                       ((not read) t)
 536                     (when (eq (vop-info-move-args
 537                                (vop-info
 538                                 (tn-ref-vop read)))
 539                               :local-call)
 540                       (return nil))))
 541          (tn-ref-vop res)))
 542
 543     (unless (eq (vop-info-name (vop-info (tn-ref-vop write)))
 544                 'move-operand)
 545       (when res (return nil))
 546       (setq res write))))
 547
 548 ;;; Try to save TN at a single location. If we succeed, return T,
 549 ;;; otherwise NIL.
 550 (defun save-single-writer-tn (tn)
 551   (declare (type tn tn))
 552   (let* ((old-save (tn-save-tn tn))
 553          (save (or old-save (pack-save-tn tn)))
 554          (writer (find-single-writer tn)))
 555     (when (and writer
 556                (or (not old-save)
 557                    (eq (tn-kind old-save) :specified-save)))
 558       (emit-operand-load (vop-node writer) (vop-block writer)
 559                          tn save (vop-next writer))
 560       (setf (tn-kind save) :save-once)
 561       t)))
 562
 563 ;;; Restore a TN with a :SAVE-ONCE save TN.
 564 (defun restore-single-writer-tn (tn vop)
 565   (declare (type tn) (type vop vop))
 566   (let ((save (tn-save-tn tn)))
 567     (aver (eq (tn-kind save) :save-once))
 568     (emit-operand-load (vop-node vop) (vop-block vop) save tn (vop-next vop)))
 569   (values))
 570
 571 ;;; Save a single TN that needs to be saved, choosing save-once if
 572 ;;; appropriate. This is also called by SPILL-AND-PACK-LOAD-TN.
 573 (defun basic-save-tn (tn vop)
 574   (declare (type tn tn) (type vop vop))
 575   (let ((save (tn-save-tn tn)))
 576     (cond ((and save (eq (tn-kind save) :save-once))
 577            (restore-single-writer-tn tn vop))
 578           ((save-single-writer-tn tn)
 579            (restore-single-writer-tn tn vop))
 580           (t
 581            (save-complex-writer-tn tn vop))))
 582   (values))
 583
 584 ;;; Scan over the VOPs in BLOCK, emiting saving code for TNs noted in
 585 ;;; the codegen info that are packed into saved SCs.
 586 (defun emit-saves (block)
 587   (declare (type ir2-block block))
 588   (do ((vop (ir2-block-start-vop block) (vop-next vop)))
 589       ((null vop))
 590     (when (eq (vop-info-save-p (vop-info vop)) t)
 591       (do-live-tns (tn (vop-save-set vop) block)
 592         (when (and (sc-save-p (tn-sc tn))
 593                    (not (eq (tn-kind tn) :component)))
 594           (basic-save-tn tn vop)))))
 595
 596   (values))
 597 \f
 598 ;;;; optimized saving
 599
 600 ;;; Save TN if it isn't a single-writer TN that has already been
 601 ;;; saved. If multi-write, we insert the save BEFORE the specified
 602 ;;; VOP. CONTEXT is a VOP used to tell which node/block to use for the
 603 ;;; new VOP.
 604 (defun save-if-necessary (tn before context)
 605   (declare (type tn tn) (type (or vop null) before) (type vop context))
 606   (let ((save (tn-save-tn tn)))
 607     (when (eq (tn-kind save) :specified-save)
 608       (setf (tn-kind save) :save))
 609     (aver (member (tn-kind save) '(:save :save-once)))
 610     (unless (eq (tn-kind save) :save-once)
 611       (or (save-single-writer-tn tn)
 612           (emit-operand-load (vop-node context) (vop-block context)
 613                              tn save before))))
 614   (values))
 615
 616 ;;; Load the TN from its save location, allocating one if necessary.
 617 ;;; The load is inserted BEFORE the specified VOP. CONTEXT is a VOP
 618 ;;; used to tell which node/block to use for the new VOP.
 619 (defun restore-tn (tn before context)
 620   (declare (type tn tn) (type (or vop null) before) (type vop context))
 621   (let ((save (or (tn-save-tn tn) (pack-save-tn tn))))
 622     (emit-operand-load (vop-node context) (vop-block context)
 623                        save tn before))
 624   (values))
 625
 626 ;;; Start scanning backward at the end of BLOCK, looking which TNs are
 627 ;;; live and looking for places where we have to save. We manipulate
 628 ;;; two sets: SAVES and RESTORES.
 629 ;;;
 630 ;;; SAVES is a set of all the TNs that have to be saved because they
 631 ;;; are restored after some call. We normally delay saving until the
 632 ;;; beginning of the block, but we must save immediately if we see a
 633 ;;; write of the saved TN. We also immediately save all TNs and exit
 634 ;;; when we see a NOTE-ENVIRONMENT-START VOP, since saves can't be
 635 ;;; done before the environment is properly initialized.
 636 ;;;
 637 ;;; RESTORES is a set of all the TNs read (and not written) between
 638 ;;; here and the next call, i.e. the set of TNs that must be restored
 639 ;;; when we reach the next (earlier) call VOP. Unlike SAVES, this set
 640 ;;; is cleared when we do the restoring after a call. Any TNs that
 641 ;;; were in RESTORES are moved into SAVES to ensure that they are
 642 ;;; saved at some point.
 643 ;;;
 644 ;;; SAVES and RESTORES are represented using both a list and a
 645 ;;; bit-vector so that we can quickly iterate and test for membership.
 646 ;;; The incoming SAVES and RESTORES args are used for computing these
 647 ;;; sets (the initial contents are ignored.)
 648 ;;;
 649 ;;; When we hit a VOP with :COMPUTE-ONLY SAVE-P (an internal error
 650 ;;; location), we pretend that all live TNs were read, unless (= speed
 651 ;;; 3), in which case we mark all the TNs that are live but not
 652 ;;; restored as spilled.
 653 (defun optimized-emit-saves-block (block saves restores)
 654   (declare (type ir2-block block) (type simple-bit-vector saves restores))
 655   (let ((1block (ir2-block-block block))
 656         (saves-list ())
 657         (restores-list ())
 658         (skipping nil))
 659     (declare (list saves-list restores-list))
 660     (clear-bit-vector saves)
 661     (clear-bit-vector restores)
 662     (do-live-tns (tn (ir2-block-live-in block) block)
 663       (when (and (sc-save-p (tn-sc tn))
 664                  (not (eq (tn-kind tn) :component)))
 665         (let ((num (tn-number tn)))
 666           (setf (sbit restores num) 1)
 667           (push tn restores-list))))
 668
 669     (do ((block block (ir2-block-prev block))
 670          (prev nil block))
 671         ((not (eq (ir2-block-block block) 1block))
 672          (aver (not skipping))
 673          (dolist (save saves-list)
 674            (let ((start (ir2-block-start-vop prev)))
 675              (save-if-necessary save start start)))
 676          prev)
 677       (do ((vop (ir2-block-last-vop block) (vop-prev vop)))
 678           ((null vop))
 679         (let ((info (vop-info vop)))
 680           (case (vop-info-name info)
 681             (allocate-frame
 682              (aver skipping)
 683              (setq skipping nil))
 684             (note-environment-start
 685              (aver (not skipping))
 686              (dolist (save saves-list)
 687                (save-if-necessary save (vop-next vop) vop))
 688              (return-from optimized-emit-saves-block block)))
 689
 690           (unless skipping
 691             (do ((write (vop-results vop) (tn-ref-across write)))
 692                 ((null write))
 693               (let* ((tn (tn-ref-tn write))
 694                      (num (tn-number tn)))
 695                 (unless (zerop (sbit restores num))
 696                   (setf (sbit restores num) 0)
 697                   (setq restores-list
 698                         (delete tn restores-list :test #'eq)))
 699                 (unless (zerop (sbit saves num))
 700                   (setf (sbit saves num) 0)
 701                   (save-if-necessary tn (vop-next vop) vop)
 702                   (setq saves-list
 703                         (delete tn saves-list :test #'eq))))))
 704
 705           (macrolet ((save-note-read (tn)
 706                        `(let* ((tn ,tn)
 707                                (num (tn-number tn)))
 708                           (when (and (sc-save-p (tn-sc tn))
 709                                      (zerop (sbit restores num))
 710                                      (not (eq (tn-kind tn) :component)))
 711                           (setf (sbit restores num) 1)
 712                           (push tn restores-list)))))
 713
 714             (case (vop-info-save-p info)
 715               ((t)
 716                (dolist (tn restores-list)
 717                  (restore-tn tn (vop-next vop) vop)
 718                  (let ((num (tn-number tn)))
 719                    (when (zerop (sbit saves num))
 720                      (push tn saves-list)
 721                      (setf (sbit saves num) 1))))
 722                (setq restores-list nil)
 723                (clear-bit-vector restores))
 724               (:compute-only
 725                (cond ((policy (vop-node vop) (= speed 3))
 726                       (do-live-tns (tn (vop-save-set vop) block)
 727                         (when (zerop (sbit restores (tn-number tn)))
 728                           (note-spilled-tn tn vop))))
 729                      (t
 730                       (do-live-tns (tn (vop-save-set vop) block)
 731                         (save-note-read tn))))))
 732
 733             (if (eq (vop-info-move-args info) :local-call)
 734                 (setq skipping t)
 735                 (do ((read (vop-args vop) (tn-ref-across read)))
 736                     ((null read))
 737                   (save-note-read (tn-ref-tn read))))))))))
 738
 739 ;;; This is like EMIT-SAVES, only different. We avoid redundant saving
 740 ;;; within the block, and don't restore values that aren't used before
 741 ;;; the next call. This function is just the top level loop over the
 742 ;;; blocks in the component, which locates blocks that need saving
 743 ;;; done.
 744 (defun optimized-emit-saves (component)
 745   (declare (type component component))
 746   (let* ((gtn-count (1+ (ir2-component-global-tn-counter
 747                          (component-info component))))
 748          (saves (make-array gtn-count :element-type 'bit))
 749          (restores (make-array gtn-count :element-type 'bit))
 750          (block (ir2-block-prev (block-info (component-tail component))))
 751          (head (block-info (component-head component))))
 752     (loop
 753       (when (eq block head) (return))
 754       (when (do ((vop (ir2-block-start-vop block) (vop-next vop)))
 755                 ((null vop) nil)
 756               (when (eq (vop-info-save-p (vop-info vop)) t)
 757                 (return t)))
 758         (setq block (optimized-emit-saves-block block saves restores)))
 759       (setq block (ir2-block-prev block)))))
 760
 761 ;;; Iterate over the normal TNs, finding the cost of packing on the
 762 ;;; stack in units of the number of references. We count all
 763 ;;; references as +1, and subtract out REGISTER-SAVE-PENALTY for each
 764 ;;; place where we would have to save a register.
 765 (defun assign-tn-costs (component)
 766   (do-ir2-blocks (block component)
 767     (do ((vop (ir2-block-start-vop block) (vop-next vop)))
 768         ((null vop))
 769       (when (eq (vop-info-save-p (vop-info vop)) t)
 770         (do-live-tns (tn (vop-save-set vop) block)
 771           (decf (tn-cost tn) *backend-register-save-penalty*)))))
 772
 773   (do ((tn (ir2-component-normal-tns (component-info component))
 774            (tn-next tn)))
 775       ((null tn))
 776     (let ((cost (tn-cost tn)))
 777       (declare (fixnum cost))
 778       (do ((ref (tn-reads tn) (tn-ref-next ref)))
 779           ((null ref))
 780         (incf cost))
 781       (do ((ref (tn-writes tn) (tn-ref-next ref)))
 782           ((null ref))
 783         (incf cost))
 784       (setf (tn-cost tn) cost))))
 785
 786 ;;; Iterate over the normal TNs, storing the depth of the deepest loop
 787 ;;; that the TN is used in TN-LOOP-DEPTH.
 788 (defun assign-tn-depths (component)
 789   (when *loop-analyze*
 790     (do-ir2-blocks (block component)
 791       (do ((vop (ir2-block-start-vop block)
 792                 (vop-next vop)))
 793           ((null vop))
 794         (flet ((find-all-tns (head-fun)
 795                  (collect ((tns))
 796                    (do ((ref (funcall head-fun vop) (tn-ref-across ref)))
 797                        ((null ref))
 798                      (tns (tn-ref-tn ref)))
 799                    (tns))))
 800           (dolist (tn (nconc (find-all-tns #'vop-args)
 801                              (find-all-tns #'vop-results)
 802                              (find-all-tns #'vop-temps)
 803                              ;; What does "references in this VOP
 804                              ;; mean"? Probably something that isn't
 805                              ;; useful in this context, since these
 806                              ;; TN-REFs are linked with TN-REF-NEXT
 807                              ;; instead of TN-REF-ACROSS. --JES
 808                              ;; 2004-09-11
 809                              ;; (find-all-tns #'vop-refs)
 810                              ))
 811             (setf (tn-loop-depth tn)
 812                   (max (tn-loop-depth tn)
 813                        (let* ((ir1-block (ir2-block-block (vop-block vop)))
 814                               (loop (block-loop ir1-block)))
 815                          (if loop
 816                              (loop-depth loop)
 817                              0))))))))))
 818
 819 \f
 820 ;;;; load TN packing
 821
 822 ;;; These variables indicate the last location at which we computed
 823 ;;; the Live-TNs. They hold the BLOCK and VOP values that were passed
 824 ;;; to COMPUTE-LIVE-TNS.
 825 (defvar *live-block*)
 826 (defvar *live-vop*)
 827
 828 ;;; If we unpack some TNs, then we mark all affected blocks by
 829 ;;; sticking them in this hash-table. This is initially null. We
 830 ;;; create the hashtable if we do any unpacking.
 831 (defvar *repack-blocks*)
 832 (declaim (type list *repack-blocks*))
 833
 834 ;;; Set the LIVE-TNS vectors in all :FINITE SBs to represent the TNs
 835 ;;; live at the end of BLOCK.
 836 (defun init-live-tns (block)
 837   (dolist (sb *backend-sb-list*)
 838     (when (eq (sb-kind sb) :finite)
 839       (fill (finite-sb-live-tns sb) nil)))
 840
 841   (do-live-tns (tn (ir2-block-live-in block) block)
 842     (let* ((sc (tn-sc tn))
 843            (sb (sc-sb sc)))
 844       (when (eq (sb-kind sb) :finite)
 845         ;; KLUDGE: we can have "live" TNs that are neither read
 846         ;; to nor written from, due to more aggressive (type-
 847         ;; directed) constant propagation.  Such TNs will never
 848         ;; be assigned an offset nor be in conflict with anything.
 849         ;;
 850         ;; Ideally, it seems to me we could make sure these TNs
 851         ;; are never allocated in the first place in
 852         ;; ASSIGN-LAMBDA-VAR-TNS.
 853         (if (tn-offset tn)
 854             (do ((offset (tn-offset tn) (1+ offset))
 855                  (end (+ (tn-offset tn) (sc-element-size sc))))
 856                 ((= offset end))
 857               (declare (type index offset end))
 858               (setf (svref (finite-sb-live-tns sb) offset) tn))
 859             (assert (and (null (tn-reads tn))
 860                          (null (tn-writes tn))))))))
 861
 862   (setq *live-block* block)
 863   (setq *live-vop* (ir2-block-last-vop block))
 864
 865   (values))
 866
 867 ;;; Set the LIVE-TNs in :FINITE SBs to represent the TNs live
 868 ;;; immediately after the evaluation of VOP in BLOCK, excluding
 869 ;;; results of the VOP. If VOP is null, then compute the live TNs at
 870 ;;; the beginning of the block. Sequential calls on the same block
 871 ;;; must be in reverse VOP order.
 872 (defun compute-live-tns (block vop)
 873   (declare (type ir2-block block) (type vop vop))
 874   (unless (eq block *live-block*)
 875     (init-live-tns block))
 876
 877   (do ((current *live-vop* (vop-prev current)))
 878       ((eq current vop)
 879        (do ((res (vop-results vop) (tn-ref-across res)))
 880            ((null res))
 881          (let* ((tn (tn-ref-tn res))
 882                 (sc (tn-sc tn))
 883                 (sb (sc-sb sc)))
 884            (when (eq (sb-kind sb) :finite)
 885              (do ((offset (tn-offset tn) (1+ offset))
 886                   (end (+ (tn-offset tn) (sc-element-size sc))))
 887                  ((= offset end))
 888                (declare (type index offset end))
 889                (setf (svref (finite-sb-live-tns sb) offset) nil))))))
 890     (do ((ref (vop-refs current) (tn-ref-next-ref ref)))
 891         ((null ref))
 892       (let ((ltn (tn-ref-load-tn ref)))
 893         (when ltn
 894           (let* ((sc (tn-sc ltn))
 895                  (sb (sc-sb sc)))
 896             (when (eq (sb-kind sb) :finite)
 897               (let ((tns (finite-sb-live-tns sb)))
 898                 (do ((offset (tn-offset ltn) (1+ offset))
 899                      (end (+ (tn-offset ltn) (sc-element-size sc))))
 900                     ((= offset end))
 901                   (declare (type index offset end))
 902                   (aver (null (svref tns offset)))))))))
 903
 904       (let* ((tn (tn-ref-tn ref))
 905              (sc (tn-sc tn))
 906              (sb (sc-sb sc)))
 907         (when (eq (sb-kind sb) :finite)
 908           (let ((tns (finite-sb-live-tns sb)))
 909             (do ((offset (tn-offset tn) (1+ offset))
 910                  (end (+ (tn-offset tn) (sc-element-size sc))))
 911                 ((= offset end))
 912               (declare (type index offset end))
 913               (if (tn-ref-write-p ref)
 914                   (setf (svref tns offset) nil)
 915                   (let ((old (svref tns offset)))
 916                     (aver (or (null old) (eq old tn)))
 917                     (setf (svref tns offset) tn)))))))))
 918
 919   (setq *live-vop* vop)
 920   (values))
 921
 922 ;;; This is kind of like OFFSET-CONFLICTS-IN-SB, except that it uses
 923 ;;; the VOP refs to determine whether a Load-TN for OP could be packed
 924 ;;; in the specified location, disregarding conflicts with TNs not
 925 ;;; referenced by this VOP. There is a conflict if either:
 926 ;;;  1. The reference is a result, and the same location is either:
 927 ;;;     -- Used by some other result.
 928 ;;;     -- Used in any way after the reference (exclusive).
 929 ;;;  2. The reference is an argument, and the same location is either:
 930 ;;;     -- Used by some other argument.
 931 ;;;     -- Used in any way before the reference (exclusive).
 932 ;;;
 933 ;;; In 1 (and 2) above, the first bullet corresponds to result-result
 934 ;;; (and argument-argument) conflicts. We need this case because there
 935 ;;; aren't any TN-REFs to represent the implicit reading of results or
 936 ;;; writing of arguments.
 937 ;;;
 938 ;;; The second bullet corresponds to conflicts with temporaries or
 939 ;;; between arguments and results.
 940 ;;;
 941 ;;; We consider both the TN-REF-TN and the TN-REF-LOAD-TN (if any) to
 942 ;;; be referenced simultaneously and in the same way. This causes
 943 ;;; load-TNs to appear live to the beginning (or end) of the VOP, as
 944 ;;; appropriate.
 945 ;;;
 946 ;;; We return a conflicting TN if there is a conflict.
 947 (defun load-tn-offset-conflicts-in-sb (op sb offset)
 948   (declare (type tn-ref op) (type finite-sb sb) (type index offset))
 949   (aver (eq (sb-kind sb) :finite))
 950   (let ((vop (tn-ref-vop op)))
 951     (labels ((tn-overlaps (tn)
 952                (let ((sc (tn-sc tn))
 953                      (tn-offset (tn-offset tn)))
 954                  (when (and (eq (sc-sb sc) sb)
 955                             (<= tn-offset offset)
 956                             (< offset
 957                                (the index
 958                                     (+ tn-offset (sc-element-size sc)))))
 959                    tn)))
 960              (same (ref)
 961                (let ((tn (tn-ref-tn ref))
 962                      (ltn (tn-ref-load-tn ref)))
 963                  (or (tn-overlaps tn)
 964                      (and ltn (tn-overlaps ltn)))))
 965              (is-op (ops)
 966                (do ((ops ops (tn-ref-across ops)))
 967                    ((null ops) nil)
 968                  (let ((found (same ops)))
 969                    (when (and found (not (eq ops op)))
 970                      (return found)))))
 971              (is-ref (refs end)
 972                (do ((refs refs (tn-ref-next-ref refs)))
 973                    ((eq refs end) nil)
 974                  (let ((found (same refs)))
 975                  (when found (return found))))))
 976       (declare (inline is-op is-ref tn-overlaps))
 977       (if (tn-ref-write-p op)
 978           (or (is-op (vop-results vop))
 979               (is-ref (vop-refs vop) op))
 980           (or (is-op (vop-args vop))
 981               (is-ref (tn-ref-next-ref op) nil))))))
 982
 983 ;;; Iterate over all the elements in the SB that would be allocated by
 984 ;;; allocating a TN in SC at Offset, checking for conflict with
 985 ;;; load-TNs or other TNs (live in the LIVE-TNS, which must be set
 986 ;;; up.) We also return true if there aren't enough locations after
 987 ;;; Offset to hold a TN in SC. If Ignore-Live is true, then we ignore
 988 ;;; the live-TNs, considering only references within Op's VOP.
 989 ;;;
 990 ;;; We return a conflicting TN, or :OVERFLOW if the TN won't fit.
 991 (defun load-tn-conflicts-in-sc (op sc offset ignore-live)
 992   (let* ((sb (sc-sb sc))
 993          (size (finite-sb-current-size sb)))
 994     (do ((i offset (1+ i))
 995          (end (+ offset (sc-element-size sc))))
 996         ((= i end) nil)
 997       (declare (type index i end))
 998       (let ((res (or (when (>= i size) :overflow)
 999                      (and (not ignore-live)
1000                           (svref (finite-sb-live-tns sb) i))
1001                      (load-tn-offset-conflicts-in-sb op sb i))))
1002         (when res (return res))))))
1003
1004 ;;; If a load-TN for OP is targeted to a legal location in SC, then
1005 ;;; return the offset, otherwise return NIL. We see whether the target
1006 ;;; of the operand is packed, and try that location. There isn't any
1007 ;;; need to chain down the target path, since everything is packed
1008 ;;; now.
1009 ;;;
1010 ;;; We require the target to be in SC (and not merely to overlap with
1011 ;;; SC). This prevents SC information from being lost in load TNs (we
1012 ;;; won't pack a load TN in ANY-REG when it is targeted to a
1013 ;;; DESCRIPTOR-REG.) This shouldn't hurt the code as long as all
1014 ;;; relevant overlapping SCs are allowed in the operand SC
1015 ;;; restriction.
1016 (defun find-load-tn-target (op sc)
1017   (declare (inline member))
1018   (let ((target (tn-ref-target op)))
1019     (when target
1020       (let* ((tn (tn-ref-tn target))
1021              (loc (tn-offset tn)))
1022         (if (and (eq (tn-sc tn) sc)
1023                  (member (the index loc) (sc-locations sc))
1024                  (not (load-tn-conflicts-in-sc op sc loc nil)))
1025             loc
1026             nil)))))
1027
1028 ;;; Select a legal location for a load TN for Op in SC. We just
1029 ;;; iterate over the SC's locations. If we can't find a legal
1030 ;;; location, return NIL.
1031 (defun select-load-tn-location (op sc)
1032   (declare (type tn-ref op) (type sc sc))
1033
1034   ;; Check any target location first.
1035   (let ((target (tn-ref-target op)))
1036     (when target
1037       (let* ((tn (tn-ref-tn target))
1038              (loc (tn-offset tn)))
1039         (when (and (eq (sc-sb sc) (sc-sb (tn-sc tn)))
1040                    (member (the index loc) (sc-locations sc))
1041                    (not (load-tn-conflicts-in-sc op sc loc nil)))
1042               (return-from select-load-tn-location loc)))))
1043
1044   (dolist (loc (sc-locations sc) nil)
1045     (unless (load-tn-conflicts-in-sc op sc loc nil)
1046       (return loc))))
1047
1048 (defevent unpack-tn "Unpacked a TN to satisfy operand SC restriction.")
1049
1050 ;;; Make TN's location the same as for its save TN (allocating a save
1051 ;;; TN if necessary.) Delete any save/restore code that has been
1052 ;;; emitted thus far. Mark all blocks containing references as needing
1053 ;;; to be repacked.
1054 (defun unpack-tn (tn)
1055   (event unpack-tn)
1056   (let ((stn (or (tn-save-tn tn)
1057                  (pack-save-tn tn))))
1058     (setf (tn-sc tn) (tn-sc stn))
1059     (setf (tn-offset tn) (tn-offset stn))
1060     (flet ((zot (refs)
1061              (do ((ref refs (tn-ref-next ref)))
1062                  ((null ref))
1063                (let ((vop (tn-ref-vop ref)))
1064                  (if (eq (vop-info-name (vop-info vop)) 'move-operand)
1065                      (delete-vop vop)
1066                      (pushnew (vop-block vop) *repack-blocks*))))))
1067       (zot (tn-reads tn))
1068       (zot (tn-writes tn))))
1069
1070   (values))
1071
1072 (defevent unpack-fallback "Unpacked some operand TN.")
1073
1074 ;;; This is called by PACK-LOAD-TN where there isn't any location free
1075 ;;; that we can pack into. What we do is move some live TN in one of
1076 ;;; the specified SCs to memory, then mark all blocks that reference
1077 ;;; the TN as needing repacking. If we succeed, we throw to UNPACKED-TN.
1078 ;;; If we fail, we return NIL.
1079 ;;;
1080 ;;; We can unpack any live TN that appears in the NORMAL-TNs list
1081 ;;; (isn't wired or restricted.) We prefer to unpack TNs that are not
1082 ;;; used by the VOP. If we can't find any such TN, then we unpack some
1083 ;;; argument or result TN. The only way we can fail is if all
1084 ;;; locations in SC are used by load-TNs or temporaries in VOP.
1085 (defun unpack-for-load-tn (sc op)
1086   (declare (type sc sc) (type tn-ref op))
1087   (let ((sb (sc-sb sc))
1088         (normal-tns (ir2-component-normal-tns
1089                      (component-info *component-being-compiled*)))
1090         (node (vop-node (tn-ref-vop op)))
1091         (fallback nil))
1092     (flet ((unpack-em (victims)
1093              (pushnew (vop-block (tn-ref-vop op)) *repack-blocks*)
1094              (dolist (victim victims)
1095                (event unpack-tn node)
1096                (unpack-tn victim))
1097              (throw 'unpacked-tn nil)))
1098       (dolist (loc (sc-locations sc))
1099         (declare (type index loc))
1100         (block SKIP
1101           (collect ((victims nil adjoin))
1102             (do ((i loc (1+ i))
1103                  (end (+ loc (sc-element-size sc))))
1104                 ((= i end))
1105               (declare (type index i end))
1106               (let ((victim (svref (finite-sb-live-tns sb) i)))
1107                 (when victim
1108                   (unless (find-in #'tn-next victim normal-tns)
1109                     (return-from SKIP))
1110                   (victims victim))))
1111
1112             (let ((conf (load-tn-conflicts-in-sc op sc loc t)))
1113               (cond ((not conf)
1114                      (unpack-em (victims)))
1115                     ((eq conf :overflow))
1116                     ((not fallback)
1117                      (cond ((find conf (victims))
1118                             (setq fallback (victims)))
1119                            ((find-in #'tn-next conf normal-tns)
1120                             (setq fallback (list conf))))))))))
1121
1122       (when fallback
1123         (event unpack-fallback node)
1124         (unpack-em fallback))))
1125
1126   nil)
1127
1128 ;;; Try to pack a load TN in the SCs indicated by Load-SCs. If we run
1129 ;;; out of SCs, then we unpack some TN and try again. We return the
1130 ;;; packed load TN.
1131 ;;;
1132 ;;; Note: we allow a Load-TN to be packed in the target location even
1133 ;;; if that location is in a SC not allowed by the primitive type.
1134 ;;; (The SC must still be allowed by the operand restriction.) This
1135 ;;; makes move VOPs more efficient, since we won't do a move from the
1136 ;;; stack into a non-descriptor any-reg through a descriptor argument
1137 ;;; load-TN. This does give targeting some real semantics, making it
1138 ;;; not a pure advisory to pack. It allows pack to do some packing it
1139 ;;; wouldn't have done before.
1140 (defun pack-load-tn (load-scs op)
1141   (declare (type sc-vector load-scs) (type tn-ref op))
1142   (let ((vop (tn-ref-vop op)))
1143     (compute-live-tns (vop-block vop) vop))
1144
1145   (let* ((tn (tn-ref-tn op))
1146          (ptype (tn-primitive-type tn))
1147          (scs (svref load-scs (sc-number (tn-sc tn)))))
1148     (let ((current-scs scs)
1149           (allowed ()))
1150       (loop
1151         (cond
1152          ((null current-scs)
1153           (unless allowed
1154             (no-load-scs-allowed-by-primitive-type-error op))
1155           (dolist (sc allowed)
1156             (unpack-for-load-tn sc op))
1157           (failed-to-pack-load-tn-error allowed op))
1158         (t
1159          (let* ((sc (svref *backend-sc-numbers* (pop current-scs)))
1160                 (target (find-load-tn-target op sc)))
1161            (when (or target (sc-allowed-by-primitive-type sc ptype))
1162              (let ((loc (or target
1163                             (select-load-tn-location op sc))))
1164                (when loc
1165                  (let ((res (make-tn 0 :load nil sc)))
1166                    (setf (tn-offset res) loc)
1167                    (return res))))
1168              (push sc allowed)))))))))
1169
1170 ;;; Scan a list of load-SCs vectors and a list of TN-REFS threaded by
1171 ;;; TN-REF-ACROSS. When we find a reference whose TN doesn't satisfy
1172 ;;; the restriction, we pack a Load-TN and load the operand into it.
1173 ;;; If a load-tn has already been allocated, we can assume that the
1174 ;;; restriction is satisfied.
1175 #!-sb-fluid (declaim (inline check-operand-restrictions))
1176 (defun check-operand-restrictions (scs ops)
1177   (declare (list scs) (type (or tn-ref null) ops))
1178
1179   ;; Check the targeted operands first.
1180   (do ((scs scs (cdr scs))
1181        (op ops (tn-ref-across op)))
1182       ((null scs))
1183       (let ((target (tn-ref-target op)))
1184         (when target
1185            (let* ((load-tn (tn-ref-load-tn op))
1186                   (load-scs (svref (car scs)
1187                                    (sc-number
1188                                     (tn-sc (or load-tn (tn-ref-tn op)))))))
1189              (if load-tn
1190                  (aver (eq load-scs t))
1191                (unless (eq load-scs t)
1192                        (setf (tn-ref-load-tn op)
1193                              (pack-load-tn (car scs) op))))))))
1194
1195   (do ((scs scs (cdr scs))
1196        (op ops (tn-ref-across op)))
1197       ((null scs))
1198       (let ((target (tn-ref-target op)))
1199         (unless target
1200            (let* ((load-tn (tn-ref-load-tn op))
1201                   (load-scs (svref (car scs)
1202                                    (sc-number
1203                                     (tn-sc (or load-tn (tn-ref-tn op)))))))
1204              (if load-tn
1205                  (aver (eq load-scs t))
1206                (unless (eq load-scs t)
1207                        (setf (tn-ref-load-tn op)
1208                              (pack-load-tn (car scs) op))))))))
1209
1210   (values))
1211
1212 ;;; Scan the VOPs in BLOCK, looking for operands whose SC restrictions
1213 ;;; aren't satisfied. We do the results first, since they are
1214 ;;; evaluated later, and our conflict analysis is a backward scan.
1215 (defun pack-load-tns (block)
1216   (catch 'unpacked-tn
1217     (let ((*live-block* nil)
1218           (*live-vop* nil))
1219       (do ((vop (ir2-block-last-vop block) (vop-prev vop)))
1220           ((null vop))
1221         (let ((info (vop-info vop)))
1222           (check-operand-restrictions (vop-info-result-load-scs info)
1223                                       (vop-results vop))
1224           (check-operand-restrictions (vop-info-arg-load-scs info)
1225                                       (vop-args vop))))))
1226   (values))
1227 \f
1228 ;;;; targeting
1229
1230 ;;; Link the TN-REFS READ and WRITE together using the TN-REF-TARGET
1231 ;;; when this seems like a good idea. Currently we always do, as this
1232 ;;; increases the success of load-TN targeting.
1233 (defun target-if-desirable (read write)
1234   (declare (type tn-ref read write))
1235   ;; As per the comments at the definition of TN-REF-TARGET, read and
1236   ;; write refs are always paired, with TARGET in the read pointing to
1237   ;; the write and vice versa.
1238   (aver (eq (tn-ref-write-p read)
1239             (not (tn-ref-write-p write))))
1240   (setf (tn-ref-target read) write)
1241   (setf (tn-ref-target write) read))
1242
1243 ;;; If TN can be packed into SC so as to honor a preference to TARGET,
1244 ;;; then return the offset to pack at, otherwise return NIL. TARGET
1245 ;;; must be already packed.
1246 (defun check-ok-target (target tn sc)
1247   (declare (type tn target tn) (type sc sc) (inline member))
1248   (let* ((loc (tn-offset target))
1249          (target-sc (tn-sc target))
1250          (target-sb (sc-sb target-sc)))
1251     (declare (type index loc))
1252     ;; We can honor a preference if:
1253     ;; -- TARGET's location is in SC's locations.
1254     ;; -- The element sizes of the two SCs are the same.
1255     ;; -- TN doesn't conflict with target's location.
1256     (if (and (eq target-sb (sc-sb sc))
1257              (or (eq (sb-kind target-sb) :unbounded)
1258                  (member loc (sc-locations sc)))
1259              (= (sc-element-size target-sc) (sc-element-size sc))
1260              (not (conflicts-in-sc tn sc loc))
1261              (zerop (mod loc (sc-alignment sc))))
1262         loc
1263         nil)))
1264
1265 ;;; Scan along the target path from TN, looking at readers or writers.
1266 ;;; When we find a packed TN, return CHECK-OK-TARGET of that TN. If
1267 ;;; there is no target, or if the TN has multiple readers (writers),
1268 ;;; then we return NIL. We also always return NIL after 10 iterations
1269 ;;; to get around potential circularity problems.
1270 ;;;
1271 ;;; FIXME: (30 minutes of reverse engineering?) It'd be nice to
1272 ;;; rewrite the header comment here to explain the interface and its
1273 ;;; motivation, and move remarks about implementation details (like
1274 ;;; 10!) inside.
1275 (defun find-ok-target-offset (tn sc)
1276   (declare (type tn tn) (type sc sc))
1277   (flet ((frob-slot (slot-fun)
1278            (declare (type function slot-fun))
1279            (let ((count 10)
1280                  (current tn))
1281              (declare (type index count))
1282              (loop
1283               (let ((refs (funcall slot-fun current)))
1284                 (unless (and (plusp count)
1285                              refs
1286                              (not (tn-ref-next refs)))
1287                   (return nil))
1288                 (let ((target (tn-ref-target refs)))
1289                   (unless target (return nil))
1290                   (setq current (tn-ref-tn target))
1291                   (when (tn-offset current)
1292                     (return (check-ok-target current tn sc)))
1293                   (decf count)))))))
1294     (declare (inline frob-slot)) ; until DYNAMIC-EXTENT works
1295     (or (frob-slot #'tn-reads)
1296         (frob-slot #'tn-writes))))
1297 \f
1298 ;;;; location selection
1299
1300 ;;; Select some location for TN in SC, returning the offset if we
1301 ;;; succeed, and NIL if we fail.
1302 ;;;
1303 ;;; For :UNBOUNDED SCs just find the smallest correctly aligned offset
1304 ;;; where the TN doesn't conflict with the TNs that have already been
1305 ;;; packed. For :FINITE SCs try to pack the TN into the most heavily
1306 ;;; used locations first (as estimated in FIND-LOCATION-USAGE).
1307 ;;;
1308 ;;; Historically SELECT-LOCATION tried did the opposite and tried to
1309 ;;; distribute the TNs evenly across the available locations. At least
1310 ;;; on register-starved architectures (x86) this seems to be a bad
1311 ;;; strategy. -- JES 2004-09-11
1312 (defun select-location (tn sc &key use-reserved-locs optimize)
1313   (declare (type tn tn) (type sc sc) (inline member))
1314   (let* ((sb (sc-sb sc))
1315          (element-size (sc-element-size sc))
1316          (alignment (sc-alignment sc))
1317          (align-mask (1- alignment))
1318          (size (finite-sb-current-size sb)))
1319     (flet ((attempt-location (start-offset)
1320              (let ((conflict (conflicts-in-sc tn sc start-offset)))
1321                (if conflict
1322                    (logandc2 (+ conflict align-mask 1)
1323                              align-mask)
1324                    (return-from select-location start-offset)))))
1325       (if (eq (sb-kind sb) :unbounded)
1326           (loop with offset = 0
1327                 until (> (+ offset element-size) size) do
1328                 (setf offset (attempt-location offset)))
1329           (let ((locations (sc-locations sc)))
1330             (when optimize
1331               (setf locations
1332                     (stable-sort (copy-list locations) #'>
1333                                  :key (lambda (location-offset)
1334                                         (loop for offset from location-offset
1335                                               repeat element-size
1336                                               maximize (svref
1337                                                         (finite-sb-always-live-count sb)
1338                                                         offset))))))
1339             (dolist (offset locations)
1340               (when (or use-reserved-locs
1341                         (not (member offset
1342                                      (sc-reserve-locations sc))))
1343                 (attempt-location offset))))))))
1344
1345 ;;; If a save TN, return the saved TN, otherwise return TN. This is
1346 ;;; useful for getting the conflicts of a TN that might be a save TN.
1347 (defun original-tn (tn)
1348   (declare (type tn tn))
1349   (if (member (tn-kind tn) '(:save :save-once :specified-save))
1350       (tn-save-tn tn)
1351       tn))
1352 \f
1353 ;;;; pack interface
1354
1355 ;;; Attempt to pack TN in all possible SCs, first in the SC chosen by
1356 ;;; representation selection, then in the alternate SCs in the order
1357 ;;; they were specified in the SC definition. If the TN-COST is
1358 ;;; negative, then we don't attempt to pack in SCs that must be saved.
1359 ;;; If Restricted, then we can only pack in TN-SC, not in any
1360 ;;; Alternate-SCs.
1361 ;;;
1362 ;;; If we are attempting to pack in the SC of the save TN for a TN
1363 ;;; with a :SPECIFIED-SAVE TN, then we pack in that location, instead
1364 ;;; of allocating a new stack location.
1365 (defun pack-tn (tn restricted optimize &key (allow-unbounded-sc t))
1366   (declare (type tn tn))
1367   (let* ((original (original-tn tn))
1368          (fsc (tn-sc tn))
1369          (alternates (unless restricted (sc-alternate-scs fsc)))
1370          (save (tn-save-tn tn))
1371          (specified-save-sc
1372           (when (and save
1373                      (eq (tn-kind save) :specified-save))
1374             (tn-sc save))))
1375     (do ((sc fsc (pop alternates)))
1376         ((null sc)
1377          (failed-to-pack-error tn restricted))
1378       (unless (or allow-unbounded-sc
1379                   (neq (sb-kind (sc-sb sc)) :unbounded))
1380         (return nil))
1381       (when (eq sc specified-save-sc)
1382         (unless (tn-offset save)
1383           (pack-tn save nil optimize))
1384         (setf (tn-offset tn) (tn-offset save))
1385         (setf (tn-sc tn) (tn-sc save))
1386         (return t))
1387       (when (or restricted
1388                 (not (and (minusp (tn-cost tn)) (sc-save-p sc))))
1389         (let ((loc (or (find-ok-target-offset original sc)
1390                        (select-location original sc)
1391                        (and restricted
1392                             (select-location original sc :use-reserved-locs t))
1393                        (when (eq (sb-kind (sc-sb sc)) :unbounded)
1394                          (grow-sc sc)
1395                          (or (select-location original sc)
1396                              (error "failed to pack after growing SC?"))))))
1397           (when loc
1398             (add-location-conflicts original sc loc optimize)
1399             (setf (tn-sc tn) sc)
1400             (setf (tn-offset tn) loc)
1401             (return t))))))
1402   (values))
1403
1404 ;;; Pack a wired TN, checking that the offset is in bounds for the SB,
1405 ;;; and that the TN doesn't conflict with some other TN already packed
1406 ;;; in that location. If the TN is wired to a location beyond the end
1407 ;;; of a :UNBOUNDED SB, then grow the SB enough to hold the TN.
1408 ;;;
1409 ;;; ### Checking for conflicts is disabled for :SPECIFIED-SAVE TNs.
1410 ;;; This is kind of a hack to make specifying wired stack save
1411 ;;; locations for local call arguments (such as OLD-FP) work, since
1412 ;;; the caller and callee OLD-FP save locations may conflict when the
1413 ;;; save locations don't really (due to being in different frames.)
1414 (defun pack-wired-tn (tn optimize)
1415   (declare (type tn tn))
1416   (let* ((sc (tn-sc tn))
1417          (sb (sc-sb sc))
1418          (offset (tn-offset tn))
1419          (end (+ offset (sc-element-size sc)))
1420          (original (original-tn tn)))
1421     (when (> end (finite-sb-current-size sb))
1422       (unless (eq (sb-kind sb) :unbounded)
1423         (error "~S is wired to a location that is out of bounds." tn))
1424       (grow-sc sc end))
1425
1426     ;; For non-x86 ports the presence of a save-tn associated with a
1427     ;; tn is used to identify the old-fp and return-pc tns. It depends
1428     ;; on the old-fp and return-pc being passed in registers.
1429     #!-(or x86 x86-64)
1430     (when (and (not (eq (tn-kind tn) :specified-save))
1431                (conflicts-in-sc original sc offset))
1432       (error "~S is wired to a location that it conflicts with." tn))
1433
1434     ;; Use the above check, but only print a verbose warning. This can
1435     ;; be helpful for debugging the x86 port.
1436     #+nil
1437     (when (and (not (eq (tn-kind tn) :specified-save))
1438                (conflicts-in-sc original sc offset))
1439           (format t "~&* Pack-wired-tn possible conflict:~%  ~
1440                      tn: ~S; tn-kind: ~S~%  ~
1441                      sc: ~S~%  ~
1442                      sb: ~S; sb-name: ~S; sb-kind: ~S~%  ~
1443                      offset: ~S; end: ~S~%  ~
1444                      original ~S~%  ~
1445                      tn-save-tn: ~S; tn-kind of tn-save-tn: ~S~%"
1446                   tn (tn-kind tn) sc
1447                   sb (sb-name sb) (sb-kind sb)
1448                   offset end
1449                   original
1450                   (tn-save-tn tn) (tn-kind (tn-save-tn tn))))
1451
1452     ;; On the x86 ports the old-fp and return-pc are often passed on
1453     ;; the stack so the above hack for the other ports does not always
1454     ;; work. Here the old-fp and return-pc tns are identified by being
1455     ;; on the stack in their standard save locations.
1456     #!+(or x86 x86-64)
1457     (when (and (not (eq (tn-kind tn) :specified-save))
1458                (not (and (string= (sb-name sb) "STACK")
1459                          (or (= offset 0)
1460                              (= offset 1))))
1461                (conflicts-in-sc original sc offset))
1462       (error "~S is wired to a location that it conflicts with." tn))
1463
1464     (add-location-conflicts original sc offset optimize)))
1465
1466 (defevent repack-block "Repacked a block due to TN unpacking.")
1467
1468 ;;; KLUDGE: Prior to SBCL version 0.8.9.xx, this function was known as
1469 ;;; PACK-BEFORE-GC-HOOK, but was non-functional since approximately
1470 ;;; version 0.8.3.xx since the removal of GC hooks from the system.
1471 ;;; This currently (as of 2004-04-12) runs now after every call to
1472 ;;; PACK, rather than -- as was originally intended -- once per GC
1473 ;;; cycle; this is probably non-optimal, and might require tuning,
1474 ;;; maybe to be called when the data structures exceed a certain size,
1475 ;;; or maybe once every N times.  The KLUDGE is that this rewrite has
1476 ;;; done nothing to improve the reentrance or threadsafety of the
1477 ;;; compiler; it still fails to be callable from several threads at
1478 ;;; the same time.
1479 ;;;
1480 ;;; Brief experiments indicate that during a compilation cycle this
1481 ;;; causes about 10% more consing, and takes about 1%-2% more time.
1482 ;;;
1483 ;;; -- CSR, 2004-04-12
1484 (defun clean-up-pack-structures ()
1485   (dolist (sb *backend-sb-list*)
1486     (unless (eq (sb-kind sb) :non-packed)
1487       (let ((size (sb-size sb)))
1488         (fill (finite-sb-always-live sb) nil)
1489         (setf (finite-sb-always-live sb)
1490               (make-array size
1491                           :initial-element
1492                           #-sb-xc #*
1493                           ;; The cross-compiler isn't very good at
1494                           ;; dumping specialized arrays, so we delay
1495                           ;; construction of this SIMPLE-BIT-VECTOR
1496                           ;; until runtime.
1497                           #+sb-xc (make-array 0 :element-type 'bit)))
1498         (setf (finite-sb-always-live-count sb)
1499               (make-array size
1500                           :initial-element
1501                           #-sb-xc #*
1502                           ;; Ibid
1503                           #+sb-xc (make-array 0 :element-type 'fixnum)))
1504
1505         (fill (finite-sb-conflicts sb) nil)
1506         (setf (finite-sb-conflicts sb)
1507               (make-array size :initial-element '#()))
1508
1509         (fill (finite-sb-live-tns sb) nil)
1510         (setf (finite-sb-live-tns sb)
1511               (make-array size :initial-element nil))))))
1512
1513 (defun tn-lexical-depth (tn)
1514   (let ((path t)) ; dummy initial value
1515     (labels ((path (lambda)
1516                (nreverse (loop while lambda
1517                                collect lambda
1518                                do (setf lambda (lambda-parent lambda)))))
1519              (register-scope (lambda)
1520                (let ((new-path (path lambda)))
1521                  (setf path (if (eql path t)
1522                                 new-path
1523                                 (subseq path
1524                                         0 (mismatch path new-path))))))
1525              (walk-tn-refs (ref)
1526                (do ((ref ref (tn-ref-next ref)))
1527                    ((null ref))
1528                  (binding* ((node (vop-node (tn-ref-vop ref))
1529                                   :exit-if-null))
1530                    (register-scope (lexenv-lambda
1531                                     (node-lexenv node)))))))
1532       (walk-tn-refs (tn-reads tn))
1533       (walk-tn-refs (tn-writes tn))
1534       (if (eql path t)
1535           most-positive-fixnum
1536           (length path)))))
1537
1538 (defun pack (component)
1539   (unwind-protect
1540        (let ((optimize nil)
1541              (2comp (component-info component)))
1542          (init-sb-vectors component)
1543
1544          ;; Determine whether we want to do more expensive packing by
1545          ;; checking whether any blocks in the component have (> SPEED
1546          ;; COMPILE-SPEED).
1547          ;;
1548          ;; FIXME: This means that a declaration can have a minor
1549          ;; effect even outside its scope, and as the packing is done
1550          ;; component-globally it'd be tricky to use strict scoping. I
1551          ;; think this is still acceptable since it's just a tradeoff
1552          ;; between compilation speed and allocation quality and
1553          ;; doesn't affect the semantics of the generated code in any
1554          ;; way. -- JES 2004-10-06
1555          (do-ir2-blocks (block component)
1556            (when (policy (block-last (ir2-block-block block))
1557                          (> speed compilation-speed))
1558              (setf optimize t)
1559              (return)))
1560
1561          ;; Call the target functions.
1562          (do-ir2-blocks (block component)
1563            (do ((vop (ir2-block-start-vop block) (vop-next vop)))
1564                ((null vop))
1565              (let ((target-fun (vop-info-target-fun (vop-info vop))))
1566                (when target-fun
1567                  (funcall target-fun vop)))))
1568
1569          ;; Pack wired TNs first.
1570          (do ((tn (ir2-component-wired-tns 2comp) (tn-next tn)))
1571              ((null tn))
1572            (pack-wired-tn tn optimize))
1573
1574          ;; Pack restricted component TNs.
1575          (do ((tn (ir2-component-restricted-tns 2comp) (tn-next tn)))
1576              ((null tn))
1577            (when (eq (tn-kind tn) :component)
1578              (pack-tn tn t optimize)))
1579
1580          ;; Pack other restricted TNs.
1581          (do ((tn (ir2-component-restricted-tns 2comp) (tn-next tn)))
1582              ((null tn))
1583            (unless (tn-offset tn)
1584              (pack-tn tn t optimize)))
1585
1586          ;; Assign costs to normal TNs so we know which ones should
1587          ;; always be packed on the stack.
1588          (when *pack-assign-costs*
1589            (assign-tn-costs component)
1590            (assign-tn-depths component))
1591
1592          ;; Allocate normal TNs, starting with the TNs that are used
1593          ;; in deep loops.  Only allocate in finite SCs (i.e. not on
1594          ;; the stack).
1595          (collect ((tns))
1596            (do-ir2-blocks (block component)
1597              (let ((ltns (ir2-block-local-tns block)))
1598                (do ((i (1- (ir2-block-local-tn-count block)) (1- i)))
1599                    ((minusp i))
1600                  (declare (fixnum i))
1601                  (let ((tn (svref ltns i)))
1602                    (unless (or (null tn)
1603                                (eq tn :more)
1604                                (tn-offset tn))
1605                      ;; If loop analysis has been disabled we might as
1606                      ;; well revert to the old behaviour of just
1607                      ;; packing TNs linearly as they appear.
1608                      (unless *loop-analyze*
1609                        (pack-tn tn nil optimize :allow-unbounded-sc nil))
1610                      (tns tn))))))
1611            (dolist (tn (stable-sort (tns)
1612                                     (lambda (a b)
1613                                       (cond
1614                                         ((> (tn-loop-depth a)
1615                                             (tn-loop-depth b))
1616                                          t)
1617                                         ((= (tn-loop-depth a)
1618                                             (tn-loop-depth b))
1619                                          (> (tn-cost a) (tn-cost b)))
1620                                         (t nil)))))
1621              (unless (tn-offset tn)
1622                (pack-tn tn nil optimize :allow-unbounded-sc nil))))
1623
1624          ;; Pack any leftover normal TNs that could not be allocated
1625          ;; to finite SCs, or TNs that do not appear in any local TN
1626          ;; map (e.g. :MORE TNs).  Since we'll likely be allocating
1627          ;; on the stack, first allocate TNs that are associated with
1628          ;; code at shallow lexical depths: this will allocate long
1629          ;; live ranges (i.e. TNs with more conflicts) first, and
1630          ;; hopefully minimise stack fragmentation.
1631          ;;
1632          ;; Collect in reverse order to give priority to older TNs.
1633          (let ((contiguous-tns '())
1634                (tns '()))
1635            (do ((tn (ir2-component-normal-tns 2comp) (tn-next tn)))
1636                ((null tn))
1637              (unless (tn-offset tn)
1638                (let ((key (cons tn (tn-lexical-depth tn))))
1639                  (if (memq (tn-kind tn) '(:environment :debug-environment
1640                                           :component))
1641                      (push key contiguous-tns)
1642                      (push key tns)))))
1643            (flet ((pack-tns (tns)
1644                     (dolist (tn (stable-sort tns #'< :key #'cdr))
1645                       (let ((tn (car tn)))
1646                         (unless (tn-offset tn)
1647                           (pack-tn tn nil optimize))))))
1648              ;; first pack TNs that are known to have simple
1649              ;; live ranges (contiguous lexical scopes)
1650              (pack-tns contiguous-tns)
1651              (pack-tns tns)))
1652
1653          ;; Do load TN packing and emit saves.
1654          (let ((*repack-blocks* nil))
1655            (cond ((and optimize *pack-optimize-saves*)
1656                   (optimized-emit-saves component)
1657                   (do-ir2-blocks (block component)
1658                     (pack-load-tns block)))
1659                  (t
1660                   (do-ir2-blocks (block component)
1661                     (emit-saves block)
1662                     (pack-load-tns block))))
1663            (loop
1664               (unless *repack-blocks* (return))
1665               (let ((orpb *repack-blocks*))
1666                 (setq *repack-blocks* nil)
1667                 (dolist (block orpb)
1668                   (event repack-block)
1669                   (pack-load-tns block)))))
1670
1671          (values))
1672     (clean-up-pack-structures)))