src/pcl/std-class.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 (defmethod slot-accessor-function ((slotd effective-slot-definition) type)
  27   (let ((info (slot-definition-info slotd)))
  28     (ecase type
  29       (reader (slot-info-reader info))
  30       (writer (slot-info-writer info))
  31       (boundp (slot-info-boundp info)))))
  32
  33 (defmethod (setf slot-accessor-function) (function
  34                                           (slotd effective-slot-definition)
  35                                           type)
  36   (let ((info (slot-definition-info slotd)))
  37     (ecase type
  38       (reader (setf (slot-info-reader info) function))
  39       (writer (setf (slot-info-writer info) function))
  40       (boundp (setf (slot-info-boundp info) function)))))
  41
  42 (defconstant +slotd-reader-function-std-p+ 1)
  43 (defconstant +slotd-writer-function-std-p+ 2)
  44 (defconstant +slotd-boundp-function-std-p+ 4)
  45 (defconstant +slotd-all-function-std-p+ 7)
  46
  47 (defmethod slot-accessor-std-p ((slotd effective-slot-definition) type)
  48   (let ((flags (slot-value slotd 'accessor-flags)))
  49     (declare (type fixnum flags))
  50     (if (eq type 'all)
  51         (eql +slotd-all-function-std-p+ flags)
  52         (let ((mask (ecase type
  53                       (reader +slotd-reader-function-std-p+)
  54                       (writer +slotd-writer-function-std-p+)
  55                       (boundp +slotd-boundp-function-std-p+))))
  56           (declare (type fixnum mask))
  57           (not (zerop (the fixnum (logand mask flags))))))))
  58
  59 (defmethod (setf slot-accessor-std-p) (value
  60                                        (slotd effective-slot-definition)
  61                                        type)
  62   (let ((mask (ecase type
  63                 (reader +slotd-reader-function-std-p+)
  64                 (writer +slotd-writer-function-std-p+)
  65                 (boundp +slotd-boundp-function-std-p+)))
  66         (flags (slot-value slotd 'accessor-flags)))
  67     (declare (type fixnum mask flags))
  68     (setf (slot-value slotd 'accessor-flags)
  69           (if value
  70               (the fixnum (logior mask flags))
  71               (the fixnum (logand (the fixnum (lognot mask)) flags)))))
  72   value)
  73
  74 (defmethod initialize-internal-slot-functions
  75     ((slotd effective-slot-definition))
  76   (let* ((name (slot-value slotd 'name))
  77          (class (slot-value slotd '%class)))
  78     (dolist (type '(reader writer boundp))
  79       (let* ((gf-name (ecase type
  80                               (reader 'slot-value-using-class)
  81                               (writer '(setf slot-value-using-class))
  82                               (boundp 'slot-boundp-using-class)))
  83              (gf (gdefinition gf-name)))
  84         ;; KLUDGE: this logic is cut'n'pasted from
  85         ;; GET-ACCESSOR-METHOD-FUNCTION, which (for STD-CLASSes) is
  86         ;; only called later, because it does things that can't be
  87         ;; computed this early in class finalization; however, we need
  88         ;; this bit as early as possible.  -- CSR, 2009-11-05
  89         (setf (slot-accessor-std-p slotd type)
  90               (let* ((std-method (standard-svuc-method type))
  91                      (str-method (structure-svuc-method type))
  92                      (types1 `((eql ,class) (class-eq ,class) (eql ,slotd)))
  93                      (types (if (eq type 'writer) `(t ,@types1) types1))
  94                      (methods (compute-applicable-methods-using-types gf types)))
  95                 (null (cdr methods))))
  96         (setf (slot-accessor-function slotd type)
  97               (lambda (&rest args)
  98                 (declare (dynamic-extent args))
  99                 ;; FIXME: a tiny amount of wasted SLOT-ACCESSOR-STD-P
 100                 ;; work here (see KLUDGE comment above).
 101                 (let ((fun (compute-slot-accessor-info slotd type gf)))
 102                   (apply fun args))))))))
 103
 104 (defmethod finalize-internal-slot-functions ((slotd effective-slot-definition))
 105   (dolist (type '(reader writer boundp))
 106     (let* ((gf-name (ecase type
 107                       (reader 'slot-value-using-class)
 108                       (writer '(setf slot-value-using-class))
 109                       (boundp 'slot-boundp-using-class)))
 110            (gf (gdefinition gf-name)))
 111       (compute-slot-accessor-info slotd type gf))))
 112
 113 ;;; CMUCL (Gerd PCL 2003-04-25) comment:
 114 ;;;
 115 ;;; Compute an effective method for SLOT-VALUE-USING-CLASS, (SETF
 116 ;;; SLOT-VALUE-USING-CLASS) or SLOT-BOUNDP-USING-CLASS for reading/
 117 ;;; writing/testing effective slot SLOTD.
 118 ;;;
 119 ;;; TYPE is one of the symbols READER, WRITER or BOUNDP, depending on
 120 ;;; GF.  Store the effective method in the effective slot definition
 121 ;;; object itself; these GFs have special dispatch functions calling
 122 ;;; effective methods directly retrieved from effective slot
 123 ;;; definition objects, as an optimization.
 124 ;;;
 125 ;;; FIXME: Change the function name to COMPUTE-SVUC-SLOTD-FUNCTION,
 126 ;;; or some such.
 127 (defmethod compute-slot-accessor-info ((slotd effective-slot-definition)
 128                                        type gf)
 129   (let* ((name (slot-value slotd 'name))
 130          (class (slot-value slotd '%class)))
 131     (multiple-value-bind (function std-p)
 132         (if (eq **boot-state** 'complete)
 133             (get-accessor-method-function gf type class slotd)
 134             (get-optimized-std-accessor-method-function class slotd type))
 135       (setf (slot-accessor-std-p slotd type) std-p)
 136       (setf (slot-accessor-function slotd type) function))))
 137
 138 (defmethod slot-definition-allocation ((slotd structure-slot-definition))
 139   :instance)
 140 \f
 141 ;;;; various class accessors that are a little more complicated than can be
 142 ;;;; done with automatically generated reader methods
 143
 144 (defmethod class-prototype :before (class)
 145   (unless (class-finalized-p class)
 146     (error "~@<~S is not finalized.~:@>" class)))
 147
 148 ;;; KLUDGE: For some reason factoring the common body into a function
 149 ;;; breaks PCL bootstrapping, so just generate it with a macrolet for
 150 ;;; all.
 151 (macrolet ((def (class)
 152              `(defmethod class-prototype ((class ,class))
 153                 (with-slots (prototype) class
 154                   (or prototype
 155                       (setf prototype (allocate-instance class)))))))
 156   (def std-class)
 157   (def condition-class)
 158   (def structure-class))
 159
 160 (defmethod class-direct-default-initargs ((class slot-class))
 161   (plist-value class 'direct-default-initargs))
 162
 163 (defmethod class-default-initargs ((class slot-class))
 164   (plist-value class 'default-initargs))
 165
 166 (defmethod class-slot-cells ((class std-class))
 167   (plist-value class 'class-slot-cells))
 168 (defmethod (setf class-slot-cells) (new-value (class std-class))
 169   (setf (plist-value class 'class-slot-cells) new-value))
 170 \f
 171 ;;;; class accessors that are even a little bit more complicated than those
 172 ;;;; above. These have a protocol for updating them, we must implement that
 173 ;;;; protocol.
 174
 175 ;;; Maintaining the direct subclasses backpointers. The update methods are
 176 ;;; here, the values are read by an automatically generated reader method.
 177 (defmethod add-direct-subclass ((class class) (subclass class))
 178   (with-slots (direct-subclasses) class
 179     (pushnew subclass direct-subclasses :test #'eq)
 180     subclass))
 181 (defmethod remove-direct-subclass ((class class) (subclass class))
 182   (with-slots (direct-subclasses) class
 183     (setq direct-subclasses (remove subclass direct-subclasses))
 184     subclass))
 185
 186 ;;; Maintaining the direct-methods and direct-generic-functions backpointers.
 187 ;;;
 188 ;;; There are four generic functions involved, each has one method for the
 189 ;;; class case and another method for the damned EQL specializers. All of
 190 ;;; these are specified methods and appear in their specified place in the
 191 ;;; class graph.
 192 ;;;
 193 ;;;   ADD-DIRECT-METHOD
 194 ;;;   REMOVE-DIRECT-METHOD
 195 ;;;   SPECIALIZER-DIRECT-METHODS
 196 ;;;   SPECIALIZER-DIRECT-GENERIC-FUNCTIONS
 197 ;;;
 198 ;;; In each case, we maintain one value which is a cons. The car is the list
 199 ;;; methods. The cdr is a list of the generic functions. The cdr is always
 200 ;;; computed lazily.
 201
 202 ;;; This needs to be used recursively, in case a non-trivial user
 203 ;;; defined ADD/REMOVE-DIRECT-METHOD method ends up calling another
 204 ;;; function using the same lock.
 205 (defvar *specializer-lock* (sb-thread:make-mutex :name "Specializer lock"))
 206
 207 (defmethod add-direct-method :around ((specializer specializer) method)
 208   ;; All the actions done under this lock are done in an order
 209   ;; that is safe to unwind at any point.
 210   (sb-thread::with-recursive-system-lock (*specializer-lock*)
 211     (call-next-method)))
 212
 213 (defmethod remove-direct-method :around ((specializer specializer) method)
 214   ;; All the actions done under this lock are done in an order
 215   ;; that is safe to unwind at any point.
 216   (sb-thread::with-recursive-system-lock (*specializer-lock*)
 217     (call-next-method)))
 218
 219 (defmethod add-direct-method ((specializer class) (method method))
 220   (let ((cell (slot-value specializer 'direct-methods)))
 221     ;; We need to first smash the CDR, because a parallel read may
 222     ;; be in progress, and because if an interrupt catches us we
 223     ;; need to have a consistent state.
 224     (setf (cdr cell) ()
 225           (car cell) (adjoin method (car cell) :test #'eq)))
 226   method)
 227
 228 (defmethod remove-direct-method ((specializer class) (method method))
 229   (let ((cell (slot-value specializer 'direct-methods)))
 230     ;; We need to first smash the CDR, because a parallel read may
 231     ;; be in progress, and because if an interrupt catches us we
 232     ;; need to have a consistent state.
 233     (setf (cdr cell) ()
 234           (car cell) (remove method (car cell))))
 235   method)
 236
 237 (defmethod specializer-direct-methods ((specializer class))
 238   (with-slots (direct-methods) specializer
 239     (car direct-methods)))
 240
 241 (defmethod specializer-direct-generic-functions ((specializer class))
 242   (let ((cell (slot-value specializer 'direct-methods)))
 243     ;; If an ADD/REMOVE-METHOD is in progress, no matter: either
 244     ;; we behave as if we got just first or just after -- it's just
 245     ;; for update that we need to lock.
 246     (or (cdr cell)
 247         (sb-thread:with-mutex (*specializer-lock*)
 248           (setf (cdr cell)
 249                 (let (collect)
 250                   (dolist (m (car cell))
 251                     ;; the old PCL code used COLLECTING-ONCE which used
 252                     ;; #'EQ to check for newness
 253                     (pushnew (method-generic-function m) collect :test #'eq))
 254                   (nreverse collect)))))))
 255 \f
 256 ;;; This hash table is used to store the direct methods and direct generic
 257 ;;; functions of EQL specializers. Each value in the table is the cons.
 258 ;;;
 259 ;;; These tables are shared between threads, so they need to be synchronized.
 260 (defvar *eql-specializer-methods* (make-hash-table :test 'eql :synchronized t))
 261 (defvar *class-eq-specializer-methods* (make-hash-table :test 'eq :synchronized t))
 262
 263 (defmethod specializer-method-table ((specializer eql-specializer))
 264   *eql-specializer-methods*)
 265
 266 (defmethod specializer-method-table ((specializer class-eq-specializer))
 267   *class-eq-specializer-methods*)
 268
 269 (defmethod add-direct-method ((specializer specializer-with-object)
 270                               (method method))
 271   (let* ((object (specializer-object specializer))
 272          (table (specializer-method-table specializer))
 273          (entry (gethash object table)))
 274     (unless entry
 275       (setf entry
 276             (setf (gethash object table) (cons nil nil))))
 277     ;; We need to first smash the CDR, because a parallel read may
 278     ;; be in progress, and because if an interrupt catches us we
 279     ;; need to have a consistent state.
 280     (setf (cdr entry) ()
 281           (car entry) (adjoin method (car entry) :test #'eq))
 282     method))
 283
 284 (defmethod remove-direct-method ((specializer specializer-with-object)
 285                                  (method method))
 286   (let* ((object (specializer-object specializer))
 287          (entry (gethash object (specializer-method-table specializer))))
 288     (when entry
 289       ;; We need to first smash the CDR, because a parallel read may
 290       ;; be in progress, and because if an interrupt catches us we
 291       ;; need to have a consistent state.
 292       (setf (cdr entry) ()
 293             (car entry) (remove method (car entry))))
 294     method))
 295
 296 (defmethod specializer-direct-methods ((specializer specializer-with-object))
 297   (car (gethash (specializer-object specializer)
 298                 (specializer-method-table specializer))))
 299
 300 (defmethod specializer-direct-generic-functions ((specializer
 301                                                   specializer-with-object))
 302   (let* ((object (specializer-object specializer))
 303          (entry (gethash object (specializer-method-table specializer))))
 304     (when entry
 305       (or (cdr entry)
 306           (sb-thread:with-mutex (*specializer-lock*)
 307             (setf (cdr entry)
 308                   (let (collect)
 309                     (dolist (m (car entry))
 310                       (pushnew (method-generic-function m) collect :test #'eq))
 311                     (nreverse collect))))))))
 312
 313 (defun map-specializers (function)
 314   (map-all-classes (lambda (class)
 315                      (funcall function (class-eq-specializer class))
 316                      (funcall function class)))
 317   (maphash (lambda (object methods)
 318              (declare (ignore methods))
 319              (intern-eql-specializer object))
 320            *eql-specializer-methods*)
 321   (maphash (lambda (object specl)
 322              (declare (ignore object))
 323              (funcall function specl))
 324            *eql-specializer-table*)
 325   nil)
 326
 327 (defun map-all-generic-functions (function)
 328   (let ((all-generic-functions (make-hash-table :test 'eq)))
 329     (map-specializers (lambda (specl)
 330                         (dolist (gf (specializer-direct-generic-functions
 331                                      specl))
 332                           (unless (gethash gf all-generic-functions)
 333                             (setf (gethash gf all-generic-functions) t)
 334                             (funcall function gf))))))
 335   nil)
 336
 337 (defmethod shared-initialize :after ((specl class-eq-specializer)
 338                                      slot-names
 339                                      &key)
 340   (declare (ignore slot-names))
 341   (setf (slot-value specl '%type) `(class-eq ,(specializer-class specl))))
 342
 343 (defmethod shared-initialize :after ((specl eql-specializer) slot-names &key)
 344   (declare (ignore slot-names))
 345   (setf (slot-value specl '%type)
 346         `(eql ,(specializer-object specl)))
 347   (setf (info :type :translator specl)
 348         (constantly (make-member-type :members (list (specializer-object specl))))))
 349
 350 (defun real-load-defclass (name metaclass-name supers slots other
 351                            readers writers slot-names source-location safe-p)
 352   (with-single-package-locked-error (:symbol name "defining ~S as a class")
 353     (%compiler-defclass name readers writers slot-names)
 354     (let ((res (apply #'ensure-class name :metaclass metaclass-name
 355                       :direct-superclasses supers
 356                       :direct-slots slots
 357                       :definition-source source-location
 358                       'safe-p safe-p
 359                       other)))
 360       res)))
 361
 362 (setf (gdefinition 'load-defclass) #'real-load-defclass)
 363
 364 (defun ensure-class (name &rest args)
 365   (with-world-lock ()
 366     (apply #'ensure-class-using-class
 367            (let ((class (find-class name nil)))
 368              (when (and class (eq name (class-name class)))
 369                ;; NAME is the proper name of CLASS, so redefine it
 370                class))
 371            name
 372            args)))
 373
 374 (defmethod ensure-class-using-class ((class null) name &rest args &key)
 375   (with-world-lock ()
 376     (multiple-value-bind (meta initargs)
 377         (frob-ensure-class-args args)
 378       (setf class (apply #'make-instance meta :name name initargs))
 379       (without-package-locks
 380         (setf (find-class name) class))))
 381   ;; After boot (SETF FIND-CLASS) does this.
 382   (unless (eq **boot-state** 'complete)
 383     (%set-class-type-translation class name))
 384   class)
 385
 386 (defmethod ensure-class-using-class ((class pcl-class) name &rest args &key)
 387   (with-world-lock ()
 388     (multiple-value-bind (meta initargs)
 389         (frob-ensure-class-args args)
 390       (unless (eq (class-of class) meta)
 391         (apply #'change-class class meta initargs))
 392       (apply #'reinitialize-instance class initargs)
 393       (without-package-locks
 394         (setf (find-class name) class))))
 395   ;; After boot (SETF FIND-CLASS) does this.
 396   (unless (eq **boot-state** 'complete)
 397     (%set-class-type-translation class name))
 398   class)
 399
 400 (defun frob-ensure-class-args (args)
 401   (let (metaclass metaclassp reversed-plist)
 402     (flet ((frob-superclass (s)
 403              (cond
 404                ((classp s) s)
 405                ((legal-class-name-p s)
 406                 (or (find-class s nil)
 407                     (ensure-class s :metaclass 'forward-referenced-class)))
 408                (t (error "Not a class or a legal class name: ~S." s)))))
 409       (doplist (key val) args
 410         (cond ((eq key :metaclass)
 411                (unless metaclassp
 412                  (setf metaclass val metaclassp key)))
 413               (t
 414                (when (eq key :direct-superclasses)
 415                  (setf val (mapcar #'frob-superclass val)))
 416                (setf reversed-plist (list* val key reversed-plist)))))
 417       (values (cond (metaclassp
 418                      (if (classp metaclass)
 419                          metaclass
 420                          (find-class metaclass)))
 421                     (t *the-class-standard-class*))
 422               (nreverse reversed-plist)))))
 423
 424 ;;; This is used to call initfunctions of :allocation :class slots.
 425 (defun call-initfun (fun slotd safe)
 426   (declare (function fun))
 427   (let ((value (funcall fun)))
 428     (when safe
 429       (let ((type (slot-definition-type slotd)))
 430         (unless (or (eq t type)
 431                     (typep value type))
 432           (error 'type-error :expected-type type :datum value))))
 433     value))
 434 \f
 435 (defmethod shared-initialize :after
 436     ((class std-class) slot-names &key
 437      (direct-superclasses nil direct-superclasses-p)
 438      (direct-slots nil direct-slots-p)
 439      (direct-default-initargs nil direct-default-initargs-p)
 440      definition-source)
 441   (cond (direct-superclasses-p
 442          (setq direct-superclasses
 443                (or direct-superclasses
 444                    (list (if (funcallable-standard-class-p class)
 445                              *the-class-funcallable-standard-object*
 446                              *the-class-standard-object*))))
 447          (dolist (superclass direct-superclasses)
 448            (unless (validate-superclass class superclass)
 449              (error "~@<The class ~S was specified as a ~
 450                      super-class of the class ~S, ~
 451                      but the meta-classes ~S and ~S are incompatible.  ~
 452                      Define a method for ~S to avoid this error.~@:>"
 453                     superclass class (class-of superclass) (class-of class)
 454                     'validate-superclass)))
 455          (setf (slot-value class 'direct-superclasses) direct-superclasses))
 456         (t
 457          (setq direct-superclasses (slot-value class 'direct-superclasses))))
 458   (setq direct-slots
 459         (if direct-slots-p
 460             (setf (slot-value class 'direct-slots)
 461                   (mapcar (lambda (pl) (make-direct-slotd class pl))
 462                           direct-slots))
 463             (slot-value class 'direct-slots)))
 464   (if direct-default-initargs-p
 465       (setf (plist-value class 'direct-default-initargs)
 466             direct-default-initargs)
 467       (setq direct-default-initargs
 468             (plist-value class 'direct-default-initargs)))
 469   (setf (plist-value class 'class-slot-cells)
 470         (let ((old-class-slot-cells (plist-value class 'class-slot-cells))
 471               (safe (safe-p class))
 472               (collect '()))
 473           (dolist (dslotd direct-slots)
 474             (when (eq :class (slot-definition-allocation dslotd))
 475               ;; see CLHS 4.3.6
 476               (let* ((name (slot-definition-name dslotd))
 477                      (old (assoc name old-class-slot-cells)))
 478                 (if (or (not old)
 479                         (eq t slot-names)
 480                         (member name slot-names :test #'eq))
 481                     (let* ((initfunction (slot-definition-initfunction dslotd))
 482                            (value
 483                             (if initfunction
 484                                 (call-initfun initfunction dslotd safe)
 485                                 +slot-unbound+)))
 486                       (push (cons name value) collect))
 487                     (push old collect)))))
 488           (nreverse collect)))
 489   (add-direct-subclasses class direct-superclasses)
 490   (if (class-finalized-p class)
 491       ;; required by AMOP, "Reinitialization of Class Metaobjects"
 492       (finalize-inheritance class)
 493       (update-class class nil))
 494   (add-slot-accessors class direct-slots definition-source)
 495   (make-preliminary-layout class))
 496
 497 (defmethod shared-initialize :after ((class forward-referenced-class)
 498                                      slot-names &key &allow-other-keys)
 499   (declare (ignore slot-names))
 500   (make-preliminary-layout class))
 501
 502 (defvar *allow-forward-referenced-classes-in-cpl-p* nil)
 503
 504 ;;; Give CLASS a preliminary layout if it doesn't have one already, to
 505 ;;; make it known to the type system.
 506 (defun make-preliminary-layout (class)
 507   (flet ((compute-preliminary-cpl (root)
 508            (let ((*allow-forward-referenced-classes-in-cpl-p* t))
 509              (compute-class-precedence-list root))))
 510     (with-world-lock ()
 511       (without-package-locks
 512         (unless (class-finalized-p class)
 513           (let ((name (class-name class)))
 514             ;; KLUDGE: This is fairly horrible.  We need to make a
 515             ;; full-fledged CLASSOID here, not just tell the compiler that
 516             ;; some class is forthcoming, because there are legitimate
 517             ;; questions one can ask of the type system, implemented in
 518             ;; terms of CLASSOIDs, involving forward-referenced classes. So.
 519             (let ((layout (make-wrapper 0 class)))
 520               (setf (slot-value class 'wrapper) layout)
 521               (let ((cpl (compute-preliminary-cpl class)))
 522                 (setf (layout-inherits layout)
 523                       (order-layout-inherits
 524                        (map 'simple-vector #'class-wrapper
 525                             (reverse (rest cpl))))))
 526               (register-layout layout :invalidate t)
 527               (%set-class-type-translation class (layout-classoid layout)))))
 528         (mapc #'make-preliminary-layout (class-direct-subclasses class))))))
 529
 530
 531 (defmethod shared-initialize :before ((class class) slot-names &key name)
 532   (declare (ignore slot-names name))
 533   ;; FIXME: Could this just be CLASS instead of `(CLASS ,CLASS)? If not,
 534   ;; why not? (See also similar expression in !BOOTSTRAP-INITIALIZE-CLASS.)
 535   (setf (slot-value class '%type) `(class ,class))
 536   (setf (slot-value class 'class-eq-specializer)
 537         (make-instance 'class-eq-specializer :class class)))
 538
 539 (defmethod reinitialize-instance :before ((class slot-class) &key direct-superclasses)
 540   (dolist (old-super (set-difference (class-direct-superclasses class) direct-superclasses))
 541     (remove-direct-subclass old-super class))
 542   (remove-slot-accessors class (class-direct-slots class)))
 543
 544 (defmethod reinitialize-instance :after ((class slot-class)
 545                                          &rest initargs
 546                                          &key)
 547   (map-dependents class
 548                   (lambda (dependent)
 549                     (apply #'update-dependent class dependent initargs))))
 550
 551 (defmethod reinitialize-instance :after ((class condition-class) &key)
 552   (let* ((name (class-name class))
 553          (classoid (find-classoid name))
 554          (slots (condition-classoid-slots classoid)))
 555     ;; to balance the REMOVE-SLOT-ACCESSORS call in
 556     ;; REINITIALIZE-INSTANCE :BEFORE (SLOT-CLASS).
 557     (dolist (slot slots)
 558       (let ((slot-name (condition-slot-name slot)))
 559         (dolist (reader (condition-slot-readers slot))
 560           ;; FIXME: see comment in SHARED-INITIALIZE :AFTER
 561           ;; (CONDITION-CLASS T), below.  -- CSR, 2005-11-18
 562           (sb-kernel::install-condition-slot-reader reader name slot-name))
 563         (dolist (writer (condition-slot-writers slot))
 564           (sb-kernel::install-condition-slot-writer writer name slot-name))))))
 565
 566 (defmethod shared-initialize :after ((class condition-class) slot-names
 567                                      &key direct-slots direct-superclasses)
 568   (declare (ignore slot-names))
 569   (let ((classoid (find-classoid (slot-value class 'name))))
 570     (with-slots (wrapper
 571                  %class-precedence-list cpl-available-p finalized-p
 572                  prototype (direct-supers direct-superclasses)
 573                  plist)
 574         class
 575       (setf (slot-value class 'direct-slots)
 576             (mapcar (lambda (pl) (make-direct-slotd class pl))
 577                     direct-slots)
 578             finalized-p t
 579             (classoid-pcl-class classoid) class
 580             direct-supers direct-superclasses
 581             wrapper (classoid-layout classoid)
 582             %class-precedence-list (compute-class-precedence-list class)
 583             cpl-available-p t
 584             (getf plist 'direct-default-initargs)
 585             (sb-kernel::condition-classoid-direct-default-initargs classoid))
 586       (add-direct-subclasses class direct-superclasses)
 587       (let ((slots (compute-slots class)))
 588         (setf (slot-value class 'slots) slots)
 589         (setf (layout-slot-table wrapper) (make-slot-table class slots)))))
 590   ;; Comment from Gerd's PCL, 2003-05-15:
 591   ;;
 592   ;; We don't ADD-SLOT-ACCESSORS here because we don't want to
 593   ;; override condition accessors with generic functions.  We do this
 594   ;; differently.
 595   ;;
 596   ;; ??? What does the above comment mean and why is it a good idea?
 597   ;; CMUCL (which still as of 2005-11-18 uses this code and has this
 598   ;; comment) loses slot information in its condition classes:
 599   ;; DIRECT-SLOTS is always NIL.  We have the right information, so we
 600   ;; remove slot accessors but never put them back.  I've added a
 601   ;; REINITIALIZE-INSTANCE :AFTER (CONDITION-CLASS) method, but what
 602   ;; was meant to happen?  -- CSR, 2005-11-18
 603   )
 604
 605 (defmethod direct-slot-definition-class ((class condition-class)
 606                                          &rest initargs)
 607   (declare (ignore initargs))
 608   (find-class 'condition-direct-slot-definition))
 609
 610 (defmethod effective-slot-definition-class ((class condition-class)
 611                                             &rest initargs)
 612   (declare (ignore initargs))
 613   (find-class 'condition-effective-slot-definition))
 614
 615 (defmethod finalize-inheritance ((class condition-class))
 616   (aver (slot-value class 'finalized-p))
 617   nil)
 618
 619 (defmethod compute-effective-slot-definition
 620     ((class condition-class) slot-name dslotds)
 621   (let* ((slotd (call-next-method))
 622          (info (slot-definition-info slotd)))
 623     (setf (slot-info-reader info)
 624           (lambda (x)
 625             (handler-case (condition-reader-function x slot-name)
 626               ;; FIXME: FIND-SLOT-DEFAULT throws an error if the slot
 627               ;; is unbound; maybe it should be a CELL-ERROR of some
 628               ;; sort?
 629               (error () (values (slot-unbound class x slot-name))))))
 630     (setf (slot-info-writer info)
 631           (lambda (v x)
 632             (condition-writer-function x v slot-name)))
 633     (setf (slot-info-boundp info)
 634           (lambda (x)
 635             (multiple-value-bind (v c)
 636                 (ignore-errors (condition-reader-function x slot-name))
 637               (declare (ignore v))
 638               (null c))))
 639     slotd))
 640
 641 (defmethod compute-slots ((class condition-class))
 642   (mapcan (lambda (superclass)
 643             (mapcar (lambda (dslotd)
 644                       (compute-effective-slot-definition
 645                        class (slot-definition-name dslotd) (list dslotd)))
 646                     (class-direct-slots superclass)))
 647           (reverse (slot-value class '%class-precedence-list))))
 648
 649 (defmethod compute-slots :around ((class condition-class))
 650   (let ((eslotds (call-next-method)))
 651     (mapc #'finalize-internal-slot-functions eslotds)
 652     eslotds))
 653
 654 (defmethod shared-initialize :after
 655     ((slotd structure-slot-definition) slot-names &key
 656      (allocation :instance) allocation-class)
 657   (declare (ignore slot-names allocation-class))
 658   (unless (eq allocation :instance)
 659     (error "Structure slots must have :INSTANCE allocation.")))
 660
 661 (defun make-structure-class-defstruct-form (name direct-slots include)
 662   (let* ((conc-name (format-symbol *package* "~S structure class " name))
 663          (constructor (format-symbol *package* "~Aconstructor" conc-name))
 664          (included-name (class-name include))
 665          (included-slots
 666           (when include
 667             (mapcar #'dsd-name (dd-slots (find-defstruct-description included-name)))))
 668          (old-slots nil)
 669          (new-slots nil)
 670          (reader-names nil)
 671          (writer-names nil))
 672     (dolist (slotd (reverse direct-slots))
 673       (let* ((slot-name (slot-definition-name slotd))
 674              (initform (slot-definition-initform slotd))
 675              (type (slot-definition-type slotd))
 676              (desc `(,slot-name ,initform :type ,type)))
 677         (push `(slot-accessor ,name ,slot-name reader)
 678               reader-names)
 679         (push `(slot-accessor ,name ,slot-name writer)
 680               writer-names)
 681         (if (member slot-name included-slots :test #'eq)
 682             (push desc old-slots)
 683             (push desc new-slots))))
 684     (let* ((defstruct `(defstruct (,name
 685                                     ,@(when include
 686                                             `((:include ,included-name
 687                                                         ,@old-slots)))
 688                                     (:constructor ,constructor ())
 689                                     (:predicate nil)
 690                                     (:conc-name ,conc-name)
 691                                     (:copier nil))
 692                          ,@new-slots))
 693            (readers-init
 694             (mapcar (lambda (slotd reader-name)
 695                       (let ((accessor
 696                              (slot-definition-defstruct-accessor-symbol
 697                               slotd)))
 698                         `(defun ,reader-name (obj)
 699                            (declare (type ,name obj))
 700                            (,accessor obj))))
 701                     direct-slots reader-names))
 702            (writers-init
 703             (mapcar (lambda (slotd writer-name)
 704                       (let ((accessor
 705                              (slot-definition-defstruct-accessor-symbol
 706                               slotd)))
 707                         `(defun ,writer-name (nv obj)
 708                            (declare (type ,name obj))
 709                            (setf (,accessor obj) nv))))
 710                     direct-slots writer-names))
 711            (defstruct-form
 712             `(progn
 713                ,defstruct
 714                ,@readers-init ,@writers-init
 715                (cons nil nil))))
 716       (values defstruct-form constructor reader-names writer-names))))
 717
 718 (defun make-defstruct-allocation-function (name)
 719   ;; FIXME: Why don't we go class->layout->info == dd
 720   (let ((dd (find-defstruct-description name)))
 721     (ecase (dd-type dd)
 722       (structure
 723        (%make-structure-instance-allocator dd nil))
 724       (funcallable-structure
 725        (%make-funcallable-structure-instance-allocator dd nil)))))
 726
 727 (defmethod shared-initialize :after
 728     ((class structure-class) slot-names &key
 729      (direct-superclasses nil direct-superclasses-p)
 730      (direct-slots nil direct-slots-p)
 731      direct-default-initargs
 732      definition-source)
 733   (declare (ignore slot-names direct-default-initargs))
 734   (if direct-superclasses-p
 735       (setf (slot-value class 'direct-superclasses)
 736             (or direct-superclasses
 737                 (setq direct-superclasses
 738                       (and (not (eq (slot-value class 'name) 'structure-object))
 739                            (list *the-class-structure-object*)))))
 740       (setq direct-superclasses (slot-value class 'direct-superclasses)))
 741   (let* ((name (slot-value class 'name))
 742          (from-defclass-p (slot-value class 'from-defclass-p))
 743          (defstruct-p (or from-defclass-p (not (structure-type-p name)))))
 744     (if direct-slots-p
 745         (setf (slot-value class 'direct-slots)
 746               (setq direct-slots
 747                     (mapcar (lambda (pl)
 748                               (when defstruct-p
 749                                 (let* ((slot-name (getf pl :name))
 750                                        (accessor
 751                                         (format-symbol *package*
 752                                                        "~S structure class ~A"
 753                                                        name slot-name)))
 754                                   (setq pl (list* :defstruct-accessor-symbol
 755                                                   accessor pl))))
 756                               (make-direct-slotd class pl))
 757                             direct-slots)))
 758         (setq direct-slots (slot-value class 'direct-slots)))
 759     (if defstruct-p
 760         (let ((include (car (slot-value class 'direct-superclasses))))
 761           (multiple-value-bind (defstruct-form constructor reader-names writer-names)
 762               (make-structure-class-defstruct-form name direct-slots include)
 763             (unless (structure-type-p name) (eval defstruct-form))
 764             (mapc (lambda (dslotd reader-name writer-name)
 765                     (let* ((reader (gdefinition reader-name))
 766                            (writer (when (fboundp writer-name)
 767                                      (gdefinition writer-name))))
 768                       (setf (slot-value dslotd 'internal-reader-function)
 769                             reader)
 770                       (setf (slot-value dslotd 'internal-writer-function)
 771                             writer)))
 772                   direct-slots reader-names writer-names)
 773             (setf (slot-value class 'defstruct-form) defstruct-form)
 774             (setf (slot-value class 'defstruct-constructor) constructor)))
 775         (setf (slot-value class 'defstruct-constructor)
 776               ;; KLUDGE: not class; in fixup.lisp, can't access slots
 777               ;; outside methods yet.
 778               (make-defstruct-allocation-function name)))
 779     (add-direct-subclasses class direct-superclasses)
 780     (setf (slot-value class '%class-precedence-list)
 781           (compute-class-precedence-list class))
 782     (setf (slot-value class 'cpl-available-p) t)
 783     (let ((slots (compute-slots class)))
 784       (setf (slot-value class 'slots) slots)
 785       (let* ((lclass (find-classoid (slot-value class 'name)))
 786              (layout (classoid-layout lclass)))
 787         (setf (classoid-pcl-class lclass) class)
 788         (setf (slot-value class 'wrapper) layout)
 789         (setf (layout-slot-table layout) (make-slot-table class slots))))
 790     (setf (slot-value class 'finalized-p) t)
 791     (add-slot-accessors class direct-slots definition-source)))
 792
 793 (defmethod direct-slot-definition-class ((class structure-class) &rest initargs)
 794   (declare (ignore initargs))
 795   (find-class 'structure-direct-slot-definition))
 796
 797 (defmethod finalize-inheritance ((class structure-class))
 798   nil) ; always finalized
 799 \f
 800 (defun add-slot-accessors (class dslotds &optional source-location)
 801   (fix-slot-accessors class dslotds 'add source-location))
 802
 803 (defun remove-slot-accessors (class dslotds)
 804   (fix-slot-accessors class dslotds 'remove))
 805
 806 (defun fix-slot-accessors (class dslotds add/remove &optional source-location)
 807   (flet ((fix (gfspec name r/w doc)
 808            (let ((gf (cond ((eq add/remove 'add)
 809                             (or (find-generic-function gfspec nil)
 810                                 (ensure-generic-function
 811                                  gfspec :lambda-list (case r/w
 812                                                        (r '(object))
 813                                                        (w '(new-value object))))))
 814                            (t
 815                             (find-generic-function gfspec nil)))))
 816              (when gf
 817                (case r/w
 818                  (r (if (eq add/remove 'add)
 819                         (add-reader-method class gf name doc source-location)
 820                         (remove-reader-method class gf)))
 821                  (w (if (eq add/remove 'add)
 822                         (add-writer-method class gf name doc source-location)
 823                         (remove-writer-method class gf))))))))
 824     (dolist (dslotd dslotds)
 825       (let ((slot-name (slot-definition-name dslotd))
 826             (slot-doc (%slot-definition-documentation dslotd)))
 827         (dolist (r (slot-definition-readers dslotd))
 828           (fix r slot-name 'r slot-doc))
 829         (dolist (w (slot-definition-writers dslotd))
 830           (fix w slot-name 'w slot-doc))))))
 831 \f
 832 (defun add-direct-subclasses (class supers)
 833   (dolist (super supers)
 834     (unless (memq class (class-direct-subclasses class))
 835       (add-direct-subclass super class))))
 836
 837 (defmethod finalize-inheritance ((class std-class))
 838   (update-class class t))
 839
 840 (defmethod finalize-inheritance ((class forward-referenced-class))
 841   ;; FIXME: should we not be thinking a bit about what kinds of error
 842   ;; we're throwing?  Maybe we need a clos-error type to mix in?  Or
 843   ;; possibly a forward-referenced-class-error, though that's
 844   ;; difficult given e.g. class precedence list calculations...
 845   (error
 846    "~@<FINALIZE-INHERITANCE was called on a forward referenced class:~
 847        ~2I~_~S~:>"
 848    class))
 849
 850 \f
 851 (defun class-has-a-forward-referenced-superclass-p (class)
 852   (or (when (forward-referenced-class-p class)
 853         class)
 854       (some #'class-has-a-forward-referenced-superclass-p
 855             ;; KLUDGE: SOME conses without knowing the type
 856             (the list (class-direct-superclasses class)))))
 857
 858 ;;; This is called by :after shared-initialize whenever a class is initialized
 859 ;;; or reinitialized. The class may or may not be finalized.
 860 (defun update-class (class finalizep)
 861   (without-package-locks
 862     (with-world-lock ()
 863       (when (or finalizep (class-finalized-p class))
 864         (%update-cpl class (compute-class-precedence-list class))
 865         ;; This invocation of UPDATE-SLOTS, in practice, finalizes the
 866         ;; class.
 867         (%update-slots class (compute-slots class))
 868         (update-gfs-of-class class)
 869         (setf (plist-value class 'default-initargs) (compute-default-initargs class))
 870         (update-ctors 'finalize-inheritance :class class))
 871       (dolist (sub (class-direct-subclasses class))
 872         (update-class sub nil)))))
 873
 874 (define-condition cpl-protocol-violation (reference-condition error)
 875   ((class :initarg :class :reader cpl-protocol-violation-class)
 876    (cpl :initarg :cpl :reader cpl-protocol-violation-cpl))
 877   (:default-initargs :references (list '(:sbcl :node "Metaobject Protocol")))
 878   (:report
 879    (lambda (c s)
 880      (format s "~@<Protocol violation: the ~S class ~S ~
 881                 ~:[has~;does not have~] the class ~S in its ~
 882                 class precedence list: ~S.~@:>"
 883              (class-name (class-of (cpl-protocol-violation-class c)))
 884              (cpl-protocol-violation-class c)
 885              (eq (class-of (cpl-protocol-violation-class c))
 886                  *the-class-funcallable-standard-class*)
 887              (find-class 'function)
 888              (cpl-protocol-violation-cpl c)))))
 889
 890 (defun class-has-a-cpl-protocol-violation-p (class)
 891   (labels ((find-in-superclasses (class classes)
 892              (cond
 893                ((null classes) nil)
 894                ((eql class (car classes)) t)
 895                (t (find-in-superclasses class (append (class-direct-superclasses (car classes)) (cdr classes)))))))
 896     (let ((metaclass (class-of class)))
 897       (cond
 898         ((eql metaclass *the-class-standard-class*)
 899          (find-in-superclasses (find-class 'function) (list class)))
 900         ((eql metaclass *the-class-funcallable-standard-class*)
 901          (not (find-in-superclasses (find-class 'function) (list class))))))))
 902
 903 (defun %update-cpl (class cpl)
 904   (when (eq (class-of class) *the-class-standard-class*)
 905     (when (find (find-class 'function) cpl)
 906       (error 'cpl-protocol-violation :class class :cpl cpl)))
 907   (when (eq (class-of class) *the-class-funcallable-standard-class*)
 908     (unless (find (find-class 'function) cpl)
 909       (error 'cpl-protocol-violation :class class :cpl cpl)))
 910   (if (class-finalized-p class)
 911       (unless (and (equal (class-precedence-list class) cpl)
 912                    (dolist (c cpl t)
 913                      (when (position :class (class-direct-slots c)
 914                                      :key #'slot-definition-allocation)
 915                        (return nil))))
 916         ;; comment from the old CMU CL sources:
 917         ;;   Need to have the cpl setup before %update-lisp-class-layout
 918         ;;   is called on CMU CL.
 919         (setf (slot-value class '%class-precedence-list) cpl)
 920         (setf (slot-value class 'cpl-available-p) t)
 921         (%force-cache-flushes class))
 922       (progn
 923         (setf (slot-value class '%class-precedence-list) cpl)
 924         (setf (slot-value class 'cpl-available-p) t)))
 925   (update-class-can-precede-p cpl))
 926
 927 (defun update-class-can-precede-p (cpl)
 928   (when cpl
 929     (let ((first (car cpl)))
 930       (dolist (c (cdr cpl))
 931         (pushnew c (slot-value first 'can-precede-list) :test #'eq)))
 932     (update-class-can-precede-p (cdr cpl))))
 933
 934 (defun class-can-precede-p (class1 class2)
 935   (member class2 (class-can-precede-list class1) :test #'eq))
 936
 937 ;;; This is called from %UPDATE-SLOTS to check if slot layouts are compatible.
 938 ;;;
 939 ;;; In addition to slot locations (implicit in the ordering of the slots), we
 940 ;;; must check classes: SLOT-INFO structures from old slotds may have been
 941 ;;; cached in permutation vectors, but new slotds have had new ones allocated
 942 ;;; to them. This is non-problematic for standard slotds, because we know the
 943 ;;; structure is compatible, but if a slot definition class changes, this can
 944 ;;; change the way SLOT-VALUE-USING-CLASS should dispatch.
 945 ;;;
 946 ;;; Also, if the slot has a non-standard allocation, we need to check that it
 947 ;;; doesn't change.
 948 (defun slot-layouts-compatible-p
 949     (oslotds new-instance-slotds new-class-slotds new-custom-slotds)
 950   (multiple-value-bind (old-instance-slotds old-class-slotds old-custom-slotds)
 951       (classify-slotds oslotds)
 952     (and
 953      ;; Instance slots: name, type, and class.
 954      (dolist (o old-instance-slotds (not new-instance-slotds))
 955        (let ((n (pop new-instance-slotds)))
 956          (unless (and n
 957                       (eq (slot-definition-name o) (slot-definition-name n))
 958                       (eq (slot-definition-type o) (slot-definition-type n))
 959                       (eq (class-of o) (class-of n)))
 960            (return nil))))
 961      ;; Class slots: name and class. (FIXME: class slots not typechecked?)
 962      (dolist (o old-class-slotds (not new-class-slotds))
 963        (let ((n (pop new-class-slotds)))
 964          (unless (and n
 965                       (eq (slot-definition-name o) (slot-definition-name n))
 966                       (eq (class-of n) (class-of o)))
 967            (return nil))))
 968      ;; Custom slots: check name, type, allocation, and class. (FIXME: should we just punt?)
 969      (dolist (o old-custom-slotds (not new-custom-slotds))
 970        (let ((n (pop new-custom-slotds)))
 971          (unless (and n
 972                       (eq (slot-definition-name o) (slot-definition-name n))
 973                       (eq (slot-definition-type o) (slot-definition-type n))
 974                       (eq (slot-definition-allocation o) (slot-definition-allocation n))
 975                       (eq (class-of o) (class-of n)))
 976            (return nil)))))))
 977
 978 (defun style-warn-about-duplicate-slots (class)
 979   (do* ((slots (slot-value class 'slots) (cdr slots))
 980         (dupes nil))
 981        ((null slots)
 982         (when dupes
 983           (style-warn
 984            "~@<slot names with the same SYMBOL-NAME but ~
 985                   different SYMBOL-PACKAGE (possible package problem) ~
 986                   for class ~S:~4I~@:_~<~@{~/sb-impl::print-symbol-with-prefix/~^~:@_~}~:>~@:>"
 987            class dupes)))
 988     (let* ((slot-name (slot-definition-name (car slots)))
 989            (oslots (and (not (eq (symbol-package slot-name)
 990                                  *pcl-package*))
 991                         (remove-if
 992                          (lambda (slot-name-2)
 993                            (or (eq (symbol-package slot-name-2)
 994                                    *pcl-package*)
 995                                (string/= slot-name slot-name-2)))
 996                          (cdr slots)
 997                          :key #'slot-definition-name))))
 998       (when oslots
 999         (pushnew (cons slot-name
1000                        (mapcar #'slot-definition-name oslots))
1001                  dupes
1002                  :test #'string= :key #'car)))))
1003
1004 (defun %update-slots (class eslotds)
1005   (multiple-value-bind (instance-slots class-slots custom-slots)
1006       (classify-slotds eslotds)
1007     (let* ((nslots (length instance-slots))
1008            (owrapper (when (class-finalized-p class) (class-wrapper class)))
1009            (nwrapper
1010              (cond ((null owrapper)
1011                     (make-wrapper nslots class))
1012                    ((slot-layouts-compatible-p (wrapper-slots owrapper)
1013                                                instance-slots class-slots custom-slots)
1014                     owrapper)
1015                    (t
1016                     ;; This will initialize the new wrapper to have the
1017                     ;; same state as the old wrapper. We will then have
1018                     ;; to change that. This may seem like wasted work
1019                     ;; (and it is), but the spec requires that we call
1020                     ;; MAKE-INSTANCES-OBSOLETE.
1021                     (make-instances-obsolete class)
1022                     (class-wrapper class)))))
1023       (%update-lisp-class-layout class nwrapper)
1024       (setf (slot-value class 'slots) eslotds
1025             (wrapper-slots nwrapper) eslotds
1026             (wrapper-slot-table nwrapper) (make-slot-table class eslotds)
1027             (wrapper-length nwrapper) nslots
1028             (slot-value class 'wrapper) nwrapper)
1029       (style-warn-about-duplicate-slots class)
1030       (setf (slot-value class 'finalized-p) t)
1031       (unless (eq owrapper nwrapper)
1032         (maybe-update-standard-slot-locations class)))))
1033
1034 (defun update-gf-dfun (class gf)
1035   (let ((*new-class* class)
1036         (arg-info (gf-arg-info gf)))
1037     (cond
1038       ((special-case-for-compute-discriminating-function-p gf))
1039       ((gf-precompute-dfun-and-emf-p arg-info)
1040        (multiple-value-bind (dfun cache info) (make-final-dfun-internal gf)
1041          (update-dfun gf dfun cache info))))))
1042
1043 (defun update-gfs-of-class (class)
1044   (when (and (class-finalized-p class)
1045              (let ((cpl (class-precedence-list class)))
1046                (or (member *the-class-slot-class* cpl :test #'eq)
1047                    (member *the-class-standard-effective-slot-definition*
1048                            cpl :test #'eq))))
1049     (let ((gf-table (make-hash-table :test 'eq)))
1050       (labels ((collect-gfs (class)
1051                  (dolist (gf (specializer-direct-generic-functions class))
1052                    (setf (gethash gf gf-table) t))
1053                  (mapc #'collect-gfs (class-direct-superclasses class))))
1054         (collect-gfs class)
1055         (maphash (lambda (gf ignore)
1056                    (declare (ignore ignore))
1057                    (update-gf-dfun class gf))
1058                  gf-table)))))
1059 \f
1060 (defmethod compute-default-initargs ((class slot-class))
1061   (let ((initargs (loop for c in (class-precedence-list class)
1062                         append (class-direct-default-initargs c))))
1063     (delete-duplicates initargs :test #'eq :key #'car :from-end t)))
1064 \f
1065 ;;;; protocols for constructing direct and effective slot definitions
1066
1067 (defmethod direct-slot-definition-class ((class std-class) &rest initargs)
1068   (declare (ignore initargs))
1069   (find-class 'standard-direct-slot-definition))
1070
1071 (defun make-direct-slotd (class initargs)
1072   (apply #'make-instance
1073          (apply #'direct-slot-definition-class class initargs)
1074          :class class
1075          initargs))
1076
1077 ;;; I (CSR) am not sure, but I believe that the particular order of
1078 ;;; slots is quite important: it is ideal to attempt to have a
1079 ;;; constant slot location for the same notional slots as much as
1080 ;;; possible, so that clever discriminating functions (ONE-INDEX et
1081 ;;; al.) have a chance of working.  The below at least walks through
1082 ;;; the slots predictably, but maybe it would be good to compute some
1083 ;;; kind of optimal slot layout by looking at locations of slots in
1084 ;;; superclasses?
1085 (defun std-compute-slots (class)
1086   ;; As specified, we must call COMPUTE-EFFECTIVE-SLOT-DEFINITION once
1087   ;; for each different slot name we find in our superclasses. Each
1088   ;; call receives the class and a list of the dslotds with that name.
1089   ;; The list is in most-specific-first order.
1090   (let ((name-dslotds-alist ()))
1091     (dolist (c (reverse (class-precedence-list class)))
1092       (dolist (slot (class-direct-slots c))
1093         (let* ((name (slot-definition-name slot))
1094                (entry (assq name name-dslotds-alist)))
1095           (if entry
1096               (push slot (cdr entry))
1097               (push (list name slot) name-dslotds-alist)))))
1098     (mapcar (lambda (direct)
1099               (compute-effective-slot-definition class
1100                                                  (car direct)
1101                                                  (cdr direct)))
1102             (nreverse name-dslotds-alist))))
1103
1104 (defmethod compute-slots ((class standard-class))
1105   (std-compute-slots class))
1106 (defmethod compute-slots ((class funcallable-standard-class))
1107   (std-compute-slots class))
1108
1109 (defun std-compute-slots-around (class eslotds)
1110   (let ((location -1)
1111         (safe (safe-p class)))
1112     (dolist (eslotd eslotds eslotds)
1113       (setf (slot-definition-location eslotd)
1114             (case (slot-definition-allocation eslotd)
1115               (:instance
1116                (incf location))
1117               (:class
1118                (let* ((name (slot-definition-name eslotd))
1119                       (from-class
1120                        (or
1121                         (slot-definition-allocation-class eslotd)
1122                         ;; we get here if the user adds an extra slot
1123                         ;; himself...
1124                         (setf (slot-definition-allocation-class eslotd)
1125                               class)))
1126                       ;; which raises the question of what we should
1127                       ;; do if we find that said user has added a slot
1128                       ;; with the same name as another slot...
1129                       (cell (or (assq name (class-slot-cells from-class))
1130                                 (let ((c (cons name +slot-unbound+)))
1131                                   (push c (class-slot-cells from-class))
1132                                   c))))
1133                  (aver (consp cell))
1134                  (if (eq +slot-unbound+ (cdr cell))
1135                      ;; We may have inherited an initfunction FIXME: Is this
1136                      ;; really right? Is the initialization in
1137                      ;; SHARED-INITIALIZE (STD-CLASS) not enough?
1138                      (let ((initfun (slot-definition-initfunction eslotd)))
1139                        (if initfun
1140                            (rplacd cell (call-initfun initfun eslotd safe))
1141                            cell))
1142                      cell)))))
1143       (unless (slot-definition-class eslotd)
1144         (setf (slot-definition-class eslotd) class))
1145       (initialize-internal-slot-functions eslotd))))
1146
1147 (defmethod compute-slots :around ((class standard-class))
1148   (let ((eslotds (call-next-method)))
1149     (std-compute-slots-around class eslotds)))
1150 (defmethod compute-slots :around ((class funcallable-standard-class))
1151   (let ((eslotds (call-next-method)))
1152     (std-compute-slots-around class eslotds)))
1153
1154 (defmethod compute-slots ((class structure-class))
1155   (mapcan (lambda (superclass)
1156             (mapcar (lambda (dslotd)
1157                       (compute-effective-slot-definition
1158                        class
1159                        (slot-definition-name dslotd)
1160                        (list dslotd)))
1161                     (class-direct-slots superclass)))
1162           (reverse (slot-value class '%class-precedence-list))))
1163
1164 (defmethod compute-slots :around ((class structure-class))
1165   (let ((eslotds (call-next-method)))
1166     (mapc #'finalize-internal-slot-functions eslotds)
1167     eslotds))
1168
1169 (defmethod compute-effective-slot-definition ((class slot-class) name dslotds)
1170   (let* ((initargs (compute-effective-slot-definition-initargs class dslotds))
1171          (class (apply #'effective-slot-definition-class class initargs))
1172          (slotd (apply #'make-instance class initargs)))
1173     slotd))
1174
1175 (defmethod effective-slot-definition-class ((class std-class) &rest initargs)
1176   (declare (ignore initargs))
1177   (find-class 'standard-effective-slot-definition))
1178
1179 (defmethod effective-slot-definition-class ((class structure-class) &rest initargs)
1180   (declare (ignore initargs))
1181   (find-class 'structure-effective-slot-definition))
1182
1183 (defmethod compute-effective-slot-definition-initargs
1184     ((class slot-class) direct-slotds)
1185   (let* ((name nil)
1186          (initfunction nil)
1187          (initform nil)
1188          (initargs nil)
1189          (allocation nil)
1190          (allocation-class nil)
1191          (type t)
1192          (documentation nil)
1193          (documentationp nil)
1194          (namep  nil)
1195          (initp  nil)
1196          (allocp nil))
1197
1198     (dolist (slotd direct-slotds)
1199       (when slotd
1200         (unless namep
1201           (setq name (slot-definition-name slotd)
1202                 namep t))
1203         (unless initp
1204           (awhen (slot-definition-initfunction slotd)
1205             (setq initform (slot-definition-initform slotd)
1206                   initfunction it
1207                   initp t)))
1208         (unless documentationp
1209           (awhen (%slot-definition-documentation slotd)
1210             (setq documentation it
1211                   documentationp t)))
1212         (unless allocp
1213           (setq allocation (slot-definition-allocation slotd)
1214                 allocation-class (slot-definition-class slotd)
1215                 allocp t))
1216         (setq initargs (append (slot-definition-initargs slotd) initargs))
1217         (let ((slotd-type (slot-definition-type slotd)))
1218           (setq type (cond
1219                        ((eq type t) slotd-type)
1220                        ;; This pairwise type intersection is perhaps a
1221                        ;; little inefficient and inelegant, but it's
1222                        ;; unlikely to lie on the critical path.  Shout
1223                        ;; if I'm wrong.  -- CSR, 2005-11-24
1224                        (t (type-specifier
1225                            (specifier-type `(and ,type ,slotd-type)))))))))
1226     (list :name name
1227           :initform initform
1228           :initfunction initfunction
1229           :initargs initargs
1230           :allocation allocation
1231           :allocation-class allocation-class
1232           :type type
1233           :class class
1234           :documentation documentation)))
1235
1236 (defmethod compute-effective-slot-definition-initargs :around
1237     ((class structure-class) direct-slotds)
1238   (let* ((slotd (car direct-slotds))
1239          (accessor (slot-definition-defstruct-accessor-symbol slotd)))
1240     (list* :defstruct-accessor-symbol accessor
1241            :internal-reader-function
1242            (slot-definition-internal-reader-function slotd)
1243            :internal-writer-function
1244            (slot-definition-internal-writer-function slotd)
1245            (call-next-method))))
1246 \f
1247 ;;; NOTE: For bootstrapping considerations, these can't use MAKE-INSTANCE
1248 ;;;       to make the method object. They have to use make-a-method which
1249 ;;;       is a specially bootstrapped mechanism for making standard methods.
1250 (defmethod reader-method-class ((class slot-class) direct-slot &rest initargs)
1251   (declare (ignore direct-slot initargs))
1252   (find-class 'standard-reader-method))
1253
1254 (defmethod add-reader-method ((class slot-class) generic-function slot-name slot-documentation source-location)
1255   (add-method generic-function
1256               (make-a-method 'standard-reader-method
1257                              ()
1258                              (list (or (class-name class) 'object))
1259                              (list class)
1260                              (make-reader-method-function class slot-name)
1261                              (or slot-documentation "automatically generated reader method")
1262                              :slot-name slot-name
1263                              :object-class class
1264                              :method-class-function #'reader-method-class
1265                              :definition-source source-location)))
1266
1267 (defmethod writer-method-class ((class slot-class) direct-slot &rest initargs)
1268   (declare (ignore direct-slot initargs))
1269   (find-class 'standard-writer-method))
1270
1271 (defmethod add-writer-method ((class slot-class) generic-function slot-name slot-documentation source-location)
1272   (add-method generic-function
1273               (make-a-method 'standard-writer-method
1274                              ()
1275                              (list 'new-value (or (class-name class) 'object))
1276                              (list *the-class-t* class)
1277                              (make-writer-method-function class slot-name)
1278                              (or slot-documentation "automatically generated writer method")
1279                              :slot-name slot-name
1280                              :object-class class
1281                              :method-class-function #'writer-method-class
1282                              :definition-source source-location)))
1283
1284 (defmethod add-boundp-method ((class slot-class) generic-function slot-name slot-documentation source-location)
1285   (add-method generic-function
1286               (make-a-method (constantly (find-class 'standard-boundp-method))
1287                              class
1288                              ()
1289                              (list (or (class-name class) 'object))
1290                              (list class)
1291                              (make-boundp-method-function class slot-name)
1292                              (or slot-documentation "automatically generated boundp method")
1293                              :slot-name slot-name
1294                              :definition-source source-location)))
1295
1296 (defmethod remove-reader-method ((class slot-class) generic-function)
1297   (let ((method (get-method generic-function () (list class) nil)))
1298     (when method (remove-method generic-function method))))
1299
1300 (defmethod remove-writer-method ((class slot-class) generic-function)
1301   (let ((method
1302           (get-method generic-function () (list *the-class-t* class) nil)))
1303     (when method (remove-method generic-function method))))
1304
1305 (defmethod remove-boundp-method ((class slot-class) generic-function)
1306   (let ((method (get-method generic-function () (list class) nil)))
1307     (when method (remove-method generic-function method))))
1308 \f
1309 ;;; MAKE-READER-METHOD-FUNCTION and MAKE-WRITER-METHOD-FUNCTION
1310 ;;; function are NOT part of the standard protocol. They are however
1311 ;;; useful; PCL makes use of them internally and documents them for
1312 ;;; PCL users.  (FIXME: but SBCL certainly doesn't)
1313 ;;;
1314 ;;; *** This needs work to make type testing by the writer functions which
1315 ;;; *** do type testing faster. The idea would be to have one constructor
1316 ;;; *** for each possible type test.
1317 ;;;
1318 ;;; *** There is a subtle bug here which is going to have to be fixed.
1319 ;;; *** Namely, the simplistic use of the template has to be fixed. We
1320 ;;; *** have to give the OPTIMIZE-SLOT-VALUE method the user might have
1321 ;;; *** defined for this metaclass a chance to run.
1322
1323 (defmethod make-reader-method-function ((class slot-class) slot-name)
1324   (make-std-reader-method-function class slot-name))
1325
1326 (defmethod make-writer-method-function ((class slot-class) slot-name)
1327   (make-std-writer-method-function class slot-name))
1328
1329 (defmethod make-boundp-method-function ((class slot-class) slot-name)
1330   (make-std-boundp-method-function class slot-name))
1331 \f
1332 (defmethod compatible-meta-class-change-p (class proto-new-class)
1333   (eq (class-of class) (class-of proto-new-class)))
1334
1335 (defmethod validate-superclass ((class class) (superclass class))
1336   (or (eq superclass *the-class-t*)
1337       (eq (class-of class) (class-of superclass))
1338       (and (eq (class-of superclass) *the-class-standard-class*)
1339            (eq (class-of class) *the-class-funcallable-standard-class*))
1340       (and (eq (class-of superclass) *the-class-funcallable-standard-class*)
1341            (eq (class-of class) *the-class-standard-class*))))
1342 \f
1343 ;;; What this does depends on which of the four possible values of
1344 ;;; LAYOUT-INVALID the PCL wrapper has; the simplest case is when it
1345 ;;; is (:FLUSH <wrapper>) or (:OBSOLETE <wrapper>), when there is
1346 ;;; nothing to do, as the new wrapper has already been created.  If
1347 ;;; LAYOUT-INVALID returns NIL, then we invalidate it (setting it to
1348 ;;; (:FLUSH <wrapper>); UPDATE-SLOTS later gets to choose whether or
1349 ;;; not to "upgrade" this to (:OBSOLETE <wrapper>).
1350 ;;;
1351 ;;; This leaves the case where LAYOUT-INVALID returns T, which happens
1352 ;;; when REGISTER-LAYOUT has invalidated a superclass of CLASS (which
1353 ;;; invalidated all the subclasses in SB-KERNEL land).  Again, here we
1354 ;;; must flush the caches and allow UPDATE-SLOTS to decide whether to
1355 ;;; obsolete the wrapper.
1356 ;;;
1357 ;;; FIXME: either here or in INVALID-WRAPPER-P looks like a good place
1358 ;;; for (AVER (NOT (EQ (LAYOUT-INVALID OWRAPPER)
1359 ;;;                    :UNINITIALIZED)))
1360 ;;;
1361 ;;; Thanks to Gerd Moellmann for the explanation.  -- CSR, 2002-10-29
1362 (defun %force-cache-flushes (class)
1363   (let* ((owrapper (class-wrapper class)))
1364     ;; We only need to do something if the wrapper is still valid. If
1365     ;; the wrapper isn't valid, state will be FLUSH or OBSOLETE, and
1366     ;; both of those will already be doing what we want. In
1367     ;; particular, we must be sure we never change an OBSOLETE into a
1368     ;; FLUSH since OBSOLETE means do what FLUSH does and then some.
1369     (when (or (not (invalid-wrapper-p owrapper))
1370               ;; KLUDGE: despite the observations above, this remains
1371               ;; a violation of locality or what might be considered
1372               ;; good style.  There has to be a better way!  -- CSR,
1373               ;; 2002-10-29
1374               (eq (layout-invalid owrapper) t))
1375       (let ((nwrapper (make-wrapper (layout-length owrapper)
1376                                     class)))
1377         (setf (wrapper-slots nwrapper)
1378               (wrapper-slots owrapper))
1379         (setf (wrapper-slot-table nwrapper)
1380               (wrapper-slot-table owrapper))
1381         (%update-lisp-class-layout class nwrapper)
1382         (setf (slot-value class 'wrapper) nwrapper)
1383         ;; Use :OBSOLETE instead of :FLUSH if any superclass has
1384         ;; been obsoleted.
1385         (if (find-if (lambda (x)
1386                        (and (consp x) (eq :obsolete (car x))))
1387                      (layout-inherits owrapper)
1388                      :key #'layout-invalid)
1389             (%invalidate-wrapper owrapper :obsolete nwrapper)
1390             (%invalidate-wrapper owrapper :flush nwrapper))))))
1391 \f
1392 ;;; MAKE-INSTANCES-OBSOLETE can be called by user code. It will cause
1393 ;;; the next access to the instance (as defined in 88-002R) to trap
1394 ;;; through the UPDATE-INSTANCE-FOR-REDEFINED-CLASS mechanism.
1395 (defmethod make-instances-obsolete ((class std-class))
1396   (with-world-lock ()
1397     (let* ((owrapper (class-wrapper class))
1398            (nwrapper (make-wrapper (layout-length owrapper)
1399                                    class)))
1400       (unless (class-finalized-p class)
1401         (if (class-has-a-forward-referenced-superclass-p class)
1402             (return-from make-instances-obsolete class)
1403             (%update-cpl class (compute-class-precedence-list class))))
1404       (setf (wrapper-slots nwrapper)
1405             (wrapper-slots owrapper))
1406       (setf (wrapper-slot-table nwrapper)
1407             (wrapper-slot-table owrapper))
1408       (%update-lisp-class-layout class nwrapper)
1409       (setf (slot-value class 'wrapper) nwrapper)
1410       (%invalidate-wrapper owrapper :obsolete nwrapper)
1411       class)))
1412
1413 (defmethod make-instances-obsolete ((class symbol))
1414   (make-instances-obsolete (find-class class))
1415   ;; ANSI wants the class name when called with a symbol.
1416   class)
1417
1418 ;;; OBSOLETE-INSTANCE-TRAP is the internal trap that is called when we
1419 ;;; see an obsolete instance. The times when it is called are:
1420 ;;;   - when the instance is involved in method lookup
1421 ;;;   - when attempting to access a slot of an instance
1422 ;;;
1423 ;;; It is not called by class-of, wrapper-of, or any of the low-level
1424 ;;; instance access macros.
1425 ;;;
1426 ;;; Of course these times when it is called are an internal
1427 ;;; implementation detail of PCL and are not part of the documented
1428 ;;; description of when the obsolete instance update happens. The
1429 ;;; documented description is as it appears in 88-002R.
1430 ;;;
1431 ;;; This has to return the new wrapper, so it counts on all the
1432 ;;; methods on obsolete-instance-trap-internal to return the new
1433 ;;; wrapper. It also does a little internal error checking to make
1434 ;;; sure that the traps are only happening when they should, and that
1435 ;;; the trap methods are computing appropriate new wrappers.
1436
1437 ;;; OBSOLETE-INSTANCE-TRAP might be called on structure instances
1438 ;;; after a structure is redefined. In most cases,
1439 ;;; OBSOLETE-INSTANCE-TRAP will not be able to fix the old instance,
1440 ;;; so it must signal an error. The hard part of this is that the
1441 ;;; error system and debugger might cause OBSOLETE-INSTANCE-TRAP to be
1442 ;;; called again, so in that case, we have to return some reasonable
1443 ;;; wrapper, instead.
1444
1445 (defvar *in-obsolete-instance-trap* nil)
1446 (defvar *the-wrapper-of-structure-object*
1447   (class-wrapper (find-class 'structure-object)))
1448
1449 (define-condition obsolete-structure (error)
1450   ((datum :reader obsolete-structure-datum :initarg :datum))
1451   (:report
1452    (lambda (condition stream)
1453      ;; Don't try to print the structure, since it probably won't work.
1454      (format stream
1455              "~@<obsolete structure error for a structure of type ~2I~_~S~:>"
1456              (type-of (obsolete-structure-datum condition))))))
1457
1458 (defun %obsolete-instance-trap (owrapper nwrapper instance)
1459   (if (not (layout-for-std-class-p owrapper))
1460       (if *in-obsolete-instance-trap*
1461           *the-wrapper-of-structure-object*
1462           (let ((*in-obsolete-instance-trap* t))
1463             (error 'obsolete-structure :datum instance)))
1464       (let* ((class (wrapper-class* nwrapper))
1465              (copy (allocate-instance class)) ;??? allocate-instance ???
1466              (oslots (get-slots instance))
1467              (nslots (get-slots copy))
1468              (added ())
1469              (discarded ())
1470              (plist ())
1471              (safe (safe-p class)))
1472
1473         ;; local  --> local     transfer value, check type
1474         ;; local  --> shared    discard value, discard slot
1475         ;; local  -->  --       discard slot
1476         ;; local  --> custom    XXX
1477
1478         ;; shared --> local     transfer value, check type
1479         ;; shared --> shared    -- (cf SHARED-INITIALIZE :AFTER STD-CLASS)
1480         ;; shared -->  --       discard value
1481         ;; shared --> custom    XXX
1482
1483         ;;  --    --> local     add slot
1484         ;;  --    --> shared    --
1485         ;;  --    --> custom    XXX
1486
1487         (multiple-value-bind (new-instance-slots new-class-slots new-custom-slots)
1488             (classify-slotds (wrapper-slots nwrapper))
1489           (declare (ignore new-class-slots))
1490           (multiple-value-bind (old-instance-slots old-class-slots old-custom-slots)
1491               (classify-slotds (wrapper-slots owrapper))
1492
1493             (let ((layout (mapcar (lambda (slotd)
1494                                     ;; Get the names only once.
1495                                     (cons (slot-definition-name slotd) slotd))
1496                                   new-instance-slots)))
1497
1498               (flet ((set-value (value cell)
1499                        (let ((name (car cell))
1500                              (slotd (cdr cell)))
1501                          (when (and safe (neq value +slot-unbound+))
1502                            (let ((type (slot-definition-type slotd)))
1503                              (assert
1504                               (typep value type) (value)
1505                               "~@<Error updating obsolete instance. Current value in slot ~
1506                                ~S of an instance of ~S is ~S, which does not match the new ~
1507                                slot type ~S.~:@>"
1508                               name class value type)))
1509                          (setf (clos-slots-ref nslots (slot-definition-location slotd)) value
1510                                ;; Prune from the list now that it's been dealt with.
1511                                layout (remove cell layout)))))
1512
1513                 ;; Go through all the old local slots.
1514                 (dolist (old old-instance-slots)
1515                   (let* ((name (slot-definition-name old))
1516                          (value (clos-slots-ref oslots (slot-definition-location old))))
1517                     (unless (eq value +slot-unbound+)
1518                       (let ((new (assq name layout)))
1519                         (cond (new
1520                                (set-value value new))
1521                               (t
1522                                (push name discarded)
1523                                (setf (getf plist name) value)))))))
1524
1525                 ;; Go through all the old shared slots.
1526                 (dolist (old old-class-slots)
1527                   (let* ((cell (slot-definition-location old))
1528                          (name (car cell))
1529                          (new (assq name layout)))
1530                     (when new
1531                       (set-value (cdr cell) new))))
1532
1533                 ;; Go through all custom slots to find added ones. CLHS
1534                 ;; doesn't specify what to do about them, and neither does
1535                 ;; AMOP. We do want them to get initialized, though, so we
1536                 ;; list them in ADDED for the benefit of SHARED-INITIALIZE.
1537                 (dolist (new new-custom-slots)
1538                   (let* ((name (slot-definition-name new))
1539                          (old (find name old-custom-slots :key #'slot-definition-name)))
1540                     (unless old
1541                       (push name added))))
1542
1543                 ;; Go through all the remaining new local slots to compute the added slots.
1544                 (dolist (cell layout)
1545                   (push (car cell) added))))))
1546
1547         (%swap-wrappers-and-slots instance copy)
1548
1549         (update-instance-for-redefined-class instance
1550                                              added
1551                                              discarded
1552                                              plist)
1553         nwrapper)))
1554 \f
1555 (defun %change-class (instance new-class initargs)
1556   (let* ((old-class (class-of instance))
1557          (copy (allocate-instance new-class))
1558          (new-wrapper (get-wrapper copy))
1559          (old-wrapper (class-wrapper old-class))
1560          (old-slots (get-slots instance))
1561          (new-slots (get-slots copy))
1562          (safe (safe-p new-class)))
1563     (multiple-value-bind (new-instance-slots new-class-slots)
1564         (classify-slotds (wrapper-slots new-wrapper))
1565       (multiple-value-bind (old-instance-slots old-class-slots)
1566           (classify-slotds (wrapper-slots old-wrapper))
1567
1568         (flet ((set-value (value slotd)
1569                  (when safe
1570                    (assert (typep value (slot-definition-type slotd)) (value)
1571                            "~@<Error changing class. Current value in slot ~S ~
1572                             of an instance of ~S is ~S, which does not match the new ~
1573                             slot type ~S in class ~S.~:@>"
1574                            (slot-definition-name slotd) old-class value
1575                            (slot-definition-type slotd) new-class))
1576                  (setf (clos-slots-ref new-slots (slot-definition-location slotd)) value)))
1577
1578           ;; "The values of local slots specified by both the class CTO and
1579           ;; CFROM are retained. If such a local slot was unbound, it
1580           ;; remains unbound."
1581           (dolist (new new-instance-slots)
1582             (let* ((name (slot-definition-name new))
1583                    (old (find name old-instance-slots :key #'slot-definition-name)))
1584               (when old
1585                 (set-value (clos-slots-ref old-slots (slot-definition-location old))
1586                            new))))
1587
1588           ;; "The values of slots specified as shared in the class CFROM and
1589           ;; as local in the class CTO are retained."
1590           (dolist (old old-class-slots)
1591             (let* ((slot-and-val (slot-definition-location old))
1592                    (new (find (car slot-and-val) new-instance-slots
1593                               :key #'slot-definition-name)))
1594               (when new
1595                 (set-value (cdr slot-and-val) new)))))))
1596
1597     ;; Make the copy point to the old instance's storage, and make the
1598     ;; old instance point to the new storage.
1599     (%swap-wrappers-and-slots instance copy)
1600
1601     (apply #'update-instance-for-different-class copy instance initargs)
1602
1603     instance))
1604
1605 (defmethod change-class ((instance standard-object) (new-class standard-class)
1606                          &rest initargs)
1607   (with-world-lock ()
1608     (unless (class-finalized-p new-class)
1609       (finalize-inheritance new-class))
1610     (let ((cpl (class-precedence-list new-class)))
1611       (dolist (class cpl)
1612         (macrolet
1613             ((frob (class-name)
1614                `(when (eq class (find-class ',class-name))
1615                   (error 'metaobject-initialization-violation
1616                          :format-control "~@<Cannot ~S objects into ~S metaobjects.~@:>"
1617                          :format-arguments (list 'change-class ',class-name)
1618                          :references (list '(:amop :initialization ,class-name))))))
1619           (frob class)
1620           (frob generic-function)
1621           (frob method)
1622           (frob slot-definition))))
1623     (%change-class instance new-class initargs)))
1624
1625 (defmethod change-class ((instance forward-referenced-class)
1626                          (new-class standard-class) &rest initargs)
1627   (with-world-lock ()
1628     (let ((cpl (class-precedence-list new-class)))
1629       (dolist (class cpl
1630                (error 'metaobject-initialization-violation
1631                       :format-control
1632                       "~@<Cannot ~S ~S objects into non-~S objects.~@:>"
1633                       :format-arguments
1634                       (list 'change-class 'forward-referenced-class 'class)
1635                       :references
1636                       (list '(:amop :generic-function ensure-class-using-class)
1637                             '(:amop :initialization class))))
1638         (when (eq class (find-class 'class))
1639           (return nil))))
1640     (%change-class instance new-class initargs)))
1641
1642 (defmethod change-class ((instance funcallable-standard-object)
1643                          (new-class funcallable-standard-class)
1644                          &rest initargs)
1645   (with-world-lock ()
1646     (let ((cpl (class-precedence-list new-class)))
1647       (dolist (class cpl)
1648         (macrolet
1649             ((frob (class-name)
1650                `(when (eq class (find-class ',class-name))
1651                   (error 'metaobject-initialization-violation
1652                          :format-control "~@<Cannot ~S objects into ~S metaobjects.~@:>"
1653                          :format-arguments (list 'change-class ',class-name)
1654                          :references (list '(:amop :initialization ,class-name))))))
1655           (frob class)
1656           (frob generic-function)
1657           (frob method)
1658           (frob slot-definition))))
1659     (%change-class instance new-class initargs)))
1660
1661 (defmethod change-class ((instance standard-object)
1662                          (new-class funcallable-standard-class)
1663                          &rest initargs)
1664   (declare (ignore initargs))
1665   (error "You can't change the class of ~S to ~S~@
1666           because it isn't already an instance with metaclass ~S."
1667          instance new-class 'standard-class))
1668
1669 (defmethod change-class ((instance funcallable-standard-object)
1670                          (new-class standard-class)
1671                          &rest initargs)
1672   (declare (ignore initargs))
1673   (error "You can't change the class of ~S to ~S~@
1674           because it isn't already an instance with metaclass ~S."
1675          instance new-class 'funcallable-standard-class))
1676
1677 (defmethod change-class ((instance t) (new-class-name symbol) &rest initargs)
1678   (apply #'change-class instance (find-class new-class-name) initargs))
1679 \f
1680 ;;;; The metaclass BUILT-IN-CLASS
1681 ;;;;
1682 ;;;; This metaclass is something of a weird creature. By this point, all
1683 ;;;; instances of it which will exist have been created, and no instance
1684 ;;;; is ever created by calling MAKE-INSTANCE.
1685 ;;;;
1686 ;;;; But, there are other parts of the protocol we must follow and those
1687 ;;;; definitions appear here.
1688
1689 (macrolet ((def (name args control)
1690                `(defmethod ,name ,args
1691                  (declare (ignore initargs))
1692                  (error 'metaobject-initialization-violation
1693                   :format-control ,(format nil "~@<~A~@:>" control)
1694                   :format-arguments (list ',name)
1695                   :references (list '(:amop :initialization "Class"))))))
1696   (def initialize-instance ((class built-in-class) &rest initargs)
1697     "Cannot ~S an instance of BUILT-IN-CLASS.")
1698   (def reinitialize-instance ((class built-in-class) &rest initargs)
1699     "Cannot ~S an instance of BUILT-IN-CLASS."))
1700
1701 (macrolet ((def (name)
1702                `(defmethod ,name ((class built-in-class)) nil)))
1703   (def class-direct-slots)
1704   (def class-slots)
1705   (def class-direct-default-initargs)
1706   (def class-default-initargs))
1707
1708 (defmethod validate-superclass ((c class) (s built-in-class))
1709   (or (eq s *the-class-t*) (eq s *the-class-stream*)
1710       ;; FIXME: bad things happen if someone tries to mix in both
1711       ;; FILE-STREAM and STRING-STREAM (as they have the same
1712       ;; layout-depthoid).  Is there any way we can provide a useful
1713       ;; error message?  -- CSR, 2005-05-03
1714       (eq s *the-class-file-stream*) (eq s *the-class-string-stream*)
1715       ;; This probably shouldn't be mixed in with certain other
1716       ;; classes, too, but it seems to work both with STANDARD-OBJECT
1717       ;; and FUNCALLABLE-STANDARD-OBJECT
1718       (eq s *the-class-sequence*)))
1719 \f
1720 ;;; Some necessary methods for FORWARD-REFERENCED-CLASS
1721 (defmethod class-direct-slots ((class forward-referenced-class)) ())
1722 (defmethod class-direct-default-initargs ((class forward-referenced-class)) ())
1723 (macrolet ((def (method)
1724              `(defmethod ,method ((class forward-referenced-class))
1725                 (error "~@<~I~S was called on a forward referenced class:~2I~_~S~:>"
1726                        ',method class))))
1727   (def class-default-initargs)
1728   (def class-precedence-list)
1729   (def class-slots))
1730
1731 (defmethod validate-superclass ((c slot-class)
1732                                 (f forward-referenced-class))
1733   t)
1734 \f
1735 (defmethod add-dependent ((metaobject dependent-update-mixin) dependent)
1736   (pushnew dependent (plist-value metaobject 'dependents) :test #'eq))
1737
1738 (defmethod remove-dependent ((metaobject dependent-update-mixin) dependent)
1739   (setf (plist-value metaobject 'dependents)
1740         (delete dependent (plist-value metaobject 'dependents))))
1741
1742 (defmethod map-dependents ((metaobject dependent-update-mixin) function)
1743   (dolist (dependent (plist-value metaobject 'dependents))
1744     (funcall function dependent)))
1745