tests/run-tests.lisp

   1 (handler-bind (#+win32 (warning #'muffle-warning))
   2   (require :sb-posix))
   3
   4 (load "test-util.lisp")
   5
   6 (defpackage :run-tests
   7     (:use :cl :test-util :sb-ext))
   8
   9 (load "assertoid.lisp")
  10
  11 (in-package run-tests)
  12
  13 (load "colorize.lisp")
  14
  15 (defvar *all-failures* nil)
  16 (defvar *break-on-error* nil)
  17 (defvar *report-skipped-tests* nil)
  18 (defvar *explicit-test-files* nil)
  19
  20 (defun run-all ()
  21   (dolist (arg (cdr *posix-argv*))
  22     (cond ((string= arg "--break-on-failure")
  23            (setf *break-on-error* t)
  24            (setf test-util:*break-on-failure* t))
  25           ((string= arg "--break-on-expected-failure")
  26            (setf test-util:*break-on-expected-failure* t))
  27           ((string= arg "--report-skipped-tests")
  28            (setf *report-skipped-tests* t))
  29           ((string= arg "--no-color"))
  30           (t
  31            (push (truename (parse-namestring arg)) *explicit-test-files*))))
  32   (pure-runner (pure-load-files) #'load-test)
  33   (pure-runner (pure-cload-files) #'cload-test)
  34   (impure-runner (impure-load-files) #'load-test)
  35   (impure-runner (impure-cload-files) #'cload-test)
  36   #-win32 (impure-runner (sh-files) #'sh-test)
  37   (report)
  38   (sb-ext:exit :code (if (unexpected-failures)
  39                          1
  40                          104)))
  41
  42 (defun report ()
  43   (terpri)
  44   (format t "Finished running tests.~%")
  45   (let ((skipcount 0)
  46         (*print-pretty* nil))
  47     (cond (*all-failures*
  48            (format t "Status:~%")
  49            (dolist (fail (reverse *all-failures*))
  50              (cond ((eq (car fail) :unhandled-error)
  51                     (output-colored-text (car fail)
  52                                           " Unhandled Error")
  53                     (format t " ~a~%"
  54                             (enough-namestring (second fail))))
  55                    ((eq (car fail) :invalid-exit-status)
  56                     (output-colored-text (car fail)
  57                                           " Invalid exit status:")
  58                     (format t " ~a~%"
  59                             (enough-namestring (second fail))))
  60                    ((eq (car fail) :skipped-disabled)
  61                     (when *report-skipped-tests*
  62                       (format t " ~20a ~a / ~a~%"
  63                               "Skipped (irrelevant):"
  64                               (enough-namestring (second fail))
  65                               (third fail)))
  66                     (incf skipcount))
  67                    (t
  68                     (output-colored-text
  69                      (first fail)
  70                      (ecase (first fail)
  71                        (:expected-failure " Expected failure:")
  72                        (:unexpected-failure " Failure:")
  73                        (:leftover-thread " Leftover thread (broken):")
  74                        (:unexpected-success " Unexpected success:")
  75                        (:skipped-broken " Skipped (broken):")
  76                        (:skipped-disabled " Skipped (irrelevant):")))
  77                     (format t " ~a / ~a~%"
  78                             (enough-namestring (second fail))
  79                             (third fail)))))
  80            (when (> skipcount 0)
  81              (format t " (~a tests skipped for this combination of platform and features)~%"
  82                      skipcount)))
  83           (t
  84            (format t "All tests succeeded~%")))))
  85
  86 (defun pure-runner (files test-fun)
  87   (when files
  88     (format t "// Running pure tests (~a)~%" test-fun)
  89     (let ((*package* (find-package :cl-user))
  90           (*failures* nil))
  91       (setup-cl-user)
  92       (dolist (file files)
  93         (format t "// Running ~a~%" file)
  94         (restart-case
  95             (handler-bind ((error (make-error-handler file)))
  96               (eval (funcall test-fun file)))
  97           (skip-file ())))
  98       (append-failures))))
  99
 100 (defun run-in-child-sbcl (load-forms forms)
 101   ;; We used to fork() for POSIX platforms, and use this for Windows.
 102   ;; However, it seems better to use the same solution everywhere.
 103   (process-exit-code
 104    (#-win32 with-open-file #-win32 (devnull "/dev/null") #+win32 progn
 105      (sb-ext:run-program
 106       (first *POSIX-ARGV*)
 107       (append
 108        (list "--core" SB-INT:*CORE-STRING*
 109              "--noinform"
 110              "--no-sysinit"
 111              "--no-userinit"
 112              "--noprint"
 113              "--disable-debugger")
 114        (loop for form in (append load-forms forms)
 115              collect "--eval"
 116              collect (write-to-string form)))
 117       :output sb-sys:*stdout*
 118       :input #-win32 devnull #+win32 sb-sys:*stdin*))))
 119
 120 (defun run-impure-in-child-sbcl (test-file test-code)
 121   (run-in-child-sbcl
 122     `((load "test-util")
 123       (load "assertoid")
 124       (defpackage :run-tests
 125         (:use :cl :test-util :sb-ext)))
 126
 127     `((in-package :cl-user)
 128       (use-package :test-util)
 129       (use-package :assertoid)
 130       (setf test-util:*break-on-failure* ,test-util:*break-on-failure*)
 131       (setf test-util:*break-on-expected-failure*
 132             ,test-util:*break-on-expected-failure*)
 133       (let ((file ,test-file)
 134             (*break-on-error* ,run-tests::*break-on-error*))
 135         (declare (special *break-on-error*))
 136         (format t "// Running ~a~%" file)
 137         (restart-case
 138             (handler-bind
 139                 ((error (lambda (condition)
 140                           (push (list :unhandled-error file)
 141                                 test-util::*failures*)
 142                           (cond (*break-on-error*
 143                                  (test-util:really-invoke-debugger condition))
 144                                 (t
 145                                  (format *error-output* "~&Unhandled ~a: ~a~%"
 146                                          (type-of condition) condition)
 147                                  (sb-debug:print-backtrace)))
 148                           (invoke-restart 'skip-file))))
 149               ,test-code)
 150           (skip-file ()
 151             (format t ">>>~a<<<~%" test-util::*failures*)))
 152         (test-util:report-test-status)
 153         (sb-ext:exit :code 104)))))
 154
 155 (defun impure-runner (files test-fun)
 156   (when files
 157     (format t "// Running impure tests (~a)~%" test-fun)
 158     (let ((*package* (find-package :cl-user)))
 159       (setup-cl-user)
 160       (dolist (file files)
 161         (force-output)
 162         (let ((exit-code (run-impure-in-child-sbcl file
 163                                                    (funcall test-fun file))))
 164           (if (= exit-code 104)
 165               (with-open-file (stream "test-status.lisp-expr"
 166                                       :direction :input
 167                                       :if-does-not-exist :error)
 168                 (append-failures (read stream)))
 169               (push (list :invalid-exit-status file)
 170                     *all-failures*)))))))
 171
 172 (defun make-error-handler (file)
 173   (lambda (condition)
 174     (push (list :unhandled-error file) *failures*)
 175     (cond (*break-on-error*
 176            (test-util:really-invoke-debugger condition))
 177           (t
 178            (format *error-output* "~&Unhandled ~a: ~a~%"
 179                    (type-of condition) condition)
 180            (sb-debug:print-backtrace)))
 181     (invoke-restart 'skip-file)))
 182
 183 (defun append-failures (&optional (failures *failures*))
 184   (setf *all-failures* (append failures *all-failures*)))
 185
 186 (defun unexpected-failures ()
 187   (remove-if (lambda (x)
 188                (or (eq (car x) :expected-failure)
 189                    (eq (car x) :unexpected-success)
 190                    (eq (car x) :skipped-broken)
 191                    (eq (car x) :skipped-disabled)))
 192              *all-failures*))
 193
 194 (defun setup-cl-user ()
 195   (use-package :test-util)
 196   (use-package :assertoid))
 197
 198 (defun load-test (file)
 199   `(load ,file))
 200
 201 (defun cload-test (file)
 202   `(let ((compile-name (compile-file-pathname ,file)))
 203      (unwind-protect
 204           (progn
 205             (compile-file ,file)
 206             (load compile-name))
 207        (ignore-errors
 208          (delete-file compile-name)))))
 209
 210 (defun sh-test (file)
 211   ;; What? No SB-POSIX:EXECV?
 212   `(let ((process (sb-ext:run-program "/bin/sh"
 213                                       (list (native-namestring ,file))
 214                                       :output *error-output*)))
 215      (let ((*failures* nil))
 216        (test-util:report-test-status))
 217      (sb-ext:exit :code (process-exit-code process))))
 218
 219 (defun filter-test-files (wild-mask)
 220   (if *explicit-test-files*
 221       (loop for file in *explicit-test-files*
 222             when (pathname-match-p file wild-mask)
 223             collect file)
 224       (directory wild-mask)))
 225
 226 (defun pure-load-files ()
 227   (filter-test-files "*.pure.lisp"))
 228
 229 (defun pure-cload-files ()
 230   (filter-test-files "*.pure-cload.lisp"))
 231
 232 (defun impure-load-files ()
 233   (filter-test-files "*.impure.lisp"))
 234
 235 (defun impure-cload-files ()
 236   (filter-test-files "*.impure-cload.lisp"))
 237
 238 (defun sh-files ()
 239   (filter-test-files "*.test.sh"))